generic immortal #89

lookup_room

Spec this none thisFlags rxdOwner #29Definer #89

Referenced by

• #2:@move line 20: this:lookup_room
• #89:@go line 2: this:lookup_room

Source

"Look up a room in your personal database of room names, returning its object number. If it's not in your database, it checks to see if it's a number or a nearby object.";
room = args[1];
if (room == "home")
return player.home;
elseif (room == "me")
return player;
elseif (room == "here")
return player.location;
elseif (room == "#-1")
return #-1;
elseif (!room)
return $failed_match;
endif
index = this:index_room(room);
if (index)
return this.rooms[index][2];
else
return this:my_match_object(room);
"old code no longer used, 2/11/96 Heathcliff";
source = player.location;
if (!(valid(source) && ($room in $object_utils:ancestors(source))))
source = $room;
endif
return source:match_object(room);
endif

teleport

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

• #2:@move line 26: this:teleport
• #89:@join_old line 47: this:teleport

Source

"Teleport a player or object. For printing messages, there are three cases: (1) teleport self (2) teleport other player (3) teleport object. There's a spot of complexity for handling the invalid location #-1.";
set_task_perms((caller == this) ? this | $no_one);
{thing, dest} = args;
source = thing.location;
if (valid(dest))
dest_name = dest.name;
else
dest_name = tostr(dest);
endif
if (source == dest)
player:tell(thing.name, " is already at ", dest_name, ".");
return;
endif
thing:moveto(dest);
if (thing.location == dest)
tsd = {thing, source, dest};
if (thing == player)
this:teleport_messages(@tsd, this:self_port_msg(@tsd), this:oself_port_msg(@tsd), this:self_arrive_msg(@tsd), "");
elseif (is_player(thing))
this:teleport_messages(@tsd, this:player_port_msg(@tsd), this:oplayer_port_msg(@tsd), this:player_arrive_msg(@tsd), this:victim_port_msg(@tsd));
else
this:teleport_messages(@tsd, this:thing_port_msg(@tsd), this:othing_port_msg(@tsd), this:thing_arrive_msg(@tsd), this:object_port_msg(@tsd));
endif
elseif (thing.location == source)
if ($object_utils:contains(thing, dest))
player:tell("Ooh, it's all twisty. ", dest_name, " is inside ", thing.name, ".");
else
if ($object_utils:has_property(thing, "po"))
pronoun = thing.po;
else
pronoun = "it";
endif
player:tell("Either ", thing.name, " doesn't want to go, or ", dest_name, " didn't accept ", pronoun, ".");
endif
else
thing_name = (thing == player) ? "you" | thing.name;
player:tell("A strange force deflects ", thing_name, " from the destination.");
endif

teleport_messages

Spec this none thisFlags rxdOwner #29Definer #89

Referenced by

• #89:teleport line 18: this:teleport_messages
• #89:teleport line 20: this:teleport_messages
• #89:teleport line 22: this:teleport_messages

Source

"Send teleport messages. There's a slight complication in that the source and dest need not be valid objects.";
{thing, source, dest, pmsg, smsg, dmsg, tmsg} = args;
if (pmsg)
"The player's own message.";
player:tell(pmsg);
endif
if (smsg)
`source:room_announce_all_but({thing, player}, smsg) ! E_VERBNF, E_INVIND';
endif
if (dmsg)
`dest:room_announce_all_but({thing, player}, dmsg) ! E_VERBNF, E_INVIND';
endif
if (tmsg)
"A message to the victim being teleported.";
thing.listening && thing:tell(tmsg);
endif

@join

Spec any none noneFlags rxdOwner #29Definer #89

Referenced by

none

Source

if (player != this)
return player:tell("I don't understand that.");
endif
who = $su:match_player(dobjstr);
if (!valid(who))
who = $npc:named(dobjstr);
endif
if (!valid(who))
player:tell("@join who?");
elseif (is_a(who.location, $generic_editor))
if ((index = who in who.location.active) && is_a(origin = who.location.original[index], $room))
this:_teleport(origin);
player:tell(((who:dnamec() + " is editing something right now, wait here until ") + who.ps) + " is done.");
else
player:tell(who:dnamec() + " is editing something right now, but I don't know where he was.");
endif
else
this:_teleport(who.location);
endif

msg_sub

Spec this none thisFlags rxdOwner #29Definer #89

Referenced by

• #89:self_port_msg line 5: this:msg_sub
• #89:oself_port_msg line 7: this:msg_sub

Source

"Do pronoun and other substitutions on the teleport messages. The arguments are: 1. The original message, before any substitutions; 2. object being teleported; 3. from location; 4. to location. The return value is the final message.";
{msg, thing, from, to} = args;
msg = $string_utils:substitute(msg, $string_utils:pronoun_quote({{"%<from room>", valid(from) ? from.name | "Nowhere"}, {"%<to room>", valid(to) ? to.name | "Nowhere"}}));
msg = $string_utils:pronoun_sub(msg, thing);
return msg;

last_huh

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

set_task_perms(caller_perms());
if (pass(@args))
return 1;
endif
{verb, args} = args;
if (valid(dobj = $string_utils:literal_object(dobjstr)) && (r = $match_utils:match_verb(verb, dobj, args)))
return r;
elseif (valid(iobj = $string_utils:literal_object(iobjstr)) && (r = $match_utils:match_verb(verb, iobj, args)))
return r;
else
return 0;
endif

init_for_core

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

• #2:init_for_core line 7: pass(

Source

if (caller_perms().wizard)
pass();
if ($code_utils:verb_location() == this)
this.rooms = {};
delete_verb(this, "@web");
delete_verb(this, "web_info");
delete_verb(this, "set_web_info");
delete_property(this, "web_info");
else
clear_property(this, "rooms");
endif
this.features = {$pasting_feature, $stage_talk};
endif

self_port_msg player_port_msg thing_port_msg join_msg

Spec this none thisFlags rxdOwner #29Definer #89

Referenced by

• #89:teleport line 18: this:self_port_msg
• #89:teleport line 20: this:player_port_msg
• #89:teleport line 22: this:thing_port_msg
• #89:@join_old line 27: this:join_msg

Source

"Copied from Frand's player class (#89):self_port_msg by Hacker (#36) Mon Sep  1 01:23:51 2008 CDT";
"This verb returns messages that go only to you. You don't need to have your name tacked on to the beginning of these. Heh.";
msg = this.(verb);
if (msg && (length(args) >= 3))
msg = this:msg_sub(msg, @args);
endif
return msg;

oself_port_msg self_arrive_msg oplayer_port_msg player_arrive_msg victim_port_msg othing_port_msg thing_arrive_msg object_port_msg

Spec this none thisFlags rxdOwner #29Definer #89

Referenced by

• #89:teleport line 18: this:oself_port_msg
• #89:teleport line 18: this:self_arrive_msg
• #89:teleport line 20: this:oplayer_port_msg
• #89:teleport line 20: this:player_arrive_msg
• #89:teleport line 20: this:victim_port_msg
• #89:teleport line 22: this:othing_port_msg
• #89:teleport line 22: this:thing_arrive_msg
• #89:teleport line 22: this:object_port_msg

Source

"This verb returns messages that go to other players. It does pronoun substitutions; if your name is not included in the final string, it adds the name in front.";
msg = this.(verb);
if (!msg)
msg = parent(this).(verb);
endif
if (length(args) >= 3)
msg = this:msg_sub(msg, @args);
endif
name = this:dnamec();
if (((!index(msg, name)) && (!index(msg, "%N"))) && (!index(msg, "%DN")))
msg = (name + " ") + msg;
endif
return msg;

die

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

body = this.body;
this:tell("");
this:tell(($ansi.bold_on + "YOU DIED, DUMBASS.") + $ansi.reset);
this:tell("");
this.blood = {};
this.queue = {};
for x in (this.fighting)
x.fighting = setremove(x.fighting, this);
x:cancel_current_action();
endfor
this.fighting = {};
this:cancel_current_action();
dtype = (length(args) > 1) ? args[2] | $damage;
diemsg = this.explode_msg;
if (dtype != #15895)
diemsg = this.die_msg;
endif
killers = {};
this:aat((($ansi.bold_on + $ansi.red) + $su:ps(diemsg, this, this)) + $ansi.reset);
for x in (this.location:occupants($creature))
if (this in x.fighting)
killers = {@killers, x};
endif
endfor
killer = killers ? killers[random(length(killers))] | #-1;
"$nets.deathnet:announce_death(this, killer, dtype);";
this:revert_code_name();
this.home:announce_all(this:inamec(), " appears in a flash of blue light.");
this:moveto(this.home);
this.health = this.health_max;
this.blood = {};
if (is_a(body, $body))
body:turn_to_corpse();
body.player = #-1;
body = #-1;
endif

gain_stress

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

if ($ou:has_prop(this, "gain_stress"))
return pass(@args);
endif

_heartbeat_hunger

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

No program (verb defined but unprogrammed).

@mjoin @mvisit

Spec any none noneFlags rxdOwner #361Definer #89

Referenced by

none

Source

who = $su:match_player(dobjstr);
if (!valid(who))
player:tell("@join who?");
return;
endif
exit = player.location.exits[random(length(player.location.exits))];
exit.location:announce_all($su:ps(exit.oleave_msg, player, exit));
where = who.location;
area = where:area();
if (area != #257121)
disguise = where:area():random_npc();
this:_morph(disguise);
else
this:revert_code_name();
endif
entrance = this:pick_visit(who);
if (verb == "@mvisit")
player:moveto(entrance.otherside.location);
player:tell(who:dnamec(), " is in ", entrance.otherside:dname(), ".");
else
entrance.location:announce_all($su:ps(entrance.oarrive_msg, player, entrance));
player:moveto(where);
endif

_morph

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

• #89:@mjoin line 12: this:_morph
• #89:@morph line 7: this:_morph
• #89:prep_to_visit line 14: this:_morph

Source

source = args[1];
this:tell((((($ansi.bold_on + $ansi.cyan) + "[ You take the form of ") + source:iname()) + ". ]") + $ansi.reset);
$gender_utils:set(this, source.gender);
this:revert_code_name();
code_name = source.name;
code_name = strsub(code_name, "generic", "");
code_name = $su:trim(code_name);
this:set_code_name(code_name, source.description);
this.has_proper_name = source.has_proper_name;
for x in ($ou:leaves($skill))
this.skills[skill.name] = {skill:raw(source), skill:ip(source), 0, 0};
endfor
this.health_max = source.health_max;
this.health = source.health;
this.wearing = {};
this.wielding = {};
this.armor = source.armor;
this.unarmed_weapon = source.unarmed_weapon;
this.body_parts = source.body_parts;

tell

Spec this none thisFlags rxdOwner #29Definer #89

Referenced by

• #2:tell line 10: pass(
• #89:die line 2: this:tell
• #89:die line 3: this:tell
• #89:die line 4: this:tell
• #89:_morph line 2: this:tell
• #89:prep_to_visit line 7: this:tell
• #89:prep_to_visit line 13: this:tell
• #89:_teleport line 22: this:tell

Source

ret = pass(@args);
if (((this.code_name != "") && (this.location == $lu:slice(callers(), 1)[$])) && (!(#181402 in $lu:slice(callers(), 1))))
objs = $lu:slice(callers(), 4);
if (((!($net in objs)) && (!(#50 in objs))) && (!(#318 in objs)))
#181402:announce(this, $su:from_list({"[", this.name[1..min(4, length(this.name))], "] ", @args}, ""), 1);
endif
endif
return ret;

encumbrance

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

No program (verb defined but unprogrammed).

tell_wearing

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

if (this.code_name)
return;
endif
return pass(@args);

pick_visit

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

• #89:@mjoin line 16: this:pick_visit
• #89:_teleport line 13: this:pick_visit

Source

who = args[1];
if (gamevalid(who.home) && (area(who) == area(who.home)))
for x in (who.home.exits)
if ((x.direction == "out") && (x.otherside.direction != "in"))
return x;
endif
endfor
endif
cand = who.location.exits;
if (cand)
return cand[random(length(cand))];
else
return #-1;
endif

@morph

Spec any none noneFlags rxdOwner #361Definer #89

Referenced by

none

Source

source = $mu:match(dobjstr, $ou:leaves_suspended($npc));
if (!valid(source))
player:tell("@morph what?");
return;
endif
player:tell("Morphing you into ", $su:nn(source), "...");
this:_morph(source);

max_carry

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

return 200000000;

prep_to_visit

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

• #89:_teleport line 30: this:prep_to_visit

Source

return;
where = args[1];
region = where:region();
area = where:area();
if (region.admin_ok || area.admin_ok)
if (this.code_name)
this:tell($ansi.bold_on, "[ Reverting to admin form. ]", $ansi.reset);
this:revert_code_name();
endif
else
if (!this.code_name)
npc = area:random_npc();
this:tell($ansi.bold_on, "[ Disguising as ", npc.name, ". ]", $ansi.reset);
this:_morph(npc);
endif
endif

_teleport

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

• #2:home line 1: this:_teleport
• #89:@join line 12: this:_teleport
• #89:@join line 18: this:_teleport
• #89:@go line 16: this:_teleport

Source

where = args[1];
entrance = #-1;
exit = #-1;
if ((!is_a(where, $room)) || (where.exits == {}))
oldloc = this.location;
for x in (oldloc:occupants($prog))
x:tell($ansi.cyan, "[ ", this.name, " has left. ]", $ansi.reset);
endfor
this:moveto(where);
return;
endif
if (people = where:occupants($player))
entrance = this:pick_visit(people[1]);
else
entrance = where.exits[random(length(where.exits))];
endif
if (!is_a(this.location, $room))
exit = #-1;
else
exit = this:pick_teleport_exit();
if (valid(exit) && (m = exit:leave_msg()))
this:tell($su:ps(m, this, exit, where));
endif
endif
if (valid(exit))
oleave = $su:ps(exit:oleave_msg(), this, exit, where);
else
oleave = this:dnamec() + " wanders out.";
endif
this:prep_to_visit(where);
if (valid(entrance))
where:announce_all($su:ps(entrance:oarrive_msg(), this, entrance, where));
else
where:announce_all(this:dnamec(), " wanders in.");
endif
oldloc = this.location;
this:moveto(where);
if (is_a(oldloc, $room))
oldloc:announce_all(oleave);
for x in (oldloc:occupants($prog))
x:tell($ansi.cyan, "[ ", this.name, " has left. ]", $ansi.reset);
endfor
endif

pick_teleport_exit

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

• #89:_teleport line 20: this:pick_teleport_exit

Source

if (is_a(here = this.location, $room))
set = here.exits;
for x in (set)
if (!((is_a(x.otherside, $exit) && is_a(x.otherside.location, $room)) && (length(x.otherside.location.exits) > 1)))
set = setremove(set, x);
endif
endfor
if (set)
return set[random($)];
endif
endif
return #-1;

@join_old

Spec any none noneFlags rxdOwner #29Definer #89

Referenced by

none

Source

"Copied from generic immortal (#89):@join by Hacker (#36) Sat Oct 25 00:29:05 2008 CDT";
"'@join <player>' - Teleport yourself to the location of any player, whether connected or not.";
if (player != this)
player:tell("I don't understand that.");
return;
endif
if (dobjstr == "")
player:tell("Usage: @join <player>. For example, '@join frand'.");
return;
endif
target = $string_utils:match_player(dobjstr);
$command_utils:player_match_result(target, dobjstr);
if (valid(target))
if (target == this)
if (player == this)
player:tell("There is little need to join yourself, unless you are split up.");
else
player:tell("No thank you. Please get your own join verb.");
endif
return;
endif
if ((!player.programmer) && (!is_a(target, $immortal)))
player:tell("You can only join other immortal beings (builders, programmers, wizards, or plain old awesome skullcano dudes.)");
return;
endif
dest = target.location;
msg = this:join_msg();
if (typeof(msg) != LIST)
msg = {msg};
endif
editing = $object_utils:isa(dest, $generic_editor);
if (editing)
dest = dest.original[target in dest.active];
editing_msg = "%N is editing at the moment. You can wait here until %s is done.";
if (player.location == dest)
msg = {editing_msg};
else
msg = {@msg, editing_msg};
endif
endif
if (msg && ((player.location != dest) || editing))
player:tell_lines($string_utils:pronoun_sub(msg, target));
elseif (player.location == dest)
player:tell("OK, you're there. You didn't need to actually move, though.");
return;
endif
this:teleport(player, dest);
endif

@go

Spec any none noneFlags rxdOwner #29Definer #89

Referenced by

none

Source

"'@go <place>' - Teleport yourself somewhere. Example: '@go liv' to go to the living room.";
dest = this:lookup_room(dobjstr);
if (dest == $failed_match)
player:tell("There's no such place known.");
else
"if (is_a(dest, $flyer) && is_a(dest.inside_area, $real_area))";
"  dest = dest.inside_area;";
"endif";
if (is_a(dest, $area))
dest = dest:random_room();
if (!valid(dest))
player:tell("Couldn't find a room to stick you in, sorry!");
return;
endif
endif
this:_teleport(dest);
endif

revert_code_name

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

• #89:die line 27: this:revert_code_name
• #89:@mjoin line 14: this:revert_code_name
• #89:_morph line 4: this:revert_code_name
• #89:prep_to_visit line 8: this:revert_code_name

Source

r = pass(@args);
for x in ($ou:leaves($skill))
this.skills[skill.name] = {20, 0, 0, 0};
endfor
clear_property(this, "resists");
clear_property(this, "armor");
return r;

examine_verbs

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

return this.obscured ? {} | pass(@args);

take_damage

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

if (is_a(this.location, $generic_editor))
return;
endif
return pass(@args);

_allows

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

who = args[2];
return is_a(who, $immortal) ? 1 | pass(@args);

cyberdeck

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

if (!is_a(this.cyberdeck, #1834))
this.cyberdeck = #-1;
endif
return this.cyberdeck;

text_sub

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

return `this.text_sub_bypass ! ANY => 0' ? pass(@args) | args[1];

awh*o

Spec none none noneFlags rxdOwner #361Definer #89

Referenced by

none

Source

mins = {};
for p in (connected_players())
if (is_a(p, $immortal))
mins = {@mins, p};
endif
endfor
return $whofo:_who(mins, {}, -1);

pwh*o

Spec none none noneFlags rxdOwner #361Definer #89

Referenced by

none

Source

nonmins = {};
for p in (connected_players())
if (!is_a(p, $immortal))
nonmins = {@nonmins, p};
endif
endfor
return $whofo:_who(nonmins, {}, 1);

who

Spec none none noneFlags rxdOwner #361Definer #89

Referenced by

none

Source

if (player != this)
raise(E_PERM);
endif
if (this.chillmin)
return this:awho(@args);
else
return $whofo:who(@args);
endif

tree_tag

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

none

Source

if (this.f)
return "";
endif
if (this.owner != this)
return "owned by " + this.owner.name;
endif
objs = $su:right(`tostr(length(this.owned_objects)) ! E_TYPE => "lots"', 5);
flags = this.programmer ? "p" | "";
flags = flags + (this.wizard ? "w" | "");
flags = flags + (this.chillmin ? "c" | "");
return tostr(objs, " ", flags);

@rotate

Spec none at/to anyFlags rxdOwner #29Definer #89

Referenced by

none

Source

"Copied from Treeclipse (#309):@rotate Mon Nov 29 22:15:54 2010 CST";
if (caller != this)
player:tell("I DON'T THINK SO!  Change your own names. sheesh.");
return E_PERM;
endif
if (!(iobjstr in this.aliases))
player:tell("You can't change to that! It isn't one of your aliases!");
else
this:set_name(iobjstr);
this:set_aliases(setadd(this.aliases, iobjstr));
player:tell("Aliases Rotated.  Your name is now: ", this.name, ".");
endif

moveto

Spec this none thisFlags rxdOwner #361Definer #89

Referenced by

• #2:home line 29: this:moveto
• #49:moveto line 3: pass(
• #89:die line 29: this:moveto
• #89:_teleport line 9: this:moveto
• #89:_teleport line 37: this:moveto

Source

where = args[1];
oldloc = this.location;
r = pass(@args);
if (!(oldloc in {this.location, where}))
for x in (callers(1))
if (x[4] == $actions.move)
return r;
endif
endfor
is_a(oldloc, $room) && oldloc:broadcast_event(0, $actions.move, this, {#-1});
is_a(l = this.location, $room) && l:broadcast_event(0, $actions.arrive, this, {#-1});
endif
return r;