generic monster #142

suggest_next_action

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (x = pass(@args))
return x;
elseif (r = this:_feed())
this.lastaction = "f";
return {r, 1};
elseif (r = this:_scavenge())
this.lastaction = "s";
return {r, 2};
elseif (r = this:_walk())
return {r, 2};
endif
if (r = this:_wander())
this.lastaction = "w";
return {r, this.wander_speed};
endif

_spawn

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (!this.f)
player:tell("Sorry; you need to run _spawn on the generic to create a child.");
return;
endif
child = this.owner:_create(this);
$cu:sin();
$wiz_utils:set_owner(child, this.owner);
child:_spawn_gender();
child:_spawn_name();
child.recycle_on_die = 1;
child:on_spawn(@args);
return child;

_spawn_gender

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

$gender_utils:set(this, this.genders[random($)]);
if (this.gender in {"male", "female"})
if ($bodyparts.groin in this.body_parts)
if (this.gender == "male")
$bodyparts.penis:add_to(this);
elseif (this.gender == "female")
$bodyparts.vagina:add_to(this);
endif
endif
if ((this.gender == "female") && ($bodyparts.chest in this.body_parts))
$bodyparts.breasts:add_to(this);
endif
endif

_spawn_name

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

"Generate a random name for this monster when spawned.";
suffix = this.("names_base_" + this.gender)[random($)];
if (typeof(suffix) == LIST)
{suffix, plural_suffix} = suffix;
else
plural_suffix = "";
endif
aliases = {suffix};
if (this.default_alias)
aliases = setadd(aliases, this.default_alias);
endif
for word in ($su:words(suffix))
aliases = setadd(aliases, word);
endfor
if (this.names_adj)
prefix = this.names_adj[random($)];
else
prefix = "";
endif
if (prefix)
combined = (prefix + " ") + suffix;
this:set_name(combined);
aliases = setadd(aliases, combined);
if (plural_suffix)
this.plural_name = (prefix + " ") + plural_suffix;
endif
else
this:set_name(suffix);
if (plural_suffix)
this.plural_name = plural_suffix;
endif
endif
this:set_aliases(aliases);

_scavenge

Spec this none thisFlags rxOwner #361Definer #142

Referenced by

• #142:suggest_next_action line 6: this:_scavenge
• #143:suggest_next_action line 5: this:_scavenge

Source

if ((this.scavenge_chance && (this.location != this.nest)) && (length(this.contents) < `this.scavenge_threshold ! E_PROPNF => 6'))
junk = {};
for x in (this.location:occupants($thing))
if ((x.weight > -1) && (x.weight < (this:max_carry() - (this:weight() - this.weight))))
if (random(100) < this.scavenge_chance)
junk = setadd(junk, x);
endif
endif
endfor
if (junk)
junk = junk[random(length(junk))];
if (!`junk.no_npc_pickup ! ANY => 0')
return {$actions.get, {{junk}, junk.location, {}}, 1, ""};
endif
endif
endif

die

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (!this:is_in_afterlife())
if (this.recycle_on_die)
if (this.f || verbs(this))
return pass(@args);
else
if (this.weapon_drop_chance && (random(100) <= this.weapon_drop_chance))
body = is_a(this.body, $body) ? this.body | this;
if (((typeof(weapon = this.unarmed_weapon) == OBJ) && weapon.f) && (!is_a(weapon, #1142)))
weapon = $rpg:spawn(weapon);
weapon:moveto(body);
elseif (typeof(weapons = this.unarmed_weapon) == LIST)
for x in (weapons)
if (!x.f)
weapons = setremove(weapons, x);
endif
endfor
if (weapons)
weapon = $rpg:spawn(weapons[random($)]);
weapon:moveto(body);
endif
endif
endif
r = pass(@args);
fork (1)
if (is_a(this, $creature))
this:clear_queue();
if (is_a(this.body, $corpse))
this.body.player = #-1;
endif
endif
endfork
return r;
endif
else
return pass(@args);
endif
endif

on_spawn

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

this.health = this.health_max;
if (this.treasure)
fork (0)
if (is_a(this, $monster))
for x in (this.treasure)
if (random(100) <= x[1])
if (valid(what = $rpg:random_treasure(@x[2..$])))
what:moveto(this);
this:got_gift(what, this);
endif
endif
endfor
endif
endfork
endif
if (this.random_homes)
this.home = this.random_homes[random(length(this.random_homes))];
this.respawn = this.home;
this.nest = this.home;
this:moveto(this.home);
endif
this:moveto(this.respawn);
pass(@args);
for x in (this.extra_aliases)
this.aliases = setadd(this.aliases, x);
endfor
if (`this.random_weapons ! ANY' && (typeof(this.random_weapons) == LIST))
this.unarmed_weapon = this.random_weapons[random($)];
endif

_wander

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

• #142:suggest_next_action line 12: this:_wander
• #143:_wander line 6: pass(

Source

if (this.executing || (is_a(this.following, $creature) && (this.following.location == this.location)))
return;
endif
next = #-1;
if ((this.hoard_in_nest && (this:encumbrance() < 0)) && valid(this.nest))
next = this.location:next_hop_to(this.nest);
elseif (this.areas && (!(area(this) in this.areas)))
next = this.location:next_hop_to(this.areas[1]);
endif
if (valid(next))
return {this.move_action, {next}, 1, ""};
else
return pass(@args);
endif

enter_room

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (`this.location.no_actions ! ANY => 0')
return;
endif
r = pass(@args);
if (this.hoard_in_nest && (this.location == this.nest))
if (this.wields_weapons)
this:wield_best();
endif
dropping = setremove(occupants(this, $thing), this:weapon());
if (dropping)
if ((!gamevalid(this.nest_container)) || (this.nest_container.location != this.location))
for x in (dropping)
this:_drop(x);
suspend(1);
endfor
else
this:queue_action($actions.drop, {dropping, this.nest_container, {}}, 1, "drop stuff");
endif
endif
endif
if (random(100) <= this.defend_sibs_chance)
for x in (this.location:occupants($creature))
if (x.fighting)
if ($ou:isa(x.fighting[1], this.species))
fork (1)
this:start_fighting(x);
endfork
return;
endif
endif
endfor
endif

hear_event_fight

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

pass(@args);
if (args[1] && this:maybe_assist(args[3], args[4][1]))
if (!(args[3] in this.fighting))
this:start_fighting(args[3]);
endif
endif

is_legal_wander_exit

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

• #142:_track line 6: this:is_legal_wander_exit

Source

"Is the given exit legal for us to wander into?";
x = args[1];
if (!x:allows(this))
return 0;
elseif ((!valid(o = x.otherside)) || (!valid(d = x.otherside.location)))
return 0;
elseif (d in this.forbidden_rooms)
return 0;
elseif (!(d:area() in this.areas))
return 0;
elseif (this.public_wander_only && (!d.public))
return 0;
elseif (d in this.lastrooms)
return 0;
elseif (this.antigang_chance && (random(100) <= (length(d:occupants(this.species)) * this.antigang_chance)))
return 0;
"elseif ((this.fear_fire && (fires = d:occupants(#35148))) && fires[1].lit)";
"  return 0;";
"elseif (is_a(d, #1047) && (!($drugs.suffocation in $lu:slice(this.resists, 1))))";
"  return 0;";
"elseif (is_a(d, #1034) && (!$skills.swim:raw(this))";
"  return 0;";
endif
return 1;

respawn

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (is_a(this.body, $corpse))
this.body.player = #-1;
endif
if ((!this.f) && this.recycle_on_die)
$recycler:_recycle(this);
return;
endif
return pass(@args);

_aggression

Spec this none thisFlags rxOwner #361Definer #142

Referenced by

• #143:suggest_next_action line 3: this:_aggression

Source

if (area(this).combat_ok)
if ((!this.fighting) && (random(100) <= this.aggression_chance))
if ($drugs.fear:doses_for(this))
return;
endif
mythreat = 0;
for x in (this.location:occupants($living))
kill = this:should_aggro(x);
if (kill)
mythreat = mythreat ? mythreat | this:threat_rating();
if (((mythreat + this.bravery) + random(20)) > x:threat_rating())
this:cancel_current_action();
this:start_fighting(x);
return {$actions.null, {}};
endif
endif
endfor
endif
endif

maybe_assist

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

• #142:hear_event_fight line 2: this:maybe_assist

Source

if ($ou:isa(args[2], this.species) && (random(100) <= this.defend_sibs_chance))
if (!args[1].programmer)
if (!(args[1] in this.fighting))
return 1;
endif
endif
endif
return 0;

update_lastrooms

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (this.turf_size)
if (length(this.lastrooms) >= this.turf_size)
return 0;
endif
this.lastrooms = setadd(this.lastrooms, this.location);
else
return pass(@args);
endif

_feed

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

• #142:suggest_next_action line 3: this:_feed

Source

for x in (this.food)
for y in ({@this.contents, @this.location.contents})
if ((((is_a(y, x) && (!is_a(y, #87534))) && (y.weight > 0)) && (y.weight < 5000)) && `y.junk_ok ! ANY => 0')
return {$actions.eat, {y}, 1, ""};
endif
endfor
endfor

_track

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (valid(this.tracking))
if (te = this.location:track_exit(this.tracking))
if (is_a(te[1], $exit))
check = $skills.track:check(this, -(te[2] / 5));
if (check >= 0)
if (this:is_legal_wander_exit(te[1]))
return {$actions.move, {te[1]}, 1, ""};
endif
endif
endif
endif
endif

weapon

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

• #142:enter_room line 9: this:weapon

Source

if (!this.wields_weapons)
return (typeof(this.unarmed_weapon) == LIST) ? this.unarmed_weapon[1] | this.unarmed_weapon;
else
return pass(@args);
endif

_compile

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

pass(@args);
{who} = args;
who:tell("Highlighting comments for ", $su:nn(this), ":");
cc = {};
allkeys = {};
for x in (this.conversation)
xl = $su:explode(x, "|");
keys = $su:explode(xl[1], ",");
v = (length(xl) > 2) ? xl[3] | "";
allkeys = {@allkeys, @keys};
$cu:sin(0);
endfor
cc2 = {};
for x in (this.comments)
words = $su:explode(x, " ");
newtext = "";
for w in (words)
ws = $su:strip_chars(w, "?!.,");
if (ws in allkeys)
newtext = (newtext + ((" " + $ansi.bold_on) + w)) + $ansi.reset;
else
newtext = (newtext + " ") + w;
endif
endfor
newtext = newtext[2..$];
$cu:sin(0);
who:tell("  ", newtext);
cc2 = {@cc2, newtext};
endfor
this.comments = cc2;
who:tell("Done!");

go_home

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (this.recycle_on_die)
return;
endif
return pass(@args);

tame

Spec this none noneFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (!this.recycle_on_die)
player:tell(this:inamec(), " can't be tamed, man!");
return;
endif
if (!player.programmer)
player:tell("Yeah.  You wish.  Soon enough.");
return;
endif
this:slave_to(player);

slave_to

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

• #142:tame line 9: this:slave_to

Source

master = args[1];
this.fighting = setremove(this.fighting, master);
this.friendly_species = {master};
this.species = master;
this.following = master;
this.defend_sibs_chance = 100;
this.wander_chance = 0;
this:aat(this:dnamec(), " heels behind ", master:dname(), ".");

_brainscan

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

• #143:_brainscan line 1: pass(

Source

pass(who = args[1]);
if (this.areas)
this:_whisper(who, "I live in ", $su:english_list($lu:map_verb(this.areas, "dname")), ".");
endif
if (!this.recycle_on_die)
this:_whisper(who, "If I get killed, at least I'll reclone.");
endif
species = strsub(this.species:iname(), "generic ", "");
if (chance = this.defend_sibs_chance)
if (chance > 90)
d = "always";
elseif (chance > 50)
d = "probably";
elseif (chance > 15)
d = "sometimes";
else
d = "maybe";
endif
this:_whisper(who, "I'll ", d, " defend a fellow ", species, ".");
endif
if (valid(this.tracking))
this:_whisper(who, "I'm tracking ", this.tracking:iname(), ".");
endif
if (this.enemy_species)
this:_whisper(who, "If I see ", $su:english_list($lu:map_verb(this.enemy_species, "iname")), ", they're dead.");
endif
if (c = this.aggression_chance)
if (c > 70)
m = "I'm crazy!  I'll kill anything I see.";
elseif (c > 30)
m = "I'm itching for a fight.";
else
m = "I'm a little bit aggressive.";
endif
this:_whisper(who, c);
endif

killed_by

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

pass(@args);
"if (valid(parent(this)))";
"  parent(this):award_species_quest(@args);";
"endif";
"if (is_a(who = args[1], $player))";
"  eff = who.xp_total - who:quest_xp();";
"  $grind_db:record(who, eff, parent(this), this.did_damage);";
"endif";

award_species_quest

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if ((!this.f) || (this == $monster))
return;
endif
who = args[1];
if (!this.species_quest)
"No species quest exists yet.";
should_create = 1;
elseif ((is_clear_property(this, "species_quest") && this.species_quest) && (!this.species_quest[2]))
"A species quest exists, but it isn't our direct parent's species quest (and it isn't overridden).";
should_create = 1;
else
"We have liftoff!";
should_create = 0;
endif
if ((!is_a(who, $builder)) && should_create)
quest = $recycler:_create(#197494);
if (!is_a(quest, $quest))
$nets.questnet:announce(#2, tostr($ansi.bold_on, "Could not create a species killer quest for ", $su:nn(this), "!"), 1);
quest = #-1;
else
quest.species = this;
quest:setup_name();
quest.xp_award = quest:calc_value();
quest:moveto($quests);
$nets.questnet:announce(#2, tostr($ansi.bold_on, "'", $su:nn(quest), "' species killer quest has been created for ", $su:nn(this), "."), 1);
$wiz_utils:set_owner(quest, this.owner);
this.species_quest = {quest, 0};
endif
else
quest = ((!should_create) && this.species_quest) ? this.species_quest[1] | #-1;
endif
if (is_a(quest, $quest))
quest:award_to(who);
endif

heartbeat

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (length(this.contents) > 10)
j = $lu:random(this.contents);
if (!((j in this.wearing) || (j in this.wielding)))
$rpg:junk(j);
endif
endif
if ((this.recycle_on_die && (this.location in {this.afterlife, #-1})) && (!this:dead()))
if (this.f || verbs(this))
$nets.prognet:announce(#-1, tostr($su:nn(this), " is in limbo, fertile or has verbs, and .recycle_on_die = 1. Not recycling."), 1);
else
$heart:unregister(this);
$recycler:_recycle(this);
endif
else
return pass(@args);
endif

tree_tag

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

r = "";
r = $su:trim(r);
if (r)
r = (pass(@args) + "  ") + r;
else
r = pass(@args);
endif
rec = this.recycle_on_die ? "" | tostr($ansi.red, "   !recycle_on_die", $ansi.reset);
r = tostr(r, rec);
return r;

_enemies

Spec this none thisFlags rxOwner #361Definer #142

Referenced by

none

Source

{?location = this.location} = args;
enemies = {};
for target in (location:occupants(this.enemy_species ? $living | $player))
if (is_a(target, $immortal))
continue;
endif
if (!this.enemy_species)
kill = 1;
else
kill = 0;
for foe in (this.enemy_species)
if (is_a(target, foe) && (kill == 0))
kill = 1;
for friend in (this.friendly_species)
if (is_a(target, friend))
kill = 0;
break;
endif
endfor
endif
endfor
endif
if (kill)
enemies = setadd(enemies, target);
endif
endfor
return enemies;

should_aggro

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

• #142:_aggression line 8: this:should_aggro
• #142:hear_event_arrive line 4: this:should_aggro

Source

who = args[1];
if (is_a(who, $prog))
return;
endif
enemy = 0;
friend = 0;
enemies = (typeof(this.enemy_species) == LIST) ? this.enemy_species | {this.enemy_species};
friends = (typeof(this.friendly_species) == LIST) ? this.friendly_species | {this.friendly_species};
for e in (enemies)
if (is_a(who, e))
enemy = 1;
endif
endfor
if ((!this.enemy_species) && is_a(who, $player))
enemy = 1;
endif
for f in (friends)
if (is_a(who, f))
friend = 1;
endif
endfor
if ((enemy && is_player(who)) && (!this.no_cower))
myval = this:xp_value(who);
if (myval < 2)
if (random(100) < (100 - (((typeof(this.xp_value) == LIST) ? this.xp_value[1] | this.xp_value) * 2)))
if (random(100) < 30)
this:aat(this:dnamec(), " cowers away from ", who:dname(), ".");
endif
return 0;
endif
endif
endif
if (enemy && (!friend))
return 1;
endif

_kill_target

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

if (valid(this.kill_target) && is_a(room = this.kill_target:room(), $room))
if (this.location != room)
if (valid(exit = this.location:next_hop_to(room)))
if ((!(exit.otherside.location in this.lastrooms)) || (random(100) > 20))
return {this.move_action, {exit}, 1, "walk to destination"};
else
$nets.pathnet:announce(#-1, (($su:nn(this) + " was in a loop going to ") + $su:nn(this.destination)) + "!", 1);
this.destination = #-1;
this.lastrooms = {};
endif
endif
else
targ = this.kill_target;
this.kill_target = #-1;
if (is_a(targ, $room))
vic = this.location:occupants($player);
elseif (targ.location == this.location)
vic = {targ};
else
return;
endif
if (vic)
vic = vic[random($)];
this:start_fighting(vic);
endif
endif
endif

kill_target

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

target = args[1];
this.kill_target = target;
this:jumpstart();

pay transfer

Spec any at/to thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

player:tell("You just don't feel right handing money to some random monster for no reason.");

hear_event_arrive

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

who = args[3];
if (!this.fighting)
if (random(100) <= this.aggression_chance)
if (this:should_aggro(who))
this:start_fighting(who);
endif
endif
endif
return pass(@args);

show_sheet

Spec this none thisFlags rxdOwner #361Definer #142

Referenced by

none

Source

player:tell($ansi.bold_on, this:inamec(), $ansi.bold_off);
parent = this.f ? this | parent(this);
alive = length(children(parent));
player:tell(alive, " alive right now.");
if (typeof(this.xp_value) == INT)
player:tell("XP value is OLD FORMAT -- ", this.xp_value, "xp.  FIX THIS.");
else
player:tell("XP value is ", $ansi.bold_on, this.xp_value[1], $ansi.bold_off, "xp up to ", this.xp_value[2], " effXP, scaling to 0 at ", this.xp_value[3], " effXP.");
endif
if (this.contract_value)
player:tell("Contract value is ", $ansi.green, "$", this.contract_value, $ansi.reset, ".");
endif
areas = [];
for x in ($ou:leaves($hive))
if (x.generic_citizen == parent)
a = area(x);
t = `areas[a] ! ANY => 0' + x.citizen_population;
areas[a] = t;
endif
endfor
for x in (keys(areas))
t = areas[x];
player:tell(t, " spawn in ", `x:dname() ! ANY => "???"', ".");
endfor
a1 = $grind_db:avg_eff_dmg(parent);
a1t = $grind_db:kills_dmg(parent);
a2 = $grind_db:avg_eff_nodmg(parent);
a2t = $grind_db:kills_nodmg(parent);
player:tell(a1t, " kills by players who took damage    (average eff: ", a1, "xp)");
player:tell(a2t, " kills by players who took no damage (average eff: ", a2, "xp)");