generic furniture #137

rise stand

Spec none out of/from inside/from thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

target = valid(dobj) ? dobj | player;
target:queue_action($actions.stand, {this}, 1, (verb + " ") + argstr);

integrated_objects

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

":integrated_objects() => { all objects this object integrates into its description when looked at }";
"This verb returns a list of every object that this object will integrate into its own description when someone looks at it.";
integrated = {};
for x in ({@this.sitting, @this.reclining})
integrated = setadd(integrated, x);
endfor
return setadd(integrated, this);

look_place_msg

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

this:validate_occupants();
return pass(@args);

recline lie lay

Spec none on top of/on/onto/upon thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

if (this.location != player.location)
player:tell("You need to set ", this:dname(), " down before you can lay on it.");
return;
endif
for x in (setremove({@this.location:occupants($furniture), this.location}, this))
if ((player in x.reclining) || (player in x.sitting))
player:tell("You're already on ", x:dname(), ", you'll have to get up if you want to recline on ", this:dname(), ".");
return;
endif
endfor
player:queue_action($actions.recline, {this}, 1, (verb + " ") + argstr);

free_seats

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

• #137:do_sit line 12: this:free_seats
• #137:do_recline line 4: this:free_seats

Source

":free_seats() => INT number_of_free_seats";
"This verb returns the number of currently available seats";
if (this.health < 1)
return 0;
endif
free = this.seats - length(this.sitting);
free = free - (2 * length(this.reclining));
return max(0, free);

sit

Spec none on top of/on/onto/upon thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

if (player in player.location.covering)
player:tell("You're already taking cover; stand up if you want to sit down somewhere.");
return;
endif
this:_sit(player);

do_sit

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

":do_sit(OBJ who) => Announce messages, update internal state";
"This verb does the state transition on the furniture and makes announcements to the who and the room about what happened.";
who = args[1];
if (valid(seat = who:sitting_on()) && (seat != this))
who:tell("You're already sitting on ", seat:dname(), ".");
return 1;
elseif (valid(seat = who:reclining_on()) && (seat != this))
who:tell("You're already reclining on ", seat:dname(), ".");
return 1;
elseif (!this.health)
who:tell(this:dnamec(), " is smashed to pieces.  You don't feel like sitting on a pile of junk.");
elseif (this:free_seats() < 1)
who:tell($string_utils:pronoun_sub(this.sit_full_msg));
return 1;
elseif (who in this.sitting)
who:tell($string_utils:pronoun_sub(this.already_sitting_msg));
return 1;
elseif (who in this.reclining)
this.sitting = {@this.sitting, who};
this.reclining = setremove(this.reclining, who);
who.posture = "sitting";
who:tell($string_utils:pronoun_sub(this.sit_from_reclining_msg));
who.location:announce($string_utils:pronoun_sub(this.osit_from_reclining_msg));
else
this.sitting = {@this.sitting, who};
who.posture = "sitting";
who.location:announce($string_utils:pronoun_sub(this.osit_msg));
who:tell($string_utils:pronoun_sub(this.sit_msg));
endif

do_stand

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

• #137:reset line 3: this:do_stand

Source

":do_stand() => Announce messages and adjust internal state";
"This verb does the real work of standing from the furniture in question.  It is a callback verb which should be called only from the processing of events which have already been placed on the event queue by the 'stand' verb.";
who = args[1];
if (!((who in this.sitting) || (who in this.reclining)))
who:tell($string_utils:pronoun_sub(this.rise_failed_msg));
else
this.sitting = setremove(this.sitting, who);
this.reclining = setremove(this.reclining, who);
if (is_player(who))
who:tell($string_utils:pronoun_sub(this.rise_msg));
who.location:announce($string_utils:pronoun_sub(this.orise_msg));
endif
endif

do_recline

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

":do_recline(OBJ who) => Announce messages and adjust internal state";
"This verb is the callback for recline actions that have been placed on the event queue.  It should only be called in order to complete the processing of a recline action.";
who = args[1];
free_seats = this:free_seats();
if (((free_seats == 0) && (this.sitting == {who})) && (this.reclining == {}))
free_seats = 1;
endif
if (valid(seat = who:reclining_on()) && (seat != this))
seatname = is_a(seat, $room) ? "the " + seat:floor_msg() | seat:dname();
who:tell("You're already reclining on ", seatname, ".");
return 1;
elseif (valid(seat = who:sitting_on()) && (seat != this))
seatname = is_a(seat, $room) ? "the " + seat:floor_msg() | seat:dname();
who:tell("You're already sitting on ", seatname, ".");
return 1;
elseif (who in this.reclining)
"is the who already reclining?";
who:tell($string_utils:pronoun_sub(this.already_reclining_msg));
return 1;
elseif (free_seats <= 0)
who:tell($string_utils:pronoun_sub(this.recline_full_msg));
return 1;
elseif (who in this.sitting)
this.sitting = setremove(this.sitting, who);
this.reclining = {@this.reclining, who};
who.posture = "reclining";
who:tell($string_utils:pronoun_sub(this.recline_from_sitting_msg));
who.location:announce($string_utils:pronoun_sub(this.orecline_from_sitting_msg));
else
this.reclining = {@this.reclining, who};
who.posture = "reclining";
who.location:announce($string_utils:pronoun_sub(this.orecline_msg));
who:tell($string_utils:pronoun_sub(this.recline_msg));
endif

sitters

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

• #137:old_users_msg line 3: this:sitters
• #137:forbid_action_move line 10: this:sitters
• #137:users_msg line 5: this:sitters

Source

":sitters() => {@this.sitting}";
"Returns a list of everyone stiing on the furniture";
return this.sitting;

recliners

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

• #137:old_users_msg line 4: this:recliners
• #137:forbid_action_move line 10: this:recliners
• #137:users_msg line 6: this:recliners

Source

":recliners() => {@this.recliners}";
"Returns a list of people reclining on the furniture.";
return this.reclining;

validate_occupants

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

• #137:look_place_msg line 1: this:validate_occupants
• #137:look_self line 2: this:validate_occupants

Source

":validate_occupants() => 0";
"This verb makes sure that the objects listed in the sitters and reliners list are actually in the same location as the furniture itself.";
for x in (this.sitting)
if (x.location != this.location)
this.sitting = setremove(this.sitting, x);
endif
endfor
for x in (this.reclining)
if (x.location != this.location)
this.reclining = setremove(this.reclining, x);
endif
endfor

look_self

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

":look_self() => Tells the player what this furniture looks like and who is using it";
this:validate_occupants();
if (typeof(desc = this:description()) == LIST)
desc = {@desc, this:users_msg()};
else
desc = (desc + "  ") + this:users_msg();
endif
player:tell_lines(desc);
if (this.health < this.health_max)
player:tell("It's " + $rpg:damage_to_desc(this.health, this.health_max), ".");
endif

old_users_msg

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

":users_msg(LIST exclude_list, OBJ looker) => STR description of who's using this";
{?exclude_list = {}, ?looker = player} = args;
sitters = this:sitters();
recliners = this:recliners();
looker_sitting = 0;
looker_reclining = 0;
if (looker in sitters)
looker_sitting = 1;
elseif (looker in recliners)
looker_reclining = 1;
endif
for x in (exclude_list)
sitters = setremove(sitters, x);
recliners = setremove(recliners, x);
endfor
not_rendered = {@sitters, @recliners};
text = "";
for x in (not_rendered)
if (!(x in exclude_list))
if (msg = x:doing_msg())
if (x in sitters)
msg = $string_utils:substitute(this.sitting_doing_msg, {{"%doing", msg}});
msg = $string_utils:pronoun_sub(msg, x, this);
else
msg = $string_utils:substitute(this.reclining_doing_msg, {{"%doing", msg}});
msg = $string_utils:pronoun_sub(msg, x, this);
endif
not_rendered = setremove(not_rendered, x);
text = (text + "  ") + msg;
endif
endif
endfor
if (length(snr = $set_utils:intersection(sitters, not_rendered)) > 1)
sitter_verb = "are";
else
sitter_verb = "is";
endif
if (length(rnr = $set_utils:intersection(recliners, not_rendered)) > 1)
recliner_verb = "are";
else
recliner_verb = "is";
endif
if (snr && rnr)
msg = $string_utils:substitute(this.look_sitting_and_reclining_msg, {{"%sitters", $string_utils:title_list(snr)}, {"%recliners", $string_utils:title_list(rnr)}, {"%sv", sitter_verb}, {"%rv", recliner_verb}});
text = (text + "  ") + $string_utils:pronoun_sub(msg);
elseif (snr)
msg = $string_utils:substitute(this.look_sitting_msg, {{"%sitters", $string_utils:title_list(snr)}, {"%sv", sitter_verb}});
text = (text + "  ") + $string_utils:pronoun_sub(msg);
elseif (rnr)
msg = $string_utils:substitute(this.look_reclining_msg, {{"%recliners", $string_utils:title_list(rnr)}, {"%rv", recliner_verb}});
text = (text + "  ") + $string_utils:pronoun_sub(msg);
endif
text = $string_utils:trim(text);
text = $string_utils:pronoun_sub(text);
return text;

forbid_action_move

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

":forbid_action(OBJ action, OBJ source, LIST callback_args)";
"This verb makes sure not to let anyone move if they're sitting or reclining on the furniture";
"It also prevents you from sitting or reclining on furniture other than the furniture you're already on.";
action = args[2];
source = args[1];
callbacks = args[3];
target = args[3][1];
if ($ou:isa(action, $actions.move) && (typeof(callbacks[1]) == OBJ))
"check to see if the source is using this furniture";
if ((source in this:sitters()) || (source in this:recliners()))
source:prequeue_action($actions.move, callbacks, 1, "go " + callbacks[1].direction, 1);
source:prequeue_action($actions.stand, {this, source}, 1, "stand", 1);
return 1;
endif
elseif ($ou:isa(action, $actions.sit))
if ((source in this:users()) && (target != this))
source:queue_action($actions.stand, {this, source}, 1, "");
source:queue_action($actions.sit, callbacks, 1, "");
return 1;
endif
elseif ($ou:isa(action, $actions.recline))
if ((source in this:users()) && (target != this))
source:queue_action($actions.stand, {this, source}, 1, "");
source:queue_action($actions.recline, callbacks, 1, "");
return 1;
endif
endif

users_msg

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

• #137:look_self line 4: this:users_msg
• #137:look_self line 6: this:users_msg

Source

":users_msg([LIST exclude_list[, OBJ looker]]) => STR text description of who is using this and what they're doing";
{?exclude_list = {}, ?looker = player} = args;
text = "";
msg_db = {};
sitters = this:sitters();
recliners = this:recliners();
looker_sitting = 0;
looker_reclining = 0;
if (looker in sitters)
looker_sitting = 1;
elseif (looker in recliners)
looker_reclining = 1;
endif
for x in (exclude_list)
sitters = setremove(sitters, x);
recliners = setremove(recliners, x);
endfor
users = {@sitters, @recliners};
"build a message database for what everyone is doing";
for x in (users)
if ((x != looker) && ((x.posture == "sitting") && looker_sitting))
if ((doing = x:doing_msg()) == looker:doing_msg())
msg = (((x.posture + " on ") + this:dname()) + (doing ? " " + doing | "")) + " with you";
else
msg = ((x.posture + " on ") + this:dname()) + (doing ? " " + doing | "");
endif
elseif ((x != looker) && ((x.posture == "reclining") && looker_reclining))
if ((doing = x:doing_msg()) == looker:doing_msg())
msg = (((x.posture + " on ") + this:dname()) + (doing ? " " + doing | "")) + " with you";
else
msg = ((x.posture + " on ") + this:dname()) + (doing ? " " + doing | "");
endif
else
msg = ((x.posture + " on ") + this:dname()) + ((doing = x:doing_msg()) ? " " + doing | "");
endif
if (msg_db)
added = 0;
for y in [1..length(msg_db)]
if (msg_db[y][1] == msg)
msg_db[y][2] = setadd(msg_db[y][2], x);
added = 1;
break;
endif
endfor
if (!added)
msg_db = setadd(msg_db, {msg, {x}});
endif
else
msg_db = {{msg, {x}}};
endif
endfor
"Now print all the messages";
for x in (msg_db)
if ((length(x[2]) > 1) || (x[2][1] == looker))
verbstr = " are ";
else
verbstr = " is ";
endif
names = {};
for y in (x[2])
if (y == looker)
names = setadd(names, "you");
else
names = setadd(names, y:name());
endif
endfor
text = (text + "  ") + $su:capitalize((($su:english_list(names) + verbstr) + x[1]) + ".");
endfor
return $su:trim(text);

users

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

• #137:forbid_action_move line 16: this:users
• #137:forbid_action_move line 22: this:users

Source

return {@this.sitting, @this.reclining};

tree_tag

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

s = pass(@args);
return ((((s + $ansi.cyan) + "s") + tostr(this.seats)) + " / c") + $ansi.reset;

junk

Spec this none noneFlags rxdOwner #361Definer #137

Referenced by

none

Source

player:tell("You can't just throw away ", this:iname(), ".");

reset

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

users = {@this.sitting, @this.reclining};
for who in (users)
this:do_stand(who);
who.posture = "standing";
endfor
this.sitting = {};
this.reclining = {};

remove_user

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

"Ensure that something is definitely not using this furniture in any way.";
who = args[1];
if (who in this.sitting)
this.sitting = setremove(this.sitting, who);
who.posture = "standing";
elseif (who in this.reclining)
this.reclining = setremove(this.reclining, who);
who.posture = "standing";
endif

cant_take

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

none

Source

if (this.sitting || this.reclining)
return "someone's sitting on it";
endif

_sit

Spec this none thisFlags rxdOwner #361Definer #137

Referenced by

• #137:sit line 5: this:_sit

Source

{who} = args;
if (this.location != who.location)
who:tell("You need to set ", this:dname(), " down before you can sit on it.");
return 0;
endif
if (who in this.sitting)
who:tell("You're already sitting on it.");
return;
endif
for x in (setremove({@this.location:occupants($furniture), this.location}, this))
if ((who in x.sitting) || (who in x.reclining))
if (x == this.location)
name = "the " + x:floor_msg();
else
name = x:dname();
endif
who:tell("You're on ", name, ", you'll have to get up if you want to sit on ", this:dname(), ".");
return;
endif
endfor
who:queue_action($actions.sit, {this}, 1, "sit");