Root Class #1

tree

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

" #1:tree(INT, INT) this none this";
"";
" args[1]:  INT, recursion level ";
" args[2]:  INT (Boolean), whether or not the 'all' option was used. ";
"";
" Returns:  0 ";
" Modifies:  none ";
" Owner:  $dm ";
" Writer:  Ixion(#5) ";
" Perms:  owner ";
" Called-by:  #10($dm):tree command-line function ";
" Screen Outputs:  sends the tree strings to the player ";
"";
" Description:  This verb outputs a nice object hierarchy tree for ";
"               all fertile objects.  Its so simple and elegant;  but ";
"               then again that is what recursion is about! ";
"";
"               Takes as arguments the recursion level which it is at ";
"               just for formatting purposes, as well as true/false 'all' ";
"               which, if true, causes the verb to print _all_ children, ";
"               even those that aren't fertile.  In reality this would mean ";
"               _every_ object downstream from the object that the verb was ";
"               called on:  if on #1, then every object in the db. ";
"";
" NOTE:  Use with caution!  This function is capable of printing EVERY object ";
"        in the entire database. ";
"";
depth = length(args) ? args[1] | 1;
all = (length(args) == 2) ? args[2] | 0;
player:tell(("~" + tostr(depth)) + "-");
for x in [1..depth]
player:tell("~  ");
endfor
player:tell((tostr(this) + " -- ") + this.name);
newdepth = depth + 1;
for y in (children(this))
if ((y.f == 1) || (all == 1))
y:tree(newdepth, all);
endif
endfor
return;

recycle

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

" #1:recycle this none this takes no arguments;  this function will change the parent of the object";
" to #22 -- reusable class and wipe any props, change the name, and fertility stuff.";
" we don't want to use builtin recycle, because we want a method for recovering object numbers.";
" after an object is recycled, it will be named to reusable object and put in #-1.  fertile objects ";
" can not be recycled; wizards cannot be recycled. Recycler, #1 and #0 cannot be recycled.  we will allow ";
" for a list of non-recyclable objects to be maintained, perhaps on #24 -- recycler. ";
" player bit should be revoked, prog bit should be revoked.  all verbs on it should be wiped. ";
for task in ($recycler.recycle_tasks)
if (task[1] == this)
player:tell(this.name + " is already queued for recycling.");
return 0;
endif
endfor
if (((((((this == #1) || (this == #0)) || (this == #24)) || (this.wizard == 1)) || (this.f == 1)) || is_player(this)) || (this in $recycler.non_recyclable))
player:tell(("You can't recycle " + this.name) + ".");
return 0;
else
if (this:is_a($reusable))
player:tell("That item is already recyclable material!");
return;
elseif (this:is_a($game_object))
fork get_task_id ($recycler.recycle_time_limit)
"if it is on a player, remove from held and worn.";
if ((this.location != #-1) && is_player(this.location))
this.location.wielded = setremove(this.location.wielded, this);
this.location.worn = setremove(this.location.worn, this);
endif
"if it is an exit, remove it from the appropriate room.exits props";
if (this:is_a($exit))
if ((this.source != #-1) && this.source:is_a($room))
#5:tell(((("removing " + tostr(this)) + " from ") + tostr(this.source)) + " exits.");
this.source.exits = setremove(this.source.exits, this);
endif
endif
this:move_to(#5);
"if has kids, chparent on kids to this.parent";
if (kids = children(this))
for kid in (kids)
chparent(kid, parent(this));
endfor
endif
"if has contents, move any that are player to the start room";
"else move to anonymous";
if (conts = this.contents)
for content in (conts)
if (is_player(content))
move(content, content.start_location);
else
move(content, $anonymous);
endif
endfor
endif
"if owns any objs, chown to anonymous";
if (this:is_a($architect))
for owned in (this.owned_objects)
result = owned:chown($anonymous);
endfor
endif
"chparent to #22";
chparent(this, $reusable);
"set all bits to 0";
this.programmer = 0;
this.wizard = 0;
this.r = 0;
this.w = 0;
this.f = 0;
"clear any verbs";
for verby in (verbs(this))
delete_verb(this, verby);
endfor
"clear any props";
for propy in (properties(this))
delete_property(this, propy);
endfor
"rename to Reusable Object";
this.name = "Reusable Object " + tostr(this);
this.aliases = {};
"remove task from recyclers task list";
for task_item in ($recycler.recycle_tasks)
if (task_item[1] == this)
$recycler.recycle_tasks = setremove($recycler.recycle_tasks, task_item);
endif
endfor
player:tell(("Object " + tostr(this)) + " has been recycled.");
endfork
$recycler.recycle_tasks = {@$recycler.recycle_tasks, {this, get_task_id}};
player:tell(((((this.name + " has been queued for recycling in ") + tostr($recycler.recycle_time_limit / 60)) + " minutes with task id ") + tostr(get_task_id)) + ".");
player:tell("Kill this task id, or use the recycle command to stop this object from being destroyed.");
else
player:tell("We do not currently support recycling of this object type.");
endif
endif

chown

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

" ok, we will call this instead of the builtin chown, so that we may add objs to our";
" owned_objects prop.";
" takes as an argument its new owner.  returns 0 on failure, new parent on success.";
" will change ownership and ";
" modify neccessary owned_objects props.";
if (length(args) != 1)
return 0;
elseif (!valid(args[1]))
return 0;
else
new_owner = args[1];
old_owner = this.owner;
this.owner = new_owner;
if (old_owner:has_prop("owned_objects"))
old_owner.owned_objects = setremove(old_owner.owned_objects, this);
endif
if (new_owner:has_prop("owned_objects"))
new_owner.owned_objects = setadd(new_owner.owned_objects, this);
endif
return new_owner;
endif

_create

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

" #1:create this none this -- #1:create(obj owner) ";
" returns the object number of the new object owned by owner ";
{owner} = args;
if (!valid(owner))
return 0;
endif
new_owner = owner;
" check for existing reusable objects ";
kids = children($reusable);
if (kids != {})
new_object_num = kids[1];
chparent(new_object_num, this);
else
" assign new obj num, create new obj, owned by $dm ";
new_object_num = create(this, $dm);
endif
" change owner to new owner ";
"player:tell(new_object_num)";
testown = new_object_num:chown(new_owner);
" make sure call to chown did not fail ";
if (testown != new_owner)
$log:add_entry("system", "[ERROR]", (((("Call to " + this.name) + ":chown() failed in call to ") + this.name) + ":create().") + "Check your verb logic, its fucked up.");
endif
new_object_num.name = "Child of " + this.name;
return new_object_num;

move_to

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

• #1:recycle line 35: this:move_to
• #8:edit line 37: player:move_to
• #10:home line 6: this:move_to
• #58:exit line 5: player:move_to

Source

"#1:move_to(OBJ) this none this ";
what = this;
destination = args[1];
old_loc = this.location;
if (destination:is_a($animate))
retval = destination:can_hold(what);
if (retval[1] == 0)
return {0, "You cannot hold any more items."};
"if you are not already carrying the weight and encumbrance check for it";
elseif (!what:contained_by(destination))
"check encumbrance";
if ((destination:encumbrance() + what:encumbrance()) > destination.capacity)
return {0, "That item is too bulky for you to carry."};
"check weight limit";
elseif ((what:weight() + destination:carried_weight()) > (($str_weight_table[destination:str()] * 150) / 100))
return {0, "That item is too heavy for you to carry."};
endif
endif
elseif (destination:is_a($container))
"check encumbrance";
if ((destination:encumbrance() + what:encumbrance()) > destination.capacity)
return {0, "There is not enough room left to fit that item."};
"check max_fit size limit";
elseif (what:encumbrance() > destination.max_fit)
return {0, "That item is too large to fit."};
endif
endif
try
move(what, destination);
if (valid(old_loc))
if (old_loc:has_property("held"))
old_loc.held = setremove(old_loc.held, this);
endif
endif
if (destination:has_property("held"))
destination.held = {@destination.held, this};
endif
return {1, ""};
except (ANY)
return {0, "That item won't go! (builtin move threw error)"};
endtry

contained_by

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

• #1:move_to line 10: what:contained_by
• #1:contained_by line 10: this:contained_by

Source

"root class:contained_by() this none this";
"is OBJ contained by this? (recursive)";
targ = args[1];
if (this in targ.contents)
return 1;
elseif (targ.contents == {})
return 0;
else
for each in (targ.contents)
if (this:contained_by(each))
return 1;
endif
endfor
return 0;
endif

descendants

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

• #3:chan*nels line 3: $architect:descendants
• #3:chan*nels line 4: $dm:descendants
• #3:silent line 2: $architect:descendants
• #3:info*rmation line 21: $architect:descendants
• #3:known_to line 6: $architect:descendants
• #5:mc line 1: #1:descendants
• #6:name line 19: $architect:descendants
• #8:des*ign line 2: $architect:descendants
• #9:grep line 4: #1:descendants
• #9:which line 7: #1:descendants
• #10:dm line 2: $dm:descendants
• #10:missing line 6: #1:descendants
• #10:missing line 18: #15:descendants
• #10:match line 23: #1:descendants

Source

"#1:descendants() this none this";
target = this;
r = children(target);
i = 1;
while (i <= length(r))
if (kids = children(r[i]))
r = {@r, @kids};
endif
i = i + 1;
endwhile
return r;

is_a

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

• #1:recycle line 18: this:is_a
• #1:recycle line 21: this:is_a
• #1:recycle line 29: this:is_a
• #1:recycle line 54: this:is_a
• #3:mes*sage line 14: player:is_a
• #6:passwd line 4: player:is_a

Source

{targ} = args;
what = this;
while (valid(what))
if (what == targ)
return 1;
endif
what = parent(what);
endwhile
return 0;

ancestors

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

what = this;
ancestors = {};
while (valid(parent(what)))
ancestors = {@ancestors, parent(what)};
what = parent(what);
endwhile
return ancestors;

properties

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

what = this;
props = properties(what);
while (valid(parent(what)))
props = {@props, @properties(parent(what))};
what = parent(what);
endwhile
return props;

has_prop*erty

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

{prop} = args;
try
this.(prop);
return 1;
except (E_PROPNF, E_INVIND)
return 0;
endtry

has_verb

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

":has_verb(STR verbname)";
"Find out if an object has a verb matching the given verbname.";
"Returns {location} if so, 0 if not, where location is the object or the ancestor on which the verb is actually defined.";
{verbname} = args;
object = this;
while (E_VERBNF == (vi = `verb_info(object, verbname) ! E_VERBNF, E_INVARG'))
object = parent(object);
endwhile
return vi ? object | 0;

describe_to

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

"#1:describe_to(target) this none this";
"returns 0 if target isn't a valid animate objidnum";
"second arg: 0 is for one line desc, e.g. a room look. 1 is for multiline desc, e.g.";
"look at this, 2 is for very detailed desc, including contents.";
{target, ?msglen = 0} = args;
if (!target:is_a($animate))
return 0;
else
shownum = "";
if (target:is_a($architect))
shownum = (" (" + tostr(this)) + ")";
endif
sees_str = this.short_desc ? (this.short_desc + shownum) + " is lying here." | ((this.name + shownum) + " is lying here.");
if (msglen == 0)
target:sees(3, {sees_str});
elseif (msglen == 1)
target:sees(3, {sees_str});
target:sees(3, {this.description});
elseif (msglen == 2)
target:sees(3, {sees_str});
target:sees(3, {this.description});
target:sees(3, {"%WInside, you see:%w"});
if (this.contents != {})
for item in (this.contents)
item:describe_to(target, 0);
endfor
endif
endif
endif

encumbrance

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

• #1:move_to line 12: what:encumbrance
• #1:move_to line 21: what:encumbrance
• #1:move_to line 24: what:encumbrance

Source

"root class:encumbrance()";
if (this.contents == {})
return this.base_enc;
else
enc = 0;
for each in (this.contents)
enc = enc + each:encumbrance();
endfor
return enc + this.base_enc;
endif

weight

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

• #1:move_to line 15: what:weight

Source

"root class:weight()";
if (this.contents == {})
return this.base_weight;
else
weight = 0;
for each in (this.contents)
weight = weight + each:weight();
endfor
return weight + this.base_weight;
endif

tell

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

return;

known_to

Spec this none thisFlags rwxdOwner #10Definer #1

Referenced by

none

Source

"$root:known_to this none this";
return {1, this.name};