generic outdoor room #257

description

Spec this none thisFlags rxdOwner #361Definer #257

Referenced by

none

Source

d = pass(@args);
if (this.landmark_msg)
d = {@d, this.landmark_msg};
endif
return d;

_room_map

Spec this none thisFlags rxdOwner #361Definer #257

Referenced by

• #257:_render_map line 64: this:_room_map

Source

"$room:_room_map([width][, height])";
if (!this.outdoor)
return pass(@args);
endif
area = this:area();
if (is_a(this, #142063) && is_a(this:area().flyer, $flyer))
area = this:area().flyer:area();
endif
if (is_a(area.bigmap, $bigmap))
ground = area.bigmap.underground_z;
else
ground = `area.underground_z ! E_PROPNF => 0';
endif
width = (length(args) > 0) ? args[1] | 5;
height = (length(args) > 1) ? args[2] | 5;
if ((width % 2) == 0)
width = width + 1;
endif
if ((height % 2) == 0)
height = height + 1;
endif
map = this:_blank_map(#-1, width, height);
midx = width / 2;
midy = height / 2;
minx = this.x - midx;
miny = this.y - midy;
maxx = this.x + midx;
maxy = this.y + midy;
map[1 + midy][1 + midx] = this;
if (is_a(area.bigmap, $bigmap))
rooms = area.bigmap.z_sorted_rooms;
else
rooms = area.z_sorted_rooms;
endif
do_rush = player.programmer ? 0 | 1;
for room in (rooms)
yield do_rush ? 0 | 3;
if (!is_a(room, $room))
continue;
elseif (room == this)
continue;
elseif ((room.z < this.z) || (room.z > ground))
continue;
elseif ((room.x > maxx) || (room.x < minx))
continue;
elseif ((room.y > maxy) || (room.y < miny))
continue;
endif
map[1 + ((room.y - this.y) + midy)][1 + ((room.x - this.x) + midx)] = room;
endfor
return map;

_render_map

Spec this none thisFlags rxdOwner #29Definer #257

Referenced by

none

Source

if (this.outdoor == 0)
return pass(@args);
endif
{?width = 5, ?height = 5, ?icon_verb = "_icon", ?blank_icon = 0, ?include_position = 1, ?include_links = 1} = args;
do_rush = player.programmer ? 0 | 1;
if ((width % 2) == 0)
width = width + 1;
endif
if ((height % 2) == 0)
height = height + 1;
endif
midx = width / 2;
midy = height / 2;
minx = this.x - midx;
miny = this.y - midy;
maxx = this.x + midx;
maxy = this.y + midy;
area = this:area();
if (is_a(this, #142063) && is_a(this:area().flyer, $flyer))
area = this:area().flyer:area();
endif
if (!is_a(area.bigmap, $bigmap))
override_z = 0;
if (!blank_icon)
normal_map = this:_blank_map(area.blank_icon, width, height);
else
normal_map = this:_blank_map(blank_icon, width, height);
endif
client_map = this:_blank_map(area.client_blank_icon, width, height);
icon_blocks = area.icon_blocks;
area_links = {{area, area.area_link_icons}};
ignore_links = {};
else
override_z = 1;
if (this.z <= area.bigmap.sky_z)
normal_map = this:_blank_map(area.bigmap.sky_normal_icon, width, height);
client_map = this:_blank_map(area.bigmap.sky_client_icon, width, height);
z = -1;
elseif (this.z >= area.bigmap.underground_z)
normal_map = this:_blank_map(area.bigmap.underground_normal_icon, width, height);
client_map = this:_blank_map(area.bigmap.underground_client_icon, width, height);
z = 1;
else
normal_map = this:_blank_map(area.bigmap.blank_normal_icon, width, height);
client_map = this:_blank_map(area.bigmap.blank_client_icon, width, height);
z = this.z;
endif
if (blank_icon)
normal_map = this:_blank_map(blank_icon, width, height);
endif
icon_blocks = {};
for block in (area.bigmap.icon_block_data)
for subblock in (block)
yield do_rush ? 0 | 3;
icon_blocks = setadd(icon_blocks, subblock);
endfor
endfor
area_links = area.bigmap:area_link_icons();
ignore_links = area.bigmap.areas;
endif
if (is_a(this, #142063) && is_a(this:area().flyer, $flyer))
ignore_links = 0;
endif
room_map = this:_room_map(width, height);
for block in (icon_blocks)
yield do_rush ? 0 | 3;
if (((!override_z) && (typeof(block[1]) == INT)) && (block[1] < this.z))
continue;
elseif (((!override_z) && (typeof(block[1]) == LIST)) && (this.z < block[1][1]))
continue;
elseif ((block[2] > maxx) || (block[4] < minx))
continue;
elseif ((block[3] > maxy) || (block[5] < miny))
continue;
endif
for y in [block[3]..block[5]]
yield do_rush ? 0 | 3;
if ((y > maxy) || (y < miny))
continue;
endif
for x in [block[2]..block[4]]
yield do_rush ? 0 | 3;
if ((x > maxx) || (x < minx))
continue;
endif
normal_map[1 + (y - miny)][1 + (x - minx)] = block[6];
endfor
endfor
endfor
for y in [1..height]
for x in [1..width]
if (is_a(room_map[y][x], $room))
normal_map[y][x] = $ou:has_verb(room_map[y][x], icon_verb) ? room_map[y][x]:(icon_verb)() | room_map[y][x]:_icon();
client_map[y][x] = room_map[y][x]:_client_icon();
endif
yield do_rush ? 0 | 3;
endfor
endfor
if (typeof(ignore_links) == LIST)
for area_link in (area_links)
link_area = area_link[1];
icon_links = area_link[2];
for link in (icon_links)
yield do_rush ? 0 | 3;
if ((link[1] in ignore_links) && (area(this) != link_area))
continue;
elseif (((link[1] in ignore_links) && (area(this) == link_area)) && (!include_links))
continue;
elseif (link[4] != this.z)
continue;
elseif ((link[2] > maxx) || (link[2] < minx))
continue;
elseif ((link[3] > maxy) || (link[3] < miny))
continue;
endif
normal_map[1 + (link[3] - miny)][1 + (link[2] - minx)] = link[1].icon;
yield do_rush ? 0 | 3;
endfor
endfor
endif
if (include_position)
if (this.public)
normal_map[1 + midy][1 + midx] = ((($ansi.cyan + $ansi.bold_on) + $ansi.bg_blue) + "()") + $ansi.reset;
else
normal_map[1 + midy][1 + midx] = ((($ansi.red + $ansi.bold_on) + $ansi.bg_blue) + "()") + $ansi.reset;
endif
endif
return {normal_map, client_map};

smell

Spec none none noneFlags rxdOwner #361Definer #257

Referenced by

none

Source

"Copied from generic necropolis outdoor room (#34129):smell by Necanthrope (#142) Tue Nov  3 15:58:08 2009 CST";
silent = args ? 1 | 0;
ss = {};
for x in ({@this:occupants($gas), @this:occupants($liquid)})
if (m = x.smell_msg)
ss = setadd(ss, m);
endif
endfor
if (roomsmell = `this.smell_msg ! E_PROPNF => ""')
ss = {@ss, @$lu:as_list(roomsmell)};
endif
for x in (this.contents)
if ($ou:has_verb(x, "room_smell_msg"))
if (smell = x:room_smell_msg())
ss = {@ss, smell};
endif
elseif ($ou:has_prop(x, "room_smell_msg") && x.room_smell_msg)
ss = {@ss, x.room_smell_msg};
endif
endfor
ss_prefix = "You ";
if (is_a(this:area().weather, $weather) && ($su:msg(this:area().weather.smell_msg) != ""))
player:tell("You sniff the air...  ", $su:msg(this:area().weather.smell_msg));
ss_prefix = "Other than that, you ";
endif
if (ss)
player:tell(ss_prefix, "smell ", $su:english_list(ss), ".");
elseif (!silent)
player:tell(ss_prefix, "don't smell anything out of the ordinary.");
endif

_darkness

Spec this none thisFlags rxdOwner #361Definer #257

Referenced by

none

Source

dark = pass(@args);
if (this.outdoor && (!dark))
dark = `area(this).dark_night ! ANY => 0';
if (dark && ($time:day_segment() < 5))
dark = 0;
endif
if (dark)
moon_phase = $time:moon_phase();
"if (area(this).weather.see_through && ((moon_phase < 10) || (moon_phase > 20)))";
if ((moon_phase < 10) || (moon_phase > 20))
dark = min(1, dark);
endif
endif
endif
return dark;