Coder Class #9

Parent #8Owner #10Flags fertileSource MurpgCore-0.4/MurpgCore-0.4.db

10 verbs · 72 properties · 1 children

Verbs

Properties

Ancestry

• #1 Root Class

  • #11 Game Class

    • #3 Animate Class

      • #6 Player Class

        • #8 Architect Class

          • #9 Coder Class

            • #10 DM Class

Ancestors (nearest first): #8 Architect Class → #6 Player Class → #3 Animate Class → #11 Game Class → #1 Root Class

Children: #10 DM Class

Call graph

Source

" #9:rmp*rop(STR) any any any";
"";
" args[1]:  Only argument this function takes is a string consisting ";
"           of OBJ.STR which refers to a prop (STR) on the OBJ. ";
"";
" Returns:  0 (command-line verb) ";
"";
" Modifies:  Removes a property from an object (and all its ";
"            descendants. ";
"";
" Owner:  $dm ";
" Writer:  Finder(#4) ";
" Perms:  owner ";
" Called by:  command-line function usable by DMs and Coders ";
" Screen Outputs:  message ";
"";
" Description:  Performs various permissions checks, then ";
"               determines whether or not the specified property ";
"               exists and can be removed (i.e., it exists on the ";
"               specified OBJ and not on a parent), then removes ";
"               the property permanently. ";
"";
" NOTE:  As of today, string matching has not been completed so ";
"        the object can only be referenced via its OBJ  number. ";
"";
" Examples:  rmprop #4.spoon ";
"            rmprop me.spoon   <=  Can't be done yet (see NOTE) ";
"";
init_string = argstr;
person = player;
"";
syntax = "SYNTAX:  <object_name/object_number>.<new_prop_name>";
example1 = "For example:  rmprop #233.flight_path";
example2 = "For example:  rmprop bird.flight_path";
"";
" This :tell() is provided for formatting purposes only. :-) ";
person:tell();
if (!args)
person:tell(syntax);
person:tell(example1);
" Add this back in once string matching has been coded. ";
"person:tell(example2);";
return 0;
else
" Ok, going to call $utils:parse_prop_ref here...  If the object ";
" string it returns can't be changed to an OBJ, just return SYNTAX.  ";
" String matching has not been coded yet. ";
if (!(obj_and_prop = $utils:parse_prop_ref(init_string)))
person:tell(syntax);
person:tell(example1);
else
target = obj_and_prop[1];
property = obj_and_prop[2];
if (target[1] != "#")
" No string matching yet. ";
person:tell("String matching has not been coded yet.  Please use an object number.");
person:tell(example1);
return 0;
else
object = toobj(target);
if (!valid(object))
" The object is not a valid object number. ";
person:tell("That is not a valid object.");
else
" Make sure the property exists at all. ";
if (!object:has_prop(property))
person:tell("There is no '", property, "' property on ", object, ".");
return 0;
else
" Make sure the property is on this specific object and not ";
" on an ancestor.  Since we already made sure the prop can ";
" be referenced by the specified OBJ an E_PROPNF must mean ";
" that the prop is defined above the OBJ.  All other errors ";
" will be parsed and returned to the player. ";
try
delete_property(object, property);
person:tell("Property removed.");
except (E_PROPNF)
person:tell("That property is defined on an ancestor of ", object.name, ".");
person:tell("At a later date there will be a function designed to test for this.");
except any_error (ANY)
person:tell("The built-in function delete_property returned the following error:");
person:tell(any_error[2]);
endtry
endif
endif
endif
endif
endif

"#9:verbs any none none";
{?target = ""} = args;
targobj = toobj(target);
if (length(target) == 0)
player:tell("Display verbs for what object?");
elseif ((!valid(targobj)) || ((targobj == #0) && ((target != "#0") && (target != "0"))))
player:tell(("%W" + target) + "%w is not a valid object reference.");
else
if (valid(targobj))
verblist = #20:sort(verbs(targobj));
player:tell("Verbs defined on ", targobj.name, " (", targobj, ")");
for verb in (verblist)
verbinfo = verb_info(targobj, is_member(verb, verbs(targobj)));
numlines = length(verb_code(targobj, is_member(verb, verbs(targobj))));
verbargs = verb_args(targobj, is_member(verb, verbs(targobj)));
player:tell("~  ", verb, " (", verbargs[1], " ", verbargs[2], " ", verbargs[3]);
player:tell("~", ")  Owned by ", verbinfo[1], ".  (", verbinfo[2]);
player:tell(")   ", numlines, " lines of code.");
endfor
else
player:tell(targobj, "is not a valid object number");
return;
endif
endif

"#9:addv*erb objnum:verbname arg1 arg2 arg3";
" Returns:  0 (command-line verb) ";
" Modifies:  Adds a verb to the specified objnum. ";
" Owner:  $dm ";
" Writer:  Ixion (#5) ";
" Called by:  command-line function usable by DMs and Coders ";
" Screen outputs:  message ";
{?init_string, ?value_one = $nothing, ?value_two = $nothing, ?value_three = $nothing} = args;
person = player;
target = verb = "";
"copied from addprop and modified";
syntax = "SYNTAX:  addverb <object_name/object_number>:<new_verb_name> args1 args2 args3";
example1 = "For example:  addverb #556:wiggle any none none";
example2 = "For example:  addverb ferret:wiggle any none none";
"";
" The following :tell() is for formatting purposes only. ";
person:tell();
if (!args)
person:tell(syntax);
person:tell(example1);
" Add this back in once string matching has been coded. ";
"person:tell(example2);";
return 0;
else
" Ok, going to call $utils:parse_verb_ref here...  If the object ";
" string it returns can't be changed to an OBJ, just return SYNTAX.  ";
" String matching has not been coded yet. ";
if (!(obj_and_verb = $utils:parse_verb_ref(init_string)))
person:tell(syntax);
person:tell(example1);
else
target = obj_and_verb[1];
verb = obj_and_verb[2];
if (target[1] != "#")
" No string matching yet. ";
person:tell();
person:tell("String matching has not been coded yet.  Please use an object number.");
person:tell(example1);
return 0;
else
object = toobj(target);
if (!valid(object))
" The object is not a valid object number. ";
person:tell("That is not a valid object.");
else
" Make sure the verb does not already exist. ";
if (object == object:has_verb(verb))
person:tell("That verb already exists: ", object, ":", verb, ".");
return 0;
else
"add the verb with specified args";
if ((value_one && value_two) && value_three)
if (((value_one == "this") && (value_two == "none")) && (value_three == "this"))
perms = "rwxd";
else
perms = "rwd";
endif
owner = #10;
try
add_verb(object, {owner, perms, verb}, {value_one, value_two, value_three});
person:tell(tostr("Verb added: ", object, "(", object.name, "):", verb));
person:tell("Don't forget to change perms on this verb if necessary.");
except e (ANY)
" Parse the error and return it. ";
person:tell("The built-in function add_verb returned the following error: ");
person:tell(e[2]);
person:tell("Verb not added");
endtry
endif
endif
endif
endif
endif
endif

"search verb code for occurrences of args[1].  no regexp";
{pattern} = args;
searchlist = {};
allobjs = #20:sort({#1, @#1:descendants()});
for each in (allobjs)
if (verbs(each) != {})
searchlist = {@searchlist, each};
endif
endfor
for each in (searchlist)
verblist = verbs(each);
for verbitem in (verblist)
verbcode = verb_code(each, is_member(verbitem, verblist));
linenum = 0;
for line in (verbcode)
linenum = linenum + 1;
pos = index(line, pattern);
if (pos > 0)
player:tell_raw(tostr(each), ":", verbitem, "() - Line ", tostr(linenum), " - ", line);
endif
endfor
endfor
endfor

" #9:show*verb any none none";
"takes one or two arguments: a verb ref, and optionally the letter 'l' to show linenums";
{?verb_ref = "", ?showlines = ""} = args;
if (verb_ref == "")
player:tell("Show which verb?");
else
parsed = $utils:parse_verb_ref(verb_ref);
if (parsed == 0)
player:tell(("%W" + verb_ref) + "%w is not a valid verb reference.");
else
object = toobj(parsed[1]);
verb = parsed[2];
if (!valid(object))
player:tell(("%W" + tostr(object)) + "%w is not a valid object reference.");
else
result = object:has_verb(verb);
if (result == 0)
player:tell(((("%W" + verb) + "%w is not defined on %W") + object.name) + "%w.");
elseif (result != object)
player:tell(((((("%W" + verb) + "%w is defined on ") + object.name) + "'s ancestor, %W") + result.name) + "%w.");
elseif (!showlines)
player:tell_raw(verb_code(object, verb));
else
x = 1;
verbcode = verb_code(object, verb);
for each in (verbcode)
player:tell_raw((tostr(x) + ":  ") + each);
x = x + 1;
endfor
endif
endif
endif
endif

" #10:tree ([OBJ], [STR all]) ";
"";
" args[1]:  Optional.  The OBJ whose descendants you wish to view. ";
"           Default value is the System Object (#0). ";
"";
" args[2]:  The string option 'all' displays every one of the OBJ's ";
"           descendants whether fertile or not.  Without this option ";
"           only fertile descendants are displayed. ";
"";
" Returns:  0 (command-line verb) ";
" Modifies:  none ";
" Owner:  $dm ";
" Writer:  Ixion(#5) ";
" Perms:  owner ";
" Called-by:  Command-line function callable by DMs and Coders. ";
" Screen Outputs:  A visual tree displaying the OBJ's descendants. ";
"";
" Description:  Displays a visual tree that lists out the target OBJ's ";
"               descendants.  If the 'all' argument is used, every ";
"               descendant is listed, even those that are not fertile. ";
"";
" Examples:  tree          =>  Displays all fertile descendants of #0. ";
"            tree #18      =>  Displays all fertile descendants of #18. ";
"            tree #18 all  =>  Displays all fertile and non-fertile ";
"                              descendants of #18. ";
"";
if (length(args) == 0)
ancestor = #1;
all = "";
else
ancestor = toobj(args[1]);
all = "";
endif
if (length(args) == 2)
all = args[2];
elseif (length(args) > 2)
player:tell("Too many arguments.");
player:tell("Syntax:  tree object [all]");
return;
endif
if (((ancestor != #0) || (args[1] == "0")) || (args[1] == "#0"))
if (all == "")
ancestor:tree(1, 0);
elseif (all == "all")
ancestor:tree(1, 1);
else
player:tell(("Unknown argument " + all) + ".  Valid second arguments are: [all]");
player:tell("Syntax:  tree object [all]");
endif
else
player:tell("First argument should be a valid object number.");
player:tell("Syntax:  tree object [all]");
endif

answer = eval(("return " + argstr) + ";");
if (answer[1])
notify(player, tostr("=> ", toliteral(answer[2])));
else
for line in (answer[2])
notify(player, line);
endfor
endif

"$coder:who_string() this none this";
viewer = args[1];
gender = {"N", "B", "F", "M"}[this.gender in {"neither", "both", "female", "male"}];
"afk";
if (this.afk)
afk = $who.afk + "  ";
else
afk = "       ";
endif
"editing";
if (this.location:is_a($editor))
edit = $who.editing + "  ";
else
edit = "           ";
endif
"idle";
idle = idle_seconds(this);
if (idle > 3600)
idle = $who.dormant + "  ";
elseif (idle > 1800)
idle = $who.vegetating + "  ";
elseif (idle >= 600)
idle = $who.idle + "  ";
else
idle = "        ";
endif
"admin";
if (this in $admins)
admin = $who.admin;
else
admin = "";
endif
name_string = $utils:padr(this.name, 16, " ");
who_string = ((((((("%Y[%yCode " + gender) + "%Y] ") + name_string) + afk) + edit) + idle) + admin) + "%w";
return who_string;

"$coder:args any any any";
"sets the args on obj:verb to specified args";
if (length(args) == 1)
{objverb} = args;
objandverb = $utils:parse_verb_ref(objverb);
if (objandverb == 0)
player:tell("syntax: obj:verb [ dobj prep iobj ]");
else
objargs = verb_args(toobj(objandverb[1]), objandverb[2]);
player:tell(objandverb[1], ":", objandverb[2], " ", objargs[1], " ", objargs[2], " ", objargs[3]);
endif
elseif (length(args) != 4)
player:tell("syntax: obj:verb dobj prep iobj");
else
{objverb, dobjarg, preparg, iobjarg} = args;
objandverb = $utils:parse_verb_ref(objverb);
if (objandverb == 0)
player:tell("syntax: obj:verb [ dobj prep iobj ]");
else
set_verb_args(toobj(objandverb[1]), objandverb[2], {dobjarg, preparg, iobjarg});
player:tell("Verb arguments changed.");
endif
endif

"$coder:which any none none";
"returns a list of objects that have matching verbs and/or props";
token = argstr;
if (token == "")
player:tell("What verb or property would you like to search for?");
else
allobjs = $utils:sort({#1, @#1:descendants()});
"verbs that match";
for each in (allobjs)
matched_verbs = {};
xverbs = verbs(each);
for xverb in (xverbs)
if (index(xverb, token) == 1)
matched_verbs = {@matched_verbs, xverb};
endif
endfor
if (matched_verbs != {})
player:tell(((each.name + " (") + tostr(each)) + ")");
for mverb in (matched_verbs)
player:tell("  :" + mverb);
endfor
endif
endfor
"props that match";
for each in (allobjs)
matched_props = {};
xprops = properties(each);
for xprop in (xprops)
if (index(xprop, token) == 1)
matched_props = {@matched_props, xprop};
endif
endfor
if (matched_props != {})
player:tell(((each.name + " (") + tostr(each)) + ")");
for mprop in (matched_props)
player:tell("  ." + mprop);
endfor
endif
endfor
endif