Login Commands #4

?

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

if ((caller != #0) && (caller != this))
return E_PERM;
else
clist = {};
for j in ({this, @$object_utils:ancestors(this)})
for i in [1..length(verbs(j))]
if ((verb_args(j, i) == {"any", "none", "any"}) && index((info = verb_info(j, i))[2], "x"))
vname = $string_utils:explode(info[3])[1];
if (!(vname in this.hidden_verbs))
star = index(vname + "*", "*");
clist = {@clist, $string_utils:uppercase(vname[1..star - 1]) + strsub(vname[star..$], "*", "")};
endif
endif
endfor
endfor
notify(player, "I don't understand that.  Valid commands at this point are");
notify(player, "   " + $string_utils:english_list(setremove(clist, "?"), "", " or "));
return 0;
endif

wel*come @wel*come

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

if ((caller != #0) && (caller != this))
return E_PERM;
else
msg = this.welcome_message;
version = server_version();
for line in ((typeof(msg) == LIST) ? msg | {msg})
if (typeof(line) == STR)
notify(player, strsub(line, "%v", version));
endif
endfor
quote = this.quotes[random(length(this.quotes))];
this:display_quote(@quote);
uptime = "???";
acount = icount = pcount = 0;
uptime = $time_utils:dhms(time() - $last_restart_time);
for x in (connected_players())
if (is_a(x, $prog))
acount = acount + 1;
elseif (is_a(x, $immortal))
icount = icount + 1;
else
pcount = pcount + 1;
endif
endfor
notify(player, "");
notify(player, "To request a character:");
notify(player, ($ansi.bold_on + "  request <player_name> for <email_address>") + $ansi.reset);
notify(player, "To connect with an existing player: ");
notify(player, ($ansi.bold_on + "  connect <player> <password>") + $ansi.reset);
notify(player, "If you forgot your password: ");
notify(player, tostr(($ansi.bold_on + "  password <player> for <email_address>") + $ansi.reset));
notify(player, "");
if (icount)
notify(player, tostr("(server v", version, " up ", uptime, ", ", pcount, " players, ", icount, " chillmins and ", acount, " admins connected)"));
else
notify(player, tostr("(server v", version, " up ", uptime, ", ", pcount, " players and ", acount, " admins connected)"));
endif
notify(player, tostr("core version: ", this.core_version));
"notify(player, tostr(\"(server v\", version, \" up \", uptime, \", \", pcount + acount, \" connected)\"));";
this:check_player_db();
this:check_for_shutdown();
this:check_for_checkpoint();
this:maybe_print_lag();
return 0;
endif

w*ho @w*ho

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

none

Source

masked = $login.who_masks_wizards ? $wiz_utils:connected_wizards() | {};
if ((caller != #0) && (caller != this))
return E_PERM;
elseif (!args)
plyrs = connected_players();
if (length(plyrs) > 100)
this:notify(tostr("You have requested a listing of ", length(plyrs), " players.  Please restrict the number of players in any single request to a smaller number.  The lag thanks you."));
return 0;
else
$code_utils:show_who_listing($set_utils:difference(plyrs, masked)) || this:notify("No one logged in.");
endif
else
plyrs = listdelete($command_utils:player_match_result($string_utils:match_player(args), args), 1);
if (length(plyrs) > 100)
this:notify(tostr("You have requested a listing of ", length(plyrs), " players.  Please restrict the number of players in any single request to a smaller number.  The lag thanks you."));
return 0;
endif
$code_utils:show_who_listing(plyrs, $set_utils:intersection(plyrs, masked));
endif
return 0;

co*nnect @co*nnect

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

"$login:connect(player-name [, password])";
" => 0 (for failed connections)";
" => objnum (for successful connections)";
((caller == #0) || (caller == this)) || raise(E_PERM);
"=================================================================";
"=== Check arguments, print usage notice if necessary";
try
{name, ?password = 0} = args;
name = strsub(name, " ", "_");
except (E_ARGS)
notify(player, tostr("Usage:  ", verb, " <existing-player-name> <password>"));
return 0;
endtry
try
"=================================================================";
"=== Is our candidate name invalid?";
if (!valid(candidate = orig_candidate = this:_match_player(name)))
raise(E_INVARG, tostr("`", name, "' matches no player name."));
endif
"=================================================================";
"=== Is our candidate unable to connect for generic security";
"=== reasons (ie clear password, non-player object)?";
if (`is_clear_property(candidate, "password") ! E_PROPNF' || (!$object_utils:isa(candidate, $player)))
server_log(tostr("FAILED CONNECT: ", name, " (", candidate, ") on ", connection_name(player), ($string_utils:connection_hostname(connection_name(player)) in candidate.all_connect_places) ? "" | "******"));
raise(E_INVARG);
endif
"=================================================================";
"=== Check password";
if (typeof(cp = candidate.password) == STR)
"=== Candidate requires a password";
if (password)
"=== Candidate requires a password, and one was provided";
if (strcmp(crypt(password, cp), cp))
"=== Candidate requires a password, and one was provided, which was wrong";
server_log(tostr("FAILED CONNECT: ", name, " (", candidate, ") on ", connection_name(player), ($string_utils:connection_hostname(connection_name(player)) in candidate.all_connect_places) ? "" | "******"));
raise(E_INVARG, "Invalid password.");
else
"=== Candidate requires a password, and one was provided, which was right";
endif
else
"=== Candidate requires a password, and none was provided";
set_connection_option(player, "binary", 1);
notify(player, "Password: ");
set_connection_option(player, "binary", 0);
set_connection_option(player, "client-echo", 0);
this:add_interception(player, "intercepted_password", candidate);
return 0;
endif
elseif (cp == 0)
"=== Candidate does not require a password";
else
"=== Candidate has a nonstandard password; something's wrong";
raise(E_INVARG);
endif
"=================================================================";
"=== Is the player locked out?";
if ($no_connect_message && (!candidate.programmer))
notify(player, $no_connect_message);
server_log(tostr("REJECTED CONNECT: ", name, " (", candidate, ") on ", connection_name(player)));
return 0;
endif
"=================================================================";
"We're keeping non-admin alts off.";
"if (((!this:is_admin_alt(candidate.email_address)) && (!(candidate in this.allowed_players))) && (candidate.donation < 1))";
"  notify(player, \"Sorry, only players who have been invited or who have donated may connect. For a similar game that is open to all, please go to aftertheend.org 7777.\");";
"  return 0;";
"endif";
"=================================================================";
"=== Check guest connections";
if ($object_utils:isa(candidate, $guest) && (!valid(candidate = candidate:defer())))
if (candidate == #-2)
server_log(tostr("GUEST DENIED: ", connection_name(player)));
notify(player, "Sorry, guest characters are not allowed from your site at the current time.");
else
notify(player, "Sorry, all of our guest characters are in use right now.");
endif
return 0;
endif
"=================================================================";
"=== Check newts";
if (candidate in this.newted)
if (entry = $list_utils:assoc(candidate, this.temporary_newts))
if ((uptime = this:uptime_since(entry[2])) > entry[3])
"Temporary newting period is over.  Remove entry.  Oh, send mail, too.";
this.temporary_newts = setremove(this.temporary_newts, entry);
this.newted = setremove(this.newted, candidate);
fork (0)
player = this.owner;
$mail_agent:send_message(player, $newt_log, tostr("automatic @unnewt ", candidate.name, " (", candidate, ")"), {"message sent from $login:connect"});
endfork
else
notify(player, "");
notify(player, this:temp_newt_registration_string(entry[3] - uptime));
boot_player(player);
return 0;
endif
else
notify(player, "");
notify(player, this:newt_registration_string());
boot_player(player);
return 0;
endif
endif
"=================================================================";
"=== Connection limits based on lag";
if ((((!candidate.wizard) && (!(candidate in this.lag_exemptions))) && ((howmany = length(connected_players())) >= (max = this:max_connections()))) && (!$object_utils:connected(candidate)))
notify(player, $string_utils:subst(this.connection_limit_msg, {{"%n", tostr(howmany)}, {"%m", tostr(max)}, {"%l", tostr(this:current_lag())}, {"%t", candidate.last_connect_attempt ? ctime(candidate.last_connect_attempt) | "not recorded"}}));
if ($object_utils:has_property($local, "mudlist"))
notify(player, "You may wish to try another MUD while waiting for the MOO to unlag.  Here are a few that we know of:");
for l in ($local.mudlist:choose(3))
notify(player, l);
endfor
endif
candidate.last_connect_attempt = time();
server_log(tostr("CONNECTION LIMIT EXCEEDED: ", name, " (", candidate, ") on ", connection_name(player)));
boot_player(player);
return 0;
endif
"=================================================================";
"=== Log the player on!";
if (candidate != orig_candidate)
notify(player, tostr("Okay,... ", name, " is in use.  Logging you in as `", candidate.name, "'"));
endif
this:record_connection(candidate);
return candidate;
except (E_INVARG)
notify(player, "Either that player does not exist, or has a different password.");
notify(player, tostr("Forgot your password? Email us at ", $login.registration_address, " and we can send you a new one."));
return 0;
endtry

cr*eate @cr*eate

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

if ((caller != #0) && (caller != this))
return E_PERM;
"... caller isn't :do_login_command()...";
elseif (!this:player_creation_enabled(player))
notify(player, this:registration_string());
"... we've disabled player creation ...";
elseif (length(args) != 2)
notify(player, tostr("Usage:  ", verb, " <new-player-name> <new-password>"));
elseif ($player_db.frozen)
notify(player, "Sorry, can't create any new players right now.  Try again in a few minutes.");
elseif ((!(name = args[1])) || (name == "<>"))
notify(player, "You can't have a blank name!");
if (name)
notify(player, "Also, don't use angle brackets (<>).");
endif
elseif ((name[1] == "<") && (name[$] == ">"))
notify(player, "Try that again but without the angle brackets, e.g.,");
notify(player, tostr(" ", verb, " ", name[2..$ - 1], " ", strsub(strsub(args[2], "<", ""), ">", "")));
notify(player, "This goes for other commands as well.");
elseif (!this:name_ok(name))
notify(player, "Sorry, that name won't work. Use a-z, 0-9, and underscores, and keep it under 20 characters.");
elseif ((!$player_db:available(name)) || (this:_match_player(name) != $failed_match))
notify(player, "Sorry, that name is not available.  Please choose another.");
"... note the :_match_player call is not strictly necessary...";
"... it is merely there to handle the case that $player_db gets corrupted.";
elseif (!(password = args[2]))
notify(player, "You must set a password for your player.");
else
new = $quota_utils:bi_create($player_class, $nothing);
if (tonum(new) == 999999)
`$wiz_utils:grab_next_objnum() ! ANY';
endif
set_player_flag(new, 1);
new.name = name;
new.aliases = {name};
new.r = 1;
new.programmer = $player_class.programmer;
new.password = crypt(password);
new.last_password_time = time();
new.last_connect_time = $maxint;
"Last disconnect time is creation time, until they login.";
new.last_disconnect_time = time();
"make sure the owership quota isn't clear!";
$quota_utils:initialize_quota(new);
this:record_connection(new);
$player_db:insert(name, new);
`move(new, $player_start) ! ANY';
return new;
endif
return 0;

q*uit @q*uit

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

if ((caller != #0) && (caller != this))
return E_PERM;
else
boot_player(player);
return 0;
endif

up*time @up*time

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

if ((caller != #0) && (caller != this))
return E_PERM;
else
notify(player, tostr("The server has been up for ", $time_utils:english_time(time() - $last_restart_time), "."));
return 0;
endif

v*ersion @v*ersion

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

if ((caller != #0) && (caller != this))
return E_PERM;
else
notify(player, tostr("The MOO is currently running version ", server_version(), " of the LambdaMOO server code."));
return 0;
endif

parse_command

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #0:do_login_command line 30: $login:parse_command

Source

":parse_command(@args) => {verb, args}";
"Given the args from #0:do_login_command,";
"  returns the actual $login verb to call and the args to use.";
"Commands available to not-logged-in users should be located on this object and given the verb_args \"any none any\"";
if ((caller != #0) && (caller != this))
return E_PERM;
endif
if (li = this:interception(player))
return {@li, @args};
endif
if (!args)
return {this.blank_command, @args};
elseif ((verb = args[1]) && (!$string_utils:is_numeric(verb)))
for i in ({this, @$object_utils:ancestors(this)})
try
if ((verb_args(i, verb) == {"any", "none", "any"}) && index(verb_info(i, verb)[2], "x"))
return args;
endif
except (ANY)
continue i;
endtry
endfor
endif
return {this.bogus_command, @args};

check_for_shutdown

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:wel*come line 41: this:check_for_shutdown

Source

when = $shutdown_time - time();
if (when >= 0)
line = "***************************************************************************";
notify(player, "");
notify(player, "");
notify(player, line);
notify(player, line);
notify(player, "****");
notify(player, ("****  WARNING:  The server will shut down in " + $time_utils:english_time(when - (when % 60))) + ".");
for piece in ($generic_editor:fill_string($shutdown_message, 60))
notify(player, "****            " + piece);
endfor
notify(player, "****");
notify(player, line);
notify(player, line);
notify(player, "");
notify(player, "");
endif

check_player_db

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:wel*come line 40: this:check_player_db

Source

if ($player_db.frozen)
line = "***************************************************************************";
notify(player, "");
notify(player, line);
notify(player, "***");
for piece in ($generic_editor:fill_string("The character-name matcher is currently being reloaded.  This means your character name might not be recognized even though it still exists.  Don't panic.  You can either wait for the reload to finish or you can connect using your object number if you remember it (e.g., `connect #1234 yourpassword').", 65))
notify(player, "***       " + piece);
endfor
notify(player, "***");
for piece in ($generic_editor:fill_string("Repeat:  Do not panic.  In particular, please do not send mail to any wizards or the registrar asking about this.  It will finish in time.  Thank you for your patience.", 65))
notify(player, "***       " + piece);
endfor
if (this:player_creation_enabled(player))
notify(player, "***       This also means that character creation is disabled.");
endif
notify(player, "***");
notify(player, line);
notify(player, "");
endif

_match_player

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:co*nnect line 17: this:_match_player
• #4:cr*eate line 22: this:_match_player
• #4:request_password line 7: $login:_match_player
• #4:reset_password line 7: $login:_match_player
• #17:check_player_request line 27: $login:_match_player

Source

":_match_player(name)";
"This is the matching routine used by @connect.";
"returns either a valid player corresponding to name or $failed_match.";
name = args[1];
if (valid(candidate = $string_utils:literal_object(name)) && is_player(candidate))
return candidate;
endif
".....uncomment this to trust $player_db and have `connect' recognize aliases";
if (valid(candidate = $player_db:find_exact(name)) && is_player(candidate))
return candidate;
endif
".....uncomment this if $player_db gets hosed and you want by-name login";
". for candidate in (players())";
".   if (candidate.name == name)";
".     return candidate; ";
".   endif ";
". endfor ";
".....";
return $failed_match;

notify

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:w*ho line 7: this:notify
• #4:w*ho line 10: this:notify
• #4:w*ho line 15: this:notify
• #4:who(vanilla) line 4: this:notify
• #4:MSSP-REQUEST line 1: this:notify
• #4:MSSP-REQUEST line 8: this:notify
• #4:MSSP-REQUEST line 15: this:notify
• #4:MSSP-REQUEST line 23: this:notify
• #4:MSSP-REQUEST line 30: this:notify

Source

set_task_perms(caller_perms());
`notify(player, args[1]) ! ANY';

tell

Spec this none thisFlags rxdOwner #29Definer #4

Referenced by

none

Source

"keeps bad things from happening if someone brings this object into a room and talks to it.";
return 0;

player_creation_enabled

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:cr*eate line 4: this:player_creation_enabled
• #4:check_player_db line 13: this:player_creation_enabled
• #25:boot line 5: $login:player_creation_enabled
• #25:create line 1: $login:player_creation_enabled

Source

"Accepts a player object.  If player creation is enabled for that player object, then return true.  Otherwise, return false.";
"Default implementation checks the player's connecting host via $login:blacklisted to decide.";
if (caller_perms().wizard)
return this.create_enabled && (!this:blacklisted($string_utils:connection_hostname(connection_name(args[1]))));
else
return E_PERM;
endif

newt_registration_string registration_string password_request_string

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:co*nnect line 99: this:newt_registration_string
• #4:cr*eate line 5: this:registration_string
• #4:req*uest line 6: this:registration_string
• #17:newt_player line 21: $login:newt_registration_string
• #25:create line 4: $login:registration_string

Source

return $string_utils:subst(this.(verb), {{"%e", this.registration_address}, {"%%", "%"}});

init_for_core

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

none

Source

if (caller_perms().wizard)
pass();
this.lag_exemptions = {};
this.max_connections = 99999;
this.lag_samples = {0, 0, 0, 0, 0};
this.print_lag = 0;
this.last_lag_sample = 0;
this.bogus_command = "?";
this.blank_command = "welcome";
this.create_enabled = 1;
this.registration_address = "";
this.registration_string = "Character creation is disabled.";
this.newt_registration_string = "Your character is temporarily hosed.";
this.welcome_message = {"Welcome to the LambdaCore database.", "", "Type 'connect wizard' to log in.", "", "You will probably want to change this text and the output of the `help' command, which are stored in $login.welcome_message and $login.help_message, respectively."};
this.help_message = {"Sorry, but there's no help here yet.  Type `?' for a list of commands."};
this.redlist = this.blacklist = this.graylist = this.spooflist = {{}, {}};
this.temporary_redlist = this.temporary_blacklist = this.temporary_graylist = this.temporary_spooflist = {{}, {}};
this.who_masks_wizards = 0;
this.newted = this.temporary_newts = {};
this.downtimes = {};
if ("monitor" in properties(this))
delete_property(this, "monitor");
endif
if ("monitor" in verbs(this))
delete_verb(this, "monitor");
endif
if ("record_connection(real)" in verbs(this))
delete_verb(this, "record_connection");
info = verb_info(this, "record_connection(real)");
set_verb_info(this, "record_connection(real)", {info[1], "rxd", "record_connection"});
endif
if ("special_action" in verbs(this))
set_verb_code(this, "special_action", {});
endif
endif

special_action

Spec this none thisFlags xOwner #361Definer #4

Referenced by

none

Source

blacklisted graylisted redlisted spooflisted

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #0:do_login_command line 24: $login:redlisted
• #4:player_creation_enabled line 4: this:blacklisted
• #17:show_netwho_listing line 36: $login:blacklisted
• #17:show_netwho_listing line 39: $login:graylisted
• #17:check_player_request line 52: $login:spooflisted
• #25:defer line 5: $login:blacklisted
• #49:@guests line 31: $login:blacklisted
• #49:@guests line 34: $login:graylisted

Source

":blacklisted(hostname) => is hostname on the .blacklist";
":graylisted(hostname)  => is hostname on the .graylist";
":redlisted(hostname)   => is hostname on the .redlist";
sitelist = this.(this:listname(verb));
hostname = args[1];
if (!caller_perms().wizard)
return E_PERM;
elseif ((hostname in sitelist[1]) || (hostname in sitelist[2]))
return 1;
elseif ($network:is_numeric_ip(hostname))
for lit in (sitelist[1])
if ((index(hostname, lit) == 1) && ((hostname + ".")[length(lit) + 1] == "."))
return 1;
endif
endfor
else
for dom in (sitelist[2])
if (index(dom, "*"))
"...we have a wildcard; let :match_string deal with it...";
if ($string_utils:match_string(hostname, dom))
return 1;
endif
else
"...tail of hostname ...";
if ((r = rindex(hostname, dom)) && ((("." + hostname)[r] == ".") && (((r - 1) + length(dom)) == length(hostname))))
return 1;
endif
endif
endfor
endif
return this:(verb + "_temp")(hostname);

blacklist_add*_temp graylist_add*_temp redlist_add*_temp spooflist_add*_temp

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

none

Source

"To add a temporary entry, only call the `temp' version.";
"blacklist_add_temp(Site, start time, duration)";
if (!caller_perms().wizard)
return E_PERM;
endif
{where, ?start, ?duration} = args;
lname = this:listname(verb);
which = 1 + (!$network:is_numeric_ip(where));
if (index(verb, "temp"))
lname = "temporary_" + lname;
this.(lname)[which] = setadd(this.(lname)[which], {where, start, duration});
else
this.(lname)[which] = setadd(this.(lname)[which], where);
endif
return 1;

blacklist_remove*_temp graylist_remove*_temp redlist_remove*_temp spooflist_remove*_temp

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

none

Source

"The temp version removes from the temporary property if it exists.";
if (!caller_perms().wizard)
return E_PERM;
endif
where = args[1];
lname = this:listname(verb);
which = 1 + (!$network:is_numeric_ip(where));
if (index(verb, "temp"))
lname = "temporary_" + lname;
if (entry = $list_utils:assoc(where, this.(lname)[which]))
this.(lname)[which] = setremove(this.(lname)[which], entry);
return 1;
else
return E_INVARG;
endif
elseif (where in this.(lname)[which])
this.(lname)[which] = setremove(this.(lname)[which], where);
return 1;
else
return E_INVARG;
endif

listname

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:blacklisted line 4: this:listname
• #4:blacklist_add*_temp line 7: this:listname
• #4:blacklist_remove*_temp line 6: this:listname
• #4:blacklisted_temp line 7: this:listname
• #49:@toad line 8: $login:listname
• #49:@blacklist line 12: $login:listname

Source

return {"???", "blacklist", "graylist", "redlist", "spooflist"}[1 + index("bgrs", (args[1] || "?")[1])];

who(vanilla)

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

none

Source

if (caller != #0)
return E_PERM;
elseif (!args)
$code_utils:show_who_listing(connected_players()) || this:notify("No one logged in.");
else
plyrs = listdelete($command_utils:player_match_result($string_utils:match_player(args), args), 1);
$code_utils:show_who_listing(plyrs);
endif
return 0;

record_connection

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:co*nnect line 124: this:record_connection
• #4:cr*eate line 45: this:record_connection

Source

":record_connection(plyr) update plyr's connection information";
"to reflect impending login.";
if (!caller_perms().wizard)
return E_PERM;
else
plyr = args[1];
plyr.first_connect_time = min(time(), plyr.first_connect_time);
plyr.previous_connection = {plyr.last_connect_time, $string_utils:connection_hostname(plyr.last_connect_place)};
plyr.last_connect_time = time();
plyr.last_connect_place = cn = connection_name(player);
chost = $string_utils:connection_hostname(cn);
acp = setremove(plyr.all_connect_places, chost);
plyr.all_connect_places = {chost, @acp[1..min($, 15)]};
endif

sample_lag

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:sample_lag line 22: this:sample_lag

Source

if (!caller_perms().wizard)
return E_PERM;
endif
lag = (time() - this.last_lag_sample) - 15;
this.lag_samples = {lag, @this.lag_samples[1..3]};
"Now compute the current lag and store it in a property, instead of computing it in :current_lag, which is called a hundred times a second.";
thislag = max(0, (time() - this.last_lag_sample) - this.lag_sample_interval);
if (thislag > (60 * 60))
"more than an hour, probably the lag sampler stopped";
this.current_lag = 0;
else
samples = this.lag_samples;
sum = 0;
cnt = 0;
for x in (listdelete(samples, 1))
sum = sum + x;
cnt = cnt + 1;
endfor
this.current_lag = max(thislag, samples[1], samples[2], sum / cnt);
endif
fork (15)
this:sample_lag();
endfork
this.last_lag_sample = time();

is_lagging

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:max_connections line 3: this:is_lagging
• #51:show_who_listing line 103: $login:is_lagging
• #90:who_html line 112: $login:is_lagging

Source

return this:current_lag() > this.lag_cutoff;

max_connections

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:co*nnect line 106: this:max_connections
• #17:boot_idlers line 20: $login:max_connections
• #17:boot_idlers line 42: $login:max_connections

Source

max = this.max_connections;
if (typeof(max) == LIST)
if (this:is_lagging())
max = max[1];
else
max = max[2];
endif
endif
return max;

request_character

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:req*uest line 12: $login:request_character
• #25:@request line 13: $login:request_character

Source

"request_character(player, name, address)";
"return true if succeeded";
if (!caller_perms().wizard)
return E_PERM;
endif
{who, name, address} = args;
connection = $string_utils:connection_hostname(connection_name(who));
if (reason = $wiz_utils:check_player_request(name, address, connection))
prefix = "";
if (reason[1] == "-")
reason = reason[2..$];
prefix = "Please";
else
prefix = "Please try again, or, to register another way,";
endif
notify(who, reason);
msg = tostr(prefix, " send mail to ", $login.registration_address, ", with the character name you want.");
for l in ($generic_editor:fill_string(msg, 70))
notify(who, l);
endfor
return 0;
endif
if (lines = $no_one:eval_d("$local.help.(\"multiple-characters\")")[2])
notify(who, "Remember, in general, only one character per person is allowed.");
notify(who, tostr("Do you already have a ", $network.moo_name, " character? [enter `yes' or `no']"));
answer = read(who);
if (answer == "yes")
notify(who, "Process terminated *without* creating a character.");
return 0;
elseif (answer != "no")
return notify(who, tostr("Please try again; when you get this question, answer `yes' or `no'. You answered `", answer, "'"));
endif
notify(who, "For future reference, do you want to see the full policy (from `help multiple-characters'?");
notify(who, "[enter `yes' or `no']");
if (read(who) == "yes")
for x in (lines)
for y in ($generic_editor:fill_string(x, 70))
notify(who, y);
endfor
endfor
endif
endif
notify(who, tostr("A character named `", name, "' will be created."));
notify(who, tostr("A random password will be generated, and e-mailed along with"));
notify(who, tostr(" an explanatory message to: ", address));
notify(who, tostr(" [Please double-check your email address and answer `no' if it is incorrect.]"));
notify(who, "Is this OK? [enter `yes' or `no']");
try
response = read(who);
except e (E_INVARG)
return 0;
endtry
if ((response != "yes") && (response != "y"))
notify(who, "Process terminated *without* creating a character.");
return 0;
endif
if (!$network.active)
$mail_agent:send_message(this.owner, $registration_db.registrar, "Player request", {"Player request from " + connection, ":", "", (("@make-player " + name) + " ") + address});
notify(who, tostr("Request for new character ", name, " email address '", address, "' accepted."));
notify(who, tostr("Please be patient until the registrar gets around to it."));
notify(who, tostr("If you don't get email within a week, please send regular"));
notify(who, tostr("  email to: ", $login.registration_address, "."));
elseif ($player_db.frozen)
notify(who, "Sorry, can't create any new players right now.  Try again in a few minutes.");
else
new = $wiz_utils:make_player(name, address);
password = new[2];
new = new[1];
notify(who, tostr("Character ", name, " (", new, ") created."));
notify(who, tostr("Mailing password to ", address, "; you should get the mail within a few minutes."));
notify(who, tostr("If you do not get it, please do NOT request another character."));
notify(who, tostr("Instead, send regular email to ", $login.registration_address, ","));
notify(who, tostr("with the name of the character you requested."));
$mail_agent:send_message(this.owner, $new_player_log, tostr(name, " (", new, ")"), {address, tostr(" Automatically created at request of ", valid(player) ? player.name | "unconnected player", " from ", connection, ".")});
$wiz_utils:send_new_player_mail(tostr("Someone connected from ", connection, " at ", ctime(), " requested a character on ", $network.moo_name, " for email address ", address, "."), name, address, new, password);
return 1;
endif

req*uest @req*uest

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

if ((caller != #0) && (caller != this))
return E_PERM;
endif
"must be #0:do_login_command";
if (!this.request_enabled)
for line in ($generic_editor:fill_string(this:registration_string(), 70))
notify(player, line);
endfor
elseif ((length(args) != 3) || (args[2] != "for"))
notify(player, tostr("Usage:  ", verb, " <new-player-name> for <email-address>"));
notify(player, "Your new player name must be one word. Do not include the angle brackets: <>.");
elseif ($login:request_character(player, args[1], args[3]))
"Set argstr below so that people can't harvest email addresses.";
argstr = "";
$furnace:new_player();
boot_player(player);
endif

h*elp @h*elp

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

if ((caller != #0) && (caller != this))
return E_PERM;
else
msg = this.help_message;
for line in ((typeof(msg) == LIST) ? msg | {msg})
if (typeof(line) == STR)
notify(player, line);
endif
endfor
return 0;
endif

maybe_print_lag

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:wel*come line 43: this:maybe_print_lag

Source

if ((caller == this) || (caller_perms() == player))
if (this.print_lag)
lag = this:current_lag();
if (lag > 1)
lagstr = tostr("approximately ", lag, " seconds");
elseif (lag == 1)
lagstr = "approximately 1 second";
else
lagstr = "low";
endif
notify(player, tostr("The lag is ", lagstr, "; there ", ((l = length(connected_players())) == 1) ? "is " | "are ", l, " connected."));
endif
endif

current_lag

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:co*nnect line 107: this:current_lag
• #4:is_lagging line 1: this:current_lag
• #4:maybe_print_lag line 3: this:current_lag
• #48:kill_if_laggy line 3: $login:current_lag
• #65:time line 3: $login:current_lag

Source

return this.current_lag;

maybe_limit_commands

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #0:do_login_command line 29: $login:maybe_limit_commands

Source

"This limits the number of commands that can be issued from the login prompt to prevent haywire login programs from lagging the MOO.";
"$login.current_connections has the current player id's of people at the login prompt.";
"$login.current_numcommands has the number of commands they have issued at the prompt so far.";
"$login.max_numcommands has the maximum number of commands they may try before being booted.";
if (!caller_perms().wizard)
return E_PERM;
else
if (iconn = player in this.current_connections)
knocks = this.current_numcommands[iconn] = this.current_numcommands[iconn] + 1;
else
this.current_connections = {@this.current_connections, player};
this.current_numcommands = {@this.current_numcommands, 1};
knocks = 1;
"...sweep idle connections...";
for p in (this.current_connections)
if (typeof(`idle_seconds(p) ! ANY') == ERR)
n = p in this.current_connections;
this.current_connections = listdelete(this.current_connections, n);
this.current_numcommands = listdelete(this.current_numcommands, n);
endif
endfor
endif
if (knocks > this.max_numcommands)
notify(player, "Sorry, too many commands issued without connecting.");
boot_player(player);
return 1;
else
return 0;
endif
endif

server_started

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #0:server_started line 4: $login:server_started

Source

"Called by #0:server_started when the server restarts.";
if (caller_perms().wizard)
this.lag_samples = {0, 0, 0, 0, 0};
this.downtimes = {{time(), this.last_lag_sample}, @this.downtimes[1..min($, 100)]};
this.intercepted_players = this.intercepted_actions = {};
endif

uptime_since

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:co*nnect line 83: this:uptime_since
• #4:templist_expired line 7: this:uptime_since
• #17:check_prog_restricted line 8: $login:uptime_since

Source

"uptime_since(time): How much time has LambdaMOO been up since `time'";
since = args[1];
up = time() - since;
for x in (this.downtimes)
if (x[1] < since)
"downtime predates when we're asking about";
return up;
endif
"since the server was down between x[2] and x[1], don't count it as uptime";
up = up - (x[1] - max(x[2], since));
endfor
return up;

count_bg_players

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

none

Source

caller_perms().wizard || $error:raise(E_PERM);
now = time();
tasks = queued_tasks();
sum = 0;
for t in (tasks)
delay = t[2] - now;
interval = (delay <= 0) ? 1 | (delay * 2);
"SUM is measured in hundredths of a player for the moment...";
(delay <= 300) && (sum = sum + (2000 / interval));
endfor
count = sum / 100;
return count;

blacklisted_temp graylisted_temp redlisted_temp spooflisted_temp

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

none

Source

":blacklisted_temp(hostname) => is hostname on the .blacklist...";
":graylisted_temp(hostname)  => is hostname on the .graylist...";
":redlisted_temp(hostname)   => is hostname on the .redlist...";
":spooflisted_temp(hostname) => is hostname on the .spooflist...";
"";
"... and the time limit hasn't run out.";
lname = this:listname(verb);
sitelist = this.("temporary_" + lname);
if (!caller_perms().wizard)
return E_PERM;
elseif (entry = $list_utils:assoc(hostname = args[1], sitelist[1]))
return this:templist_expired(lname, @entry);
elseif (entry = $list_utils:assoc(hostname, sitelist[2]))
return this:templist_expired(lname, @entry);
elseif ($network:is_numeric_ip(hostname))
for lit in (sitelist[1])
if ((index(hostname, lit[1]) == 1) && ((hostname + ".")[length(lit[1]) + 1] == "."))
return this:templist_expired(lname, @lit);
endif
endfor
else
for dom in (sitelist[2])
if (index(dom[1], "*"))
"...we have a wildcard; let :match_string deal with it...";
if ($string_utils:match_string(hostname, dom[1]))
return this:templist_expired(lname, @dom);
endif
else
"...tail of hostname ...";
if ((r = rindex(hostname, dom[1])) && ((("." + hostname)[r] == ".") && (((r - 1) + length(dom[1])) == length(hostname))))
return this:templist_expired(lname, @dom);
endif
endif
endfor
endif
return 0;

templist_expired

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:blacklisted_temp line 12: this:templist_expired
• #4:blacklisted_temp line 14: this:templist_expired
• #4:blacklisted_temp line 18: this:templist_expired
• #4:blacklisted_temp line 26: this:templist_expired
• #4:blacklisted_temp line 31: this:templist_expired

Source

"check to see if duration has expired on temporary_<colorlist>. Removes entry if so, returns true if still <colorlisted>";
":(listname, hostname, start time, duration)";
{lname, hname, start, duration} = args;
if (!caller_perms().wizard)
return E_PERM;
endif
if (this:uptime_since(start) > duration)
this:(lname + "_remove_temp")(hname);
return 0;
else
return 1;
endif

temp_newt_registration_string

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:co*nnect line 93: this:temp_newt_registration_string

Source

return ("Your character is unavailable for another " + $time_utils:english_time(args[1])) + ".";

add_interception

Spec this none thisFlags rxdOwner #29Definer #4

Referenced by

• #4:co*nnect line 46: this:add_interception

Source

(caller == this) || raise(E_PERM);
{who, verbname, @arguments} = args;
(who in this.intercepted_players) && raise(E_INVARG, "Player already has an interception set.");
this.intercepted_players = {@this.intercepted_players, who};
this.intercepted_actions = {@this.intercepted_actions, {verbname, @arguments}};
return 1;

delete_interception

Spec this none thisFlags rxdOwner #29Definer #4

Referenced by

• #4:intercepted_password line 2: this:delete_interception

Source

(caller == this) || raise(E_PERM);
{who} = args;
if (loc = who in this.intercepted_players)
this.intercepted_players = listdelete(this.intercepted_players, loc);
this.intercepted_actions = listdelete(this.intercepted_actions, loc);
return 1;
else
"raise an error?  nah.";
return 0;
endif

interception

Spec this none thisFlags rxdOwner #29Definer #4

Referenced by

• #4:parse_command line 8: this:interception

Source

(caller == this) || raise(E_PERM);
{who} = args;
return (loc = who in this.intercepted_players) ? this.intercepted_actions[loc] | 0;

intercepted_password

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

none

Source

(caller == #0) || raise(E_PERM);
this:delete_interception(player);
set_connection_option(player, "client-echo", 1);
notify(player, "");
try
{candidate, ?password = ""} = args;
except (E_ARGS)
return 0;
endtry
return this:connect(tostr(candidate), password);

do_out_of_band_command doobc

Spec this none thisFlags rxdOwner #29Definer #4

Referenced by

none

Source

"This is where oob handlers need to be put to handle oob commands issued prior to assigning a connection to a player object.  Right now it simply returns.";
return;

check_for_checkpoint

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:wel*come line 42: this:check_for_checkpoint

Source

if (this.checkpoint_in_progress)
line = "***************************************************************************";
notify(player, "");
notify(player, "");
notify(player, line);
notify(player, line);
notify(player, "****");
notify(player, "****  NOTICE:  The server is very slow now.");
notify(player, "****           The database is being saved to disk.");
notify(player, "****");
notify(player, line);
notify(player, line);
notify(player, "");
notify(player, "");
endif

display_quote

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:wel*come line 12: this:display_quote

Source

lines = args[1];
source = args[2];
tab = "  ";
for x in (lines)
if (length(lines) == 1)
notify(player, ((tab[1..$ - 1] + "\"") + x) + "\"");
elseif (x == lines[1])
notify(player, (tab[1..$ - 1] + "\"") + x);
elseif (x == lines[$])
notify(player, (tab + x) + "\"");
else
notify(player, tab + x);
endif
tab = tab + " ";
endfor
notify(player, "");
notify(player, (tab + "      -- ") + source);

name_ok

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:cr*eate line 20: this:name_ok
• #17:check_player_request line 21: $login:name_ok

Source

name = args[1];
if (match(name, "[^a-zA-Z0-9_%-%.]") || (length(name) > 20))
return 0;
endif
return 1;

MSSP-REQUEST

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

this:notify("MSSP-REPLY-START");
vars = [];
vars["NAME"] = $network.MOO_name;
vars["PLAYERS"] = length(connected_players());
vars["UPTIME"] = $last_restart_time;
for kv in (vars)
{k, v} = kv;
this:notify((k + $ansi.tab) + tostr(v));
endfor
for kv in (this.extra_mssp_vars)
{k, v} = kv;
if (typeof(v) == LIST)
v = $su:from_list(v, $ansi.tab);
endif
this:notify((k + $ansi.tab) + tostr(v));
yield;
endfor
for kv in (this.evalled_mssp_vars)
{k, v} = kv;
try
result = eval(("return " + v) + ";");
if (result[1])
this:notify((k + $ansi.tab) + tostr(result[2]));
endif
except e (ANY)
$rpg:report_error(e, "MSSP");
endtry
yield;
endfor
this:notify("MSSP-REPLY-END");
`$nets.sysnet:announce(this, tostr("MSSP request from ", connection_name(player)), 1) ! ANY';

pass*word

Spec any none anyFlags rxdOwner #361Definer #4

Referenced by

none

Source

"Copied from Login Commands (#10):request by Satan (#2) Mon May  3 12:50:36 2010 CDT";
if ((caller != #0) && (caller != this))
return E_PERM;
endif
"must be #0:do_login_command";
if (!this.password_request_enabled)
notify(player, this.password_request_string);
elseif ((length(args) != 3) || (args[2] != "for"))
notify(player, tostr("Usage:  ", verb, " <player-name> for <email-address>"));
notify(player, "The email address must be the one your character is currently registered to. Do not include the angle brackets: <>.");
notify(player, "If you do not know your character name or registered email address, please send us an email at " + $network.password_postmaster);
elseif ($login:request_password(player, args[1], args[3]))
boot_player(player);
endif

request_password

Spec this none thisFlags rxdOwner #361Definer #4

Referenced by

• #4:pass*word line 12: $login:request_password

Source

"request_password(player, name, address)";
"return true if succeeded";
if (!caller_perms().wizard)
return E_PERM;
endif
{who, name, address} = args;
playerobj = $login:_match_player(name);
connection = $string_utils:connection_hostname(connection_name(who));
"Check that the name is valid, that the address is registered to the name, and that there isn't already an active request.";
"Also make sure .password is not set to 'scrambled'";
if (playerobj == $failed_match)
notify(who, tostr("There is no player with that name."));
return 0;
elseif (playerobj.email_address != address)
notify(who, tostr("The player \"", name, "\" is not registered to the email address \"", address, "\"."));
return 0;
"elseif (((!this:is_admin_alt(address)) && (!(playerobj in this.allowed_players))) && (playerobj.donation < 1))";
"  notify(player, \"Sorry, only players who have been invited or who have donated may connect. For a similar game that is open to all, please go to aftertheend.org 7777.\");";
"  return 0;";
elseif (playerobj.password == "scrambled")
notify(who, tostr("The password for \"", name, "\" is scrambled."));
return 0;
elseif (playerobj in keys(this.password_requests))
req = this.password_requests[playerobj];
if ((time() - req[2]) < 86400)
notify(who, tostr("You already have requested a password reset in the last 24 hours."));
return 0;
endif
endif
notify(who, tostr("A new password for `", name, "' will be requested."));
notify(who, tostr("A response with further instructions for resetting your password will be sent to: ", address));
notify(who, tostr(" [Please double-check your email address and answer `no' if it is incorrect.]"));
notify(who, "Is this OK? [enter `yes' or `no']");
response = read(who);
if ((response != "yes") && (response != "y"))
notify(who, "Process terminated *without* requesting a password.");
return 0;
endif
if ((!$network.active) || $player_db.frozen)
notify(who, tostr("Automatic password requests are disabled. Please send your request by"));
notify(who, tostr("  email to: ", $login.registration_address, "."));
else
reqhash = crypt(tostr(random($maxint)));
this.password_requests[playerobj] = {reqhash, time()};
notify(who, tostr("Mailing password reset instructions for ", name, " to ", address, "; you should get the mail within a few minutes."));
notify(who, tostr("If you do not get it, please send email to ", $login.registration_address, ","));
notify(who, tostr("with the name of the character you need a new password for, and we can reset it for you."));
$mail_agent:send_message(this.owner, $new_password_log, tostr(name, " (", who, ")"), {address, tostr(" Password reset requested by ", valid(player) ? player.name | "unconnected player", " from ", connection, ".")});
$wiz_utils:send_new_password_mail(tostr("Someone connected from ", connection, " at ", ctime(), " requested a password on ", $network.moo_name, " for email address ", address, "."), name, address, reqhash);
return 1;
endif