generic RPG player #100

sc*ore sk*ills ss*tats

Spec any none noneFlags rxdOwner #361Definer #100

Referenced by

none

Source

if (dobjstr && player.programmer)
if (!valid(dobj))
dobj = $su:match_player(dobjstr);
if (!valid(dobj))
player:tell(verb + " who?");
return;
endif
endif
if (!is_a(dobj, $creature))
player:tell(verb + " who?");
return;
endif
player:tell("Showing sheet for ", $su:nn(dobj), ":");
dobj:show_score_full(#-1, verb);
elseif (dobjstr)
if (valid(oneskill = $mu:match(dobjstr, $ou:leaves($skill))))
this:show_score_full(oneskill);
elseif (dobjstr == "ip")
this:ip_daily();
else
player:tell("No such skill '", dobjstr, "'.");
endif
else
this:show_score_full(#-1, verb);
endif

dname_disabled

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

if (!this.code_name)
return this:name();
endif
return pass(@args);

time date temp*erature

Spec none none noneFlags rxdOwner #361Definer #100

Referenced by

none

Source

if (this:area() == #1436)
if (#1436.phase == 4)
felt = 98;
else
felt = this:felt_temperature();
endif
cfelt = ((felt - 32) * 5) / 9;
temp = ((("Feels like " + tostr(felt)) + "F (") + tostr(cfelt)) + "C).";
player:tell("Today is ", $ansi.bold_on, "Friday, July 7, 2051", $ansi.reset, ". It is ", $time.day_segments[$time:day_segment()], ". ", temp);
return;
endif
if ((!this.programmer) && (this:region() == #144869))
player:tell("Time?  You're not sure what that means here...");
return;
endif
t = `this.location:temperature() ! ANY => ""';
if (t)
ctemp = ((t - 32) * 5) / 9;
temp = ((("  Temp " + tostr(t)) + "F (") + tostr(ctemp)) + "C).";
else
temp = "";
endif
felt = this:felt_temperature();
if (felt != t)
cfelt = ((felt - 32) * 5) / 9;
temp = ((((temp + " Feels like ") + tostr(felt)) + "F (") + tostr(cfelt)) + "C).";
endif
lag = $flywheel:lagstr();
if (lag != (($ansi.green + "0.000s") + $ansi.reset))
lag = tostr("[ Lag: ", $flywheel:lagstr(), "]");
else
lag = "";
endif
player:tell("You check your wristpad: ", $ansi.bold_on, $time:ctime(), $ansi.bold_off, ".  It is ", $time.day_segments[$time:day_segment()], ".", temp, " ", lag);
if (valid(hol = $time:holiday_today()))
player:tell("Oh hey -- it's ", hol.name, ".  ", hol.description);
endif
return;
birthday = $time:ctime(player.first_connect_time);
birthday = birthday[5..10];
if (birthday == $time:ctime()[5..10])
player:tell("It's your birthday!");
endif

help phelp h ?

Spec any none noneFlags rxdOwner #361Definer #100

Referenced by

none

Source

if (dobjstr == "help help")
player:tell("Kill yourself immediately.");
return;
endif
player:tell("");
spaced = strsub(argstr, " ", "_");
if (dobjstr == "index")
$phelp:tell_index();
elseif (!dobjstr)
"if (player:area() in $rpg.chargen_areas)";
"  $phelp:tell_topic(\"chargen\");";
if (player.xp_total < 1000)
$phelp:tell_topic("newbie");
else
$phelp:tell_index();
endif
elseif (topic = $phelp:match_topic(spaced))
$phelp:tell_topic(topic);
elseif (`valid($skills.(dobjstr)) ! ANY => 0')
$phelp:tell_skill(dobjstr);
elseif (topics = $mail_help:find_topics(dobjstr))
player:tell_lines($mail_help:get_topic(topics[1]));
elseif (valid(dobj = $mu:match(dobjstr, player.contents)))
$phelp:tell_object_help(dobj);
elseif (valid(dobj = $mu:match(dobjstr, player.location.contents)))
$phelp:tell_object_help(dobj);
else
similars = `$su:properties_like($phelp, dobjstr) ! E_RANGE => {}';
player:notify(("No help is available on '" + dobjstr) + "'.  Try 'help' by itself for a help index.");
if (similars)
player:tell(" Did you mean: ", $ansi.cyan, $ansi.bold_on, $su:english_list(similars, "", " or "), $ansi.reset, "?");
endif
player:tell("For help with specific items, make sure you're nearby the item (or holding it). You can also try ", $ansi.bold_on, "examine <item>", $ansi.bold_off, ".");
$nets.helpfilenet:announce(player, tostr(player:dnamec(), " wanted to read help on '", dobjstr, "'.", similars ? " Similar: " + $su:english_list(similars) | ""), 1);
return;
endif
"$nets.helpfilenet:announce(player, ((player:dnamec() + \" read help on '\") + dobjstr) + \"'.\", 1);";

stop

Spec any none noneFlags rxdOwner #361Definer #100

Referenced by

none

Source

pvp = #-1;
restraining = this:is_restraining();
for x in (this.fighting)
if (is_player(x) && (x.location == this.location))
pvp = x;
endif
endfor
if (!dobjstr)
if (this:is_doing($actions.move))
dobjstr = "moving";
elseif (this:is_doing(#1858))
dobjstr = "aiming";
elseif (restraining = this:is_restraining())
dobjstr = "holding";
elseif ((this.queue || this.executing) && (!(this.fighting && this:is_doing($actions.attack))))
dobjstr = "acting";
elseif (valid(pvp) || this.fighting)
dobjstr = "fighting";
elseif (valid(this.following))
dobjstr = "following";
elseif (this.hunting)
dobjstr = "hunting";
endif
if (!dobjstr)
player:tell("You aren't doing anything you can stop. (Things you could stop: moving, aiming, acting, restraining, following, fighting, hunting.)");
return;
endif
endif
if (dobjstr in {"moving", "move", "walking", "walk"})
if ((this.executing && (this.executing[1] == $actions.move)) || (((!this.executing) && this.queue) && (this.queue[1][1] == $actions.move)))
this:clear_queue();
player:tell("You stop walking the path you'd planned.");
else
player:tell("You aren't going anywhere.");
endif
elseif (dobjstr in {"fighting", "fight", "combat", "kill", "shoot"})
target = player.fighting ? player.fighting[1] | #-1;
if (valid(pvp))
player:tell("You stop fighting ", pvp:dname(), ".");
player:aat(player:dnamec(), " backs away from ", pvp:dname(), ", hands raised.");
player:stop_fighting(pvp);
return;
elseif (is_a(target, $creature) && ((!target.fighting) || (target.fighting[1] != player)))
player:tell("You back off from ", target:dname(), ".");
player:stop_fighting(target);
return;
elseif (!player.fighting)
player:tell("I don't think you're fighting anyone right now, champ.");
return;
else
player:tell("You can't stop fighting!  It's to the death now, my friend.");
return;
endif
elseif (dobjstr in {"aim", "aiming"})
if ((!this.executing) || (this.executing[1] != #1858))
player:tell("You aren't aiming at anyone.");
else
this:cancel_current_action();
endif
elseif (dobjstr in {"acting", "queue"})
if (this.executing && `this.executing[1]:unstoppable(this) ! E_VERBNF => 0')
player:tell("You can't stop anything right now, buddy.");
return;
endif
f = this.fighting;
this:cancel_current_action();
this:clear_queue();
this.fighting = f;
if (f)
this:jumpstart();
endif
elseif (dobjstr in {"holding", "hold", "restrain", "restraining"})
if (restraining)
restraining[1]:cancel_current_action();
restraining[1]:clear_queue();
else
player:tell("You aren't restraining anyone.");
endif
elseif (dobjstr in {"follow", "f", "following"})
if (is_a(this.following, #1))
player:tell("You stop following ", this.following:dname(), ".");
this.following = #-1;
else
player:tell("You aren't following anyone.");
this.following = #-1;
endif
elseif (dobjstr in {"hunting", "h", "hunt"})
if (this.hunting)
player:tell("You stop hunting '", this.hunting, "'.");
this.hunting = "";
else
player:tell("You aren't hunting anything.");
endif
else
player:tell("Stop what?");
endif

st*atus

Spec any none noneFlags rxdOwner #361Definer #100

Referenced by

none

Source

if (dobjstr && player.programmer)
if (!valid(dobj))
dobj = $su:match_player(dobjstr);
if (!valid(dobj))
player:tell("Rape who?");
return;
endif
endif
if (!$ou:has_verb(dobj, "show_status"))
player:tell($su:nn(dobj) + " does not have a show_status verb.");
return;
endif
player:tell("Showing sheet for ", $su:nn(dobj), ":");
dobj:show_status();
elseif (dobjstr)
player:tell("I don't understand that.");
else
this:show_status();
endif

hunt

Spec any none noneFlags rxdOwner #361Definer #100

Referenced by

none

Source

if (dobjstr)
if (this.hunting)
player:tell("You stop hunting for '", this.hunting, "' and start hunting for '", dobjstr, "'.");
else
player:tell("You start hunting for '", dobjstr, "'.");
endif
this.hunting = dobjstr;
else
player:tell("You're hunting for '", this.hunting, "'. (type 'stop hunting' to give up.)");
endif

stop

Spec any none noneFlags rdOwner #362Definer #100

Referenced by

none

Source

No program (verb defined but unprogrammed).

forbid_action

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

if (((!this.executing) || (length(this.executing) < 2)) || (length(this.executing[2]) < 1))
return;
endif
if (this:is_doing($actions.aim, args[1]))
if (((length(args[3]) > 3) && args[3][4]) && (args[2] == #1858))
"incoming johnwoo reply, ignore...";
elseif (args[2] in $actions.aim.hostile_actions)
if (((args[2] == $actions.verb) && (!(args[3][2] in {"_get", "_wield", "_use"}))) || (args[1] == this))
return 0;
endif
args[1]:aat(args[1]:dname(), " makes a move...");
args[1]:_pvp_record({this}, "aimed");
$actions.aim:blam(this, args[1], this.executing[2][3]);
this:cancel_current_action();
this:start_fighting(args[1]);
endif
endif

beg_disabled

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

killers = {};
for x in (this.location:occupants($creature))
if (this in x.fighting)
killers = setadd(killers, x);
endif
endfor
if (!killers)
player:tell("Nobody's attacking you.  Calm down.");
else
this:queue_action($actions.beg, {@killers}, 1, "beg for mercy");
endif

tell_appraise

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

pass(@args);
if ($skills.senses:check(this, 0) > 0)
this:tell("You notice ", player:dname(), " sizing you up.");
endif
player:tell($su:ps(m, this));
if (this.hardcore)
player:tell(this:dnamec(), " has the hardened look of a true hardcore.");
endif

respawn

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

• #6:respawn line 4: pass(

Source

if (this:is_hardcore())
this.health = this.health_max;
this.blood = {};
if (valid(this.body) && $ou:isa(this.body, $corpse))
this.body.player = #-1;
endif
this.body = #-1;
this:moveto($rpg.chargen);
return;
endif
clone_aging = $rpg.base_clone_aging;
this_aging = 5 + random(2 * clone_aging);
this.char_extra_age = this.char_extra_age + (this_aging * 86400);
return pass(@args);

xp_improve_penalty

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

days = ((time() - this.first_connect_time) / 3600) / 24;
xp_total = this.xp_total;
journal = this:quest_xp();
xp = xp_total - journal;
if (xp < 10000)
return 100;
endif
f = (50000 * days) / xp;
f = max(40, f);
if (xp < 15000)
f = max(70, f);
endif
return min(100, f);

_milk

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

if ($drugs.pregnancy:doses_for(this))
return #204953;
endif
return #-1;

ro*se @rose

Spec none none noneFlags rxdOwner #361Definer #100

Referenced by

none

Source

this.location:list_exits();

tell_karma

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

if (this.karma < 0)
m = $rpg.evil_msg[max(1, min(length($rpg.evil_msg), (0 - this.karma) / 20))];
player:tell("You're ", m, ".");
elseif (this.karma == 0)
player:tell("You're just some ", this:karma_gender(), ".");
else
m = $rpg.good_msg[max(1, min(length($rpg.good_msg), this.karma / 20))];
player:tell("You're ", m, ".");
endif

karma

Spec any none noneFlags rxdOwner #361Definer #100

Referenced by

none

Source

if (argstr && (!this.programmer))
player:Tell("I don't understand that.");
return;
endif
if (argstr)
who = $su:match_player(dobjstr);
else
who = this;
endif
who:tell_karma();

fac*tions rep*utation

Spec none none noneFlags rxdOwner #361Definer #100

Referenced by

none

Source

this:tell_standings();
this:tell_wanted();

karma_gender

Spec this none thisFlags rxdOwner #29Definer #100

Referenced by

• #100:tell_karma line 5: this:karma_gender

Source

"Copied from Ammut (#365733):karma_gender Fri Jun  5 21:31:16 2009 CDT";
if (this.gender == "male")
return "guy";
elseif (this.gender == "female")
return "chick";
else
return "...thing";
endif

birthday

Spec any none noneFlags rxdOwner #361Definer #100

Referenced by

none

Source

if (dobjstr)
if (!valid(who = $su:match_player(dobjstr)))
who = this;
endif
else
who = this;
endif
"birthday = $time:ctime(who.first_connect_time);";
"birthyear = toint(birthday[21..24]);";
"birthday = birthday[5..10];";
"birthyear = birthyear - 13;";
birthday = $time:ctime($time:time(who.first_connect_time));
this:tell((who == this) ? "Your" | (who.name + "'s"), " birthday is ", birthday[5..10], ", ", tostr(toint(birthday[21..24]) - 13), ".");

set_quest_data

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

":set_quest_data(key, value) => Set a quest data value.";
{key, value} = args;
return $quest_data:set_data_for(this, key, value);

get_quest_data

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

":get_quest_data(key[, default = 0]) => Get a quest data value.";
{key, ?default = 0} = args;
return $quest_data:get_data_for(this, key, default);

reset_quest_data clear_quest_data

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

":reset_quest_data(key) => Reset a quest data value.";
{key} = args;
return $quest_data:reset_data_for(this, key);

set_quest_flag

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

":set_quest_flag(key[, value = 1]) => Set a quest flag value.";
{key, ?value = 1} = args;
return $quest_data:set_flag_for(this, key, value);

get_quest_flag

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

":get_quest_flag(key[, default = 0]) => Get a quest flag value.";
{key, ?default = 0} = args;
return $quest_data:get_flag_for(this, key, default);

clear_quest_flag reset_quest_flag

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

":reset_quest_flag(key) => Reset a quest flag value.";
{key} = args;
return $quest_data:reset_flag_for(this, key);

can_see_in_dark

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

• #3:look_self line 14: player:can_see_in_dark
• #3:player_integration_msg line 3: player:can_see_in_dark
• #3:player_integration_msg line 16: player:can_see_in_dark
• #3:list_exits line 6: player:can_see_in_dark
• #3:title line 3: player:can_see_in_dark
• #3:description line 8: player:can_see_in_dark
• #3:description line 10: player:can_see_in_dark
• #3:tell_map_backup line 30: player:can_see_in_dark
• #3:look_self_old line 159: player:can_see_in_dark
• #3:look_self_old line 162: player:can_see_in_dark
• #3:tell_map_old line 22: player:can_see_in_dark
• #3:description_old line 3: player:can_see_in_dark
• #3:list_exits_old line 4: player:can_see_in_dark
• #3:player_integration_msg_old line 2: player:can_see_in_dark
• #3:player_integration_msg_old line 11: player:can_see_in_dark
• #6:lm*ap line 6: player:can_see_in_dark
• #107:diag*nose line 17: player:can_see_in_dark

Source

return pass(@args);

change_karma

Spec this none thisFlags rxdOwner #361Definer #100

Referenced by

none

Source

change = toint(args[1]);
this.karma = this.karma + change;