generic NPC #106

wield_best

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:get_gift line 5: this:wield_best
• #106:start_fighting line 8: this:wield_best
• #142:enter_room line 7: this:wield_best

Source

best = #-1;
for x in (this.contents)
if (is_a(x, $weapon))
if ((!valid(best)) || (x.value > best.value))
best = x;
endif
endif
endfor
if (valid(best))
uw = #-1;
if (typeof(this.unarmed_weapon) == LIST)
uw = this.unarmed_weapon[1];
else
uw = this.unarmed_weapon;
endif
if (best:damage()[1][3] < uw:damage()[1][3])
for x in (this.wielding)
this:_unwield(x);
endfor
else
if (!(best in this.wielding))
for x in (this.wielding)
this:_unwield(x);
endfor
this:_wield(best);
endif
endif
endif

get_gift

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

r = pass(@args);
what = args[1];
if (this.wields_weapons)
if (is_a(what, $weapon))
this:wield_best();
endif
endif
return r;

_wander

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:_fight line 32: this:_wander
• #106:suggest_next_action line 11: this:_wander
• #106:_suggest_next_action line 2: this:_wander
• #106:_fight_ari line 31: this:_wander
• #142:_wander line 13: pass(
• #155:_wander line 1: pass(

Source

e = {};
er = {};
if ((time() - this.last_wander_time) < this.wander_speed)
return 0;
endif
if (`this.here_for_something ! ANY')
return 0;
endif
if ((random(100) < this.wander_chance) || is_a(this.location, #2180))
if (random(100) < 10)
this.lastrooms = {};
endif
if (is_a(this.location, $room))
for x in (this.location.exits)
if (this:is_legal_wander_exit(x))
if (!(x.otherside.location in this.lastrooms))
e = setadd(e, x);
endif
er = setadd(er, x);
endif
endfor
if (e)
ex = e[random(length(e))];
elseif (er)
ex = er[random(length(er))];
this.lastrooms = {};
else
ex = #-1;
this.lastrooms = {};
endif
if (valid(ex))
if (ex == this.wander_last_try)
this.lastrooms = {};
this.wander_last_try = #-1;
return {};
endif
this.wander_last_try = ex;
this.last_wander_time = time();
return {this.move_action, {ex}, 1, ex.name};
endif
endif
endif

_fight

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:suggest_next_action line 3: this:_fight
• #143:suggest_next_action line 1: this:_fight
• #155:suggest_next_action line 1: this:_fight

Source

"Copied from generic NPC (#138):_fight_ari by Gilmore (#98) Fri Mar  6 20:52:24 2009 CST";
"Copied from generic NPC (#138):_fight by Gilmore (#98) Fri Mar  6 10:36:30 2009 CST";
if (random(100) < 20)
if (`this.location.no_combat ! ANY => 0')
return;
endif
"do a bravery check";
if (this.fighting)
vs = 0;
me = this:threat_rating() + this.bravery;
for x in (this.location:occupants($creature))
if (this in x.fighting)
vs = vs + x:threat_rating();
endif
if (x in this.friends)
me = me + x:threat_rating();
endif
endfor
if (vs > me)
return this:_flee();
else
return pass(@args);
endif
else
for x in (setremove(this.location:occupants($creature), this))
if (x in this.enemies)
if (x:threat_rating() < (this:threat_rating() + this.bravery))
this:start_fighting(x);
return pass(@args);
else
this:say_idea("flee");
return this:_wander();
endif
endif
endfor
endif
else
this:sanitize_fighting();
"tactics = `this.tactics ! E_PROPNF => $tactics.default';";
"tactic = (typeof(tactics) == LIST) ? tactics[random($)] | tactics;";
"if ((chance = `this.tactics_chance ! ANY') && (random(100) <= chance))";
"  return tactic:decide_on_action(this) || pass(@args);";
"endif";
return pass(@args);
endif

is_legal_wander_exit

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:_wander line 15: this:is_legal_wander_exit
• #106:_flee line 3: this:is_legal_wander_exit

Source

"Is the given exit legal for us to wander into?";
x = args[1];
if (valid(x.otherside) && valid(d = x.otherside.location))
if ((!this.public_wander_only) || d.public)
return x:allows(this) ? 1 | 0;
endif
endif
return 0;

die

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #142:die line 4: pass(
• #142:die line 23: pass(
• #142:die line 35: pass(
• #155:die line 4: pass(

Source

if (!this:is_in_afterlife())
this.death_time = time();
endif
for x in (this.contents)
for y in (this.junk_on_death)
if (is_a(x, y))
$rpg:junk(x);
endif
endfor
endfor
this.enemies = {};
pass(@args);
if (is_a(this.body, $body))
`this.body.clothing = this.clothing ! ANY';
endif

moveto

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #142:on_spawn line 20: this:moveto
• #142:on_spawn line 22: this:moveto

Source

this:update_lastrooms();
return pass(@args);

start_fighting

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:_fight line 28: this:start_fighting
• #106:_fight_ari line 27: this:start_fighting
• #142:enter_room line 26: this:start_fighting
• #142:hear_event_fight line 4: this:start_fighting
• #142:_aggression line 13: this:start_fighting
• #142:_kill_target line 24: this:start_fighting
• #142:hear_event_arrive line 5: this:start_fighting
• #143:hear_event_pick line 6: this:start_fighting
• #155:p_defend line 13: this:start_fighting
• #155:p_defend line 17: this:start_fighting
• #341:call_police line 16: this:start_fighting

Source

if (!this:reachable_by(args[1]))
return 0;
endif
if (is_a(this:area(), $real_area))
this.enemies = setadd(this.enemies, args[1]);
this:add_nemesis(args[1]);
if (this.wields_weapons)
this:wield_best();
endif
this:say_idea("fight");
this.did_damage = 0;
return pass(@args);
"elseif (is_a(this:area(), #2488) && this.can_fight_in_dream)";
"  if (this.wields_weapons)";
"    this:wield_best();";
"  endif";
"  this:say_idea(\"fight\");";
"  this.did_damage = 0;";
"  return pass(@args);";
endif

say_idea

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:_fight line 31: this:say_idea
• #106:start_fighting line 10: this:say_idea
• #106:_fight_ari line 30: this:say_idea

Source

i = args[1];
m = this.(("say_" + i) + "_msg");
if (m)
if (typeof(m) == STR)
this:say(m);
else
this:say(m[random(length(m))]);
endif
endif

hear_event_arrive

Spec this none thisFlags rxOwner #361Definer #106

Referenced by

• #142:hear_event_arrive line 9: pass(

Source

if ((!this.fighting) && this.preemptible)
if (is_a(args[3], $player))
fork (1)
this:clear_queue();
this:greet(args[3], args[4][1]);
this.reacting_to = $actions.arrive;
this:jumpstart();
endfork
endif
endif

hear_say_to

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:hear_event_say line 8: this:hear_say_to
• #155:hear_say_to line 2: pass(

Source

if (this._conversation)
text = args[2];
stripped = $su:strip_chars(text, "?!.,");
words = $su:words(stripped);
who = args[1];
if (this:is_nemesis(who))
fork (1)
this:say($su:ps($su:msg(this.fuck_off_msg), who), who);
endfork
return;
endif
allhits = {};
for x in (this:_conversation(who))
if (this:match_convo(who, words, x))
allhits = {@allhits, x[2..$]};
endif
endfor
if (allhits)
res = allhits[random(length(allhits))];
fork (1)
this:respond_convo(who, res, text);
endfork
else
fork (1)
m = `this.comments ! ANY' ? this.comments | this.dunno_msg;
this:say($su:msg(m), who);
endfork
endif
endif

hear_event_say

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

if (!this.fighting)
if (is_player(args[3]))
if ((length(args[4]) > 1) && (args[4][2] == this))
if (this.ignore_next_say && ((time() - this.ignore_next_say) < 5))
this.ignore_next_say = 0;
return;
endif
this:hear_say_to(args[3], args[4][1]);
endif
endif
endif

hear_event_shake

Spec this none thisFlags rxOwner #361Definer #106

Referenced by

none

Source

if (args[4][1] == this)
who = args[3];
this:heard_no_from(who);
endif

hear_event_nod

Spec this none thisFlags rxOwner #361Definer #106

Referenced by

none

Source

if (args[4][1] == this)
who = args[3];
this:heard_yes_from(who);
endif

_step_toward

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

where = args[1];
if (valid(nh = this.location:next_hop_to(where)))
return {$actions.move, {nh}, 1, nh.name};
endif

heartbeat

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #142:heartbeat line 15: pass(
• #155:heartbeat line 1: pass(
• #233:heartbeat line 1: pass(

Source

if (this:is_in_afterlife() && (this.location != this.respawn))
"Either respawn or don't.  Do nothing else.";
if ((time() - this.death_time) > this.respawn_time)
if ((this.respawn != this.home) || (!this.respawn:occupants($player)))
return this:respawn();
endif
endif
raise(E_NONE, "Can't respawn yet.");
endif
if (heresince = `this.here_for_something ! ANY')
if (time() > heresince)
this.here_for_something = 0;
endif
endif
if (length(this.contents) > this.max_contents)
`$rpg:junk(this.contents[random(length(this.contents))]) ! ANY => 0';
endif
if (random(10) == 1)
this:reap_nemeses();
this:forget_enemies();
endif
this.reacting_to = $actions.heartbeat;
if (random(100) < 25)
if (area(this).hibernating && (!this.dont_hibernate))
$heart:unregister(this);
endif
if (decal = this:occupants($decal))
decal[random($)]:reduce_by(1);
endif
endif
return pass(@args);

update_lastrooms

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:moveto line 1: this:update_lastrooms
• #142:update_lastrooms line 7: pass(

Source

if (is_a(this.location, $room))
this.lastrooms = {this.location, @this.lastrooms};
if (length(this.lastrooms) > 10)
this.lastrooms = this.lastrooms[1..10];
endif
endif

@compile

Spec this none noneFlags rxdOwner #361Definer #106

Referenced by

none

Source

if (!player.programmer)
player:tell($huh_text);
else
this:_compile(player);
endif

hear_event_die

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

victim = args[3];
this.enemies = setremove(this.enemies, victim);

respawn

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:heartbeat line 5: this:respawn
• #142:respawn line 8: pass(

Source

this:on_spawn();
if (this.respawn_clothing)
this.clothing = this.respawn_clothing;
endif
return pass(@args);

cant_take

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

what = args[1];
if (what:weight() < 0)
return "it's attached to the " + this.location:floor_msg();
endif
if (is_a(what, #3167) || is_a(what, #156864))
if (what.to == this)
return 0;
else
return "that package isn't for " + this.po;
endif
endif
for x in (this.accepted_gifts)
if (is_a(what, x))
return 0;
endif
endfor
return pass(@args);

greet

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:hear_event_arrive line 5: this:greet

Source

who = args[1];
from = args[2];
if (((m = this:greet_msg(who)) && ((time() - this.last_greet_time) > 12)) && (who.location == this.location))
this:say($su:ps(m, who), who);
this.last_greet_time = time();
endif

_reload

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:suggest_next_action line 1: this:_reload

Source

if (is_a(w = this:weapon(), #285))
if (w.jammed)
return {$actions.verb, {w, "clear", {}, 2.0, 0}};
endif
if ((!w.contents) && ((this.reload_guns || (w == this.unarmed_weapon)) || ((typeof(this.unarmed_weapon) == LIST) && (w in this.unarmed_weapon))))
type = valid(w.ammo_type) ? w.ammo_type | w.default_ammo;
ammo = #-1;
for x in (this.contents)
if (is_a(x, type))
ammo = x;
endif
endfor
ammo = valid(ammo) ? ammo | $rpg:spawn(type);
ammo:moveto(this);
return {$actions.verb, {w, "_load", {ammo, this}, 1.0, 0}, 1, "load"};
endif
endif

_wield_best

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

best = #-1;
bestval = 0;
for x in (this.contents)
if (is_a(x, $weapon))
if (x.value > bestval)
best = x;
bestval = x.value;
endif
endif
endfor
if (valid(best) && (!(best in this.wielding)))
return {$actions.verb, {this, "_wield", {best}, 1.0, 0}, 1, "wield best weapon"};
endif

_home

Spec this none thisFlags rxOwner #361Definer #106

Referenced by

none

Source

if (valid(this.home) && is_a(this.home, $room))
if (this.location != this.home)
if (valid(exit = this.location:next_hop_to(this.home)))
return {this.move_action, {exit}, 1, "walk home"};
endif
endif
endif

suggest_next_action

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:_suggest_next_action line 6: this:suggest_next_action
• #142:suggest_next_action line 1: pass(

Source

if (r = this:_reload())
return {r, 0};
elseif (r = this:_fight())
return {r, 0};
elseif (r = this:_aggression())
return {r, 0};
elseif (r = this:_comment())
return {r, 5};
elseif (r = this:_walk())
return {r, this.walk_speed};
elseif (r = this:_wander())
return {r, this.wander_speed};
endif

_comment

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:suggest_next_action line 7: this:_comment
• #143:suggest_next_action line 11: this:_comment

Source

"Don't comment inside clone vats.";
if (!is_a(this.location, #2180))
if ((time() - this.last_comment_time) > 20)
if (this.lastaction != "c")
if (random(100) <= this.comment_chance)
if (people = this.location:occupants($player))
if (comment = this:random_comment())
who = people[random(length(people))];
comment = this:random_comment();
this.last_comment_time = time();
return {$actions.verb, {this, "say", {comment, who}, 0.0}, 1, ""};
endif
endif
endif
endif
endif
endif

_allows

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

if (this:is_doing($actions.struggle) || this:is_doing($actions.beg))
return 1;
endif
return 0;

hear_event_fight

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #142:hear_event_fight line 1: pass(

Source

this.reacting_to = $actions.fight;
return pass(@args);

_notice_nude

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

if (this.notice_nude_msg && (length(this.notice_nude_msg) > 0))
if (!(this.lastaction in {"nn", "c"}))
if (random(100) < this.comment_chance)
for x in (this.location:occupants($player))
if (!x:wearing_on(#305))
this.lastaction = "nn";
return {$actions.verb, {this, "say", {$su:msg(this.notice_nude_msg), x}, 1.0, 1}, 1, ""};
endif
endfor
endif
endif
endif

_flee

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:_fight line 20: this:_flee
• #106:_fight_ari line 19: this:_flee

Source

c = {};
for x in (this.location.exits)
if (this:is_legal_wander_exit(x))
if (!is_a(x, $door))
c = {@c, x};
endif
endif
endfor
if (c)
c = c[random(length(c))];
if (msg = $su:msg(this.say_flee_msg))
this:say(msg);
endif
return {$actions.move, {c}, 1, c.name};
endif

_suggest_next_action

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

if (is_a(this.location, #2180))
if (r = this:_wander())
return {r, this.wander_speed};
endif
else
return this:suggest_next_action();
endif

spawn_with

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:on_spawn line 3: this:spawn_with

Source

fork (0)
for x in (this.spawns_with)
if (typeof(x) == LIST)
if (typeof(x[2]) == NUM)
if (random(100) <= x[2])
x = x[1];
else
x = #-1;
endif
else
x = x[random(length(x))];
endif
endif
if (valid(x) && valid(what = $rpg:spawn(x)))
what:moveto(this);
if (is_a(what, $weapon) && this.wields_weapons)
this.wielding = setadd(this.wielding, what);
elseif (is_a(what, $clothing))
this.wearing = setadd(this.wearing, what);
endif
endif
endfor
endfork

on_spawn

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:respawn line 1: this:on_spawn
• #142:on_spawn line 23: pass(

Source

$heart:register(this);
$cu:sin();
this:spawn_with();
this:go_home();

add_nemesis

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:start_fighting line 6: this:add_nemesis

Source

who = args[1];
updated = 0;
for x in [1..length(this.nemeses)]
if (this.nemeses[x][1] == who)
this.nemeses[x][2] = time();
updated = 1;
endif
endfor
if (!updated)
this.nemeses = {@this.nemeses, {who, time()}};
endif

reap_nemeses

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:heartbeat line 19: this:reap_nemeses

Source

nn = {};
for x in (this.nemeses)
if ((time() - x[2]) < (this.nemesis_lifetime * 60))
nn = {@nn, x};
endif
endfor
this.nemeses = nn;

_walk

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:suggest_next_action line 9: this:_walk
• #142:suggest_next_action line 9: this:_walk

Source

if ((time() - this.here_for_something) < 0)
return;
endif
if (gamevalid(this.body))
"we're dreaming, we don't have anywhere to be.";
return;
endif
if (is_a(this.location, #31584))
return;
endif
if ((((!this.wander_chance) && (this.location != this.home)) && (!valid(this.destination))) && this.stay_home)
if (valid(this.home))
this:head_to(this.home);
endif
endif
if (gamevalid(this.destination) && gamevalid(room = this.destination:room()))
if ($drugs.neurophage:doses_for(this) && (random(100) < 75))
return;
endif
if (this.location != room)
exit = this.location:next_hop_to(room);
if (!valid(exit))
0 && $nets.pathnet:announce(this, ((("I gave up trying to reach " + $su:nn(this.destination)) + " from ") + $su:nn(this.location)) + ".");
this.walk_last_try = #-1;
this.destination = #-1;
elseif (exit == this.walk_last_try)
0 && $nets.pathnet:announce(this, tostr("I can't get through this exit, ", $su:nn(exit), ", to get to ", $su:nn(this.destination), " from ", $su:nn(this.location), ". I give up."));
this.walk_last_try = #-1;
this.destination = #-1;
else
if ((!(exit.otherside.location in this.lastrooms)) || (random(100) > 20))
this.walk_last_try = exit;
return {this.move_action, {exit}, 1, "walk to destination"};
else
0 && $nets.pathnet:announce(#-1, (($su:nn(this) + " was in a loop going to ") + $su:nn(this.destination)) + "!", 1);
this.destination = #-1;
this.walk_last_try = #-1;
this.lastrooms = {};
endif
endif
else
this.destination = #-1;
this.walk_last_try = #-1;
this.here_for_something = time() + 120;
`this:show_up() ! E_VERBNF => 0';
endif
endif

go_home

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:on_spawn line 4: this:go_home
• #142:go_home line 4: pass(

Source

if ((is_a(this.respawn, #2180) && valid(this.home)) && (!is_a(this.home:area(), $area)))
this.destination = #317;
elseif (valid(this.home) && (this.home != this.respawn))
this.destination = this.home;
endif

_aggression

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:suggest_next_action line 5: this:_aggression

Source

No program (verb defined but unprogrammed).

_pee

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

if (this:has_penis() && (#8811:doses_for(this) > 2))
return;
endif
if (#25493:doses_for(this) < 1)
return;
endif
if (args == {})
dobj = this.location;
else
dobj = args[1];
endif
stillsuit = #-1;
for x in (this:wearing_on(#305))
if (is_a(x, #26285))
stillsuit = x;
endif
endfor
if (valid(stillsuit))
stillsuit:receive_pee(1);
else
if (is_a(dobj, #82393))
if (this:has_vagina())
if ((this.posture != "standing") && (!(this in dobj.sitting)))
this:queue_action($actions.stand, {dobj}, 1, "stand");
endif
if (!(this in dobj.sitting))
this:queue_action($actions.sit, {dobj}, 1, "sit " + argstr);
endif
endif
endif
length = #25493:doses_for(this);
for a in [1..length]
this:queue_action($actions.verb, {#160, "_do_social", {this, dobj, "pee"}, 1.0, 1}, 1, "");
endfor
fork (#25493:doses_for(this) + random(3))
`dobj:post_pee(this) ! ANY => 0';
endfork
endif
fork (#25493:doses_for(this) + random(3))
#25493:remove_from(this, #25493:doses_for(player));
exit = this.location.exits[random(length(this.location.exits))];
this:queue_action($actions.move, {exit.name}, 1, exit.name);
endfork

forget_enemies

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:heartbeat line 20: this:forget_enemies

Source

forget_list = {};
for x in (this.enemies)
$cu:sin(0);
if (!is_a(x, $creature))
forget_list = setadd(forget_list, x);
continue;
endif
if (#114:check(this, 5) > 0)
forget_list = setadd(forget_list, x);
endif
endfor
for x in (forget_list)
this.enemies = setremove(this.enemies, x);
$cu:sin(0);
endfor

take_damage

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

amount = pass(@args);
attacker = (length(args) > 3) ? args[4] | #-1;
if (amount > 0)
if (valid(attacker))
if (attacker.location == this.location)
fork (1)
if (this.health)
if (this:beg_check(attacker))
this:queue_action($actions.npcbeg, {attacker});
endif
endif
endfork
endif
endif
endif
return amount;

beg_check

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:take_damage line 8: this:beg_check

Source

who = args[1];
if (this.health <= this.beg_health)
if (this.health > 0)
if (random(100) <= this.beg_chance)
return 1;
endif
endif
endif

spare_old

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

#365733:tell($ansi.yellow, $ansi.bold_on, $su:nn(player), $ansi.bold_off, " called the old spare verb on ", $ansi.bold_on, $su:nn(this), $ansi.reset);
if (this.executing)
if (this.executing[1] == $actions.npcbeg)
if (this.executing[2][1] == player)
this:spared_by(player);
return;
endif
endif
endif
player:tell(this:dnamec(), " isn't asking to be spared.");

spared_by

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:spare_old line 5: this:spared_by

Source

who = args[1];
this:say("Whew.  I'm glad that's settled.");
who:stop_fighting(this);
this:stop_fighting(who);
this:cancel_current_action();
this:clear_queue();
this.health = this.health_max;
this:remove_nemesis(who);
this.enemies = setremove(this.enemies, who);
if (cams = this.location:occupants(#9348))
if (valid(cams[1].system) && has_callable_verb(cams[1].system, "decrease_wanted_level"))
cams[1].system:decrease_wanted_level(who, 2);
endif
endif

beg_msg

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

return this.beg_msg;

_brainscan

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #142:_brainscan line 1: pass(

Source

pass(who = args[1]);
if (valid(dest = this.destination))
if (dest == this.home)
this:_whisper(who, "I'm headed home.");
else
this:_whisper(who, "I'm headed to ", dest.name, ".");
endif
endif

random_comment

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:_comment line 7: this:random_comment
• #106:_comment line 9: this:random_comment

Source

return `this.comments[random(length(this.comments))] ! ANY => ""';

random_rumor

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

if (valid(this.rumor_db) && (this.rumor_db != $rpg))
return this.rumor_db:random_rumor();
elseif (valid(rumor = this:area():random_rumor()))
return rumor;
else
return $rpg:random_rumor();
endif

encumbrance

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #142:_wander line 5: this:encumbrance

Source

No program (verb defined but unprogrammed).

_is_nude

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

if (this.is_nude_msg && (length(this.is_nude_msg) > 0))
if (!(this.lastaction in {"isnude", "c"}))
if (random(10) < 8)
for x in (this.location:occupants($player))
if (this:wearing_on(#305) == {})
this.lastaction = "isnude";
this:say($su:msg(this.is_nude_msg));
endif
endfor
endif
endif
endif

greet_msg

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:greet line 3: this:greet_msg

Source

m = this.(verb);
return (typeof(m) == STR) ? m | $su:msg(m);

com*mand

Spec this at/to anyFlags rxdOwner #361Definer #106

Referenced by

none

Source

"Copied from generic creature (#109):command by Spunky (#97) Sat Jan  3 13:32:55 2009 CST";
if (!player.programmer)
player:tell("You don't see why ", this:dname(), " would listen to you.");
return;
endif
command = iobjstr;
words = $su:explode(iobjstr);
this:do_command(iobjstr, words);

wearing_on

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:_pee line 13: this:wearing_on
• #106:_is_nude line 5: this:wearing_on

Source

":wearing_on(OBJ bodypart) => LIST what I'm wearing there.";
part = args[1];
s = {};
for x in (this.clothing)
if (is_a(x, $clothing))
for y in (x.covers)
if (is_a(part, y))
s = setadd(s, x);
break;
endif
endfor
endif
endfor
if (s)
return s;
endif
return pass(@args);

match_convo

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:hear_say_to line 14: this:match_convo

Source

who = args[1];
words = args[2];
convoline = args[3];
wordstring = $su:from_list(words, " ");
for x in (convoline[1])
if (match(wordstring, tostr("%(^%|%W%)", x, "%($%|%W%)")))
return 1;
endif
endfor

none

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

No program (verb defined but unprogrammed).

respond_convo

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:hear_say_to line 21: this:respond_convo

Source

who = args[1];
res = args[2];
whotxt = args[3];
resp = res[1];
respv = res[2];
if (resp && (resp != "NULL"))
qname = "";
if (resp[1] == "*")
resp = resp[2..$];
i = index(resp, "*");
qname = resp[1..i - 1];
resp = resp[i + 1..$];
endif
this:say(resp, who);
if (qname)
quest = $quests.(qname);
quest:add_hint(who, ((this:inamec() + " said, \"") + resp) + "\"");
endif
endif
if (respv && (respv != "NULL"))
this:(respv)(who, whotxt);
endif

convo_words

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

none

Source

cw = {};
for x in (this._conversation)
for y in (x[1])
cw = setadd(cw, y);
endfor
endfor
return cw;

head_to head_for

Spec this none thisFlags rxdOwner #361Definer #106

Referenced by

• #106:_walk line 13: this:head_to

Source

what = args[1];
where = is_a(what, $room) ? what | what:room();
if ((where == this.location) || (!$recycler:valid(where)))
return;
$nets.pathnet:_announce(#-1, tostr($su:nn(this), " tried to head to ", $su:nn(what), " (where: ", $su:nn(where), ")"), 1);
return;
endif
if (length(args) > 3)
m = args[4];
else
if (m = `$su:msg(this.head_to_msg) ! ANY')
if (where == this.home)
m = strsub(m, "%t", "home");
else
m = $su:ps(m, this, where);
endif
endif
endif
if (this.fighting)
return;
endif
stay_for = (length(args) > 1) ? args[2] | 1;
force = (length(args) > 2) ? args[3] | 0;
if (valid(this.destination) && (!force))
return;
endif
this.destination = where;
this.lastrooms = {};
`this.headed_to_stay_for = stay_for ! ANY';
`this.headed_to_count = 0 ! ANY';
this.here_for_something = 0;
m && this:say(m);
this:jumpstart();