Character Creation #60

Parent #2Owner #5Flags read, writeSource MurpgCore-0.4/MurpgCore-0.4.db

3 verbs · 21 properties · 0 children

Verbs

Properties

Ancestry

• #1 Root Class

  • #11 Game Class

    • #2 Room Class

      • #60 Character Creation

Ancestors (nearest first): #2 Room Class → #11 Game Class → #1 Root Class

Children: none

Call graph

Source

"Char Creation Room:describe_to this none this";
"returns 0 if target isn't a valid animate objidnum";
{target} = args;
if (pass(@args))
return 0;
elseif (target.finished == 1)
target:tell("Your character is already finished.  You can't do anything here.  Go away!");
else
target:tell("");
"species";
target:tell("~", $utils:padr("  Species:", 16), $utils:padr(target.species.generic_name, 20), "(");
allowed_species = $player_species;
target:tell("~", allowed_species[1].generic_name);
for each in (allowed_species[2..$])
target:tell("~, ", each.generic_name);
endfor
target:tell(")");
"name";
target:tell($utils:padr("  Name:", 16), $utils:padr(target.name, 20), "(20 chars, no spaces)");
target:tell($utils:padr("  Full Name:", 16), $utils:padr(target.full_name, 20), "(20 chars, including spaces)");
"gender";
target:tell("~", $utils:padr("  Gender:", 16), $utils:padr(target.gender, 20), "(");
allowed_genders = $genders;
target:tell("~", allowed_genders[1]);
for each in (allowed_genders[2..$])
target:tell("~, ", each);
endfor
target:tell(")");
"height";
target:tell($utils:padr("  Height:", 16), $utils:padr(target:height_str(), 20), "(", $utils:height_str(target.species.min_height), " - ", $utils:height_str(target.species.max_height), ")");
"weight";
target:tell($utils:padr("  Weight:", 16), $utils:padr(tostr(target.base_weight) + " lbs.", 20), "(", target.species.min_weight, " - ", target.species.max_weight, " lbs.)");
"languages";
if (length(target.known_languages) == 0)
lang_str = "";
elseif (length(target.known_languages) == 1)
lang_str = target.known_languages[1].name;
else
lang_str = target.known_languages[1].name;
for each in (target.known_languages[2..$])
lang_str = (lang_str + ", ") + each.name;
endfor
endif
target:tell("~", $utils:padr("  Languages:", 16), $utils:padr(lang_str, 20), "(");
allowed_langs = $languages;
target:tell("~", allowed_langs[1].name);
for each in (allowed_langs[2..$])
target:tell("~, ", each.name);
endfor
target:tell(")");
"ability scores";
target:tell($utils:padr("  Strength:", 16), $utils:padr(tostr(target.base_str), 20), "(", target.species.min_str, " - ", target.species.max_str, ")");
target:tell($utils:padr("  Intelligence:", 16), $utils:padr(tostr(target.base_int), 20), "(", target.species.min_int, " - ", target.species.max_int, ")");
target:tell($utils:padr("  Dexterity:", 16), $utils:padr(tostr(target.base_dex), 20), "(", target.species.min_dex, " - ", target.species.max_dex, ")");
target:tell($utils:padr("  Constitution:", 16), $utils:padr(tostr(target.base_con), 20), "(", target.species.min_con, " - ", target.species.max_con, ")");
target:tell($utils:padr("  Concentration:", 16), $utils:padr(tostr(target.base_cnc), 20), "(", target.species.min_cnc, " - ", target.species.max_cnc, ")");
target:tell($utils:padr("  Speed:", 16), $utils:padr(tostr(target.base_spd), 20), "(", target.species.min_spd, " - ", target.species.max_spd, ")");
target:tell("");
points_left = (target.total_points - target.base_str) - ((((target.base_int + target.base_dex) + target.base_spd) + target.base_con) + target.base_cnc);
target:tell("You have ", points_left, " points left.  Type CREATE to create this character and start playing!");
endif

"char creation room : species any any any";
"sets player's species, checks scores for min/max values";
"assigns extra points for modifying primary attributes.";
species = $utils:trimr(argstr);
species_names = {};
for each in ($player_species)
species_names = {@species_names, each.generic_name};
endfor
if (species in species_names)
player:tell("Good choice.");
player.species = $player_species[species in species_names];
player.total_points = 60 + random(player.species.bonus_points);
"adjust ability scores";
player.base_str = (player.base_str > player.species.max_str) ? player.species.max_str | player.base_str;
player.base_str = (player.base_str < player.species.min_str) ? player.species.min_str | player.base_str;
player.base_int = (player.base_int > player.species.max_int) ? player.species.max_int | player.base_int;
player.base_int = (player.base_int < player.species.min_int) ? player.species.min_int | player.base_int;
player.base_dex = (player.base_dex > player.species.max_dex) ? player.species.max_dex | player.base_dex;
player.base_dex = (player.base_dex < player.species.min_dex) ? player.species.min_dex | player.base_dex;
player.base_spd = (player.base_spd > player.species.max_spd) ? player.species.max_spd | player.base_spd;
player.base_spd = (player.base_spd < player.species.min_spd) ? player.species.min_spd | player.base_spd;
player.base_con = (player.base_con > player.species.max_con) ? player.species.max_con | player.base_con;
player.base_con = (player.base_con < player.species.min_con) ? player.species.min_con | player.base_con;
player.base_cnc = (player.base_cnc > player.species.max_cnc) ? player.species.max_cnc | player.base_cnc;
player.base_cnc = (player.base_cnc < player.species.min_cnc) ? player.species.min_cnc | player.base_cnc;
"if total of scores is greater than total points, then reduce everything to minimums.";
total_scores = ((((player.base_str + player.base_int) + player.base_dex) + player.base_spd) + player.base_con) + player.base_cnc;
if (total_scores > player.total_points)
player.base_str = player.species.min_str;
player.base_int = player.species.min_int;
player.base_dex = player.species.min_dex;
player.base_spd = player.species.min_spd;
player.base_cnc = player.species.min_cnc;
player.base_con = player.species.min_con;
endif
"adjust height and weight";
player.height = (player.height > player.species.max_height) ? player.species.max_height | player.height;
player.height = (player.height < player.species.min_height) ? player.species.min_height | player.height;
player.base_weight = (player.base_weight > player.species.max_weight) ? player.species.max_weight | player.base_weight;
player.base_weight = (player.base_weight < player.species.min_weight) ? player.species.min_weight | player.base_weight;
else
if (species == "")
player:tell("Please select a species from the following list:");
else
player:tell("That is not a valid species.  Please select from the following list:");
endif
for each in (species_names)
player:tell("  " + each);
endfor
endif

"Char creation : full*name any any any";
"assigns name to player, letters only, no spaces.";
fullnamestr = argstr;
invalid = 0;
for x in [1..length(fullnamestr)]
if (!(index($letters, fullnamestr[x]) || (fullnamestr[x] == " ")))
invalid = 1;
endif
endfor
if (invalid || (length(fullnamestr) > 20))
player:tell("Your full name can only be 20 characters long, and must only contain letters and spaces.");
else
player.full_name = fullnamestr;
player:tell("Your full name has been changed.");
endif