The System Object #0

Parent #1Owner #2Flags obsolete1, readSource QuestCore.db

Aliases: The System Object

22 verbs · 213 properties · 0 children

Verbs

Properties

Ancestry

• #1 Root Class

  • #0 The System Object

Ancestors (nearest first): #1 Root Class

Children: none

Call graph

Source

"...This code should only be run as a server task...";
if (callers())
return E_PERM;
endif
if (typeof(h = $network:incoming_connection(player)) == OBJ)
"connected to an object";
return h;
elseif (h)
return 0;
endif
host = $string_utils:connection_hostname(connection_name(player));
if ($login:redlisted(host))
boot_player(player);
server_log(tostr("REDLISTED: ", player, " from ", host));
return 0;
endif
"...checks to see if the login is spamming the server with too many commands...";
if (!$login:maybe_limit_commands())
args = $login:parse_command(@args);
return $login:(args[1])(@listdelete(args, 1));
endif

if (!callers())
$last_restart_time = time();
$network:server_started();
$login:server_started();
endif

saved = {#0};
for p in (properties(#0))
v = #0.(p);
if ((typeof(v) == OBJ) && valid(v))
saved = setadd(saved, v);
endif
endfor
for o in (saved)
p = parent(o);
while (valid(p))
saved = setadd(saved, p);
p = parent(p);
endwhile
endfor
return $list_utils:sort(saved);

if (caller_perms().wizard)
pass();
if ("server_started" in verbs(this))
code = {"if (!callers())", "$last_restart_time = time(); $network:server_started(); $login:server_started(); endif"};
set_verb_code(this, "server_started", code);
endif
(clean = 0) || "set clean to 1 if you want to erase your custom verbs";
if (clean)
`delete_verb(this, "uptime_since") ! E_VERBNF';
`delete_verb(this, "do_command") ! E_VERBNF';
`delete_verb(this, "checkpoint_started") ! E_VERBNF';
`delete_verb(this, "checkpoint_finished") ! E_VERBNF';
endif
$core_history = {{$network.MOO_name, server_version(), time()}, @$core_history};
$shutdown_message = "";
$shutdown_time = 0;
$dump_interval = 3600;
$gripe_recipients = {player};
$dead_zone = $player_start;
$reaper = player;
$default_holder = $hacker;
$class_registry = {{"generics", "Generic objects intended for use as the parents of new objects", {$room, $exit, $thing, $note, $letter, $container, $root_class, $player, $prog, $wiz, $generic_editor, $mail_recipient, $mail_agent, $monster, $homer, $weapon, $hand, $collective, $ammo, $puppet, $clothing, $veroom, $terrain, $terrexit, $cuffs, $medkit, $rp_note, $light, $realm, $school, $lobby, $food1, $food2, $temple, $sales_bot, $display_room, $replicating_monster, $breeder_relay, $breeder, $booth}}, {"utilities", "Objects holding useful general-purpose verbs", children($generic_utils)}};
for v in ({"do_login_command", "server_started"})
c = {};
for i in (verb_code(this, v))
c = {@c, strsub(i, "$local.login", "$login")};
endfor
set_verb_code(#0, v, c);
endfor
endif

if (callers())
return;
endif
user = args[1];
set_task_perms(user);
try
user.location:confunc(user);
except id (ANY)
endtry

if (callers())
return;
endif
if (args[1] < #0)
"not logged in user";
return;
endif
user = args[1];
user.last_disconnect_time = time();
set_task_perms(user);
where = user.location;
`user:disfunc() ! ANY => 0';
if (user.location != where)
`where.location:disfunc(user) ! ANY => 0';
endif
`user.location:disfunc(user) ! ANY => 0';

"chparent(object, new-parent) -- see help on the builtin. This verb is called by the server when $server_options.protect_chparent exists and is true and caller_perms are not wizardly.";
who = caller_perms();
{what, papa} = args;
if (typeof(what) != OBJ)
retval = E_TYPE;
elseif (!valid(what))
retval = E_INVARG;
elseif (typeof(papa) != OBJ)
retval = E_TYPE;
elseif ((!valid(papa)) && (papa != #-1))
retval = E_INVIND;
elseif (!$perm_utils:controls(who, what))
retval = E_PERM;
elseif ((is_player(what) && (!$object_utils:isa(papa, $player_class))) && (!who.wizard))
retval = E_PERM;
elseif ((is_player(what) && (!$object_utils:isa(what, $player_class))) && (!who.wizard))
retval = E_PERM;
elseif ((children(what) && $object_utils:isa(what, $player_class)) && (!$object_utils:isa(papa, $player_class)))
retval = E_PERM;
elseif ((!valid(papa)) || ($perm_utils:controls(who, papa) || papa.f))
retval = `chparent(@args) ! ANY';
else
retval = E_PERM;
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

"add_verb() -- see help on the builtin for more information. This verb is called by the server when $server_options.protect_add_verb exists and is true and caller_perms() are not wizardly.";
who = caller_perms();
{what, info, verbargs} = args;
if (typeof(what) != OBJ)
retval = E_TYPE;
elseif (!valid(what))
retval = E_INVARG;
elseif ((!$perm_utils:controls(who, what)) && (!what.w))
"caller_perms() is not allowed to hack on the object in question";
retval = E_PERM;
elseif (!$perm_utils:controls(who, info[1]))
"caller_perms() is not permitted to add a verb with the specified owner.";
retval = E_PERM;
elseif (index(info[2], "w") && (!$server_options.permit_writable_verbs))
retval = E_INVARG;
elseif (!$quota_utils:verb_addition_permitted(who))
retval = E_QUOTA;
elseif (((what.owner != who) && (!who.wizard)) && (!$quota_utils:verb_addition_permitted(what.owner)))
retval = E_QUOTA;
elseif (!who.programmer)
retval = E_PERM;
else
"we now know that the caller's perms control the object or the object is writable, and we know that the caller's perms control the prospective verb owner (by more traditional means)";
retval = `add_verb(@args) ! ANY';
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

"add_property() -- see help on the builtin for more information. This verb is called by the server when $server_options.protect_add_property exists and is true and caller_perms() are not wizardly.";
who = caller_perms();
{what, propname, value, info} = args;
if (typeof(what) != OBJ)
retval = E_TYPE;
elseif (!valid(what))
retval = E_INVARG;
elseif ((!$perm_utils:controls(who, what)) && (!what.w))
retval = E_PERM;
elseif (!$perm_utils:controls(who, info[1]))
retval = E_PERM;
elseif (!$quota_utils:property_addition_permitted(who))
retval = E_QUOTA;
elseif (((what.owner != who) && (!who.wizard)) && (!$quota_utils:property_addition_permitted(what.owner)))
retval = E_QUOTA;
"elseif (!who.programmer)";
"  return E_PERM;     I wanted to do this, but $builder:@newmessage relies upon nonprogs being able to call add_property.  --Nosredna";
elseif ((propname in {"object_size", "size_quota", "queued_task_limit"}) && (!who.wizard))
retval = E_PERM;
else
"we now know that the caller's perms control the object (or the object is writable), and that the caller's perms are permitted to control the new property's owner.";
retval = `add_property(@args) ! ANY';
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

"recycle(object) -- see help on the builtin. This verb is called by the server when $server_options.protect_recycle exists and is true and caller_perms() are not wizardly.";
if (!valid(what = args[1]))
retval = E_INVARG;
elseif (!$perm_utils:controls(who = caller_perms(), what))
retval = E_PERM;
elseif ((p = is_player(what)) && (!who.wizard))
for p in ($wiz_utils:connected_wizards_unadvertised())
p:tell($string_utils:pronoun_sub("%N (%#) is currently trying to recycle %t (%[#t])", who, what));
endfor
retval = E_PERM;
else
if (p)
$wiz_utils:unset_player(what);
endif
retval = `recycle(what) ! ANY';
if (typeof(retval) != ERR)
$recycler:kill_all_tasks(what);
endif
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

if (callers())
return;
endif
if ($object_utils:isa(user = args[1], $guest))
"from $guest:boot";
oldloc = user.location;
move(user, $nothing);
"..force enterfunc to be called so that the newbie gets a room description.";
move(user, user.home);
user:do_reset();
if ($object_utils:isa(oldloc, $room))
oldloc:announce("In the distance you hear someone's alarm clock going off.");
if (oldloc != user.location)
oldloc:announce(user.name, " wavers and vanishes into insubstantial mist.");
else
oldloc:announce(user.name, " undergoes a wrenching personality shift.");
endif
endif
set_task_perms(user);
`user:confunc() ! ANY';
endif

"set_verb_info() -- see help on the builtin for more information. This verb is called by the server when $server_options.protect_set_verb_info exists and is true and caller_perms() are not wizardly.";
{o, v, i} = args;
if (typeof(vi = `verb_info(o, v) ! ANY') == ERR)
"probably verb doesn't exist";
retval = vi;
elseif (!$perm_utils:controls(cp = caller_perms(), vi[1]))
"perms don't control the current verb owner";
retval = E_PERM;
elseif ((typeof(i) != LIST) || (typeof(no = i[1]) != OBJ))
"info is malformed";
retval = E_TYPE;
elseif ((!valid(no)) || (!is_player(no)))
"invalid new verb owner";
retval = E_INVARG;
elseif (!$perm_utils:controls(cp, no))
"perms don't control prospective verb owner";
retval = E_PERM;
elseif (index(i[2], "w") && (!`$server_options.permit_writable_verbs ! E_PROPNF, E_INVIND => 1'))
retval = E_INVARG;
else
retval = `set_verb_info(o, v, i) ! ANY';
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

"do_out_of_band_command -- a cheap and very dirty do_out_of_band verb.  Forwards to verb on player with same name if it exists, otherwise forwards to $login.  May only be called by the server in response to an out of band command, otherwise E_PERM is returned.";
if (((caller == #-1) && (caller_perms() == #-1)) && (callers() == {}))
if (valid(player) && is_player(player))
set_task_perms(player);
player:do_out_of_band_command(@args);
else
$login:do_out_of_band_command(@args);
endif
else
return E_PERM;
endif

if (player.wizard)
player:infobar();
return 0;
endif
if ((args[1] in {"@who", "help", "page", "@mail", "@read", "@peek", "@next", "@nn", "@subscribed", "public", "pub", "cb", "help!", "@quit", "@stats", "@score", "@points", "@status"}) || player.programmer)
player:infobar();
return 0;
endif
if (`player.alert ! E_PROPNF => 0' && `player.mobile ! E_PROPNF => 0')
player:infobar();
return 0;
elseif (!`player.alert ! E_PROPNF => 1')
player:tell("[bold][red]You are unconscious.[normal]");
player:infobar();
return 1;
elseif (!`player.mobile ! E_PROPNF => 1')
if (args[1] in {"say", "look"})
player:infobar();
return 0;
else
player:tell("[bold][red]You are immobilized.[normal]");
player:infobar();
return 1;
endif
endif
player:infobar();
return 0;

m = `match(@args) ! ANY';
return ((typeof(m) == ERR) && $code_utils:dflag_on()) ? raise(m) | m;
if ((length(args[1]) > 256) && index(args[2], "*"))
return E_INVARG;
else
return match(@args);
endif

r = `rmatch(@args) ! ANY';
return ((typeof(r) == ERR) && $code_utils:dflag_on()) ? raise(r) | r;
if ((length(args[1]) > 256) && index(args[2], "*"))
return E_INVARG;
else
return rmatch(@args);
endif

if (!callers())
{code, msg, value, stack, traceback} = args;
"change the following (1) to (0) after major debugging is done";
if (1)
#2:tell($string_utils:nn(player), " invoked this traceback:");
#2:tell_lines(traceback);
endif
if (!$object_utils:connected(player))
"Mail the player the traceback if e isn't connected.";
$mail_agent:send_message(#0, player, {"traceback", $gripe_recipients}, traceback);
endif
"now let the player do something with it if e wants...";
return `player:(verb)(@args) ! ANY';
endif

"see help on the builtin for more information. This verb is called by the server when $server_options.protect_force_input exists and is true and caller_perms() are not wizardly.";
{conn, line, ?at_front = 0} = args;
if (caller_perms() != conn)
retval = E_PERM;
elseif (conn in $login.newted)
retval = E_PERM;
else
retval = `force_input(@args) ! ANY';
this.force_input_count = this.force_input_count + 1;
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

"keep it still.";
return pass(#-1);

who = caller_perms();
retval = 0;
try
{what, propname, info} = args;
except (E_ARGS)
retval = E_ARGS;
endtry
try
{owner, perms, ?newname = 0} = info;
except (E_ARGS)
retval = E_ARGS;
except (E_TYPE)
retval = E_TYPE;
endtry
if (retval != 0)
elseif ((newname in {"object_size", "size_quota", "queued_task_limit"}) && (!who.wizard))
retval = E_PERM;
else
set_task_perms(who);
retval = `set_property_info(@args) ! ANY';
endif
return ((typeof(retval) == ERR) && $code_utils:dflag_on()) ? raise(retval) | retval;

if (callers())
return E_PERM;
elseif (!$server_options.announce_checkpoint)
return;
endif
`$local.dump_started = time() ! ANY => "skip it"';
msg = $wiz_utils:checkpoint_started_msg();
for p in (connected_players())
p:notify(msg);
endfor

if (callers())
return E_PERM;
elseif (!args[1])
`$local.dump_finished = -1 ! ANY => "skip it"';
msg = $wiz_utils:checkpoint_failed_msg();
elseif (!$server_options.announce_checkpoint)
return;
else
`$local.dump_finished = time() ! ANY => "skip it"';
msg = $wiz_utils:checkpoint_finished_msg();
endif
for p in (connected_players())
p:notify(msg);
endfor