Mjolnir #214

heartbeat

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

none

Source

return;
fork (0)
this:simulate();
endfork

debug

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:change_random_pressure line 24: this:debug
• #214:average_pressures line 1: this:debug
• #214:average_pressures line 8: this:debug
• #214:update_wind_room line 5: this:debug
• #214:drift_clouds line 1: this:debug
• #214:simulate line 1: this:debug
• #214:reset_pressure line 1: this:debug
• #214:disperse_clouds line 1: this:debug
• #214:create_cloud line 5: this:debug

Source

#38143:announce(this, tostr(@args), 1);

change_random_pressure

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:simulate line 2: this:change_random_pressure

Source

"Change a random sky room's pressure.";
rooms = this:rooms();
rooms = $lu:randomly_permute(rooms);
rooms = rooms[1..min($, 3 + random(3))];
log = {};
for room in (rooms)
if (!is_a(room, $skyroom))
continue;
endif
change = random(9);
change = change - 5;
if (change == 0)
continue;
endif
room.pressure = room.pressure + change;
log = listappend(log, tostr($su:nn(room), ":", change));
localrooms = room:_room_map_list(3, 3);
pressures = $lu:map_property(localrooms, "pressure");
if ((room.pressure < (max(@pressures) - this.cloud_check)) || (room.pressure > (min(@pressures) + this.cloud_check)))
this:create_cloud(room);
this:average_pressure(room);
endif
endfor
this:debug($su:from_list(log, ", "));

average_pressures

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:simulate line 11: this:average_pressures

Source

this:debug("averaging pressures start");
rooms = this:rooms();
rooms = $lu:randomly_permute(rooms);
for room in (rooms)
this:average_pressure(room);
$cu:sin();
endfor
this:debug("averaging pressures stop");

inspect

Spec this none noneFlags rxdOwner #361Definer #214

Referenced by

none

Source

rooms = #24855.contents;
pressures = $lu:map_property(rooms, "pressure");
average = $math_utils:average(pressures);
player:tell("Average pressure is ", average);
player:tell("Last averaging of pressure was ", $time:duration(time() - this.last_average), " ago");
player:tell("Last drifting of clouds was ", $time:duration(time() - this.last_drift_clouds), " ago");
player:tell("Last update of wind room was ", $time:duration(time() - this.last_wind_room), " ago");
player:tell("The current wind room is ", $su:nn(this.wind_room));

average_pressure

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:change_random_pressure line 21: this:average_pressure
• #214:average_pressures line 5: this:average_pressure

Source

{room} = args;
if (!is_a(room, $skyroom))
raise(E_INVARG);
endif
rooms = room:_room_map_list(3, 3);
pressures = $lu:map_property(rooms, "pressure");
average = $math_utils:average(@pressures);
for room in (rooms)
room.pressure = average;
endfor

update_wind_room

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:simulate line 17: this:update_wind_room

Source

rooms = #24855.contents;
rooms = $lu:sort_prop(rooms, "pressure");
this.wind_room = rooms ? rooms[1] | #-1;
$cu:sin(3);
this:debug("New wind room ", $su:nn(this.wind_room), " = ", this.wind_room.pressure);

drift_clouds

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:simulate line 22: this:drift_clouds

Source

this:debug("drifting clouds");
clouds = $ou:leaves($aweather);
drifted = {};
for cloud in (clouds)
$cu:sin(1);
if (!is_a(cloud, $aweather))
continue;
elseif (cloud.f)
continue;
elseif (!is_a(cloud.location, #79017))
continue;
elseif (!cloud.drifts)
continue;
elseif (cloud.location == this.wind_room)
continue;
elseif (random(100) < 80)
continue;
elseif (!is_a(hop = cloud.location:next_hop_to(this.wind_room), $exit))
continue;
elseif (((!is_a(hop.otherside, $exit)) || (!is_a(hop.otherside.location, $skyroom))) || (hop.otherside.location in drifted))
continue;
endif
drifting = random(cloud.accumulation);
if (cloud.dispersable)
left = cloud.accumulation - drifting;
oldlocation = cloud.location;
cloud.accumulation = drifting;
if (m = cloud:drift_msg())
cloud.location:announce_all($su:ps(m, cloud, hop, hop.otherside.location));
endif
if (m = cloud:odrift_msg())
hop.otherside.location:announce_all($su:ps(m, cloud, hop.otherside, cloud.location));
endif
cloudparent = parent(cloud);
cloud:moveto(hop.otherside.location);
if (left)
newcloud = $rpg:spawn(cloudparent);
newcloud.accumulation = left;
newcloud:moveto(oldlocation);
endif
else
newcloud = $rpg:spawn(parent(cloud));
newcloud.accumulation = drifting;
if (m = cloud:drift_msg())
cloud.location:announce_all($su:ps(m, cloud, hop, hop.otherside.location));
endif
if (m = cloud:odrift_msg())
hop.otherside.location:announce_all($su:ps(m, cloud, hop.otherside, cloud.location));
endif
newcloud.dispersable = 1;
newcloud:moveto(hop.otherside.location);
endif
drifted = setadd(drifted, hop.otherside.location);
endfor

rooms

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:change_random_pressure line 2: this:rooms
• #214:average_pressures line 2: this:rooms
• #214:reset_pressure line 2: this:rooms

Source

return #24855.contents;

simulate

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:heartbeat line 3: this:simulate

Source

this:debug("simulate");
this:change_random_pressure();
"Reset pressures every 24 hours.";
if (this.last_reset_pressure < (time() - 86400))
this.last_reset_pressure = time();
this:reset_pressure();
endif
"Average pressure every 10 minutes.";
if (this.last_average < (time() - 600))
this.last_average = time();
this:average_pressures();
this:disperse_clouds();
endif
"Update wind room every 5 minutes.";
if (this.last_wind_room < (time() - 300))
this.last_wind_room = time();
this:update_wind_room();
endif
"Drift clouds every 4 minutes.";
if (this.last_drift_clouds < (time() - 240))
this.last_drift_clouds = time();
this:drift_clouds();
endif

reset_pressure

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:simulate line 6: this:reset_pressure

Source

this:debug("resetting pressures");
for room in (this:rooms())
room.pressure = 1000;
endfor

broadcast_to

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

none

Source

No program (verb defined but unprogrammed).

disperse_clouds

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:simulate line 12: this:disperse_clouds

Source

this:debug("dispersing clouds");
clouds = $ou:leaves($aweather);
for cloud in (clouds)
$cu:sin(1);
if (!is_a(cloud, $aweather))
continue;
elseif (cloud.f)
continue;
elseif (!is_a(cloud.location, #79017))
continue;
elseif (random(100) >= this.disperse_chance)
continue;
endif
cloud:decrease_accumulation(random(cloud.accumulation));
endfor

create_cloud

Spec this none thisFlags rxdOwner #361Definer #214

Referenced by

• #214:change_random_pressure line 20: this:create_cloud

Source

room = args[1];
generic = (is_a(room.generic_cloud, $aweather) && room.generic_cloud.f) ? room.generic_cloud | $cloud;
cloud = $rpg:spawn(generic);
cloud:moveto(room);
this:debug("created ", $su:nn(cloud), " in ", $su:nn(room));