grenade #135

pull activate light

Spec this none noneFlags rxdOwner #361Definer #135

Referenced by

none

Source

player:queue_action($actions.verb, {this, "_pull", {player}}, 1, "pull " + this:name());

_explode

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

• #135:_pull line 18: this:_explode
• #135:burn_up line 3: this:_explode
• #135:_break line 2: this:_explode
• #135:moveto line 12: this:_explode
• #135:on_failed_breakdown line 7: this:_explode

Source

if (!valid(where = is_a(this.location, $creature) ? this:room() | this.location))
return;
endif
if (valid(this.target) && (this.target.location != where))
this.target = #-1;
endif
if (is_a(this.location, $living))
msg = this.explode_in_hand_msg;
elseif (valid(this.target) && ((this.target_cover == (!(!(this.target in where.covering)))) && this.explode_near_msg))
msg = this.explode_near_msg;
else
msg = this.explode_in_room_msg;
endif
decal = this.blast_decal;
for nd in (this.no_decal)
if (is_a(where, nd))
decal = #-1;
endif
endfor
where:announce_all($su:ps(msg, this.location, this, this.target));
if (this.cause_explosion)
this:explode_at(decal);
endif
$rpg:junk(this);

_pull

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

• #135:grenade line 11: this:_pull

Source

who = args[1];
if (who:_wield(this))
if (task_valid(this.explode_task))
who:tell("It's already active!");
else
if (who:area() == #94696)
check = 2;
else
check = $skills.bombs:check(who, this.difficulty + 2);
endif
if (check < 0)
time = random(4) - 1;
else
time = this:time();
endif
fork task_id (time)
if (gamevalid(this))
this:_explode(who);
endif
endfork
this.explode_task = task_id;
who:aat($su:ps(this.pull_msg, player, this));
this.thrower = who;
if (this.is_crime)
this:room():broadcast_event(1, $actions.pull, who, {this});
this:room():broadcast_event(1, $actions.fight, this.thrower, {$player});
endif
endif
else
who:tell("You need to be holding it to do that.");
endif

time

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

• #135:_pull line 14: this:time

Source

return this.time;

affect_creature

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

"Copied from testnade (#156795):affect_creature by Socrates (#290421) Fri Jan  9 19:08:31 2009 CST";
who = args[1];
where = args[2];
if (!who:grenade_can_affect(this, where))
return;
endif
if (valid(this.thrower))
if (is_a(this.thrower, $player) && is_a(who, $player))
who:_pvp_record({this.thrower}, this.name);
endif
if (((!is_a(who, $player)) && (who.location != this.thrower.location)) && (this.thrower.location == #44969.location))
#44969:add_win(this.thrower);
endif
endif
mod = -3;
amount_multiplier = 1.0;
if (is_a(where, $outdoor_room))
mod = mod + 3;
endif
if ((is_a(where, $room) && (who in where.covering)) && (this.target != who))
mod = mod + 3;
endif
if (this.faller || (this.location == who))
amount_multiplier = amount_multiplier + 4.0;
else
"Very low damage if grenade is blowing at a target in cover and this is not the target OR if we are and have left cover.";
if (!this:receives_full_blast(who))
mod = mod + 3;
amount_multiplier = amount_multiplier * 0.5;
"Simulate that it's put in a nook or something.";
if (valid(this.target) && this.target_cover)
amount_multiplier = amount_multiplier * 0.25;
endif
endif
endif
mod = max($skills.dodge:check(who, mod), 0);
if (mod > 0)
who:tell("You manage to shield yourself from some of the blast...");
endif
for d in (this.damage)
amount = d[2] + (((d[3] - d[2]) > 0) ? random(d[3] - d[2]) | 0);
amount = toint(tofloat(amount) * amount_multiplier);
if ((mod > 0) && (!(d[1] in {#308, #1326})))
amount = amount - min(amount / 2, random(max(1, mod)));
endif
who:take_damage(d[1], amount, $bodypart);
if ((this.location == who.location) && (random(100) <= (toint((tofloat(amount) / tofloat(who.health_max)) * 100.0) - (who.health_max / 5))))
check = #113:check(who, -5, 1);
if ((check <= 0) && (who.movable_by_explosion == 1))
if (is_a(this.location, $room) && this.location.exits)
direction = this.location.exits[random($)];
location = direction.otherside.location;
if (is_a(direction, $door) && (direction.open == 0))
return;
elseif (is_a(direction, #18385))
return;
elseif (direction.passable == 0)
return;
endif
who:moveto(location);
location:announce_all(who:name(), " comes sailing in.");
this.location:announce_all(who:name(), " is blown ", direction.name, " by the explosion!");
location:fall_into(who, this.location, 20);
endif
endif
endif
endfor

fall leap

Spec none on top of/on/onto/upon thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

if (this.location != this:room())
if (g = player.location:occupants($grenade))
g[$]:fall();
return;
endif
player:tell("You can't fall on a grenade until it's actually on the ground, Einstein.");
return;
endif
if (valid(this.faller) && this.faller:is_in(this.location))
if (this.faller == player)
player:Tell("You're already lying on it.  Make your peace with your god...");
else
player:tell(this.faller:dnamec(), " is already lying on ", this:dname(), "!");
endif
return;
endif
this.faller = player;
player:aat(player:dnamec(), " leaps heroically onto ", this:dname(), ", covering it with ", player.pp, " body!");

burn_up

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

this:room():announce_all(this:dnamec(), " sparks and bounces in the flames.  It's clearly about to blow...");
this:moveto(this:room());
this:_explode();

_break

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

this.thrower = is_a(player, $living) ? player | #-1;
this:_explode();

is_junkable

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

if (task_valid(this.explode_task))
return 0;
endif
return pass(@args);

moveto

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

• #135:burn_up line 2: this:moveto

Source

"Copied from testnade (#156795):moveto by Socrates (#290421) Fri Jan  9 19:08:49 2009 CST";
"Copied from grenade (#1573):moveto by Gilmore (#98) Fri Jan  9 10:22:26 2009 CST";
o = this.location;
r = pass(@args);
"Picking up a lit grenade is dangerous.";
if ((this.volatility == 2) || (task_valid(this.explode_task) && (this.volatility == 1)))
if (!is_a(o, #2801))
if (is_a(this.location, $creature))
check = $skills.bombs:check(this.location, this.difficulty + 2);
if (check < 0)
fork (0)
`this:_explode() ! ANY => 0';
endfork
endif
endif
endif
endif
"This is so if you drop it, you will be the primary target of the blast.";
if (is_a(this.location, $creature))
this.target = this.location;
this.awarers = {};
elseif (valid(this.target) && (this.target.location == this.location))
this.target_cover = this.target in this.target.location.covering;
elseif (is_a(this.location, $room))
this.target = #-1;
this.awarers = {};
for who in (this.location:occupants($living))
if ($skills.senses:check(who, this:detect_difficulty(), 1) > 0)
this.awarers = {who, @this.awarers};
endif
endfor
else
this.target = #-1;
this.awarers = {};
endif
return r;

grenade nade

Spec any with/using thisFlags rxdOwner #29Definer #135

Referenced by

none

Source

"Activate and throw the grenade in the specified direction.";
target = dobj;
if (!valid(target))
player:tell("What's a '", dobjstr, "'?");
elseif (this.location != player)
player:tell("You're not carrying ", this:dname(), ".");
elseif (target == player)
player:tell("Really? I don't think you are serious.");
elseif ((target.location == player.location) && ((is_a(target, $exit) && target.passable) || is_a(target, $living)))
if (player:_wield(this))
this:_pull(player);
if ($rpg:valid(this))
player:queue_action($actions.throw, {this, target}, 0, "throw " + this.name);
endif
endif
else
player:tell("You can't throw ", this:iname(), " to ", dobj:dname(), ".");
endif

detect_difficulty

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

• #135:moveto line 28: this:detect_difficulty
• #135:hear_event_arrive line 5: this:detect_difficulty

Source

"Copied from testnade (#156795):detect_difficulty by Socrates (#290421) Fri Jan  9 19:08:08 2009 CST";
":detect_difficulty() => Return the modifier to the senses check for noticing this grenade.";
return this.detect_difficulty;

receives_full_blast

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

• #135:affect_creature line 27: this:receives_full_blast
• #135:receives_full_blast line 6: this:receives_full_blast
• #135:blast_severity line 11: this:receives_full_blast

Source

":receives_full_blast(who, [checked]) => Return true if who is at the blast, either because he's the target, fighting the target or because he's not aware of it.";
who = args[1];
checked = (length(args) >= 2) ? args[2] | {};
for other in (who.fighting)
if (is_a(other, $living))
if (((other in checked) || this:receives_full_blast(other, setadd(checked, who))) && (!is_a(other:weapon(), #284)))
return 1;
endif
endif
endfor
unaware = !(who in this.awarers);
being_flushed_out = (this.target == who) && (this.target_cover == (!(!(who in who.location.covering))));
return (unaware || being_flushed_out) && (who != this.thrower);

hear_event_arrive

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

"Copied from testnade (#156795):hear_event_arrive by Socrates (#290421) Fri Jan  9 19:08:26 2009 CST";
"Copied from generic mine (#35898):hear_event_arrive by Jed (#45097) Fri Jan  9 14:55:17 2009 CST";
who = args[3];
if (is_a(who, $living))
if ($skills.senses:check(who, this:detect_difficulty(), 1) > 0)
this.awarers = setadd(this.awarers, who);
endif
endif

hear_event_move

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

"Copied from testnade (#156795):hear_event_move by Socrates (#290421) Fri Jan  9 19:08:44 2009 CST";
{is_start, action, who, cwords} = args;
if (!is_start)
if (who == this.target)
this.target = #-1;
endif
this.awarers = setremove(this.awarers, who);
endif

thrown_at

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

"Copied from testnade (#156795):thrown_at by Socrates (#290421) Fri Jan  9 19:08:54 2009 CST";
{target, thrower} = args;
this.target = target;
this.awarers = target:room():contents($living);
pass(@args);

blast_severity

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

":blast_severity(who) => Return the blast severity as a two element list:  a modifier to a dodge roll and a floating point multiplier for damage.";
who = args[1];
where = this:room();
mod = -3;
damage_multiplier = 1.0;
if (valid(this.faller) && (this.faller != who))
return {0, 0.0};
endif
if ((this.faller == who) || (this.location == who))
damage_multiplier = damage_multiplier + `this.proximity_damage_multiplier ! E_PROPNF => 2.0';
elseif (!this:receives_full_blast(who))
mod = mod + 3;
damage_multiplier = damage_multiplier * 0.5;
"Simulate that it's put in a nook or something.";
if (valid(this.target) && this.target_cover)
damage_multiplier = damage_multiplier * 0.5;
mod = mod + 3;
endif
endif
return {mod, damage_multiplier};

can_glob

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

return pass(@args) && (!this.explode_task);

on_failed_breakdown

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

{who, check} = args;
if (check < -3)
who:tell("Oh... shit.");
fork (0)
if (is_a(this, $grenade))
this.thrower = who;
this:_explode();
endif
endfork
endif

on_munch

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

who = args[1];
if (task_valid(this.explode_task))
suspend(2);
who:aat(who:name() + " looks rather ill.");
suspend(1);
who:take_damage($damages.explosion, 100, #304);
endif
$rpg:junk(this);

stash

Spec this none noneFlags rxdOwner #361Definer #135

Referenced by

none

Source

if (task_valid(this.explode_task))
player:tell("Fuck you.");
else
pass(@args);
endif

explode_at

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

• #135:_explode line 22: this:explode_at

Source

{decal} = args;
$explosion:at(this.location, this.damage, this.thrower, this.explode_msg, this.noise_msg, this.noise_volume, decal, `this.max_depth ! E_PROPNF => 0', {this, "blast_severity"});

tree_tag

Spec this none thisFlags rxdOwner #361Definer #135

Referenced by

none

Source

r = pass(@args);
r = tostr(r, " ", $ansi.bold_on, $ansi.red, this.difficulty, $ansi.reset);
if (this != $grenade)
r = tostr(r, " ", $su:from_list(verbs(this), ","));
endif
return r;