generic creature #107

_wield

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #5:improv*ise line 1: player:_wield
• #106:wield_best line 25: this:_wield
• #107:give_to line 5: this:_wield
• #107:got_gift line 3: this:_wield
• #107:_drop line 3: this:_wield
• #107:get_gift line 13: this:_wield
• #107:cuts_with line 8: this:_wield
• #133:read line 7: player:_wield
• #135:grenade line 10: player:_wield
• #144:hang line 7: player:_wield
• #223:read line 8: player:_wield
• #338:dump line 6: player:_wield
• #338:toast line 1: player:_wield

Source

":_wield(OBJ thing, INT dont_force [,INT silent])";
"Hold thing in our hands.  Force if necessary, otherwise print handsfull message.";
thing = args[1];
dont_force = (length(args) > 1) ? args[2] | 0;
silent = (length(args) > 2) ? args[3] | 0;
if ((!is_player(this)) && (!is_a(thing, $weapon)))
silent = 1;
endif
if (((thing in this.wielding) && is_a(thing, $weapon)) && (thing != this.wielding[1]))
this.wielding = {thing, @setremove(this.wielding, thing)};
this:aat($su:ps("%DN shifts %dt to %p primary hand.", this, thing));
return;
endif
if (thing in this.wielding)
return 1;
elseif (!is_a(thing, $thing))
return 0;
elseif (thing.location != this)
return 0;
endif
if (this:hands() < thing.handed)
this:tell("You don't have enough functional hands to hold ", thing:iname(), "!");
return 0;
endif
if (this:clear_hands(thing.handed, silent))
if (!thing:try_wield(this))
return 0;
endif
`thing:wielded_by(this) ! E_VERBNF';
this.wielding = {thing, @this.wielding};
if ((length(args) < 3) || (!args[3]))
if (!this.fighting)
this:announce_action_text($string_utils:pronoun_sub(thing.wield_msg, this, thing, thing));
else
this:tell("You get out your ", thing:name(), ".");
endif
endif
return 1;
endif

skill_modifier_for

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #107:show_score_full line 48: this:skill_modifier_for
• #107:show_score_full line 124: this:skill_modifier_for

Source

":skill_modifier_for(OBJ skill)";
"Total up any skill modifiers in effect for a skill, such as status effects, cybertech, etc.  Return a positive/negative value.";
skill = args[1];
mod = 0;
for x in (this.blood)
mod = mod + x[1]:skill_mod(skill, this, x[3]);
endfor
"for x in (this.implants)";
"  mod = mod + `x:skill_mod(skill) ! ANY => 0';";
"endfor";
mod = mod + skill:modifier(this);
"for x in (this.skill_mod_items)";
"  if (x[1] == skill)";
"    for y in (x[2])";
"      if (y.location == this)";
"        if (has_callable_verb(y, \"skill_modifier\"))";
"          modlist = y:skill_modifier(this);";
"          if (modlist[1] == skill)";
"            mod = mod + modlist[2];";
"          endif";
"        elseif (gamevalid(y))";
"          \"  $nets.prognet:announce(this, tostr($su:nn(y), \\\" is missing a :skill_modifier verb?\\\"), 1);\";";
"        endif";
"      endif";
"    endfor";
"  endif";
"endfor";
return mod;

_unwield

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #106:wield_best line 18: this:_unwield
• #106:wield_best line 23: this:_unwield
• #107:exitfunc line 4: this:_unwield
• #107:clear_hands line 10: this:_unwield
• #107:clear_hands line 51: this:_unwield
• #107:clear_hands line 55: this:_unwield
• #107:clear_hands line 60: this:_unwield

Source

":_unwield(OBJ thing, INT silent)";
"Stop holding an object.  Do so silently if args[2] == 1.";
thing = args[1];
if (!is_a(thing, #1))
this.wielding = setremove(this.wielding, thing);
return;
endif
if (thing in this.wielding)
`thing:unwielded_by(this) ! E_VERBNF';
this.wielding = setremove(this.wielding, thing);
if ((length(args) < 2) || (!args[2]))
if (is_player(this) || (random(10) < 3))
if (!this.fighting)
this:announce_action_text($string_utils:pronoun_sub(thing.unwield_msg, this, thing, thing));
else
this:tell("You put away your ", thing:name(), ".");
endif
endif
endif
endif

exitfunc

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #6:exitfunc line 6: pass(

Source

this.encumbrance = {0, 0};
what = args[1];
if (what in this.wielding)
this:_unwield(what, 1);
this.wielding = setremove(this.wielding, what);
endif
if (what in this.wearing)
this:_unwear(what, 1);
this.wearing = setremove(this.wearing, what);
endif
kill = {};
for x in [1..length(this.skill_mod_items)]
this.skill_mod_items[x][2] = setremove(this.skill_mod_items[x][2], what);
if (!this.skill_mod_items[x][2])
kill = listappend(kill, this.skill_mod_items[x]);
endif
endfor
for x in (kill)
this.skill_mod_items = setremove(this.skill_mod_items, x);
endfor

_heartbeat_disabled

Spec this none thisFlags rxOwner #361Definer #107

Referenced by

none

Source

"Keep the heartbeat running.";
"No work is done here -- it's just a wrapper to keep :heartbeat() up.";
set_task_perms(this.owner);
if ((!task_valid(this.heartbeat_task)) && (!this.f))
if (is_a(this, #109))
fork task_id (($rpg.heartbeat_interval - 3) + random(6))
if (is_a(this, $creature))
this.heartbeat_task = 0;
this:_heartbeat();
endif
endfork
this.heartbeat_task = task_id;
this:heartbeat();
`this.location:creature_heartbeat(this) ! ANY => 0';
endif
endif

heartbeat

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #6:heartbeat line 1: pass(
• #106:heartbeat line 31: pass(
• #107:_heartbeat_disabled line 13: this:heartbeat
• #148:heartbeat line 1: pass(

Source

"The actual heartbeat.";
"Apply drug effects and bleeding, and launch the process_queue if we don't have one.";
"This probably shouldn't be overridden; do your AI processing in :suggest_next_action() if possible.";
this.action_count = 0;
if (!this.executing)
this.preemptible = 1;
endif
if (!this.fighting)
this.combat_rounds = 0;
endif
if (!is_player(this))
this:jumpstart();
endif
this:process_blood();
for item in (this.contents)
`item:creature_heartbeat(this) ! E_VERBNF => 0';
endfor
return;

take_damage

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #6:take_damage line 10: pass(
• #106:take_damage line 1: pass(
• #148:_eat line 12: this:take_damage
• #154:popmon line 22: this:take_damage

Source

":take_damage(OBJ type, INT amount, OBJ bodypart, OBJ attacker)";
"Damage myself and let the damage type inflict specials.";
"Return the actual amount of damage we took.";
{type, amount, ?bodypart = $bodypart, ?attacker = #-1} = args;
if (this:is_in_afterlife())
return 0;
endif
if ((is_a(this, $body) && gamevalid(this.player)) && is_a(area(this.player), #1837))
this.player:queue_action($actions.verb, {this.player:cyberdeck(), "do_jackout", {this.player, this}, 0.0, 0}, 1, "jack out");
endif
`type:damage_taken(this, amount, bodypart) ! E_VERBNF => 0';
if (armor = this:wearing_on(bodypart))
for x in (armor)
if (amount > 0)
amount = x:take_damage(type, amount);
endif
endfor
endif
if ($ou:has_verb(this, "armor"))
armor = this:armor();
else
armor = {@this.armor, @`this.location.armor ! ANY => {}'};
endif
for x in (armor)
{atype, amin, amax, ?frontmod = E_NONE} = x;
if (is_a(type, atype))
range = amax - amin;
abx = amin + (max(0, range) ? random(range) | 0);
if (frontmod)
if ((!this.attacking) || (attacker != this.attacking[1]))
abx = toint(tofloat(abx) * frontmod);
endif
endif
amount = max(0, amount - abx);
endif
endfor
if (amount)
if (((is_player(this) && valid(attacker)) && is_player(attacker)) && (attacker != this))
amount = max(1, amount / 2);
endif
amount = bodypart:take_damage(this, amount, type);
this.health = max(0, min(this.health - amount, this.health_max));
type:affect(this, amount, bodypart);
if (amount > type.blood_min)
if (valid(blood = this.bloodstain))
if (random(100) < $rpg.bloodstain_chance)
stainee = occupants(this.location, $creature)[random($)];
if (stainee != this)
blood:add_to(stainee, 1, this:diseases());
stainee:tell($su:ps(blood.spray_blood_msg, this, blood));
endif
endif
endif
endif
if (this.health <= 0)
fork (0)
if ($rpg:valid(this))
$ou:has_verb(this, "die") && this:die(this, type);
endif
endfork
this:cancel_current_action();
elseif (this.executing)
if (((amount > 0) && (amount > ($skills.cool:total(this) + random(this.health_max * 3)))) && (!`this.executing[1].unstoppable ! E_PROPNF => 0'))
actname = this.executing[1]:action_name(this, @this.executing[2..$]);
fork (0)
this:tell($ansi.red, "OUCH! ", $ansi.reset, " The pain makes you fumble", (actname == "verb") ? "." | ((" your " + actname) + "."));
endfork
this:cancel_current_action();
endif
endif
endif
return amount;

die

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #6:die line 6: pass(
• #106:die line 12: pass(
• #107:take_damage line 58: this:die

Source

":die(?[, OBJ dtype, INT noannounce]) Cause me to die.  If args[3], don't announce on gamenet.";
if (this:dead() || is_a(this.body, $corpse))
return;
endif
"Just to be sure...";
this.health = 0;
this.dead = time();
dtype = (length(args) > 1) ? args[2] | $damage;
if ((($rpg:valid(this.body) && is_a(this.body, $body)) && (!is_a(this.body, $corpse))) && this.body.health)
"We died in a dream as our body is still alive.";
if (is_a(area = area(this), $area) && `area:handle_creature_death(this) ! E_VERBNF => 0')
return;
endif
this.dead = 0;
this:disengage_from_combat();
this:clear_queue();
this.health = this.health_max;
this:aat(this:dnamec(), " falls to the ground -- dead!");
killers = {};
for x in (occupants(this.location, $creature))
if (this in x.fighting)
killers = {@killers, x};
endif
endfor
killer = killers ? killers[random($)] | #-1;
`this.location:broadcast_event(0, $actions.die, this, {killer}) ! ANY => 0';
if ($ou:has_property(area, "player_respawn"))
this:moveto(area.player_respawn);
endif
return 0;
endif
"If we get here, WE DIE FOR REAL (unless the area decides otherwise).";
"Store this here because a knockout may remove it.";
fighting = this.fighting;
"rrs = $drugs.recent_revival_syndrome:doses_for(this);";
"Figure out how we died.";
"Now figure out how we died.";
deathtype = "unknown";
if (is_a(this.body, $body) && (!is_a(this.body, $corpse)))
"We died while being in a dream, drop any items we may have picked up.";
for x in (this.contents)
move(x, this.location);
endfor
where = this.body.location;
this.location:announce_all_but({this}, $su:ps("%DN suddenly disappears with a popping sound.", this));
if (is_a(area = area(where), $area) && `area:handle_creature_death(this) ! E_VERBNF => 0')
return;
endif
unconscious = 1;
elseif (!is_a(this.body, $body))
"We died while awake.";
where = this.location;
if (is_a(area = area(where), $area) && `area:handle_creature_death(this) ! E_VERBNF => 0')
return;
endif
unconscious = 0;
else
"WTF?  Killed while we already have a corpse?  This should never happen.";
$nets.prognet:announce(me, "$creature:die fuckup ", $su:nn(this.body));
where = this.body.location;
unconscious = 1;
endif
if (this.listening)
this:tell("");
this:tell(($ansi.bold_on + "You feel an ethereal hand reaching down into your body and ripping your soul free of its corporeal prison.  You rise faster, faster, through infinite space rushing toward a tunnel of bright light...") + $ansi.reset);
this:tell("");
this:tell("");
this:tell("");
this:tell("");
this:tell("");
endif
if (this.last_words_msg)
this:say($su:msg(this.last_words_msg));
endif
if (unconscious)
"We died while being in a dream, items have already been dropped, so just jump to the afterlife.";
this:moveto(this:afterlife());
else
"We died while awake, knock us into the afterlife.";
this:_knockout(this:afterlife(), dtype);
endif
if (is_a(this.body, $body))
this.body:turn_to_corpse(dtype);
endif
killers = {};
has_player_killer = 0;
for x in (occupants(where, $creature))
if ((this in x.fighting) || (this.body in x.fighting))
killers = listappend(killers, x);
if (is_a(x, $player))
has_player_killer = 1;
endif
endif
endfor
if ((this.executing && (this.executing[1] == $actions.npcbeg)) && gamevalid(this.executing[2][1]))
killers = setadd(killers, this.executing[2][1]);
if (is_a(this.executing[2][1], $player))
has_player_killer = 1;
endif
endif
if (has_player_killer)
for x in (killers)
if (!is_a(x, $player))
killers = setremove(killers, x);
endif
endfor
endif
killer = killers ? killers[random($)] | #-1;
if (valid(killer))
try
this:killed_by(killer, killers);
except e (ANY)
$rpg:report_error(e, {"killers: " + $su:nn(killers)});
endtry
endif
for x in (dl = this:death_listeners())
try
(valid(x) && has_callable_verb(x, "hear_death")) && x:hear_death(this, killer, #-1);
except e (ANY)
if (e[1] != E_NONE)
extra_info = tostr("death listener ", $su:nn(x), " args: ", toliteral({this, killer, #-1}));
$rpg:report_error(e, extra_info);
endif
endtry
endfor
paid = 0;
for x in (`killer.employer.contents ! ANY => {}')
if ((!paid) && (!(x in dl)))
paid = `x:hear_death(this, killer, #-1) ! E_VERBNF => 0';
endif
endfor
$rpg:notify_death(this, killer);
"If we are not fighting anything, then we'll give the XP to everything that was fighting us.";
"This matters if we were knocked unconscious before we died.";
fighting = ((!unconscious) && fighting) || killers;
"We're no longer disabling XP gain from fighting.  Crazy!";
"fighting = {};";
if (fighting)
pfighting = {};
for x in (fighting)
if (is_player(x))
pfighting = {@pfighting, x};
endif
endfor
if (pfighting)
ratio = 1.0 / tofloat(length(pfighting));
if (ratio < 1.0)
ratio = ratio * 1.8;
endif
for x in (pfighting)
val = this:xp_value(x);
"val = (!rrs) ? this:xp_value(x) | 0;";
x:award_xp(toint(tofloat(val) * ratio));
"if (val)";
"  x:ingest(#541309, 1);";
"endif";
endfor
endif
endif
this:disengage_from_combat();
this:cancel_current_action();
this:clear_queue();
if ((length(args) < 3) || (!args[3]))
"$nets.deathnet:announce_death(this, killer, dtype, unconscious);";
endif
die_msgprop = (dtype != $damages.explode) ? "die_msg" | "explode_msg";
if (unconscious && is_a(this.body, $body))
diemsg = $su:ps(this.body.(die_msgprop), this.body, this.body);
else
diemsg = $su:ps(this.(die_msgprop), this, this);
endif
where:announce_all((($ansi.bold_on + $ansi.red) + diemsg) + $ansi.reset);
if (is_a(this.bloodstain, $decal) && valid(killer))
this.bloodstain:add_to(where, 1, this:diseases());
if (random(100) < $rpg.bloodstain_chance)
killer:tell("Ugh! Some ", this.bloodstain:name(), " splashed on you.");
this.bloodstain:add_to(killer, 1, this:diseases());
endif
endif
"`where:broadcast_event(0, $actions.die, this, {killer}) ! ANY => 0';";
which_body = is_a(this.body, $body) ? this.body | this;
`x:died_on(this) ! E_VERBNF';
`x.implanted_in = this ! E_PROPNF';
"Some oddball creatures may not leave bodies when knocked out, try to accomodate them...";
if (is_a(this.body, $body) && $rpg:valid(this.body))
if (dtype == $damages.explode)
this.body:explode(this, dtype);
else
this.body.killed_by = killers;
endif
else
for decal in (this:occupants($decal))
$rpg:junk(decal);
endfor
endif

dodge_or_parry

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #6:dodge_or_parry line 1: pass(

Source

":dodge_or_parry(OBJ who, OBJ with, INT attack_bonus, OBJ bodypart)";
"Attempt to actively defend against an incoming attack of quality attack_bonus.";
"Return the attack_bonus back if we didn't completely avoid it.";
"Return a message if we successfully avoided the attack.";
attack = args[3];
attacker = args[1];
weapon = args[2];
if (is_a(weapon, #284))
return attack;
endif
this._tohit_next = this._tohit_next + `this:weapon().melee_defense_mod ! ANY => 0';
if ((ld = time() - this.last_dodge_time) < 5)
"...we just tried to defend a few seconds ago, so give a bonus...";
attack = attack + 4;
endif
if ((!this.fighting) || (this.fighting[1] != attacker))
"...we're not attacking the attacker, so give a bonus...";
attack = attack + 3;
endif
if ((timemod = time() - this.last_dodge_time) < 5)
timemod = timemod - 5;
else
timemod = 0;
endif
this.last_dodge_time = time();
if (random(100) <= 6)
"...lucky shot!  no dodge or parry this time...";
return args[3];
endif
if ((myweapon = this:weapon()):can_parry(weapon) && ((!valid(doing = this:is_doing())) || `doing.can_parry ! ANY => 1'))
"...try to parry...";
parry = myweapon.skill:check(this, myweapon.parry_bonus + (timemod - ((attack * 3) / 2)));
"parry = myweapon.skill:check(this, (myweapon.parry_bonus + (timemod - ((attack * 3) / 2))) + $rpg.fight_styles_defend[this.fight_style]);";
if (parry >= 0)
if (parry < 2)
this:cancel_if_possible();
return {"X", tostr(this:dnamec(), "'s ", myweapon:name(), " stops ", attacker:dname(), "'s ", weapon:name(), " in mid-swing.")};
endif
return {"x", tostr(this:dnamec(), " knocks aside ", attacker:dname(), "'s ", weapon:name(), "!")};
else
return args[3];
endif
else
"...try to dodge...";
dodge = $skills.dodge:check(this, (timemod + 1) - attack);
"dodge = $skills.dodge:check(this, ((timemod + 1) - attack) + $rpg.fight_styles_defend[this.fight_style]);";
if (dodge > 0)
if (dodge < 3)
this:cancel_current_action();
this:jumpstart();
return {">", tostr(this:dnamec(), " dodges away from ", attacker:dname(), "'s ", is_a(weapon, #284) ? "shot." | "attack.")};
endif
return {")", tostr(this:dnamec(), " smoothly dodges out of the way.")};
else
return args[3];
endif
endif

dname

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #6:pinch line 12: this:dname
• #6:pinch line 14: this:dname
• #84:|* line 13: player:dname
• #100:tell_appraise line 3: player:dname
• #104:get_as_it_once_was line 19: player:dname
• #104:dname line 2: pass(
• #106:com*mand line 3: this:dname
• #107:cant_take line 8: this:dname
• #107:follow line 9: this:dname
• #107:follow line 11: this:dname
• #107:follow line 13: this:dname
• #107:hand_to line 8: this:dname
• #107:_get line 13: this:dname
• #107:_get line 22: this:dname
• #107:@setup line 6: this:dname
• #107:_get_from_container line 11: this:dname
• #107:rescue line 12: this:dname
• #107:rescue line 25: this:dname
• #107:dress line 6: this:dname
• #107:get_wet line 3: this:dname
• #148:search line 2: player:dname
• #148:search line 2: this:dname
• #148:search line 4: this:dname
• #148:search line 14: this:dname
• #148:search line 16: this:dname
• #148:kick line 1: this:dname
• #148:kick line 2: this:dname
• #148:grab line 1: this:dname
• #148:cant_get_from line 4: this:dname
• #148:cant_get_from line 12: this:dname
• #154:feed line 12: this:dname
• #154:scam line 1: this:dname
• #156:invite line 6: player:dname
• #167:biz_promote line 22: player:dname
• #167:biz_demote line 30: player:dname
• #167:biz_successor line 19: player:dname
• #167:biz_successor line 21: player:dname
• #167:biz_voteout line 24: player:dname
• #167:biz_voteout line 57: player:dname
• #167:biz_voteout line 58: player:dname

Source

if (!this.has_proper_name)
return "the " + this:name();
else
return this:name();
endif

iname

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #6:killed_by line 14: this:iname
• #6:scam line 2: this:iname
• #6:inamec line 1: this:iname
• #107:killed_by line 3: this:iname

Source

if (!this.has_proper_name)
return pass(@args);
else
return this:name();
endif

random_bodypart

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

none

Source

r = random(100);
total = 0;
parts = this.body_parts;
for x in (parts)
if (r < (total = total + x.size))
return x;
endif
endfor
return parts[$];

wearing_on

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #6:worn line 4: player:wearing_on
• #6:post_pee line 3: this:wearing_on
• #104:wearing_on line 17: pass(
• #106:wearing_on line 17: pass(
• #107:take_damage line 12: this:wearing_on
• #107:tell_wearing line 8: this:wearing_on
• #107:wearing_on_covering line 5: this:wearing_on
• #107:is_wearing line 5: this:wearing_on
• #111:rem*ove line 5: player:wearing_on
• #154:popmon line 4: this:wearing_on

Source

":wearing_on(OBJ bodypart) => LIST what I'm wearing there.";
part = args[1];
s = {};
for x in (this.wearing)
if (is_a(x, $clothing))
for y in (x.covers)
if (is_a(part, y))
s = setadd(s, x);
break;
endif
endfor
endif
endfor
return s;

encumbrance

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #107:show_status line 23: this:encumbrance
• #107:tell_encumbrance line 3: this:encumbrance

Source

"Returns skill modifier indicative of how much we're carrying.";
if ((time() - this.encumbrance[2]) < 10)
return this.encumbrance[1];
endif
maxcarry = this:max_carry();
carried = this:weight() - this.weight;
`carried = tonum(tofloat(carried) * area(this.location).gee) ! ANY => 0';
per = maxcarry / 7;
e = min(0, -6 + ((maxcarry - carried) / per));
this.encumbrance = {e, time()};
return e;

attacking

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

none

Source

"Return creature we're currently attacking, if anyone.";
if (this.executing)
if (this.executing[1] == $actions.attack)
return this.executing[2][1];
endif
endif
return #-1;

weapon

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #6:tell_contents_sub line 12: this:weapon
• #6:inventory_tag line 4: this:weapon
• #50:sizeup line 6: this:weapon
• #95:brandish line 6: player:weapon
• #104:butch*er line 15: player:weapon
• #104:cut line 20: player:weapon
• #106:_reload line 1: this:weapon
• #107:dodge_or_parry line 11: this:weapon
• #107:dodge_or_parry line 30: this:weapon
• #107:at*tack line 32: this:weapon
• #107:show_score_full line 20: this:weapon
• #107:start_fighting line 13: this:weapon
• #107:start_fighting line 20: this:weapon
• #107:_fight line 3: this:weapon
• #107:_threat_rating line 2: this:weapon
• #107:tell_contents line 23: this:weapon
• #107:threat_rating line 1: this:weapon
• #107:brandish line 6: this:weapon
• #107:brandish line 6: this:weapon
• #107:_fight_ari line 6: this:weapon
• #142:weapon line 4: pass(

Source

"Return the weapon I'm wielding.";
for x in (this.wielding)
if (is_a(x, $weapon))
return x;
endif
endfor
return this:unarmed_weapon();

do_command

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #106:com*mand line 8: this:do_command
• #107:@qp line 19: this:do_command

Source

rawcmd = args[1];
if (rawcmd[1] == "\"")
rawcmd[1..1] = "say ";
elseif (rawcmd[1] == ":")
rawcmd[1..1] = "emote ";
elseif (rawcmd[1] == "'")
rawcmd[1..1] = "page ";
elseif (rawcmd[1] == ";")
player:eval(argstr = rawcmd[2..$]);
return;
elseif ((length(rawcmd) > 4) && (rawcmd[1..4] == "eval"))
player:eval(argstr = rawcmd[5..$]);
return;
endif
cmdwords = $su:explode(rawcmd);
player = this;
if (length(cmdwords) > 1)
huhargs = cmdwords[2..$];
else
huhargs = {};
endif
{verbstr, dobjstr, prepstr, iobjstr, argstr} = this:parse_command(rawcmd);
objlist = {@player:contents(), @player.location:contents(), @player.location:exits()};
dobj = $match_utils:match(tdobjstr = $su:trim(dobjstr), objlist);
iobj = $match_utils:match(tiobjstr = $su:trim(iobjstr), objlist);
checklist = {player, player.location, #160, #60528};
if (valid(dobj))
checklist = {@checklist, dobj};
endif
if (valid(iobj))
checklist = {@checklist, iobj};
endif
for x in (checklist)
if (location = $ou:has_verb(x, verbstr))
verbargs = verb_args(location[1], verbstr);
if ((verbargs[1] == "none") && valid(dobj))
continue;
elseif ((verbargs[1] == "this") && (dobj != x))
continue;
elseif ((verbargs[3] == "none") && valid(iobj))
continue;
elseif ((verbargs[3] == "this") && (iobj != x))
continue;
elseif (((verbargs[2] != "none") && (verbargs[2] != "any")) && (!index(verbargs[2], prepstr)))
continue;
else
"we have a winner";
set_task_perms(caller_perms());
player = this;
x:(verbstr)(@huhargs);
return 1;
endif
endif
endfor
"if we made it here, nothing matched.";
"pass to the :huh verbs";
if (player.location:huh(cmdwords[1], huhargs))
return 1;
else
player:tell("I don't understand that.");
endif

parse_command

Spec this none thisFlags rxdOwner #361Definer #107

Referenced by

• #107:do_command line 22: this:parse_command

Source

":parse_command(STR command) => { STR verbstr, STR dobjstr, STR prepstr, STR iobjstr, STR argstr}";
command = args[1];
"first pick the verb string off the beginning";
command = $su:triml(command);
if (verbsep = index(command, " "))
verbstr = command[1..verbsep - 1];
argstr = command[verbsep + 1..$];
subject = argstr;
else
"we only got a verb, no args";
return {command, "", "", "", ""};
endif
"look for quoted text";
encoding = 0;
encoded_subject = "";
for x in [1..length(subject)]
if ((x != 1) && (subject[x - 1] == "\\"))
char = subject[x];
encoded_subject = encoded_subject[1..$ - 1];
elseif (subject[x] == "~")
encoded_subject = encoded_subject + "~";
char = "~";
"this will produce ~ which will come back as a single ~ in decode_binary() later";
elseif (encoding && (subject[x] == "\""))
encoding = 0;
char = "\"";
elseif (((!encoding) && (subject[x] == "\"")) && (x != length(subject)))
"make sure we have a closing quote";
for y in [x + 1..length(subject)]
if ((subject[y] == "\"") && (subject[y - 1] != "\\"))
encoding = 1;
break;
endif
endfor
char = "\"";
elseif (encoding && (subject[x] == " "))
char = " ";
else
char = subject[x];
endif
encoded_subject = encoded_subject + char;
endfor
preps = {"with", "using", "at", "to", "in front of", "in", "inside", "into", "on top of", "on", "onto", "upon", "out of", "from inside", "from", "over", "through", "under", "underneath", "beneath", "behind", "beside", "for", "about", "is", "as", "off of", "off"};
for prep in (preps)
if (prepidx = index(encoded_subject, prep))
if (((prepidx == 1) && (length(argstr) > length(prep))) && (argstr[length(prep) + 1] != " "))
continue;
elseif ((prepidx != 1) && (argstr[prepidx - 1] != " "))
continue;
elseif ((((prepidx + length(prep)) - 1) != length(argstr)) && (argstr[prepidx + length(prep)] != " "))
continue;
endif
prepstr = prep;
prepend = (prepidx + length(prep)) - 1;
if (prepidx > 1)
dobjstr = argstr[1..prepidx - 2];
dobjstr = $su:trim(dobjstr);
dobjstr = $su:trim(dobjstr, "\"");
else
dobjstr = "";
endif
if ((prepend + 2) > length(argstr))
iobjstr = "";
else
iobjstr = argstr[prepend + 2..$];
iobjstr = $su:trim(iobjstr);
iobjstr = $su:trim(iobjstr, "\"");
endif
return {verbstr, dobjstr, prepstr, iobjstr, argstr};
endif
endfor
"if no prep was found, then the whole argstr is considered dobjstr";
dobjstr = argstr;
iobjstr = "";
prepstr = "";
return {verbstr, dobjstr, prepstr, iobjstr, argstr};

at*tack kill shoot stab smash k murder

Spec any none noneFlags rxdOwner #361Definer #107

Referenced by

none

Source

if (dobjstr == "me")
what = this;
else
targets = {};
for x in (this.location.contents)
if ((($api.attackable:is_on(x) && (x != this)) && (!is_a(x, $corpse))) && (!(is_a(x, #59951) && (!x.smashable))))
targets = {@targets, x};
endif
$cu:sin();
endfor
what = $match_utils:match(dobjstr, targets);
if (!valid(what))
player:tell("Kill what?  There's no '", dobjstr, "' here to kill.");
return;
endif
endif
if (what.f)
this:tell("I absolutely refuse!");
return;
endif
if ((what != player) && `this.location.no_combat ! E_PROPNF => 0')
no_combat_msg = `this.location.no_combat_msg ! E_PROPNF => "Somehow you just don't feel like it."';
this:tell(no_combat_msg);
return;
endif
if (is_a(this, $player))
if (is_a(what, $player) && (player != what))
what:_pvp_record({player}, "attacked");
this.attacked = setadd(this.attacked, what);
endif
endif
this:weapon():attack(what);