Architect Class #8

Parent #6Owner #10Flags fertileSource MurpgCore-0.4/MurpgCore-0.4.db

5 verbs · 72 properties · 1 children

Verbs

Properties

Ancestry

• #1 Root Class

  • #11 Game Class

    • #3 Animate Class

      • #6 Player Class

        • #8 Architect Class

          • #9 Coder Class

Ancestors (nearest first): #6 Player Class → #3 Animate Class → #11 Game Class → #1 Root Class

Children: #9 Coder Class

Call graph

Source

"$architect:props any none none";
{?target = ""} = args;
if (length(target) == 0)
player:tell("Display properties for what object?");
else
result = player:match(target);
if (result == {})
player:tell(("%W" + target) + "%w is not a valid object reference.");
elseif (length(result) > 1)
x = 1;
player:tell(("Which %W" + target) + "%w do you mean?");
for each in (result)
player:tell(((((tostr(x) + ":  ") + each.name) + " (") + tostr(each)) + ")");
x = x + 1;
endfor
else
target = result[1];
proplist = $utils:sort(target:properties());
player:tell("%WProperties on ", target.name, " (", tostr(target), "):");
player:tell("%gFundamental Object Attributes:");
player:tell("  Is Player --> ", is_player(target));
player:tell("  Parent --> ", parent(target));
player:tell("  Children --> ", toliteral(children(target)));
player:tell("%GBuiltin Properties:");
player:tell("  Owner --> ", target.owner);
player:tell("  Location --> ", target.location);
player:tell("  Contents --> ", toliteral(target.contents));
player:tell("  Programmer --> ", target.programmer);
player:tell("  Wizard --> ", target.wizard);
player:tell("  rwf --> ", target.r, target.w, target.f);
player:tell("%wAdditional Properties:");
for prop in (proplist)
defined_on = target;
while (!(prop in properties(defined_on)))
defined_on = parent(defined_on);
endwhile
value = toliteral(target.(prop));
if (length(value) > 80)
value = "[too long; use EVAL to display.]";
endif
player:tell_raw("  ", prop, " (", tostr(defined_on), ") --> ", value);
endfor
endif
endif

"parse args[1] for obj and prop, if list of strings, send arch to editor";
if (player.location == $editor)
player:tell("You are already in the Editor!");
elseif (length(args) != 1)
player:tell("%Gsyntax: %Wedit objnum.propname");
else
obj_and_prop = $utils:parse_prop_ref(args[1]);
if (obj_and_prop == 0)
player:tell("%Gsyntax: %Wedit objnum.propname");
else
objref = obj_and_prop[1];
propref = obj_and_prop[2];
targobj = toobj(objref);
"must use objnum, not name reference";
if ((objref[1] != "#") || ((objref != "#0") && (targobj == #0)))
player:tell("%Gsyntax: %Wedit objnum.propname");
elseif (!valid(targobj))
player:tell("Object %W", objref, "%w does not exist.");
elseif (!targobj:has_prop(propref))
player:tell(targobj.name, " does not have a property named %W", propref, "%w.");
"check to see if propref is a list of strings";
elseif (typeof(targobj.(propref)) != LIST)
player:tell("You can only edit properties that are of type LIST and that only contain strings.");
else
for each in (targobj.(propref))
if (typeof(each) != STR)
player:tell("You can only edit properties that are of type LIST and that only contain strings.");
return 0;
endif
endfor
"propref is list of strings, engage editing mode";
player:tell("You are being %Wtransported%w to the editor, and are now editing %W", args[1], "%w.");
player.editing_prop = propref;
player.editing_obj = targobj;
player.editing_loc = player.location;
player.insert_point = 1;
player:move_to($editor);
endif
endif
endif

"$architect:design any any any";
if (player in $architect:descendants())
if (!("design" in player.current_channels))
player:tell("%WYour channel has been turned on.%w");
player.current_channels = setadd(player.current_channels, "design");
endif
for designer in ($channels.design_channel)
if ("design" in designer.current_channels)
designer:tell();
designer:tell((((($channels.design_prefix + " ") + player.name) + ": ") + argstr) + "%w");
endif
endfor
else
player:tell($bad_command);
endif

"$architect:who_string() this none this";
viewer = args[1];
gender = {"N", "B", "F", "M"}[this.gender in {"neither", "both", "female", "male"}];
"afk";
if (this.afk)
afk = $who.afk + "  ";
else
afk = "       ";
endif
"editing";
if (this.location:is_a($editor))
edit = $who.editing + "  ";
else
edit = "           ";
endif
"idle";
idle = idle_seconds(this);
if (idle > 3600)
idle = $who.dormant + "  ";
elseif (idle > 1800)
idle = $who.vegetating + "  ";
elseif (idle >= 600)
idle = $who.idle + "  ";
else
idle = "        ";
endif
"admin";
if (this in $admins)
admin = $who.admin;
else
admin = "";
endif
name_string = $utils:padr(this.name, 16, " ");
who_string = ((((((("%Y[%yArch " + gender) + "%Y] ") + name_string) + afk) + edit) + idle) + admin) + "%w";
return who_string;

"$architect:say any any any";
if (player.location == $editor)
article = {};
old_article = player.editing_obj.(player.editing_prop);
for x in [1..player.insert_point - 1]
article = {@article, old_article[x]};
endfor
article = {@article, argstr};
for x in [player.insert_point..length(old_article)]
article = {@article, old_article[x]};
endfor
player.editing_obj.(player.editing_prop) = article;
player:tell("Line added.");
player.insert_point = player.insert_point + 1;
else
pass(@args);
endif