generic container #54

weight

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

• #54:acceptable line 11: this:weight
• #147:weight line 4: pass(

Source

if (this.weight < 0)
return -1;
endif
weight = 0;
for x in (this.contents)
weight = weight + toint(`x:weight() ! ANY => 0 && $nets.prognet:announce(player, "broken :weight for " + $su:nn(x), 1)');
$cu:sin(0);
endfor
return toint(tofloat(weight) * this.weight_reduction) + this.weight;

acceptable

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

what = args[1];
if (is_a(what, $lock))
return 1;
endif
if ((is_a(what, $container) && (this.weight > 0)) && (this.weight < 50000))
return 0;
endif
if (length(this.contents) > 250)
return 0;
endif
return ((this:weight() - this.weight) + what:weight()) < this.capacity;

look_self

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

• #54:peek line 7: this:look_self
• #146:look_self line 1: pass(
• #367:look_self line 1: pass(

Source

pass(@args);
if (this.open || (!this.opaque))
if (this:tell_contents() == 0)
"    player:tell($su:ps(this.empty_msg));";
endif
endif
$lu:map_verb(occupants(this, $decal), "tell_person", this);

open

Spec this none noneFlags rxdOwner #361Definer #54

Referenced by

• #105:open line 2: pass(
• #366:open line 1: pass(
• #367:open line 5: pass(

Source

if (this:locked())
player:aat($su:ps(this.open_fail_msg, player, this, this));
elseif (this.open)
player:tell(this:dnamec(), " is already open.");
else
this.open = 1;
if (this.location == player)
player:client_tell("#$#inventory");
player:client_tell("open #", toint(this));
player:client_tell("#$#/inventory");
endif
player:aat($su:ps(this.open_msg, player, this, this));
endif

locked

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

• #54:open line 1: this:locked
• #54:peek line 2: this:locked

Source

return 0;

close

Spec this none noneFlags rxdOwner #361Definer #54

Referenced by

• #367:close line 1: pass(

Source

if (!this.closable)
player:tell("You can't close ", this:dname(), ".");
elseif (!this.open)
player:tell(this:dnamec(), " is already closed.");
else
if (this.location == player)
player:client_tell("#$#inventory");
player:client_tell("close #", toint(this));
player:client_tell("#$#/inventory");
endif
this.open = 0;
player:aat($su:ps(this.close_msg, player, this, this));
endif

tell_appraise

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

roll = args[1];
pass(@args);
if (roll > 0)
player:tell("It can hold about ", this.capacity / 1000, "kg.");
wr = 1.0 - this.weight_reduction;
wr = toint(wr * 10.0);
player:tell("It seems ", {"barely", "somewhat", "quite", "very", "extremely"}[min(5, max(1, wr))], " efficient for carrying heavy loads.");
endif
if (roll > 1)
val = this:contents_value();
if (val > 0)
var = max(1, val / (3 + roll));
val = val + (random(var) - (var / 2));
val = max(1, val);
if (val > 1000)
val = (val / 100) * 100;
elseif (val > 100)
val = (val / 10) * 10;
endif
player:tell(("You think its contents might fetch about $" + tostr(val)) + " on the market.");
endif
endif

description

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

• #147:look_self line 1: this:description

Source

d = (typeof(d = pass(@args)) == LIST) ? d | {d};
if ((!this.open) && this.closed_msg)
d[$] = (d[$] + " ") + $su:ps(this.closed_msg, this, this);
endif
return d;

tell_contents_backup

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

"Copied from generic container (#931):tell_contents by Gilmore (#98) Fri Apr  2 01:51:47 2004 PST";
if (this.open || (!this.opaque))
if (this.dark || (!this.contents))
if (m = this.empty_msg)
player:tell($su:ps(this.empty_msg, player, this, this));
endif
else
contents = $su:english_list($lu:map_verb(this.contents, "iname"));
player:tell($su:ps(strsub(this.contents_msg, "%t", contents), player, this, this));
endif
endif

broadcast_noise broadcast_sound

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

":broadcast_noise(STR noise-message, INT volume[, INT noiseid, OBJ sourceexit])";
msg = args[1];
volume = args[2];
sourceexit = (length(args) > 3) ? args[4] | #-1;
noiseid = (length(args) > 2) ? args[3] | random(9999999);
volume = min(volume, 7);
volume = max(volume, -4);
sd = {"faint", "faint", "faint", "distant", "muffled", "muffled", "loud", "loud", "loud", "deafening", "deafening", "deafening"}[volume + 5];
if (is_a(this.location, $room))
this.location:broadcast_noise(msg, volume, noiseid, this);
endif

get_from

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

who = args[1];
targets = (typeof(args[2]) == LIST) ? $lu:randomly_permute(args[2]) | {args[2]};
if (this.open)
who:queue_action($actions.get, {targets, this, {}}, 1, "get from " + this.name);
else
return E_INVARG;
endif

put_into

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

who = args[1];
targets = (typeof(args[2]) == LIST) ? $lu:randomly_permute(args[2]) | {args[2]};
if (this.open)
who:queue_action($actions.put, {targets, this, {}}, 1, "put into " + this.name);
else
return E_INVARG;
endif

cant_get_from

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

getter = args[1];
targets = args[2];
if (typeof(targets) != LIST)
targets = {targets};
endif
if (!this.contents)
return this:dname() + " is empty";
elseif (!this.open)
return this:dname() + " isn't open";
endif
for x in (targets)
if (!(x in this.contents))
targets = setremove(targets, x);
endif
endfor
if (!targets)
return "that's not in " + this:dname();
endif
return 0;

exitfunc

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

• #178:exitfunc line 26: pass(

Source

what = args[1];
location = this;
while (valid(location))
location = location.location;
if (is_a(location, $player) && location.client)
location:client_tell("#$#inventory");
$client:tell_inv_rm(location, what);
location:client_tell("#$#/inventory");
break;
endif
endwhile

enterfunc

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

what = args[1];
location = this;
while (valid(location))
location = location.location;
if (is_a(location, $player) && location.client)
location:client_tell("#$#inventory");
$client:tell_inv_add(location, what);
location:client_tell("#$#/inventory");
break;
endif
endwhile

match_backup

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

return $match_utils:match(args[1], this:contents());

tell_contents

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

• #54:look_self line 3: this:tell_contents
• #54:peek line 11: this:tell_contents
• #147:look_self line 7: this:tell_contents

Source

{?c = this.contents} = args;
names = {@$iu:pluralsc(), "Misc"};
show_nonthings = 0;
if (is_a(player, $prog))
names = {@names, "Non-things"};
show_nonthings = 1;
nonthings = {};
endif
things = {};
count = 0;
for x in (c)
if (!is_a(x, $thing))
if (show_nonthings && (!is_a(x, $decal)))
nonthings = {@nonthings, x};
count = count + 1;
endif
else
things = {@things, x};
count = count + 1;
endif
endfor
buckets = $iu:group_by_type(things);
if (show_nonthings)
buckets = {@buckets, nonthings};
endif
for x in [1..length(buckets)]
if (buckets[x])
player:tell($ansi.bold_on, names[x], ":", $ansi.reset);
this:tell_contents_sub(buckets[x]);
endif
endfor
return count;

tell_contents_sub

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

• #54:tell_contents line 29: this:tell_contents_sub
• #146:tell_contents line 40: this:tell_contents_sub

Source

"Copied from generic container (#931):tell_contents by Satan (#2) Sat Jul 22 18:45:06 2006 PDT";
"Copied from generic player (#6):tell_contents by Satan (#2) Sat Jul 22 18:39:37 2006 PDT";
msg_db = {};
names = {};
if (args)
things = args[1];
else
things = this:contents();
endif
for x in (things)
if (is_a(x, $decal))
things = setremove(things, x);
endif
endfor
weights = player:check_pref("weights");
if (#594466 in $lu:slice(callers(), 1))
weights = 0;
endif
total_weight = 0;
if (things)
for x in (things)
yield 1;
added = 0;
if (list_name = `x:list_name() ! ANY => 0')
iname = list_name;
else
iname = x:iname();
endif
if (weights)
iname = ((((iname + $ansi.cyan) + " [") + $su:english_weight_short(weight = x:weight())) + "]") + $ansi.reset;
total_weight = total_weight + weight;
endif
if (msg_db)
for y in [1..length(msg_db)]
if (msg_db[y][2] == iname)
msg_db[y][3] = msg_db[y][3] + 1;
msg_db[y][1] = setadd(msg_db[y][1], x);
added = 1;
endif
endfor
endif
if (!added)
msg_db = setadd(msg_db, {{x}, iname, 1});
endif
endfor
for x in (msg_db)
if (x[3] > 1)
name = ($string_utils:aggregate_number(x[3]) + " ") + x[1][1]:plural_name();
if (weights)
wt = 0;
for z in (x[1])
wt = wt + z:weight();
endfor
name = ((((name + $ansi.cyan) + " [") + $su:english_weight_short(wt)) + "]") + $ansi.reset;
endif
else
name = x[2];
endif
names = {@names, name};
endfor
player:tell_item_list(names);
endif

contents_value

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

• #54:tell_appraise line 10: this:contents_value

Source

"Copied from generic container (#931):weight by Gilmore (#98) Sun Aug 13 21:08:11 2006 PDT";
val = 0;
for x in (this.contents)
if (is_a(x, $thing))
val = val + x:value();
endif
endfor
return val;

can_glob

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

if (this.contents)
return 0;
endif
return pass(@args);

cant_put_into

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

what = args[1];
who = args[2];
if (!this.open)
return "it's closed";
elseif (length(this.contents) >= this.max_objects)
return "it's full";
elseif (this.health <= 0)
return "it's far too broken";
elseif (what == this)
return "that's just crazy";
endif

clean

Spec any out of/from inside/from thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

"Clean dirt or grime from the container.";
decals = args[1];
thing = $match_utils:match(decals, this.contents);
if (!valid(thing))
player:tell("There isn't any of that in ", this:dname(), ".");
return;
elseif (!is_a(thing, $decal))
player:tell("The ", thing.name, " isn't dirt or grime. It's possible that the ", this.name, " is clean.");
return;
else
player:tell($su:ps(this.clean_start_msg, player, thing, this));
player.location:announce($su:ps(this.oclean_start_msg, player, thing, this));
suspend(4);
player:tell($su:ps(this.clean_finish_msg, player, thing, this));
player.location:announce($su:ps(this.oclean_finish_msg, player, thing, this));
r = random(4);
if (r == 4)
suspend(2);
player:tell("Ugh. You got some ", thing.name, " on yourself!");
thing:moveto(player);
else
$rpg:junk(thing);
endif
endif

match_contents

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

s = args[1];
return $mu:match(s, this.contents);

make_noise

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

":broadcast_noise(OBJ noise, OBJ source[, LIST params, INT volume, INT noiseid, OBJ sourceexit])";
this:room():make_noise(@args);

count

Spec any in/inside/into thisFlags rxdOwner #29Definer #54

Referenced by

none

Source

"Copied from stuffzzzzzzz (#487387):count by Mada (#299353) Mon Mar  1 21:21:11 2010 CST";
if ((!this.open) && this.opaque)
player:tell("It's not open.");
return;
endif
matches = {};
for candidate in ({@this.contents})
if (((((valid(match = $mu:match(dobjstr, {candidate})) && match:name()) && (!`match:is_hidden(player) ! E_VERBNF => 0')) && (!is_a(match, $exit))) && (match != player)) && (!is_a(match, $decal)))
matches = {@matches, match};
endif
endfor
cats = $lu:remove_duplicates($lu:map_verb(matches, "name"));
can_glob = is_a(this, #216254);
forstr = {};
for cat in (cats)
howmany = 0;
for candidate in (matches)
if (candidate:name() == cat)
globcheck = can_glob && is_a(candidate, $glob);
if (!howmany)
if (globcheck)
generic = candidate.item;
else
parent = parent(candidate);
generic = (parent:name() == candidate:name()) ? parent | candidate;
endif
endif
howmany = howmany + (globcheck ? candidate.amount | 1);
endif
yield;
endfor
if ((howmany == 1) && `generic.long_name_msg ! E_PROPNF => ""')
cat = generic.long_name_msg;
endif
if (is_a(generic, $player) || (!howmany))
pref = "";
else
pref = $su:english_number(howmany) + " ";
endif
forstr = {@forstr, pref + ((howmany > 1) ? generic:plural_name() | cat)};
endfor
locstr = (this.location == player) ? "your" | "the";
if (!forstr)
player:tell("You don't see any '", dobjstr, "' in ", this:dname(), " to count.");
return;
elseif (length(forstr) > 1)
forstr[$] = "and " + forstr[$];
endif
thelist = (length(forstr) == 2) ? (forstr[1] + " ") + forstr[2] | $su:from_list(forstr, ", ");
player:tell("Searching for \"", dobjstr, "\" in ", locstr, " ", this:name(), " you find ", thelist, ".");

_break

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

• #146:_break line 1: pass(

Source

if (this.spill_on_break)
room_left = (`this.location.max_objects ! E_PROPNF => 100000' - length(this.location:occupants(#1))) + this.junk_on_break;
occupants = this:occupants(#1);
if (length(occupants) > room_left)
excess = occupants[max(0, room_left) + 1..$];
else
excess = {};
endif
if (is_a(this.location, $creature))
dest = this:room();
else
dest = this.location;
endif
if (room_left && occupants)
for what in (occupants[1..min(room_left, length(occupants))])
what:moveto(dest);
endfor
endif
if (this.junk_on_break)
for what in (excess)
what:moveto(dest);
endfor
fork (0)
for what in (excess)
if (is_a(what, #1))
$rpg:junk(what);
endif
endfor
endfork
endif
endif
pass(@args);

peek

Spec this none noneFlags rxdOwner #361Definer #54

Referenced by

none

Source

"Peek inside without bothering to open it.";
if (this:locked())
player:tell("It's locked, you can't just peek in!");
return;
endif
if (this.open)
this:look_self();
return;
else
player.location:announce_all($su:ps(this.peek_msg, player, this));
this:tell_contents();
if (!this.contents)
player:tell("Huh. It's empty.");
endif
endif

old_count this none this

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

"Copied from generic container (#931):count by MARViN (#241405) Mon Mar  1 21:20:43 2010 CST";
if (!this.open)
player:tell("It's not open.");
return;
endif
target = $match_utils:match(dobjstr, this.contents);
if ((!$recycler:valid(target)) || is_a(target, $decal))
player:tell("You don't see any '", dobjstr, "' in ", this:dname(), " to count.");
return;
endif
if (is_a(target, $glob))
parent = target.item;
else
parent = parent(target);
endif
howmany = length(this:occupants(parent));
player:tell("You count ", $su:english_number(howmany), " ", (howmany > 1) ? parent:plural_name() | parent.name, ".");

set_plural_name

Spec this none thisFlags rxdOwner #361Definer #54

Referenced by

none

Source

"Copied from generic container (#931):set_name by Satan (#2) Tue May 25 14:41:49 2010 CDT";
"Copied from door (#170):set_name by Satan (#2) Sat Aug 19 12:00:14 2006 PDT";
"set_name(newname) attempts to change this.name to newname";
"  => E_PERM   if you don't own this or aren't its parent, or are a player trying to do an end-run around $player_db...";
return (typeof(e = `this.plural_name = args[1] ! ANY') != ERR) || e;