Mail Distribution Center #38

resolve_addr

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #38:resolve_addr line 9: this:resolve_addr
• #38:resolve_addr line 35: this:resolve_addr
• #38:raw_send line 13: this:resolve_addr
• #39:who line 14: $mail_agent:resolve_addr

Source

"resolve(name,from,seen,prevrcpts,prevnotifs) => {rcpts,notifs} or E_INVARG";
"resolve(list,from,seen,prevrcpts,prevnotifs) => {bogus,rcpts,notifs}";
"Given either an address (i.e., objectid) or a list of such, traces down all .mail_forward lists and .mail_notify to determine where a message should actually go and who should be told about it.  Both forms take previous lists of recipients/notifications and add only those addresses that weren't there before.  `seen' is the stack of addresses we are currently resolving (for detecting loops).  The first form returns E_INVARG if `name' is invalid.  The second form returns all invalid addresses in the `bogus' list but still does the appropriate search on the remaining addresses.";
{recip, from, ?seen = {}, ?prevrcpts = {}, ?prevnotifs = {}} = args;
sofar = {prevrcpts, prevnotifs};
if (typeof(recip) == LIST)
bogus = {};
for r in (recip)
result = this:resolve_addr(r, from, seen, @sofar);
if (result)
sofar = result;
else
bogus = setadd(bogus, r);
endif
endfor
return {bogus, @sofar};
else
fwd = include_recip = 0;
if ((recip == $nothing) || (recip in seen))
return sofar;
elseif ((!valid(recip)) || ((!(is_player(recip) || $object_utils:isa(recip, $mail_recipient))) || (typeof(fwd = recip:mail_forward(from)) != LIST)))
"recip is a non-player non-mailing-list/folder or forwarding is screwed.";
if (typeof(fwd) == STR)
player:tell(fwd);
endif
return E_INVARG;
elseif (is_player(recip) && `recip:refuses_action(from, "mail") ! E_VERBNF')
player:tell(recip:mail_refused_msg());
return E_INVARG;
elseif (fwd)
if (r = recip in fwd)
include_recip = 1;
fwd = listdelete(fwd, r);
endif
result = this:resolve_addr(fwd, recip, setadd(seen, recip), @sofar);
if (bogus = result[1])
player:tell(recip.name, "(", recip, ")'s .mail_forward list includes the following bogus entr", (length(bogus) > 1) ? "ies:  " | "y:  ", $string_utils:english_list(bogus));
endif
sofar = result[2..3];
else
include_recip = 1;
endif
if ((ticks_left() < 1000) || (seconds_left() < 2))
suspend(0);
endif
biffs = sofar[2];
for n in (this:mail_notify(recip, from))
if (valid(n))
if (i = $list_utils:iassoc_suspended(n, biffs))
biffs[i] = setadd(biffs[i], recip);
else
biffs = {{n, recip}, @biffs};
endif
endif
if ((ticks_left() < 1000) || (seconds_left() < 2))
suspend(0);
endif
endfor
return {include_recip ? setadd(sofar[1], recip) | sofar[1], biffs};
endif

sends_to

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #37:is_readable_by line 1: $mail_agent:sends_to
• #38:sends_to line 8: this:sends_to

Source

"sends_to(from,addr,rcpt[,seen]) ==> true iff mail sent to addr passes through rcpt.";
{from, addr, rcpt, ?seen = {}} = args;
if (addr == rcpt)
return 1;
elseif (!(addr in seen))
seen = {@seen, addr};
for a in ((typeof(fwd = this:mail_forward(addr, @from ? {} | {from})) == LIST) ? fwd | {})
if (this:sends_to(addr, a, rcpt, seen))
return 1;
endif
$command_utils:suspend_if_needed(0);
endfor
endif
return 0;

send_message

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #2:@measure line 111: $mail_agent:send_message
• #4:co*nnect line 89: $mail_agent:send_message
• #4:request_character line 58: $mail_agent:send_message
• #4:request_character line 74: $mail_agent:send_message
• #4:request_password line 48: $mail_agent:send_message
• #6:@registerme line 51: $mail_agent:send_message
• #6:@registerme line 63: $mail_agent:send_message
• #17:set_programmer line 26: $mail_agent:send_message
• #17:set_programmer line 27: $mail_agent:send_message
• #17:do_new_password line 13: $mail_agent:send_message
• #17:newt_player line 24: $mail_agent:send_message
• #17:unset_programmer line 19: $mail_agent:send_message
• #17:expire_mail_players line 18: $mail_agent:send_message
• #17:expire_mail_lists line 15: $mail_agent:send_message
• #17:reset_password line 14: $mail_agent:send_message
• #17:do_make_player line 25: $mail_agent:send_message
• #33:@forward line 35: $mail_agent:send_message
• #33:@@sendmail line 69: $mail_agent:send_message
• #33:@resend line 60: $mail_agent:send_message
• #33:@quickr*eply line 33: $mail_agent:send_message
• #33:@quick*send line 78: $mail_agent:send_message
• #33:@add-notify line 15: $mail_agent:send_message
• #49:@toad line 53: $mail_agent:send_message
• #49:@quota line 41: $mail_agent:send_message
• #49:@unnewt line 20: $mail_agent:send_message
• #49:@blacklist line 160: $mail_agent:send_message
• #50:@rp-award line 19: $mail_agent:send_message
• #53:init_for_core line 14: $mail_agent:send_message
• #75:measurement_task line 19: $mail_agent:send_message
• #75:measurement_task_nofork line 6: $mail_agent:send_message
• #75:measurement_task_body line 59: $mail_agent:send_message
• #75:measurement_task_body line 67: $mail_agent:send_message
• #96:report_daily_gain line 32: $mail_agent:send_message
• #103:handle_aborted_task line 64: $mail_agent:send_message
• #296:_handle_error line 19: $mail_agent:send_message
• #296:_do line 25: $mail_agent:send_message
• #297:report_from_issuelists line 43: $mail_agent:send_message

Source

"send_message(from,rcpt-list,hdrs,msg) -- formats and sends a mail message.  hders is either the text of the subject line, or a {subject,{reply-to,...}} list.";
"Return E_PERM if from isn't owned by the caller.";
"Return {0, @invalid_rcpts} if rcpt-list contains any invalid addresses.  No mail is sent in this case.";
"Return {1, @actual_rcpts} if successful.";
{from, to, orig_hdrs, msg} = args;
"...";
"... remove bogus Resent-To/Resent-By headers...";
"...";
if ((typeof(orig_hdrs) == LIST) && (length(orig_hdrs) > 2))
hdrs = orig_hdrs[1..2];
orig_hdrs[1..2] = {};
strip = {"Resent-To", "Resent-By"};
for h in (orig_hdrs)
(h[1] in strip) || (hdrs = {@hdrs, h});
endfor
else
hdrs = orig_hdrs;
endif
"...";
"... send it...";
"...";
text = $mail_agent:make_message(from, to, hdrs, msg);
return this:raw_send(text, to, from);

raw_send

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

• #38:send_message line 23: this:raw_send
• #38:send_log_message line 10: this:raw_send
• #38:resend_message line 16: this:raw_send
• #39:send line 14: $mail_agent:raw_send

Source

"Copied from Mail Distribution Center (#6418):raw_send by Nosredna (#2487) Mon Feb 24 10:46:26 1997 PST";
"WIZARDLY";
"raw_send(text,rcpts,sender) -- does the actual sending of a message.  Assumes that text has already been formatted correctly.  Decides who to send it to and who wants to be notified about it and does so.";
"Return {E_PERM} if the caller is not entitled to use this verb.";
"Return {0, @invalid_rcpts} if rcpts contains any invalid addresses.  No mail is sent in this case.";
"Return {1, @actual_rcpts} if successful.";
{text, rcpts, from} = args;
if (typeof(rcpts) != LIST)
rcpts = {rcpts};
endif
if (!(caller in {$mail_agent, $mail_editor}))
return {E_PERM};
elseif (bogus = (resolve = this:resolve_addr(rcpts, from))[1])
return {0, bogus};
else
set_task_perms($wiz_utils:random_wizard());
this:touch(rcpts);
actual_rcpts = resolve[2];
biffs = resolve[3];
results = {};
for recip in (actual_rcpts)
if ((ticks_left() < 10000) || (seconds_left() < 2))
player:notify(tostr("...", recip));
suspend(1);
endif
if (typeof(e = recip:receive_message(text, from)) in {ERR, STR})
"...receive_message bombed...";
player:notify(tostr(recip, ":receive_message:  ", e));
e = 0;
elseif ((!is_player(recip)) || (!e))
"...not a player or receive_message isn't giving out the message number";
"...no need to force a notification...";
elseif (i = $list_utils:iassoc(recip, biffs))
"...player-recipient was already getting a notification...";
"...make sure notification includes a mention of him/her/itself.";
if (!(recip in listdelete(biffs[i], 1)))
biffs[i][2..1] = {recip};
endif
else
"...player-recipient wasn't originally being notified at all...";
biffs = {{recip, recip}, @biffs};
endif
results = {@results, e};
endfor
"The following is because the scheduler can BITE ME. --Nosredna";
fork (0)
for b in (biffs)
if ((ticks_left() < 10000) || (seconds_left() < 2))
suspend(1);
endif
if ($object_utils:has_callable_verb(b[1], "notify_mail"))
mnums = {};
for r in (listdelete(b, 1))
mnums = {@mnums, (rn = r in actual_rcpts) && results[rn]};
endfor
b[1]:notify_mail(from, listdelete(b, 1), mnums);
endif
endfor
endfork
return {1, @actual_rcpts};
endif

mail_forward mail_notify

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #38:resolve_addr line 47: this:mail_notify
• #38:sends_to line 7: this:mail_forward
• #38:touch line 12: this:mail_forward

Source

who = args[1];
if ($object_utils:has_verb(who, verb))
return who:(verb)(@listdelete(args, 1));
else
return {};
endif

touch

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #38:raw_send line 17: this:touch
• #38:touch line 5: this:touch
• #38:touch line 13: this:touch

Source

"touch(name or list,seen) => does .last_used_time = time() if we haven't already touched this in the last hour";
{recip, ?seen = {}} = args;
if (typeof(recip) == LIST)
for r in (recip)
result = this:touch(r, seen);
$command_utils:suspend_if_needed(0);
endfor
else
if (((!valid(recip)) || (recip in seen)) || ((!is_player(recip)) && (!($mail_recipient in $object_utils:ancestors(recip)))))
"recip is neither a player nor a mailing list/folder";
else
if (fwd = this:mail_forward(recip))
this:touch(fwd, {@seen, recip});
endif
if (!is_player(recip))
recip.last_used_time = time();
endif
endif
endif

look_self

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

none

Source

player:tell_lines(this.description);
for c in (this.contents)
c:look_self();
endfor

acceptable

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

none

Source

"Only allow mailing lists/folders in here and only if their names aren't already taken.";
what = args[1];
return is_a(what, $mail_recipient) && this:check_names(@what.aliases);

check_names

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #38:acceptable line 3: this:check_names

Source

"...make sure the list has at least one usable name.";
"...make sure none of the aliases are already taken.";
ok = 0;
for a in (args)
sub1 = strsub(a, "_", "-");
sub2 = strsub(a, "-", "_");
if (sub1 == sub2)
check = 0;
else
check = 1;
endif
if (index(a, " "))
elseif (rp = $mail_agent:reserved_pattern(a))
player:tell("Mailing list name \"", a, "\" uses a reserved pattern: ", rp[1]);
return 0;
elseif (valid(p = $mail_agent:match(a, #-1)) && (a in p.aliases))
player:tell("Mailing list name \"", a, "\" in use on ", p.name, "(", p, ")");
return 0;
elseif ((check && valid(p = $mail_agent:match(sub1, #-1))) && (sub1 in p.aliases))
player:tell("Mailing list name \"", sub1, "\" in use on ", p.name, "(", p, ")");
return 0;
elseif ((check && valid(p = $mail_agent:match(sub2, #-1))) && (sub2 in p.aliases))
player:tell("Mailing list name \"", sub2, "\" in use on ", p.name, "(", p, ")");
return 0;
else
ok = 1;
endif
endfor
return ok;

match

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #33:@random line 5: $mail_agent:match
• #37:set_aliases line 16: $mail_agent:match
• #37:set_name line 12: $mail_agent:match
• #38:check_names line 16: $mail_agent:match
• #38:check_names line 19: $mail_agent:match
• #38:check_names line 22: $mail_agent:match
• #38:match_recipient line 8: this:match
• #38:match_recipient line 15: this:match
• #38:parse_new_mailspec line 19: $mail_agent:match
• #39:subsc*ribe line 6: $mail_agent:match
• #39:unsubsc*ribe line 4: $mail_agent:match

Source

":match(string) => mailing list object in here that matches string.";
":match(string,player) => similar but also matches against player's private mailing lists (as kept in .mail_lists).";
if (!(string = args[1]))
return $nothing;
elseif (string[1] == "*")
string = string[2..$];
endif
if (valid(o = $string_utils:literal_object(string)) && ($mail_recipient in $object_utils:ancestors(o)))
return o;
elseif (rp = this:reserved_pattern(string))
return rp[2]:match_mail_recipient(string);
else
if (valid(who = {@args, player}[2]) && (typeof(use = `who.mail_lists ! E_PROPNF, E_PERM') == LIST))
use = {@this.contents, @use};
else
use = this.contents;
endif
partial = 1;
string = strsub(string, "_", "-");
for l in (use)
if (string in l.aliases)
return l;
endif
if (partial != $ambiguous_match)
for a in (l.aliases)
if ((index(a, string) == 1) && (!index(a, " ")))
if (partial)
partial = l;
elseif (partial != l)
partial = $ambiguous_match;
endif
endif
$command_utils:suspend_if_needed(2);
endfor
endif
endfor
return partial && $failed_match;
endif

match_recipient

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #6:@top line 23: $mail_agent:match_recipient
• #20:literal_object line 10: $mail_agent:match_recipient
• #33:parse_folder_spec line 20: $mail_agent:match_recipient
• #33:@renumber line 4: $mail_agent:match_recipient
• #33:@forward line 15: $mail_agent:match_recipient
• #33:@skip line 7: $mail_agent:match_recipient
• #33:@subscribe*-quick line 35: $mail_agent:match_recipient
• #33:@subscribe*-quick line 74: $mail_agent:match_recipient
• #33:@unsub*scribe line 9: $mail_agent:match_recipient
• #33:@resend line 18: $mail_agent:match_recipient
• #33:@refile line 9: $mail_agent:match_recipient
• #39:not-to*: line 18: $mail_agent:match_recipient
• #39:parse_recipients line 11: $mail_agent:match_recipient
• #50:@mine line 4: $mail_agent:match_recipient

Source

":match_recipient(string[,meobj]) => $player or $mail_recipient object that matches string.  Optional second argument (defaults to player) is returned in the case string==\"me\" and is also used to obtain a list of private $mail_recipients to match against.";
{string, ?me = player} = args;
if (valid(me) && ($failed_match != (o = me:my_match_recipient(string))))
return o;
elseif (!string)
return $nothing;
elseif ((string[1] == "*") && (string != "*"))
return this:match(@args);
elseif (string[1] == "`")
args[1][1..1] = "";
return $string_utils:match_player(@args);
elseif (valid(o = $string_utils:match_player(@args)) || (o == $ambiguous_match))
return o;
else
return this:match(@args);
endif

match_failed

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #6:@top line 25: $mail_agent:match_failed
• #33:parse_folder_spec line 20: $mail_agent:match_failed
• #33:@renumber line 4: $mail_agent:match_failed
• #33:@forward line 15: $mail_agent:match_failed
• #33:@skip line 7: $mail_agent:match_failed
• #33:@subscribe*-quick line 35: $mail_agent:match_failed
• #33:@subscribe*-quick line 74: $mail_agent:match_failed
• #33:@unsub*scribe line 21: $mail_agent:match_failed
• #33:@resend line 18: $mail_agent:match_failed
• #33:@refile line 9: $mail_agent:match_failed
• #38:parse_new_mailspec line 21: $mail_agent:match_failed
• #39:parse_recipients line 11: $mail_agent:match_failed
• #39:subsc*ribe line 6: $mail_agent:match_failed
• #39:unsubsc*ribe line 4: $mail_agent:match_failed

Source

{match_result, string, ?cmd_id = ""} = args;
cmd_id = cmd_id || "";
if (match_result == $nothing)
player:tell(cmd_id, "You must specify a valid mail recipient.");
elseif (match_result == $failed_match)
player:tell(cmd_id, "There is no mail recipient called \"", string, "\".");
elseif (match_result == $ambiguous_match)
if (nostar = ((index(string, "*") != 1) && player.programmer) && (lst = $player_db:find_all(string)))
player:tell(cmd_id, "\"", string, "\" could refer to ", (length(lst) > 20) ? tostr("any of ", length(lst), " players") | $string_utils:english_list($list_utils:map_arg(2, $string_utils, "pronoun_sub", "%n (%#)", lst), "no one", " or "), ".");
else
player:tell(cmd_id, "I don't know which \"", nostar ? "*" | "", string, "\" you mean.");
endif
elseif (!valid(match_result))
player:tell(cmd_id, match_result, " does not exist.");
else
return 0;
endif
return 1;

make_message

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #38:send_message line 22: $mail_agent:make_message
• #38:send_log_message line 9: $mail_agent:make_message
• #38:resend_message line 15: $mail_agent:make_message
• #39:message_with_headers line 1: $mail_agent:make_message
• #39:make_message line 1: $mail_agent:make_message

Source

":make_message(sender,recipients,subject/replyto/additional-headers,body)";
" => message in the form as it will get sent.";
{from, recips, hdrs, body} = args;
try
fromowner = from.owner;
except (E_INVIND)
raise(E_PERM);
endtry
fromline = this:name_list(from);
if (typeof(recips) != LIST)
recips = {recips};
endif
recips = this:name_list(@recips);
others = {};
replyto = 0;
if (typeof(hdrs) != LIST)
hdrs = {hdrs};
endif
subj = $su:escape(hdrs[1]);
if (!valid(from))
others = {"Probable-Sender:   " + this:name(fromowner)};
"  others = {'Possible-Sender:   ' + this:name(player)}";
"  if (caller_perms() != player)";
"    others = {@others, 'Possible-Sender:   ' + this:name(caller_perms())}";
"  endif";
endif
replyto = {@hdrs, 0}[2] && this:name_list(@hdrs[2]);
if (length(hdrs) > 2)
hdrs[1..2] = {};
for h in (hdrs)
if (match(h[1], "[a-z1-9-]+"))
others = {@others, $su:escape($su:left(h[1] + ": ", 15) + h[2])};
endif
endfor
endif
if (typeof(body) != LIST)
body = body ? {body} | {};
endif
for i in [1..length(body)]
body[i] = $su:escape($ansi:strip(body[i]));
endfor
return {time(), fromline, recips, subj || " ", @replyto ? {"Reply-to: " + replyto} | {}, @others, "", @body};

name

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #9:_repair line 144: $mail_agent:name
• #17:newt_player line 28: $mail_agent:name
• #33:notify_mail line 10: $mail_agent:name
• #33:parse_mailread_cmd line 34: $mail_agent:name
• #33:parse_mailread_cmd line 45: $mail_agent:name
• #33:@mail line 13: $mail_agent:name
• #33:@read line 17: $mail_agent:name
• #33:@rmm*ail line 6: $mail_agent:name
• #33:@rmm*ail line 13: $mail_agent:name
• #33:@rmm*ail line 16: $mail_agent:name
• #33:@renumber line 8: $mail_agent:name
• #33:@unrmm*ail line 21: $mail_agent:name
• #33:@unrmm*ail line 24: $mail_agent:name
• #33:@unrmm*ail line 27: $mail_agent:name
• #33:@unrmm*ail line 29: $mail_agent:name
• #33:@forward line 39: $mail_agent:name
• #33:@skip line 16: $mail_agent:name
• #33:@subscribe*-quick line 79: $mail_agent:name
• #33:@subscribe*-quick line 92: $mail_agent:name
• #33:@rn line 39: $mail_agent:name
• #33:@unsub*scribe line 27: $mail_agent:name
• #33:@netforw*ard line 14: $mail_agent:name
• #33:@keep-m*ail line 16: $mail_agent:name
• #33:@resend line 71: $mail_agent:name
• #33:@nn line 11: $mail_agent:name
• #33:@mail-all-new*-mail line 13: $mail_agent:name
• #33:@mail-all-new*-mail line 16: $mail_agent:name
• #33:@read-all-new*-mail line 18: $mail_agent:name
• #33:@read-all-new*-mail line 21: $mail_agent:name
• #33:@read-all-new*-mail line 23: $mail_agent:name
• #37:expire_old_messages line 13: $mail_agent:name
• #38:make_message line 21: this:name
• #38:display_message_improved line 12: $mail_agent:name
• #38:parse_new_mailspec line 36: $mail_agent:name
• #38:parse_new_mailspec line 43: $mail_agent:name
• #43:y*ank line 19: $mail_agent:name
• #49:@toad line 54: $mail_agent:name

Source

if (!args)
return pass(@args);
endif
what = args[1];
if (!valid(what))
name = "???";
elseif ((!is_player(what)) && $object_utils:has_callable_verb(what, "mail_name"))
name = what:mail_name();
else
name = what.name;
endif
return tostr(name, " (", what, ")");

name_list

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #33:@forward line 39: $mail_agent:name_list
• #33:@@sendmail line 74: $mail_agent:name_list
• #33:@resend line 71: $mail_agent:name_list
• #33:@quickr*eply line 16: $mail_agent:name_list
• #33:@quickr*eply line 21: $mail_agent:name_list
• #33:@quickr*eply line 25: $mail_agent:name_list
• #33:@quickr*eply line 35: $mail_agent:name_list
• #33:@quick*send line 53: $mail_agent:name_list
• #33:@quick*send line 80: $mail_agent:name_list
• #38:make_message line 9: this:name_list
• #38:make_message line 13: this:name_list
• #38:make_message line 27: this:name_list
• #38:resend_message line 13: this:name_list
• #38:resend_message line 13: this:name_list
• #39:recipient_names line 1: $mail_agent:name_list
• #39:reply-to*: line 10: $mail_agent:name_list
• #39:send line 34: $mail_agent:name_list
• #39:who line 18: $mail_agent:name_list
• #39:who line 18: $mail_agent:name_list
• #39:local_editing_info line 1: $mail_agent:name_list
• #39:local_editing_info line 3: $mail_agent:name_list
• #59:show_replyto line 2: $mail_agent:name_list

Source

return $string_utils:english_list($list_utils:map_arg(this, "name", args), "no one");

parse_address_field

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #9:to_msg_seq line 17: $mail_agent:parse_address_field
• #33:receive_message line 7: $mail_agent:parse_address_field
• #33:@@sendmail line 36: $mail_agent:parse_address_field
• #33:@@sendmail line 41: $mail_agent:parse_address_field
• #33:@@sendmail line 47: $mail_agent:parse_address_field
• #33:@resend line 36: $mail_agent:parse_address_field
• #33:@resend line 37: $mail_agent:parse_address_field
• #38:to_msg_seq line 13: $mail_agent:parse_address_field
• #39:parse_msg_headers line 10: $mail_agent:parse_address_field
• #39:parse_msg_headers line 18: $mail_agent:parse_address_field
• #39:parse_msg_headers line 21: $mail_agent:parse_address_field
• #39:parse_msg_headers(slow) line 7: $mail_agent:parse_address_field
• #39:parse_msg_headers(slow) line 23: $mail_agent:parse_address_field

Source

":parse_address_field(string) => list of objects";
"This is the standard routine for parsing address lists that appear in From:, To: and Reply-To: lines";
objects = {};
string = args[1];
while (e = index(string, ")"))
if ((s = rindex(string[1..e], "(#")) && (#0 != (o = toobj(string[s + 2..e - 1]))))
objects = {@objects, o};
endif
string = string[e + 1..$];
endwhile
return objects;

display_seq_full

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":display_seq_full(msg_seq[,preamble]) => {cur, last-read-date}";
"This is the default message display routine.";
"Prints entire messages on folder (caller) to player.  msg_seq is the handle returned by :parse_message_seq(...) and indicates which messages should be printed.  preamble, if given will precede the output of the message itself, in which case the message number will be substituted for \"%d\".  Returns the number of the final message in the sequence (which can be then used as the new current message number).";
set_task_perms(caller_perms());
{msg_seq, ?preamble = ""} = args;
cur = date = 0;
for x in (msgs = caller:messages_in_seq(msg_seq))
cur = x[1];
date = x[2][1];
if (!player:check_pref("oldmail"))
this:display_message_improved(cur, caller, @x[2]);
else
player:display_message(preamble ? strsub(preamble, "%d", tostr(cur)) | {}, caller:msg_full_text(@x[2]));
endif
if ((ticks_left() < 500) || (seconds_left() < 2))
suspend(0);
endif
endfor
if (cur)
player:tell("");
endif
return {cur, date};

display_seq_headers

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":display_seq_headers(msg_seq[,cur[,last_read_date]])";
"This is the default header display routine.";
"Prints a list of headers of messages on caller to player.  msg_seq is the handle returned by caller:parse_message_seq(...).  cur is the player's current message.  last_read_date is the date of the last of the already-read messages.";
set_task_perms(caller_perms());
{msg_seq, ?cur = 0, ?last_old = $maxint, ?show_end = 1} = args;
keep_seq = {@$seq_utils:contract(caller:kept_msg_seq(), $seq_utils:complement(msg_seq, 1, caller:length_all_msgs())), $maxint};
k = 1;
mcount = 0;
width = player:linelen() || 79;
for x in (msgs = caller:messages_in_seq(msg_seq))
if (keep_seq[k] <= (mcount = mcount + 1))
k = k + 1;
endif
annot = ((d = x[2][1]) > last_old) ? "+" | ((k % 2) ? " " | "=");
yield;
summary = caller:msg_summary_line(@x[2]);
yield;
if (typeof(summary) != LIST)
summary = {summary};
endif
prefix = tostr($string_utils:right(x[1], 4, (cur == x[1]) ? ">" | " "), ":", annot, " ");
player:tell($su:left(prefix + summary[1], -width));
prefix = $su:space(length(prefix));
for l in (summary[2..$])
player:tell($su:left(prefix + l, -width));
yield;
endfor
yield;
endfor
show_end && player:tell("----+");

rm_message_seq

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":rm_message_seq(msg_seq)  removes the given sequence of from folder (caller)";
"...removed messages are saved in .messages_going for possible restoration.";
set_task_perms(caller_perms());
old = caller.messages;
new = save = nums = {};
next = 1;
for i in [1..length(seq = args[1]) / 2]
if ($command_utils:running_out_of_time())
player:tell("... rmm ", old[next][1] - 1);
suspend(0);
endif
start = seq[(2 * i) - 1];
new = {@new, @old[next..start - 1]};
save = {@save, {start - next, old[start..(next = seq[2 * i]) - 1]}};
nums = {@nums, old[start][1], old[next - 1][1] + 1};
endfor
new = {@new, @old[next..$]};
$command_utils:suspend_if_needed(0, "... rmm ...");
save_kept = $seq_utils:intersection(caller.messages_kept, seq);
$command_utils:suspend_if_needed(0, "... rmm ...");
new_kept = $seq_utils:contract(caller.messages_kept, seq);
$command_utils:suspend_if_needed(0, "... rmm ...");
caller.messages_going = save_kept ? {save_kept, save} | save;
caller.messages = new;
caller.messages_kept = new_kept;
if ($object_utils:has_callable_verb(caller, "_fix_last_msg_date"))
caller:_fix_last_msg_date();
endif
return $seq_utils:tostr(nums);

undo_rmm

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":undo_rmm()  restores previously deleted messages in .messages_going to .messages.";
set_task_perms(caller_perms());
old = caller.messages;
going = caller.messages_going;
new = seq = {};
last = 0;
next = 1;
"there are two possible formats here:";
"OLD: {{n,msgs},{n,msgs},...}";
"NEW: {kept_seq, {{n,msgs},{n,msgs},...}}";
if (going && ((!going[1]) || (typeof(going[1][2]) == INT)))
kept = going[1];
going = going[2];
else
kept = {};
endif
for s in (going)
new = {@new, @old[last + 1..last + s[1]], @s[2]};
last = last + s[1];
seq = {@seq, next + s[1], next = length(new) + 1};
endfor
caller.messages = {@new, @old[last + 1..$]};
caller.messages_going = {};
caller.messages_kept = $seq_utils:union(kept, $seq_utils:expand(caller.messages_kept, seq));
if ($object_utils:has_callable_verb(caller, "_fix_last_msg_date"))
caller:_fix_last_msg_date();
endif
return seq;

expunge_rmm list_rmm

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":list_rmm()    displays contents of .messages_going.";
":expunge_rmm() destroys contents of .messages_going once and for all.";
"... both return the number of messages in .messages_going.";
set_task_perms(caller_perms());
cmg = caller.messages_going;
if (cmg && ((!cmg[1]) || (typeof(cmg[1][2]) == INT)))
kept = cmg[1];
cmg = cmg[2];
else
kept = {};
endif
if (verb == "expunge_rmm")
caller.messages_going = {};
count = 0;
for s in (cmg)
count = count + length(s[2]);
endfor
return count;
elseif (!cmg)
return 0;
else
msgs = seq = {};
next = 1;
for s in (cmg)
msgs = {@msgs, @s[2]};
seq = {@seq, next = next + s[1], next = next + length(s[2])};
endfor
kept = {@$seq_utils:contract(kept, $seq_utils:complement(seq, 1, $seq_utils:last(seq))), $maxint};
k = 1;
mcount = 0;
for x in (msgs)
if (kept[k] <= (mcount = mcount + 1))
k = k + 1;
endif
player:tell($string_utils:right(x[1], 4), ":", (k % 2) ? "  " | "= ", caller:msg_summary_line(@x[2]));
if ((ticks_left() < 500) || (seconds_left() < 2))
suspend(0);
endif
endfor
if (msgs)
player:tell("----+");
endif
return length(msgs);
endif

renumber

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":renumber([cur]) -- assumes caller is a $mail_recipient or a $player.";
"...renumbers caller.messages, doing a suspend() if necessary.";
"...returns {number of messages,new cur}.";
set_task_perms(caller_perms());
{?cur = 0} = args;
caller.messages_going = {};
"... blow away @rmm'ed messages since there's no way to tell what their new numbers should be...";
msgs = caller.messages;
if (cur)
cur = $list_utils:iassoc_sorted(cur, msgs);
endif
while (1)
"...find first out-of-sequence message...";
l = 0;
r = (len = length(msgs)) + 1;
while ((r - 1) > l)
if (msgs[i = (r + l) / 2][1] > i)
r = i;
else
l = i;
endif
endwhile
"... r == first out-of-sequence, l == last in-sequence, l+1 == r ...";
if (l >= len)
return {l, cur};
endif
"...renumber as many messages as we have time for...";
chunk = {};
while (((r <= len) && (ticks_left() > 3000)) && (seconds_left() > 2))
for x in (msgs[r..min(r + 9, len)])
chunk = {@chunk, {r, x[2]}};
r = r + 1;
endfor
endwhile
caller.messages = {@msgs[1..l], @chunk, @msgs[r..len]};
if (chunk)
player:tell("...(renumbering ", l + 1, " -- ", r - 1, ")");
suspend(0);
else
player:tell("You lose.  This message collection is just too big.");
return;
endif
"... have to be careful since new mail may be received at this point...";
msgs = caller.messages;
endwhile

msg_summary_line

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #33:msg_summary_line line 1: $mail_agent:msg_summary_line
• #37:msg_summary_line line 1: $mail_agent:msg_summary_line

Source

":msg_summary_line(@msg) => date/from/subject as a single string.";
body = ("" in {@args, ""}) + 1;
if ((length(args) > body) && (!args[body]))
body = body + 1;
endif
if ((body > length(args)) || (!(subject = args[body])))
subject = "(no text)";
endif
if (args[1] < (time() - 31536000))
c = player:ctime(args[1]);
date = c[5..11] + c[21..25];
else
date = player:ctime(args[1])[5..16];
endif
from = args[2];
from_obj = from[rindex(from, " ") + 2..$ - 1];
if (args[4] != " ")
subject = args[4];
endif
return tostr(date, "   ", $string_utils:left(from, 20), "   ", subject);

parse_message_seq

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

"parse_message_seq(strings,cur[,last_old])";
"This is the default <message-sequence> parsing routine for those mail commands that refer to sequences of messages (@mail, @read,...) on a folder.";
"  caller (the folder) is assumed to be a $mail_recipient or a player.";
"  strings is the <message-sequence> portion of the arg list.";
"  cur is the number of the player's current message for this folder.";
"Returns a string error message if the parse fails, otherwise";
"returns a list {msg_seq, @unused_strings}, where";
"   msg_seq is a handle understood by caller:display_seq_full/headers(), and ";
"   unused_strings is the list of remaining uninterpreted strings";
set_task_perms(caller_perms());
{strings, ?cur = 0, ?last_old = 0} = args;
if (!(nummsgs = caller:length_all_msgs()))
return "%f %<has> no messages.";
elseif (typeof(strings) != LIST)
strings = {strings};
endif
seq = result = {};
mode = #0;
"... changes to 0 if we start seeing message numbers, to 1 if we see masks...";
keywords = ":from:%from:to:%to:subject:body:before:after:since:until:first:last:kept:unkept";
keyalist = {{1, "from"}, {6, "%from"}, {12, "to"}, {15, "%to"}, {19, "subject"}, {27, "body"}, {32, "before"}, {39, "after"}, {45, "since"}, {51, "until"}, {57, "first"}, {63, "last"}, {68, "kept"}, {73, "unkept"}};
strnum = 0;
for string in (strings)
strnum = strnum + 1;
$command_utils:suspend_if_needed(0);
if (string && ((c = index(string, ":")) && ((k = index(keywords, ":" + string[1..c - 1])) && (k == rindex(keywords, ":" + string[1..c - 1])))))
"...we have a mask to apply...";
keywd = $list_utils:assoc(k, keyalist)[2];
if (mode == #0)
seq = {1, nummsgs + 1};
endif
mode = 1;
if (k <= 27)
"...from, subject, to, body...";
pattern = string[c + 1..$];
if (keywd in {"subject", "body"})
elseif (keywd[1] == "%")
pattern = $string_utils:explode(pattern, "|");
else
pattern = this:((keywd == "to") ? "_parse_to" | "_parse_from")(pattern);
if (typeof(pattern) == STR)
return pattern;
endif
endif
seq = caller:(keywd + "_msg_seq")(pattern, seq);
if (typeof(seq) == STR)
if (strnum == 1)
return seq;
else
seq = {};
endif
endif
elseif (k <= 51)
"...before, since, after, until...";
if (typeof(date = this:_parse_date(string[c + 1..$])) != INT)
return tostr("Bad date `", string, "':  ", date);
endif
s = caller:length_date_le((keywd in {"before", "since"}) ? date - 1 | (date + 86399));
if (keywd in {"before", "until"})
seq = $seq_utils:remove(seq, s + 1, nummsgs);
else
seq = $seq_utils:remove(seq, 1, s);
endif
elseif (k <= 63)
"...first, last...";
if (n = toint(string[c + 1..$]))
seq = $seq_utils:(keywd + "n")(seq, n);
else
return tostr("Bad number in `", string, "'");
endif
else
"...kept, unkept...";
if (c < length(string))
return tostr("Unexpected junk after `", keywd, ":'");
elseif ((!(seq = caller:(keywd + "_msg_seq")(seq))) && (strnum == 1))
return tostr("%f %<has> no ", keywd, " messages.");
endif
endif
else
"...continue building the present sequence...";
if (mode)
seq && (result = $seq_utils:union(result, seq));
seq = {};
endif
mode = 0;
if (!string)
"...default case for @read: get the current message but skip to the next one if it's not there...";
if (cur)
i = min(caller:length_num_le(cur - 1) + 1, nummsgs);
seq = $seq_utils:add(seq, i, i);
else
return "%f %<has> no current message.";
endif
elseif ((index(string, "next") == 1) && (!index(string, "-")))
string[1..4] = "";
if ((n = string ? toint(string) | 1) <= 0)
return tostr("Bad number `", string, "'");
elseif ((i = caller:length_num_le(cur) + 1) <= nummsgs)
seq = $seq_utils:add(seq, i, min((i + n) - 1, nummsgs));
else
return "%f %<has> no next message.";
endif
elseif ((index(string, "prev") == 1) && (!index(string, "-")))
string[1..4] = "";
if ((n = string ? toint(string) | 1) <= 0)
return tostr("Bad number `", string, "'");
elseif (i = caller:length_num_le(cur - 1))
seq = $seq_utils:add(seq, max(1, (i - n) + 1), i);
else
return "%f %<has> no previous message.";
endif
elseif (string == "new")
s = last_old ? caller:length_date_le(last_old) | caller:length_num_le(cur);
if (s < nummsgs)
seq = $seq_utils:add(seq, s + 1, nummsgs);
else
return "%f %<has> no new messages.";
endif
elseif (string == "first")
seq = $seq_utils:add(seq, 1, 1);
elseif (n = toint(string) || (((string in {"last", "$"}) && -1) || ((string == "cur") && cur)))
if (n <= 0)
seq = $seq_utils:add(seq, max(0, nummsgs + n) + 1, nummsgs);
elseif (i = caller:exists_num_eq(n))
seq = $seq_utils:add(seq, i, i);
else
return (string == "cur") ? "%f's current message has been removed." | tostr("%f %<has> no message numbered `", string, "'.");
endif
elseif (((i = index(string, "..")) > 1) || ((i = index(string, "-")) > 1))
if ((start = toint(sst = string[1..i - 1])) > 0)
s = caller:length_num_le(start - 1);
elseif (sst in {"next", "prev", "cur"})
s = max(0, caller:length_num_le(cur - (sst != "next")) - (sst == "prev"));
elseif (sst in {"last", "$"})
s = nummsgs - 1;
elseif (sst == "first")
s = 0;
else
return {$seq_utils:union(result, seq), @strings[strnum..$]};
endif
j = (string[i] == ".") ? i + 2 | (i + 1);
if ((end = toint(est = string[j..$])) > 0)
e = caller:length_num_le(end);
elseif (est in {"next", "prev", "cur"})
e = min(nummsgs, caller:length_num_le(cur - (est == "prev")) + (est == "next"));
elseif (est in {"last", "$"})
e = nummsgs;
elseif (est == "first")
e = 1;
else
return {$seq_utils:union(result, seq), @strings[strnum..$]};
endif
if (s < e)
seq = $seq_utils:add(seq, s + 1, e);
else
return tostr("%f %<has> no messages in range ", string, ".");
endif
elseif (string == "cur")
return "%f %<has> no current message.";
else
return {$seq_utils:union(result, seq), @strings[strnum..$]};
endif
endif
endfor
return {$seq_utils:union(result, seq)};

_parse_from _parse_to

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

none

Source

":_parse_from(string with |'s in it) => object list";
":_parse_to(string with |'s in it) => object list";
"  for from:string and to:string items in :parse_message_seq";
if (verb == "_parse_to")
match_obj = fail_obj = this;
match_verb = "match_recipient";
fail_verb = "match_failed";
else
match_obj = $string_utils;
match_verb = "match_player";
fail_obj = $command_utils;
fail_verb = "player_match_failed";
endif
plist = {};
for w in ($string_utils:explode(args[1], "|"))
if (fail_obj:(fail_verb)(p = match_obj:(match_verb)(w), w))
p = $string_utils:literal_object(w);
if ((p == $failed_match) || (!$command_utils:yes_or_no("Continue? ")))
return "Bad address list:  " + args[1];
endif
endif
plist = setadd(plist, p);
endfor
return plist;

_parse_date

Spec this none thisFlags rxdOwner #29Definer #38

Referenced by

• #38:parse_message_seq line 55: this:_parse_date
• #293:parse_message_seq line 65: $mail_agent:_parse_date
• #293:pms_old line 65: $mail_agent:_parse_date

Source

words = $string_utils:explode(args[1], "-");
if (length(words) == 1)
if (index("yesterday", words[1]) == 1)
time = $time_utils:dst_midnight((time() - (time() % 86400)) - 86400);
elseif (index("today", words[1]) == 1)
time = $time_utils:dst_midnight(time() - (time() % 86400));
elseif (index("lastweek", words[1]) == 1)
time = $time_utils:dst_midnight((time() - (time() % 86400)) - (7 * 86400));
elseif (index("lastmonth", words[1]) == 1)
time = $time_utils:dst_midnight((time() - (time() % 86400)) - (30 * 86400));
elseif (index("lastyear", words[1]) == 1)
time = $time_utils:dst_midnight((time() - (time() % 86400)) - (365 * 86400));
elseif (typeof(time = $time_utils:from_day(words[1], -1)) == ERR)
time = "weekday, `Today', `Yesterday', or date expected.";
endif
elseif ((!words) || ((length(words) > 3) || ((!toint(words[1])) || (E_TYPE == (year = $code_utils:toint({@words, "-1"}[3]))))))
time = "Date should be of the form `5-Jan', `5-Jan-92', `Wed',`Wednesday'";
else
day = toint(words[1]);
time = $time_utils:dst_midnight($time_utils:from_month(words[2], -1, day));
if (length(words) == 3)
thisyear = toint(ctime(time)[21..24]);
if (100 > year)
year = (thisyear + 50) - (((thisyear - year) + 50) % 100);
endif
time = $time_utils:dst_midnight($time_utils:from_month(words[2], (year - thisyear) - (year <= thisyear), day));
endif
endif
return time;

new_message_num

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":new_message_num() => number that the next incoming message will receive.";
set_task_perms(caller_perms());
new = (msgs = caller.messages) ? msgs[$][1] + 1 | 1;
if (rmsgs = caller.messages_going)
if ((!rmsgs[1]) || (typeof(rmsgs[1][2]) == INT))
rmsgs = rmsgs[2];
endif
lbrm = rmsgs[$][2];
return max(new, lbrm[$][1] + 1);
else
return new;
endif

length_all_msgs

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

set_task_perms(caller_perms());
return length(caller.messages);

length_date_le

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

set_task_perms(caller_perms());
date = args[1];
msgs = caller.messages;
if ((r = length(caller.messages)) < 25)
for l in [1..r]
if (msgs[l][2][1] > date)
return l - 1;
endif
endfor
return r;
else
l = 1;
while (l <= r)
if (date < msgs[i = (r + l) / 2][2][1])
r = i - 1;
else
l = i + 1;
endif
endwhile
return r;
endif

length_date_gt

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

set_task_perms(caller_perms());
date = args[1];
msgs = caller.messages;
if ((len = length(caller.messages)) < 25)
for r in [0..len - 1]
if (msgs[len - r][2][1] <= date)
return r;
endif
endfor
return len;
else
l = 1;
r = len;
while (l <= r)
if (date < msgs[i = (r + l) / 2][2][1])
r = i - 1;
else
l = i + 1;
endif
endwhile
return len - r;
endif

length_num_le

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":length_num_le(num) => number of messages in folder numbered <= num";
set_task_perms(caller_perms());
return $list_utils:iassoc_sorted(args[1], caller.messages);

exists_num_eq

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":exists_num_eq(num) => index of message in folder numbered == num";
set_task_perms(caller_perms());
return (i = $list_utils:iassoc_sorted(args[1], caller.messages)) && ((caller.messages[i][1] == args[1]) && i);

from_msg_seq

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":from_msg_seq(object or list[,mask])";
" => msg_seq of messages from any of these senders";
set_task_perms(caller_perms());
{plist, ?mask = {1}} = args;
if (typeof(plist) != LIST)
plist = {plist};
endif
i = 1;
fseq = {};
for msg in (caller.messages)
if ((!mask) || (i < mask[1]))
elseif ((length(mask) < 2) || (i < mask[2]))
fromline = msg[2][2];
if (toobj(fromline[rindex(fromline, "(") + 1..rindex(fromline, ")") - 1]) in plist)
fseq = $seq_utils:add(fseq, i, i);
endif
else
mask = mask[3..$];
endif
i = i + 1;
$command_utils:suspend_if_needed(0);
endfor
return fseq || ("%f %<has> no messages from " + $string_utils:english_list($list_utils:map_arg(2, $string_utils, "pronoun_sub", "%n (%#)", plist), "no one", " or "));

%from_msg_seq

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":%from_msg_seq(string or list of strings[,mask])";
" => msg_seq of messages with one of these strings in the from line";
set_task_perms(caller_perms());
{nlist, ?mask = {1}} = args;
if (typeof(nlist) != LIST)
nlist = {nlist};
endif
i = 1;
fseq = {};
for msg in (caller.messages)
if ((!mask) || (i < mask[1]))
elseif ((length(mask) < 2) || (i < mask[2]))
fromline = " " + msg[2][2];
for n in (nlist)
if (index(fromline, n))
fseq = $seq_utils:add(fseq, i, i);
endif
endfor
else
mask = mask[3..$];
endif
i = i + 1;
$command_utils:suspend_if_needed(0);
endfor
return fseq || ("%f %<has> no messages from " + $string_utils:english_list($list_utils:map_arg($string_utils, "print", nlist), "no one", " or "));

to_msg_seq

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":to_msg_seq(object or list[,mask]) => msg_seq of messages to those people";
set_task_perms(caller_perms());
{plist, ?mask = {1}} = args;
if (typeof(plist) != LIST)
plist = {plist};
endif
i = 1;
seq = {};
for msg in (caller.messages)
if ((!mask) || (i < mask[1]))
elseif ((length(mask) < 2) || (i < mask[2]))
toline = msg[2][3];
for r in ($mail_agent:parse_address_field(toline))
if (r in plist)
seq = $seq_utils:add(seq, i, i);
endif
endfor
else
mask = mask[3..$];
endif
i = i + 1;
$command_utils:suspend_if_needed(0);
endfor
return seq || ("%f %<has> no messages to " + $string_utils:english_list($list_utils:map_arg(2, $string_utils, "pronoun_sub", "%n (%#)", plist), "no one", " or "));

%to_msg_seq

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":%to_msg_seq(string or list of strings[,mask])";
" => msg_seq of messages containing one of strings in the to line";
set_task_perms(caller_perms());
{nlist, ?mask = {1}} = args;
if (typeof(nlist) != LIST)
nlist = {nlist};
endif
i = 1;
seq = {};
for msg in (caller.messages)
if ((!mask) || (i < mask[1]))
elseif ((length(mask) < 2) || (i < mask[2]))
toline = " " + msg[2][3];
for n in (nlist)
if (index(toline, n))
seq = $seq_utils:add(seq, i, i);
endif
endfor
else
mask = mask[3..$];
endif
i = i + 1;
$command_utils:suspend_if_needed(0);
endfor
return seq || ("%f %<has> no messages to " + $string_utils:english_list($list_utils:map_arg($string_utils, "print", nlist), "no one", " or "));

subject_msg_seq

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":subject_msg_seq(target) => msg_seq of messages with target in the Subject:";
set_task_perms(caller_perms());
{target, ?mask = {1}} = args;
i = 1;
seq = {};
for msg in (caller.messages)
if ((!mask) || (i < mask[1]))
elseif ((length(mask) < 2) || (i < mask[2]))
subject = msg[2][4];
if (index(subject, target))
seq = $seq_utils:add(seq, i, i);
endif
else
mask = mask[3..$];
endif
i = i + 1;
$command_utils:suspend_if_needed(0);
endfor
return seq || (("%f %<has> no messages with subjects containing `" + target) + "'");

body_msg_seq

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":body_msg_seq(target[,mask]) => msg_seq of messages with target in the body";
set_task_perms(caller_perms());
{target, ?mask = {1}} = args;
i = 1;
seq = {};
for msg in (caller.messages)
if ((!mask) || (i < mask[1]))
elseif ({@mask, $maxint}[2] <= i)
mask = mask[3..$];
"Old code follows. Lets save ticks and munge up the whole message body into one big string and index it. Don't need to know where target is in there, just that it is or isn't there";
elseif (((bstart = "" in (msg = msg[2])) && (length(msg) > bstart)) && index(tostr(@msg[bstart + 1..$]), target))
seq = $seq_utils:add(seq, i, i);
"elseif ((bstart = \"\" in (msg = msg[2])) && (l = length(msg)) > bstart)";
"while (!index(msg[l], target) && (l = l - 1) > bstart)";
"$command_utils:suspend_if_needed(0);";
"endwhile";
"if (l > bstart)";
"seq = $seq_utils:add(seq, i, i);";
"endif";
endif
i = i + 1;
$command_utils:suspend_if_needed(0);
endfor
return seq || tostr("%f %<has> no messages containing `", target, "' in the body.");

messages_in_seq

Spec this none thisFlags rxdOwner #361Definer #38

Referenced by

none

Source

":messages_in_seq(msg_seq) => list of messages in msg_seq on folder (caller)";
set_task_perms(caller_perms());
if (typeof(msgs = args[1]) != LIST)
return caller.messages[msgs];
elseif (length(msgs) == 2)
return caller.messages[msgs[1]..msgs[2] - 1];
else
return $seq_utils:extract(msgs, caller.messages);
endif