Player Class #6

Parent #3Owner #10Flags fertileSource MurpgCore-0.4/MurpgCore-0.4.db

8 verbs · 67 properties · 2 children

Verbs

Properties

Ancestry

• #1 Root Class

  • #11 Game Class

    • #3 Animate Class

      • #6 Player Class

        • #8 Architect Class
        • #25 Anonymous

Ancestors (nearest first): #3 Animate Class → #11 Game Class → #1 Root Class

Children: #8 Architect Class, #25 Anonymous

Call graph

Source

"$player:north south east west up down";
exit = this.location:match_exit(verb);
if (length(args) > 0)
dirs = {verb, @args};
else
dirs = {verb};
endif
if (this.consciousness != "awake")
this:tell("You cannot move...you are ", this.consciousness, "!");
else
if (valid(exit))
this:go(dirs);
elseif (exit == $failed_match)
player:tell("You can't go that way.");
else
player:tell("I don't know which direction `", verb, "' you mean.");
endif
endif

"#6:passwd any none none";
targetstr = argstr;
if (targetstr != "")
if (player:is_a($dm) && (player.wizard == 1))
targetnum = $utils:match(targetstr, players(), 1, 1);
if (targetnum != {})
target = targetnum[1];
player:tell("~New password:");
newpwd = read(player, 0);
player:tell("~Retype new password:");
renewpwd = read(player, 0);
if (newpwd == renewpwd)
if (length(newpwd) >= 7)
target.password = crypt(newpwd);
player:tell(("Password for %W" + target.name) + "%w changed.");
else
player:tell("Password too short.  Not changed.");
endif
else
player:tell("Passwords do not match.");
endif
else
player:tell(("Player %W" + targetstr) + "%w does not exist.");
endif
else
player:tell("Syntax: passwd <cr>");
endif
else
this:tell("~Old password:");
oldpwd = read(player, 0);
auth = crypt(oldpwd, player.password[1..2]) == player.password;
if (auth)
player:tell("~New password:");
newpwd = read(player, 0);
player:tell("~Retype new password:");
renewpwd = read(player, 0);
if (newpwd == renewpwd)
if (length(newpwd) >= 7)
player.password = crypt(newpwd);
player:tell(("Password for %W" + player.name) + "%w changed.");
else
player:tell("Password too short.  Not changed.");
endif
else
player:tell("Passwords do not match.");
endif
else
player:tell("Password change failed.  Failures are logged for security.");
endif
endif

"$player:look(any any any)";
"$player:north south east west up down";
if (this.consciousness == "unconscious")
this:tell("You see nothing but a dull red glow.  You are unconscious.");
elseif (this.consciousness == "dead")
this:tell("You see a bright white light glowing at the end of a long, dark tunnel.");
elseif (this.consciousness == "asleep")
this:tell("You see crazy stuff that we can generate with a dream generator.  That would be fun. And we can pull it from random text strings pulled from stuff that the player saw that day.");
elseif (length(args) == 0)
player.location:describe_to(player);
elseif (prepstr == "")
"parse dobjstr, do a describe to on it";
target = dobjstr;
"build list of candidates to which to match";
items = player.location.contents;
matches = player:match(target, items);
if (matches == {})
player:tell(("There is no %W" + dobjstr) + "%w here.");
"multiple matches";
elseif (length(matches) > 1)
player:tell_ambiguous(dobjstr, matches);
"unique match";
else
targobj = matches[1];
targobj:describe_to(player, 2);
endif
elseif (prepstr == "on")
"parse dobjstr and iobjstr, do a describe on it";
target = dobjstr;
loc = iobjstr;
elseif (prepstr == "in")
"parse dobjstr and iobjstr, do a describe on it";
target = dobjstr;
loc = iobjstr;
items = {@player.contents, @player.location.contents};
locobj = player:match(loc, items);
if (locobj == {})
player:tell(("There is no %W" + loc) + "%w here.");
elseif (target == "")
locobj[1]:describe_to(player, 2);
else
items = locobj[1].contents;
matches = player:match(target, items);
if (matches == {})
player:tell(((("There is no %W" + target) + "%w in ") + locobj[1].name) + ".");
else
targobj = matches[1];
targobj:describe_to(player, 1);
endif
endif
else
player:tell("Syntax:  look [in | on] object");
player:tell("Example:  look in sack");
"syntax message";
endif

"$player:who_string() this none this";
viewer = args[1];
gender = {"N", "B", "F", "M"}[this.gender in {"neither", "both", "female", "male"}];
species = this.species.who_str;
"Check if this player is known to viewer.";
known = this:known_to(viewer);
if (known[1])
name = known[2];
pad = 16;
else
name = $who.unknown;
pad = 18;
endif
"afk";
if (this.afk)
afk = $who.afk + "  ";
else
afk = "       ";
endif
"editing";
if (this.location:is_a($editor))
edit = $who.editing + "  ";
else
edit = "           ";
endif
"idle";
idle = idle_seconds(this);
if (idle > 3600)
idle = $who.dormant + "  ";
elseif (idle > 1800)
idle = $who.vegetating + "  ";
elseif (idle >= 600)
idle = $who.idle + "  ";
else
idle = "        ";
endif
"admin";
if (this in $admins)
admin = $who.admin;
else
admin = "";
endif
name_string = $utils:padr(name, pad, " ");
who_string = (((((((((("%G[" + "%g") + species) + "  ") + gender) + "%G] ") + name_string) + afk) + edit) + idle) + admin) + "%w";
return who_string;

"$player:kn*own() any any any";
if (player in $admins)
player:tell("%WAll players are already known to you.  But here's the output anyway:%w");
endif
if (player.known_players)
names = {};
objs = {};
for x in (player.known_players)
if (typeof(x) == 2)
names = {@names, x};
else
objs = {@objs, x};
endif
endfor
pad = $utils:longest(names) + 4;
player:tell("");
player:tell("%yKnown Players:");
player:tell("%W--------------");
for x in [1..length(objs)]
name = "%y" + names[x];
namestr = $utils:padr(name, pad, " ");
spec = objs[x].species.adj + " ";
gend = #0.(objs[x].gender)[1];
if (spec[1] == "e")
prep = "%yAn ";
else
prep = "%yA ";
endif
player:tell(((((namestr + "%W=>   ") + prep) + spec) + gend) + ".%w");
endfor
player:tell("");
else
player:tell("%WYou do not know any players.%w");
endif

"$player:ren*ame any any any";
newname = 0;
if (!args)
player:tell("%WRename which player?%w");
else
target = $utils:capitalize(args[1]);
known = player.known_players;
inlist = target in known;
if (!inlist)
player:tell("%WYou don't know any player by that name.%w");
else
alen = length(target);
newstr = argstr[alen + 2..$];
if (!newstr)
player:tell(("%WRename " + target) + " to what?%w");
else
if (argstr[alen + 2..alen + 3] == "to")
if (length(argstr) == (alen + 3))
player:tell(("%WRename " + target) + " to what?%w");
else
newname = newstr[4..$];
endif
else
newname = newstr;
endif
endif
endif
endif
if (newname)
newname = $utils:capitalize(newname);
"Determine if there are disallowed spaces or characters in the name.";
if ((index(newname, " ") || index(newname, "#")) || index(newname, "%"))
player:tell("%WNames cannot contain spaces, pound signs, or percent signs.%w");
else
"Determine if the new name is too long.";
if (length(newname) > 20)
player:tell("%WThat name is too long.%w");
else
"Determine if there is already a player with that name.";
if (newname in known)
player:tell(("%WYou already know a player with the name " + newname) + ".%w");
else
oldname = known[inlist];
player.known_players[inlist] = newname;
player:tell(((("%c" + oldname) + " is now known as ") + newname) + ".%w");
endif
endif
endif
endif

"$player:intro*duce any any any";
name = player.name;
group = setremove(player.location.contents, player);
gend = #0.(player.gender)[6];
lang = player.current_language;
if (args)
targmatch = $utils:match(args[1], player.location.contents);
if (!targmatch)
player:tell("%WThere is no such player here.%w");
else
if (length(targmatch) > 1)
player:tell("%WMultiple matches, please be more specific.%w");
else
target = targmatch[1];
subgroup = setremove(group, target);
if (target == player)
for x in (group)
pname = $utils:capitalize(player:known_to(x)[2]);
okmsg = ((((pname + " introduces ") + gend) + "... to ") + gend) + ".";
nomsg = ((((pname + " is talking to ") + gend) + " in ") + lang.name) + " again...";
x:hears(3, {okmsg}, lang, {nomsg});
endfor
player:tell("You introduce yourself.. to yourself.");
else
"Send messages to audience in room.";
for x in (subgroup)
pname = $utils:capitalize(player:known_to(x)[2]);
tname = target:known_to(x)[2];
okmsg = ((((pname + " introduces ") + gend) + " to ") + tname) + ".";
nomsg = ((((pname + " says something to ") + tname) + " in ") + lang.name) + ".";
x:hears(3, {okmsg}, lang, {nomsg});
endfor
"Send message to designated target.";
pname = $utils:capitalize(player:known_to(target)[2]);
targokmsg = ((((pname + " introduces ") + gend) + " to you as '") + name) + "'.";
targnomsg = ((pname + " says something to you in ") + lang.name) + ".";
target:hears(3, {targokmsg}, lang, {targnomsg});
"Send message to player.";
tname = target:known_to(player)[2];
pmsg = ((("You introduce yourself as '" + name) + "' to ") + tname) + ".";
player:tell(pmsg);
endif
endif
endif
else
for x in (group)
pname = $utils:capitalize(player:known_to(x)[2]);
okmsg = ((((pname + " introduces ") + gend) + " to the room as '") + name) + "'.";
nomsg = ((pname + " says something in ") + lang.name) + ".";
x:hears(3, {okmsg}, lang, {nomsg});
endfor
"Send message to player.";
pmsg = ("You introduce yourself to the room as '" + name) + "'.";
player:tell(pmsg);
endif

"$player:call/name any any any";
if (player in $admins)
player:tell("%WAdmins see all players' real names.  But here's the output anyway:%w");
player:tell("");
endif
verbstr = $utils:capitalize(verb);
if (!args)
player:tell(("%W" + verbstr) + " who what?%w");
else
targmatch = this:match(args[1], player.location.contents);
if (!targmatch)
player:tell("%WThere is no such player here.%w");
else
if (length(targmatch) > 1)
player:tell("%WMultiple matches, please be more specific.%w");
else
target = targmatch[1];
"Game designers and admins are not included in known_players.";
nope = {@$architect:descendants(), @$admins};
if (target in nope)
player:tell("%WGame designers and administrators are always known by their real names.%w");
elseif (target == player)
player:tell("%WHaving an identity crisis?%w");
else
gend = #0.(target.gender)[3];
if (length(argstr) == length(args[1]))
player:tell(((("%W" + verbstr) + " ") + gend) + " what?%w");
else
"Now we have TARGET and NAME.";
name = tostr(args[2]);
oldname = $utils:capitalize(target:known_to(player)[2]);
known = player.known_players;
"Determine if NAME is already in known_players.";
nref = name in known;
if (nref)
if (name == known[nref])
player:tell(("%WYou already know " + gend) + " by that name.%w");
else
len = length(name);
inc = 1;
inuse = name;
while (name in known)
name = name[1..len] + tostr(inc);
inc = inc + 1;
endwhile
name = $utils:capitalize(name);
player.known_players[nref] = name;
player:tell(((("%WThe name " + inuse) + " was already in use, so ") + name) + " has been used instead.");
player:tell("To change this value, use the rename command.");
player:tell(((oldname + " is now known as ") + name) + ".%w");
endif
else
name = $utils:capitalize(name);
player.known_players = listappend(player.known_players, target);
player.known_players = listappend(player.known_players, name);
player:tell(((("%W" + oldname) + " is now known as ") + name) + ".");
endif
endif
endif
endif
endif
endif