The System Object #0

Parent #1Owner #361Flags obsolete1, readSource hellcore/hellcore.db

Aliases: The System Object

22 verbs · 347 properties · 0 children

Verbs

Properties

Ancestry

• #1 root

  • #0 The System Object

Ancestors (nearest first): #1 root

Children: none

Call graph

Source

"...This code should only be run as a server task...";
if (callers())
return E_PERM;
endif
host = `connection_name(player) ! E_INVARG => 0';
if (!host)
"They disconnected.";
return 0;
endif
host = $string_utils:connection_hostname(host);
cens_args = args;
if (length(cens_args) >= 3)
cens_args[$] = "******";
endif
if (player in $login.intercepted_players)
cens_args = {"******"};
endif
if (typeof(h = $network:incoming_connection(player)) == OBJ)
"connected to an object";
return h;
elseif (h)
return 0;
endif
if ($login:redlisted(host))
boot_player(player);
server_log(tostr("REDLISTED: ", player, " from ", host));
return 0;
endif
if (!$login:maybe_limit_commands())
args = $login:parse_command(@args);
return $login:(args[1])(@listdelete(args, 1));
endif

if (!callers())
$last_restart_time = time();
$network:server_started();
$login:server_started();
endif

saved = {#0};
for p in (properties(#0))
v = #0.(p);
if ((typeof(v) == OBJ) && valid(v))
saved = setadd(saved, v);
endif
endfor
for o in (saved)
p = parent(o);
while (valid(p))
saved = setadd(saved, p);
p = parent(p);
endwhile
endfor
return $list_utils:sort(saved);

if (caller_perms().wizard)
pass();
if ("server_started" in verbs(this))
code = {"if (!callers())", "$last_restart_time = time(); $network:server_started(); $login:server_started(); endif"};
set_verb_code(this, "server_started", code);
endif
if ("uptime_since" in verbs(this))
delete_verb(this, "uptime_since");
endif
if ("do_command" in verbs(this))
delete_verb(this, "do_command");
endif
`delete_verb(this, "checkpoint_finished") ! E_VERBNF';
$core_history = {{$network.MOO_name, server_version(), time()}, @$core_history};
$shutdown_message = "";
$shutdown_time = 0;
$dump_interval = 3600;
$gripe_recipients = {player};
$class_registry = {{"generics", "Generic objects intended for use as the parents of new objects", {$room, $exit, $thing, $note, $letter, $container, $root_class, $player, $prog, $wiz, $generic_editor, $mail_recipient, $mail_agent}}, {"utilities", "Objects holding useful general-purpose verbs", children($generic_utils)}};
`set_verb_code(this, "user_connected", verb_code(this, "user_connected(core)")) ! ANY';
`delete_verb(this, "user_connected(core)") ! ANY';
`set_verb_code(this, "user_reconnected", verb_code(this, "user_reconnected(core)")) ! ANY';
`delete_verb(this, "user_reconnected(core)") ! ANY';
for v in ({"do_login_command", "server_started"})
c = {};
for i in (verb_code(this, v))
c = {@c, strsub(i, "$local.login", "$login")};
endfor
set_verb_code(#0, v, c);
endfor
endif

"Copied from The System Object (#0):user_connected by Slartibartfast (#4242) Sun May 21 18:14:16 1995 PDT";
if (callers())
return;
endif
user = args[1];
try
$mcp:(verb)(user);
except e (ANY)
$rpg:report_error(e);
endtry
try
$rpg.connected_players = setadd($rpg.connected_players, user);
except e (ANY)
$rpg:report_error(e);
endtry
set_task_perms(user);
try
user.location:confunc(user);
user:confunc();
except e (ANY)
$rpg:report_error(e, "confunc");
endtry

if (callers())
return;
endif
if ((user = args[1]) < #0)
"not logged in user.  probably should do something clever here involving Carrot's no-spam hack.  --yduJ";
return;
endif
user.last_disconnect_time = time();
try
$mcp:(verb)(user);
except e (ANY)
$rpg:report_error(e);
endtry
try
$rpg.connected_players = setremove($rpg.connected_players, user);
except e (ANY)
$rpg:report_error(e);
endtry
set_task_perms(user);
where = user.location;
try
user:disfunc();
user.location:disfunc(user);
if (user.location != where)
where:disfunc(user);
endif
except e (ANY)
$rpg:report_error(e, {tostr("disfunc on ", $su:nn(user)), tostr("disconnected at ", $su:nn(where), " -- now at ", $su:nn(user.location))});
endtry

"chparent(object, new-parent) -- see help on the builtin.";
if (caller == #63)
return chparent(@args);
endif
who = caller_perms();
{what, papa} = args;
old_parent = parent(what);
if (typeof(what) != OBJ)
retval = E_TYPE;
elseif (!valid(what))
retval = E_INVARG;
elseif (typeof(papa) != OBJ)
retval = E_TYPE;
elseif ((!valid(papa)) && (papa != #-1))
retval = E_INVIND;
elseif (!$perm_utils:controls(who, what))
retval = E_PERM;
elseif ((is_player(what) && (!is_a(papa, $player_class))) && (!who.wizard))
retval = E_PERM;
elseif ((is_player(what) && (!is_a(what, $player_class))) && (!who.wizard))
retval = E_PERM;
elseif ((children(what) && is_a(what, $player_class)) && (!is_a(papa, $player_class)))
retval = E_PERM;
elseif ((!valid(papa)) || ($perm_utils:controls(who, papa) || papa.f))
retval = `chparent(@args) ! ANY';
else
retval = E_PERM;
endif
if (typeof(retval) != ERR)
try
$sst:watch_tell("-", `what.name ! ANY => ""', old_parent, what.location);
$sst:watch_tell("+", `what.name ! ANY => ""', papa, what.location);
except e (ANY)
endtry
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

"add_verb() -- see help on the builtin for more information. This verb is called by the server when $server_options.protect_add_verb exists and is true and caller_perms() are not wizardly.";
who = caller_perms();
{what, info, verbargs} = args;
if (typeof(what) != OBJ)
retval = E_TYPE;
elseif (!valid(what))
retval = E_INVARG;
elseif ((!$perm_utils:controls(who, what)) && (!what.w))
"caller_perms() is not allowed to hack on the object in question";
retval = E_PERM;
elseif (!$perm_utils:controls(who, info[1]))
"caller_perms() is not permitted to add a verb with the specified owner.";
retval = E_PERM;
elseif (index(info[2], "w") && (!$server_options.permit_writable_verbs))
retval = E_INVARG;
elseif (!$quota_utils:verb_addition_permitted(who))
retval = E_QUOTA;
elseif (((what.owner != who) && (!who.wizard)) && (!$quota_utils:verb_addition_permitted(what.owner)))
retval = E_QUOTA;
elseif (!who.programmer)
retval = E_PERM;
else
"we now know that the caller's perms control the object or the object is writable, and we know that the caller's perms control the prospective verb owner (by more traditional means)";
retval = `add_verb(@args) ! ANY';
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

"add_property() -- see help on the builtin for more information. This verb is called by the server when $server_options.protect_add_property exists and is true and caller_perms() are not wizardly.";
who = caller_perms();
{what, propname, value, info} = args;
if (typeof(what) != OBJ)
retval = E_TYPE;
elseif (!valid(what))
retval = E_INVARG;
elseif ((!$perm_utils:controls(who, what)) && (!what.w))
retval = E_PERM;
elseif (!$perm_utils:controls(who, info[1]))
retval = E_PERM;
elseif (!$quota_utils:property_addition_permitted(who))
retval = E_QUOTA;
elseif (((what.owner != who) && (!who.wizard)) && (!$quota_utils:property_addition_permitted(what.owner)))
retval = E_QUOTA;
"elseif (!who.programmer)";
"  return E_PERM;     I wanted to do this, but $builder:@newmessage relies upon nonprogs being able to call add_property.  --Nosredna";
elseif ((propname in {"object_size", "size_quota", "queued_task_limit"}) && (!who.wizard))
retval = E_PERM;
else
"we now know that the caller's perms control the object (or the object is writable), and that the caller's perms are permitted to control the new property's owner.";
retval = `add_property(@args) ! ANY';
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

"recycle(object) -- see help on the builtin. This verb is called by the server when $server_options.protect_recycle exists and is true and caller_perms() are not wizardly.";
if (!valid(what = args[1]))
retval = E_INVARG;
elseif (!$perm_utils:controls(who = caller_perms(), what))
retval = E_PERM;
elseif ((p = is_player(what)) && (!who.wizard))
for p in ($wiz_utils:connected_wizards_unadvertised())
p:tell($string_utils:pronoun_sub("%N (%#) is currently trying to recycle %t (%[#t])", who, what));
endfor
retval = E_PERM;
else
if (p)
$wiz_utils:unset_player(what);
endif
retval = `recycle(what) ! ANY';
if (typeof(retval) != ERR)
"$recycler:kill_all_tasks(what);";
endif
endif
"return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval";
return retval;

if (callers())
return;
endif
user = args[1];
try
$mcp:(verb)(user);
except e (ANY)
$rpg:report_error(e);
endtry
if (is_a(user, $guest))
"from $guest:boot";
oldloc = user.location;
move(user, $nothing);
"..force enterfunc to be called so that the newbie gets a room description.";
move(user, user.home);
user:do_reset();
if ($object_utils:isa(oldloc, $room))
oldloc:announce("In the distance you hear someone's alarm clock going off.");
if (oldloc != user.location)
oldloc:announce(user.name, " wavers and vanishes into insubstantial mist.");
else
oldloc:announce(user.name, " undergoes a wrenching personality shift.");
endif
endif
set_task_perms(user);
`user:confunc() ! ANY';
endif

"set_verb_info() -- see help on the builtin for more information. This verb is called by the server when $server_options.protect_set_verb_info exists and is true and caller_perms() are not wizardly.";
{o, v, i} = args;
if (typeof(vi = `verb_info(o, v) ! ANY') == ERR)
"probably verb doesn't exist";
retval = vi;
elseif (!$perm_utils:controls(cp = caller_perms(), vi[1]))
"perms don't control the current verb owner";
retval = E_PERM;
elseif ((typeof(i) != LIST) || (typeof(no = i[1]) != OBJ))
"info is malformed";
retval = E_TYPE;
elseif (!valid(no))
"invalid new verb owner";
retval = E_INVARG;
elseif (!$perm_utils:controls(cp, no))
"perms don't control prospective verb owner";
retval = E_PERM;
elseif (index(i[2], "w") && (!`$server_options.permit_writable_verbs ! E_PROPNF, E_INVIND => 1'))
retval = E_INVARG;
else
retval = `set_verb_info(o, v, i) ! ANY';
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

m = `match(@args) ! ANY';
return ((typeof(m) == ERR) && $code_utils:dflag_on()) ? raise(m) | m;
if ((length(args[1]) > 256) && index(args[2], "*"))
return E_INVARG;
else
return match(@args);
endif

r = `rmatch(@args) ! ANY';
return ((typeof(r) == ERR) && $code_utils:dflag_on()) ? raise(r) | r;
if ((length(args[1]) > 256) && index(args[2], "*"))
return E_INVARG;
else
return rmatch(@args);
endif

try
return $mcp:do_out_of_band_command(@args);
except e (ANY)
$rpg:report_error(e, {}, $nets.mcpnet);
endtry

{code, msg, value, stack, plaintb} = args;
return $rpg:handle_aborted_task(player, msg, stack);
if (!callers())
{code, msg, value, stack, traceback} = args;
"now let the player do something with it if e wants...";
return `player:(verb)(@args) ! ANY';
endif

"Copied from Jay (#3920):bf_force_input Mon Jun 16 20:55:27 1997 PDT";
"force_input(conn, line [, at-front])";
"see help on the builtin for more information. This verb is called by the server when $server_options.protect_force_input exists and is true and caller_perms() are not wizardly.";
{conn, line, ?at_front = 0} = args;
if (caller_perms() != conn)
retval = E_PERM;
elseif (conn in $login.newted)
retval = E_PERM;
else
retval = `force_input(@args) ! ANY';
this.force_input_count = this.force_input_count + 1;
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

"Let's keep bozos from partying.  --Nosredna the partypooper";
return pass(#-1);

who = caller_perms();
retval = 0;
try
{what, propname, info} = args;
except (E_ARGS)
retval = E_ARGS;
endtry
try
{owner, perms, ?newname = 0} = info;
except (E_ARGS)
retval = E_ARGS;
except (E_TYPE)
retval = E_TYPE;
endtry
if (retval != 0)
elseif ((newname in {"object_size", "size_quota", "queued_task_limit"}) && (!who.wizard))
retval = E_PERM;
else
set_task_perms(who);
retval = `set_property_info(@args) ! ANY';
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

this.checkpoint_in_progress = 1;
$sysnet:announce(#0, ctime() + " Database checkpoint started.", 1);

{resource, stack, plaintb} = args;
msg = "Task ran out of " + resource;
return $rpg:handle_aborted_task(player, msg, stack);

r = occupants(@args);
if (r == 0)
return {};
endif
return r;