explosion #247

Parent #1Owner #361Flags readSource hellcore/hellcore.db

Aliases: explosion

5 verbs · 15 properties · 0 children

Verbs

Properties

Ancestry

• #1 root

  • #247 explosion

Ancestors (nearest first): #1 root

Children: none

Call graph

Source

":at(where, damage, source, explode_msg, noise_msg, noise_volume, blast_decal, max_depth, blast_info_callback) => Make a big boom.";
{where, ?damage = this.damage, ?source = #-1, ?explode_msg = this.explode_msg, ?noise_msg = this.noise_msg, ?noise_volume = this.noise_volume, ?blast_decal = this.blast_decal, ?max_depth = 0, ?blast_info_callback = {}} = args;
from_flyer = is_a(where:area(), #20103);
if (is_a(where, $room) || is_a(where, $creature))
room = where:room();
if (explode_msg)
room:announce_all("");
room:announce_all(explode_msg);
room:announce_all("");
endif
room:broadcast_noise(noise_msg, noise_volume + max_depth);
this:visit_room(room, damage, source, blast_decal, max_depth, blast_info_callback, {});
if (from_flyer)
if (valid(plane = where:area().flyer))
this:visit_flyer(plane, damage);
endif
endif
elseif (is_a(where, $container))
for d in (damage)
x = 2 + (!where.open);
amount = (d[2] * x) + random((d[3] * x) - (d[2] * x));
where:take_damage(d[1], amount);
endfor
for what in (where.contents)
for d in (damage)
`what:take_damage(d[1], d[2] + random(d[3] - d[2])) ! E_VERBNF => 0';
endfor
endfor
if (where.health < 1)
where.location:announce_all($su:ps("%DN ruptures from an internal explosion!", where));
this:at(where.location, damage, source, explode_msg, noise_msg, noise_volume, blast_decal, max_depth, blast_info_callback);
elseif (where.open)
where.location:announce_all($su:ps("An explosion escapes the open %n.", where));
reduced_damage = {};
for d in (damage)
reduced_damage = {{d[1], d[2] / 2, d[3] / 2}, @reduced_damage};
endfor
this:at(where.location, reduced_damage, source, explode_msg, noise_msg, noise_volume, blast_decal, max_depth, blast_info_callback);
else
if (is_a(where.location, $creature))
where.location:tell($su:ps("A muffled explosion can be heard from your %t.", where.location, where));
where:room():announce_all_but({where.location}, $su:ps("A muffled explosion can be heard from %dn's %t.", where.location, where));
else
where.location:announce_all($su:ps("A muffled explosion can be heard from %dn.", where));
endif
endif
endif

"Copied from grenade (#1573):affect_creature by Gilmore (#98) Sun Jan 11 07:49:57 2009 CST";
{who, where, damage, source, blast_info_callback} = args;
{callback_obj, callback_verb, @callback_data} = blast_info_callback || {#-1, 0, 0};
if (!who:grenade_can_affect(source, where))
return;
endif
if (is_a(source, $player))
if (is_a(source, $player) && is_a(who, $player))
who:_pvp_record({source}, this.name);
endif
if (((!is_a(who, $player)) && (who.location != source.location)) && (source.location == #44969.location))
#44969:add_win(source);
endif
endif
{mod, amount_multiplier} = valid(callback_obj) ? callback_obj:(callback_verb)(who, @callback_data) | {-3, 1.0};
if (is_a(where, $outdoor_room))
mod = mod + 3;
endif
if (is_a(where, $room) && (who in where.covering))
mod = mod + 3;
endif
mod = max($skills.dodge:check(who, mod), 0);
if (mod > 0)
who:tell("You manage to shield yourself from some of the blast...");
endif
blown = 0;
oldlocation = who.location;
for d in (damage)
amount = d[2] + (((d[3] - d[2]) > 0) ? random(d[3] - d[2]) | 0);
amount = toint(tofloat(amount) * amount_multiplier);
if ((mod > 0) && (!(d[1] in {#308, #1326})))
amount = amount - min(amount / 2, random(max(1, mod)));
endif
oldhealth = who.health;
who:take_damage(d[1], amount, $bodypart, source);
if ((((oldhealth || is_a(who, $corpse)) && (!blown)) && (random(100) <= (toint((tofloat(amount) / tofloat(who.health_max)) * 100.0) - (who.health_max / 5)))) && (d[1] in {$damages.explode, $damages.laser, $damages.bullets}))
check = #113:check(who, -5, 1);
if ((check <= 0) && (who.movable_by_explosion == 1))
if (is_a(who.location, $room) && who.location.exits)
direction = who.location.exits[random($)];
location = direction.otherside.location;
if (is_a(direction, $door) && (direction.open == 0))
return;
elseif (is_a(direction, #18385))
return;
elseif (direction.passable == 0)
return;
elseif (!valid(location))
return;
endif
blown = 1;
fork (0)
if (who.location == oldlocation)
who:tell("You are blown ", direction.name, " by the explosion!");
who.location:announce_all_but({who}, who:name(), " is blown ", direction.name, " by the explosion!");
location:announce_all(who:name(), " comes sailing in.");
who:moveto(location);
location:fall_into(who, who.location, max(3, amount / 5));
endif
endfork
endif
endif
endif
endfor

":visit_room(room, damage, source, blast_decal, max_depth, blast_info_callback, already_visited) => Make a big boom.";
{room, damage, source, blast_decal, max_depth, blast_info_callback, already_visited} = args;
if (valid(source))
room:broadcast_event(1, this, source, {$citizen});
endif
if (valid(blast_decal))
blast_decal:add_to(room);
endif
for x in ({@room:occupants($creature), @room:occupants($thing)})
if (is_a(x, $living))
this:affect_creature(x, room, damage, source, blast_info_callback);
else
this:affect_thing(x, room, damage, source, blast_info_callback);
endif
$cu:sin(0);
endfor
if ((!already_visited) && is_a(room, #1047))
max_depth = max_depth + 1;
if (d = $lu:assoc($damages.explode, damage))
damage = {d};
else
"Just make up some ad hoc damage... we don't have a general notion of 'strength' wrt explosives.";
damage = {{$damages.explode, 5, 15}};
endif
endif
already_visited = setadd(already_visited, room);
if (max_depth)
for exit in (room:occupants($exit))
if ((((((!is_a(exit, $door)) || exit.open) && exit.next_hop_ok) && valid(exit.otherside)) && is_a(exit.otherside.location, $room)) && (!(exit.otherside.location in already_visited)))
exit.otherside.location:announce_all(((($ansi.red + "OH HOLY FUCK, a sudden explosive surge hits you from ") + exit.otherside:dname()) + "!") + $ansi.reset);
already_visited = this:visit_room(exit.otherside.location, damage, source, blast_decal, max_depth - 1, blast_info_callback, already_visited);
endif
endfor
endif
return already_visited;

"Copied from grenade (#1573):affect_creature by Gilmore (#98) Sun Jan 11 07:49:57 2009 CST";
{what, where, damage, source, blast_info_callback} = args;
if ($ou:has_verb(what, "take_damage"))
amount_multiplier = 0.4;
for d in (damage)
if ($rpg:valid(what))
amount = d[2] + (((d[3] - d[2]) > 0) ? random(d[3] - d[2]) | 0);
amount = toint(tofloat(amount) * amount_multiplier);
what:take_damage(d[1], amount, $bodypart, source);
endif
endfor
endif

{flyer, damage, ?source = #-1} = args;
for d in (damage)
x = tofloat(flyer.size) / tofloat($flyer.size);
x = max(1.0, x);
dm = {tofloat(d[2]), tofloat(d[3])};
amount = toint(dm[1] / x) + `random(toint(dm[2] / x)) - toint(dm[1] / x) ! E_INVARG => 0';
flyer:take_damage(d[1], amount, source);
endfor