Utility Object #20

parse_prop_ref

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #8:edit line 7: $utils:parse_prop_ref
• #9:rmp*rop line 48: $utils:parse_prop_ref
• #10:addp*rop line 21: $utils:parse_prop_ref

Source

" #20:parse_prop_ref this none this";
prop_ref = args[1];
dot = index(prop_ref, ".");
if (!dot)
if (prop_ref[1] != "$")
return 0;
else
return {"#0", prop_ref[2..$]};
endif
else
object = prop_ref[1..dot - 1];
prop = prop_ref[dot + 1..$];
if (!(object && prop))
return 0;
elseif (object[1] != "$")
return {object, prop};
else
sysprop = object[2..$];
if (!$has_prop(sysprop))
return 0;
else
object = #0.(sysprop);
if (typeof(object) != OBJ)
return 0;
else
object = tostr(object);
return {object, prop};
endif
endif
endif
endif

cap*italize

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

none

Source

" #20:capitalize(STR) this none this ";
if ((string = args[1]) && (i = index("abcdefghijklmnopqrstuvwxyz", string[1], 1)))
string[1] = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"[i];
endif
return string;

triml*eft

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

none

Source

"$utils:triml*eft this none this";
"copied from LambdaMOO";
{string, ?what = " "} = args;
index = match(string, tostr("[^", what, "]%|$"));
return string[index[1]..$];

list_to_str*ing

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

none

Source

"$utils:list_to_str*ing this none this";
{thelist, ?separator = "", ?conj = ""} = args;
if (thelist == {})
return "";
else
if (length(thelist) == 1)
return tostr(thelist[1]);
else
if (separator == "")
return tostr(@thelist);
else
if (conj)
if (length(thelist) == 2)
result = (((tostr(thelist[1]) + " ") + conj) + " ") + tostr(thelist[2]);
return result;
else
thelist[$] = (conj + " ") + tostr(thelist[$]);
endif
endif
result = tostr(thelist[1]);
for item in (listdelete(thelist, 1))
result = tostr(result, separator, item);
endfor
return result;
endif
endif
endif

trimr*ight

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

none

Source

"$utils:trimr*ight this none this";
"Copied from LambdaMOO";
{string, ?what = " "} = args;
return string[1..rmatch(string, tostr("[^", what, "]%|^"))[2]];

parse_verb_ref

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #9:addverb line 28: $utils:parse_verb_ref
• #9:show*verb line 7: $utils:parse_verb_ref
• #9:args line 5: $utils:parse_verb_ref
• #9:args line 16: $utils:parse_verb_ref

Source

"$utils:parse_verb_ref this none this";
verb_ref = args[1];
colon = index(verb_ref, ":");
if (!colon)
if (verb_ref[1] != "$")
return 0;
else
return {"#0", verb_ref[2..$]};
endif
else
object = verb_ref[1..colon - 1];
verbname = verb_ref[colon + 1..$];
if (!(object && verbname))
return 0;
elseif (object[1] != "$")
return {object, verbname};
else
prop_name = object[2..$];
if (!$has_prop(prop_name))
return 0;
else
object = #0.(prop_name);
if (typeof(object) != OBJ)
return 0;
else
object = tostr(object);
return {object, verbname};
endif
endif
endif
endif

sort

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #3:sc*ore line 67: $utils:sort
• #3:sc*ore line 82: $utils:sort
• #3:admins line 21: $utils:sort
• #5:testsort line 7: $utils:sort
• #8:props line 18: $utils:sort
• #9:verbs line 10: #20:sort
• #9:grep line 4: #20:sort
• #9:which line 7: $utils:sort
• #10:missing line 14: $utils:sort
• #20:sort line 24: $utils:sort
• #20:sort line 25: $utils:sort

Source

"quick sort algorithm";
sortlist = args[1];
if (length(sortlist) <= 1)
return sortlist;
elseif (length(sortlist) == 2)
return (sortlist[1] < sortlist[2]) ? {sortlist[1], sortlist[2]} | {sortlist[2], sortlist[1]};
else
"partition into left and right";
left = {};
right = {};
pivotlist = {};
pivotindex = random(length(sortlist));
pivotitem = sortlist[pivotindex];
for each in (sortlist)
if (each < pivotitem)
left = {@left, each};
elseif (each > pivotitem)
right = {@right, each};
else
pivotlist = {@pivotlist, each};
endif
endfor
"sort each side";
sortedleft = $utils:sort(left);
sortedright = $utils:sort(right);
return {@sortedleft, @pivotlist, @sortedright};
endif

match

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #0:do_login_command line 30: $utils:match
• #3:mes*sage line 17: $utils:match
• #3:info*rmation line 18: $utils:match
• #3:cast line 22: $utils:match
• #3:_speak line 4: $utils:match
• #6:passwd line 5: $utils:match
• #6:intro*duce line 7: $utils:match

Source

"#20:match(str, objlist, ?exact, ?nameonly) - returns a list of objs from args[2] that";
"are named or aliased to args[1].  args[3] if true forces a full match. args[4] will";
"if true match only to object's name";
"if no match, returns empty list.";
{token, objlist, ?exact = 0, ?nameonly = 0} = args;
count = 0;
count_and_item = $utils:parse_dot_ref(token);
if (count_and_item)
{count, item} = count_and_item;
endif
if (count > 0)
token = item;
endif
matchlist = {};
for each in (objlist)
if (!(each in matchlist))
doesmatch = 0;
if (nameonly)
names = {each.name};
else
names = {each.name, @each.aliases};
endif
for name in (names)
if (exact)
doesmatch = doesmatch || (token == name);
else
doesmatch = doesmatch || (index(name, token) == 1);
endif
endfor
if (doesmatch)
matchlist = {@matchlist, each};
endif
endif
endfor
if (count == 0)
return matchlist;
elseif (count <= length(matchlist))
return {matchlist[count]};
else
return {};
endif

parse_dot_ref

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #3:match line 11: $utils:parse_dot_ref
• #10:match line 26: $utils:parse_dot_ref
• #20:match line 7: $utils:parse_dot_ref

Source

"$utils:parse_dot_ref(str) returns {int count, str}";
"used for dot matching... 2.sword, etc.";
{prop_ref} = args;
dot = index(prop_ref, ".");
if (dot > 1)
NUM = prop_ref[1..dot - 1];
token = prop_ref[dot + 1..$];
return {tonum(NUM), token};
else
return 0;
endif

padl*eft

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

none

Source

"$utils:padleft(str token, int length, str char)";
{token, len, ?char = " "} = args;
token = tostr(token);
needed = len - length(token);
times = 1 + (needed / length(char));
for x in [1..times]
token = char + token;
endfor
newlen = length(token);
if (newlen != len)
token = token[(newlen - len) + 1..newlen];
endif
return token;

padr*ight

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

none

Source

"$utils:padright(str token, int length, str char)";
{token, len, ?char = " "} = args;
token = tostr(token);
needed = len - length(token);
times = 1 + (needed / length(char));
for x in [1..times]
token = token + char;
endfor
newlen = length(token);
if (newlen != len)
token = token[1..len];
endif
return token;

dhms

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #3:info*rmation line 48: $utils:dhms
• #3:admins line 35: $utils:dhms
• #20:_uptime line 2: $utils:dhms

Source

"$utils:dhms(seconds)";
"returns {days, hours, minutes, seconds}";
{seconds} = args;
days = seconds / 86400;
seconds = seconds % 86400;
hours = seconds / 3600;
seconds = seconds % 3600;
minutes = seconds / 60;
seconds = seconds % 60;
return {days, hours, minutes, seconds};

_uptime

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #3:who line 61: $utils:_uptime
• #3:uptime line 2: $utils:_uptime

Source

"$utils:_uptime() this none this";
times = $utils:dhms(time() - $start_time);
uptime_str = $utils:dhms_str(times);
return uptime_str;

ftime

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #3:who line 49: $utils:ftime
• #3:who line 51: $utils:ftime
• #3:set_disconnect_info line 8: $utils:ftime
• #10:time line 2: $utils:ftime

Source

"$utils:ftime this none this";
"format any string in ctime format";
ctime = args[1];
_day = ctime[1..3];
_mo = ctime[5..7];
_hour = ctime[12..13];
daynum = ctime[9..10];
min = ctime[15..16];
daysav = ctime[26..28];
day = {"Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday"}[_day in {"Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat"}];
mo = {"January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November", "December"}[_mo in {"Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec"}];
"switch to standard time format";
if (tonum(_hour) > 11)
hour = tonum(_hour) - 12;
ampm = "pm";
else
hour = tonum(_hour);
ampm = "am";
endif
hour = tostr(hour);
if (hour == "0")
hour = "12";
endif
"set ordinal notation";
x = daynum in {" 1", "21", "31", " 2", "22", " 3", "23"};
if (x)
ord = {"st", "st", "st", "nd", "nd", "rd", "rd"}[x];
else
ord = "th";
endif
"eliminate extra spaces";
if (daynum[1] == " ")
daynum = daynum[2];
endif
new_string = (((((((((((day + ", ") + mo) + " ") + daynum) + ord) + ", ") + hour) + ":") + min) + ampm) + " ") + daysav;
return new_string;

dhms_str

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #3:info*rmation line 48: $utils:dhms_str
• #3:admins line 35: $utils:dhms_str
• #20:_uptime line 3: $utils:dhms_str

Source

"$utils:dhms_str() this none this";
times = args[1];
days = times[1];
daystr = (days == 1) ? " day, " | " days, ";
day_var = (days == 0) ? "" | (tostr(days) + daystr);
hours = times[2];
hourstr = (hours == 1) ? " hour, " | " hours, ";
hour_var = ((days == 0) && (hours == 0)) ? "" | (tostr(hours) + hourstr);
mins = times[3];
minstr = (mins == 1) ? " minute." | " minutes.";
min_var = tostr(mins) + minstr;
final_str = (day_var + hour_var) + min_var;
return final_str;

longest*_length

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

none

Source

"$utils:longest*_length this none this";
"If more than one is longest, returns length of first.";
thelist = args[1];
longest = 0;
for x in (thelist)
xlen = length(x);
if (xlen > longest)
longest = xlen;
endif
endfor
return longest;

string_to_list

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #4:test line 2: $utils:string_to_list
• #20:string_to_frag*ment line 2: $utils:string_to_list

Source

"$utils:string_to_list this none this";
string = args[1];
newlist = {};
if (length(string))
while (ref = index(string, " "))
newlist = {@newlist, string[1..ref - 1]};
string = string[ref + 1..$];
endwhile
newlist = {@newlist, string};
endif
"Clear out any doubled spaces that ended up in the list.";
newlist = $utils:remove(newlist, "", 1);
return newlist;

rem*ove

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

none

Source

"$utils:remove this none this";
{thelist, what, ?all = 0} = args;
if (all)
while (what in thelist)
thelist = setremove(thelist, what);
endwhile
else
thelist = setremove(thelist, what);
endif
return thelist;

string_to_frag*ment

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

none

Source

"$utils:string_to_frag*ment this none this";
words = $utils:string_to_list(args[1]);
len = length(words);
first = random(len);
rest = len - first;
if (!rest)
frag = words[first];
else
newlist = {};
more = random(rest + 1) - 1;
count = first;
while (count <= (first + more))
newlist = {@newlist, words[count]};
count = count + 1;
endwhile
frag = $utils:list_to_string(newlist, " ");
endif
return frag;

match_dollar_ref

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #10:match line 15: $utils:match_dollar_ref

Source

"$utils:match_dollar_ref this none this";
"matches a $ref to the object it evals to";
dollar_ref = args[1];
if (dollar_ref[1] != "$")
return 0;
else
try
xobj = #0.(dollar_ref[2..$]);
if (typeof(xobj) == OBJ)
return xobj;
else
return 0;
endif
except (ANY)
return 0;
endtry
endif

height_str

Spec this none thisFlags rwxdOwner #10Definer #20

Referenced by

• #60:describe_to line 30: $utils:height_str
• #60:describe_to line 30: $utils:height_str

Source

"$utils:height_str this none this";
{height} = args;
height_str = ((tostr(height / 12) + "' ") + tostr(height % 12)) + "\"";
return height_str;