Generic Guest #31

boot

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

none

Source

if (!caller_perms().wizard)
return;
endif
player = this;
this:notify(tostr("Sorry, but you've been here for ", $string_utils:from_seconds(connected_seconds(this)), " and someone else wants to be a guest now.  Feel free to come back", @$login:player_creation_enabled(player) ? {" or even create your own character if you want..."} | {" or type `create' to learn more about how to get a character of your own."}));
"boot_player(this)";
return;
"See #0:user_reconnected.";

disfunc

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

none

Source

if ((((valid(cp = caller_perms()) && (caller != this)) && (!$perm_utils:controls(cp, this))) && (cp != this)) && (caller != #0))
return E_PERM;
endif
"Don't let another guest use this one until all this is done. See :defer, Ho_Yan 1/19/94";
this.free_to_use = 0;
this:log_disconnect();
this:erase_paranoid_data();
try
if (this.location != this.home)
this:room_announce(player.name, " has disconnected.");
this:room_announce("The housekeeper arrives to remove ", this.name, ".");
move(this, this.home);
this:room_announce("The housekeeper arrives to drop off ", this.name, ".");
endif
finally
this:do_reset();
this.free_to_use = 1;
endtry

defer

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

none

Source

"Called by #0:connect_player when this object is about to be used as the next guest character.  Usually returns `this', but if for some reason some other guest character should be used, that player object is returned instead";
if (!caller_perms().wizard)
"...caller is not :do_login_command; doesn't matter what we return...";
return this;
elseif ($login:blacklisted($string_utils:connection_hostname(connection_name(player))))
return #-2;
elseif (!(this in connected_players()))
"...not logged in, no problemo...";
return this;
endif
longest = 900;
"...guests get 15 minutes before they can be dislodged...";
candidate = #-1;
free = {};
for g in ($object_utils:leaves($guest))
if (!is_player(g))
"...a toaded guest?...";
elseif ((!(con = g in connected_players())) && g.free_to_use)
"...yay; found an unused guest...and their last :disfunc is complete";
free = {@free, g};
elseif (con && ((t = connected_seconds(g)) > longest))
longest = t;
candidate = g;
endif
endfor
if (free)
candidate = free[random($)];
elseif (valid(candidate))
"...someone's getting bumped...";
candidate:boot();
endif
return candidate;

mail_catch_up

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

none

Source

return;

create

Spec any any anyFlags rdOwner #36Definer #31

Referenced by

none

Source

if ($login:player_creation_enabled(player))
player:tell("First @quit, then connect to the MOO again and, rather than doing `connect guest' do `create <name> <password>'");
else
player:tell($login:registration_string());
endif

eject

Spec this none thisFlags rxdOwner #36Definer #31

Referenced by

• #31:do_reset line 13: this:eject

Source

return pass(@args);

log

Spec this none thisFlags rxdOwner #36Definer #31

Referenced by

none

Source

":log(islogin,time,where) adds an entry to the connection log for this guest.";
if (caller != this)
return E_PERM;
elseif (length(this.connect_log) < this.max_connect_log)
this.connect_log = {args, @this.connect_log};
else
this.connect_log = {args, @this.connect_log[1..this.max_connect_log - 1]};
endif

confunc

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

none

Source

if ((((valid(cp = caller_perms()) && (caller != this)) && (!$perm_utils:controls(cp, this))) && (cp != this)) && (caller != #0))
return E_PERM;
else
$guest_log:enter(1, time(), $string_utils:connection_hostname(connection_name(this)));
ret = pass(@args);
this:tell_lines(this:extra_confunc_msg());
return ret;
endif

log_disconnect

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

• #31:disfunc line 6: this:log_disconnect

Source

if (caller != this)
return E_PERM;
else
cname = `connection_name(this) ! ANY' || this.last_connect_place;
$guest_log:enter(0, time(), $string_utils:connection_hostname(cname));
endif

@last-c*onnection

Spec any none noneFlags rxdOwner #2Definer #31

Referenced by

none

Source

if (!valid(caller_perms()))
player:tell("Sorry, that information is not available.");
endif

@read @peek

Spec any any anyFlags rdOwner #36Definer #31

Referenced by

none

Source

return pass(@args);

set_current_folder

Spec this none thisFlags rxdOwner #36Definer #31

Referenced by

none

Source

return pass(@args);
"only for setting permission";

init_for_core

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

none

Source

if (caller_perms().wizard)
this.extra_confunc_msg = "";
`clear_property(this, "rooms") ! E_PROPNF => ""';
this.features = {$pasting_feature, $social_feature};
endif

set_name set_aliases

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

none

Source

"disallow guests from setting aliases on themselves";
if ($perm_utils:controls(caller_perms(), this))
return pass(@args);
else
return E_PERM;
endif

extra_confunc_msg

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

• #31:confunc line 6: this:extra_confunc_msg

Source

return $string_utils:pronoun_sub(this.(verb));

do_reset

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

• #31:disfunc line 16: this:do_reset

Source

if (!caller_perms().wizard)
return E_PERM;
else
flush_input(this, 0);
for x in ({"paranoid", "lines", "responsible", "linelen", "linebuffer", "brief", "gaglist", "rooms", "pagelen", "current_message", "current_folder", "messages", "messages_going", "request", "mail_options", "edit_options", "home", "ansi_options", "replace_codes"})
if ($object_utils:has_property(parent(this), x))
clear_property(this, x);
endif
endfor
this:set_description(this.default_description);
this:set_gender(this.default_gender);
for x in (this.contents)
this:eject(x);
endfor
for x in (this.features)
if (!(x in $guest.features))
this:remove_feature(x);
endif
endfor
for x in ($guest.features)
if (!(x in this.features))
this:add_feature(x);
endif
endfor
for x in ($object_utils:descendants($generic_editor))
if (loc = this in x.active)
x:kill_session(loc);
endif
endfor
endif

@request

Spec any any anyFlags rdOwner #2Definer #31

Referenced by

none

Source

"Copied from Generic Guest (#5678):@request by Froxx (#49853) Mon Apr  4 10:49:26 1994 PDT";
"Usage:  @request <player-name> for <email-address>";
if (player != this)
return player:tell(E_PERM);
endif
if (this.request)
return player:tell("Sorry, you appear to have already requested a character.");
endif
name = dobjstr;
if ((prepstr != "for") || ((!dobjstr) || index(address = iobjstr, " ")))
return player:notify_lines($code_utils:verb_usage());
endif
if ($login:request_character(player, name, address))
this.request = 1;
endif

connection_name_hash

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

none

Source

"Compute an encrypted hash of the guest's (last) connection, using 'crypt'. Basically, you can't tell where the guest came from, but it is unlikely that two guests will have the same hash";
"You can use guest:connection_name_hash(seed) as a string to identify whether two guests are from the same place.";
xx = $wiz_utils:connection_hash(caller_perms(), $string_utils:connection_hostname(this.last_connect_place), @args);
hash = toint(caller_perms());
host = $string_utils:connection_hostname(this.last_connect_place);
for i in [1..length(host)]
hash = (hash * 14) + index($string_utils.ascii, host[i]);
endfor
return crypt(tostr(hash), @args);

@kids @s*how @verbs @props @properties @exam*ine exam*ine where*is @where*is home

Spec any none noneFlags rdOwner #2Definer #31

Referenced by

none

Source

if (!$rp_regulator.do_restrict_guests)
return `player:(verb)(@args) ! E_VERBNF => ""';
else
player:tell("Sorry, guests aren't allowed to peek at the details.");
endif

@add-feature @addfeature @remove-feature @rmfeature

Spec any none noneFlags rdOwner #2Definer #31

Referenced by

none

Source

if ($rp_regulator.do_restrict_guests)
return player:notify("Sorry, only a wizard can add or remove your features on this MOO.");
elseif (caller == this)
pass(@args);
endif

my_huh

Spec this none thisFlags rxdOwner #2Definer #31

Referenced by

none

Source

if (caller_perms().wizard || (caller_perms() in {this, $hacker}))
return pass(@args);
else
return E_PERM;
endif