Network Utilities #72

parse_address

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #16:suspicious_address line 16: $network:parse_address
• #24:check_player_request line 42: $network:parse_address
• #72:email_will_fail line 17: this:parse_address
• #72:email_will_fail line 19: this:parse_address

Source

"Given an email address, return {userid, site}.";
"Valid addresses are of the form `userid[@site]'.";
"At least for now, if [@site] is left out, site will be returned as blank.";
"Should be a default address site, or something, somewhere.";
address = args[1];
return (at = index(address, "@")) ? {address[1..at - 1], address[at + 1..$]} | {address, ""};

local_domain

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #16:suspicious_address line 21: $network:local_domain
• #24:check_player_request line 52: $network:local_domain
• #24:check_player_request line 52: $network:local_domain

Source

"given a site, try to figure out what the `local' domain is.";
"if site has a @ or a % in it, give up and return E_INVARG.";
"blank site is returned as is; try this:local_domain(this.localhost) for the answer you probably want.";
site = args[1];
if (index(site, "@") || index(site, "%"))
return E_INVARG;
elseif (match(site, "^[0-9.]+$"))
return E_INVARG;
elseif (!site)
return "";
elseif (!(dot = rindex(site, ".")))
dot = rindex(site = this.site, ".");
endif
if ((!dot) || (!(dot = rindex(site[1..dot - 1], "."))))
return site;
else
domain = site[dot + 1..$];
site = site[1..dot - 1];
while (site && (domain in this.large_domains))
if (dot = rindex(site, "."))
domain = tostr(site[dot + 1..$], ".", domain);
site = site[1..dot - 1];
else
return tostr(site, ".", domain);
endif
endwhile
return domain;
endif

open

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #72:raw_sendmail line 33: $network:open
• #75:get_now line 14: $network:open
• #75:show_text line 7: $network:open
• #87:open line 5: $network:open
• #87:open_data line 13: $network:open

Source

":open(address, port, [connect-connection-to])";
"Open a network connection to address/port.  If the connect-connection-to is passed, then the connection will be connected to that object when $login gets ahold of it.  If not, then the connection is just ignored by $login, i.e. not bothered by it with $welcome_message etc.";
"The object specified by connect-connection-to has to be a player (though it need not be a $player).";
"Returns the (initial) connection or an error, as in open_network_connection";
if (!this:trust(caller_perms()))
return E_PERM;
endif
address = args[1];
port = args[2];
if (length(args) < 3)
connect_to = $nothing;
elseif ((typeof(connect_to = args[3]) == OBJ) && (valid(connect_to) && is_player(connect_to)))
if (!$perm_utils:controls(caller_perms(), connect_to))
return E_PERM;
endif
else
return E_INVARG;
endif
if (typeof(connection = `open_network_connection(address, port) ! ANY') != ERR)
if (valid(connect_to))
this.connect_connections_to = {@this.connect_connections_to, {connection, connect_to}};
endif
endif
return connection;

close

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #72:raw_sendmail line 67: $network:close
• #75:get_now line 35: $network:close
• #75:show_text line 30: $network:close
• #87:open line 12: $network:close
• #87:close line 8: $network:close
• #87:close line 10: $network:close
• #87:close_data line 8: $network:close

Source

if (!this:trust(caller_perms()))
return E_PERM;
endif
con = args[1];
if (!index(`connection_name(con) ! ANY => ""', " to "))
return E_INVARG;
endif
boot_player(con);
if (i = $list_utils:iassoc(con, $network.connect_connections_to))
$network.connect_connections_to = listdelete($network.connect_connections_to, i);
endif
return 1;

sendmail

Spec any none noneFlags rxdOwner #2Definer #72

Referenced by

• #6:@registerme line 45: $network:sendmail
• #9:mailme line 15: $network:sendmail
• #24:send_new_player_mail line 12: $network:sendmail
• #24:do_new_password line 26: $network:sendmail
• #40:send_self_netmail line 15: $network:sendmail
• #45:expire_old_messages line 14: $network:sendmail
• #45:@register line 34: $network:sendmail

Source

"sendmail(to, subject, line1, line2, ...)";
"  sends mail to internet address 'to', with given subject.";
"  It fills in various fields, such as date, from (from player), etc.";
"  the rest of the arguments are remaining lines of the message, and may begin with additional header fields.";
"  (must match RFC822 specification).";
"Requires $network.trust to call (no anonymous mail from MOO).";
"Returns 0 if successful, or else error condition or string saying why not.";
if (!this:trust(caller_perms()))
return E_PERM;
endif
mooname = this.MOO_name;
mooinfo = tostr(mooname, " (", this.site, " ", this.port, ")");
if (reason = this:invalid_email_address(to = args[1]))
return reason;
endif
"took out Envelope-from:  + this.errors_to_address";
return this:raw_sendmail(to, "Date: " + ctime(), "From: " + this:return_address_for(player), "To: " + to, "Subject: " + args[2], "Errors-to: " + this.errors_to_address, "X-Mail-Agent: " + mooinfo, @args[3..$]);

trust

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #72:open line 5: this:trust
• #72:close line 1: this:trust
• #72:sendmail line 8: this:trust
• #72:read line 2: this:trust
• #72:notify line 2: this:trust

Source

return (who = args[1]).wizard || (who in this.trusts);

init_for_core

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

none

Source

if (caller_perms().wizard)
pass(@args);
this.active = 0;
this.errors_to_address = "moomailerrors@yourhost";
this.site = "yoursite";
this.postmaster = "postmastername@yourhost";
this.usual_postmaster = "postmastername@yourhost";
this.password_postmaster = "postmastername@yourhost";
this.envelope_from = "postmastername@yourhost";
this.blank_envelope = 0;
this.MOO_name = "YourMOO";
this.maildrop = "localhost";
this.port = 7777;
this.large_domains = {};
this.trusts = {$hacker};
this.connect_connections_to = {};
endif

raw_sendmail

Spec any none noneFlags rxdOwner #2Definer #72

Referenced by

• #72:sendmail line 17: this:raw_sendmail
• #72:send_queued_mail line 5: this:raw_sendmail

Source

"Copied from sendmail fix (#88079):raw_sendmail by Lineman (#108318) Mon Feb  1 19:29:43 1999 PST";
"rawsendmail(to, @lines)";
"sends mail without processing. Returns 0 if successful, or else reason why not.";
if (!caller_perms().wizard)
return E_PERM;
endif
if (!this.active)
return "Networking is disabled.";
endif
if (typeof(this.debugging) == LIST)
"who to notify";
debugging = this.debugging;
else
"notify this owner";
debugging = this.debugging && {this.owner};
endif
address = args[1];
body = listdelete(args, 1);
data = {"HELO " + this.site, ("MAIL FROM:<" + this.postmaster) + ">", ("RCPT TO:<" + address) + ">", "DATA"};
blank = 0;
for x in (body)
this:suspend_if_needed(0);
if (!(blank || match(x, "[a-z0-9-]*: ")))
if (x)
data = {@data, ""};
endif
blank = 1;
endif
data = {@data, (x && (x[1] == ".")) ? "." + x | x};
endfor
data = {@data, ".", "QUIT", ""};
suspend(0);
target = $network:open(this.maildrop, 25);
if (typeof(target) == ERR)
return tostr("Cannot open connection to maildrop ", this.maildrop, ": ", target);
endif
set_connection_option(target, "hold-input", 1);
blast = 0;
msg = 0;
expects = {"220", "250", "250", "250%|251", "354", "250", "221"};
for line in (data)
if (!blast)
reply = this:tcp_wait(target);
if (typeof(reply) == ERR)
msg = "Connection dropped or timed out.";
break;
elseif (!match(reply[1..3], expects[1]))
msg = (("Expected " + expects[1]) + " but got ") + reply;
break;
endif
debugging && notify(debugging[1], "GET: " + reply);
expects[1..1] = {};
if (reply[1..3] == "221")
"Service closing transmission channel";
break;
elseif (reply[1..3] == "354")
"Start mail input; end with <CRLF>.<CRLF>";
blast = 1;
endif
elseif (line == ".")
blast = 0;
endif
debugging && notify(debugging[1], "SEND:" + line);
notify(target, line);
((ticks_left() < 4000) || (seconds_left() < 2)) && suspend(0);
endfor
$network:close(target);
debugging && notify(debugging[1], "EXIT:" + (msg || "Mail sent successfully."));
return msg;

invalid_email_address

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #24:check_player_request line 39: $network:invalid_email_address
• #24:do_register line 16: $network:invalid_email_address
• #40:send_self_netmail line 5: $network:invalid_email_address
• #45:@register line 28: $network:invalid_email_address
• #72:sendmail line 13: this:invalid_email_address
• #72:email_will_fail line 3: this:invalid_email_address

Source

"invalid_email_address(email) -- check to see if email looks like a valid email address. Return reason why not.";
address = args[1];
if (!address)
return "no email address supplied";
endif
if (!(at = rindex(address, "@")))
return ("'" + address) + "' doesn't look like a valid internet email address";
endif
name = address[1..at - 1];
host = address[at + 1..$];
if (match(name, "^in%%") || match(name, "^smtp%%"))
return tostr("'", name, "' doesn't look like a valid username (try removing the 'in%' or 'smtp%')");
endif
if (!match(host, $network.valid_host_regexp))
return tostr("'", host, "' doesn't look like a valid internet host");
endif
if (!match(name, $network.valid_email_regexp))
return tostr("'", name, "' doesn't look like a valid user name for internet mail");
endif
return "";

invalid_hostname

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

none

Source

return match(args[1], this.valid_host_regexp) ? "" | tostr("'", args[1], "' doesn't look like a valid internet host name");

email_will_fail

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #40:@netforw*ard line 7: $network:email_will_fail
• #65:check_netmail line 8: $network:email_will_fail

Source

":email_will_fail(email-address[, display?]) => Makes sure the email-address is one that can actually be used by $network:sendmail().";
{email, ?display = 0} = args;
reason = this:invalid_email_address(email);
if (reason && display)
player:tell("Invalid email address: ", reason);
endif
return reason;
"following is code from OpalMOO, not used here";
"Possible situations where the address would be unusable are when the address is invalid or we can't connect to the site to send mail.";
"If <display> is true, error messages are displayed to the player and 1 is returned when address is unuable.  If <display> is false and address is unusable, the error message is returned.  If the address is usable, 0 is always returned.";
if (!this:approved_for_network(caller_perms()))
return E_PERM;
endif
if (!this:valid_email_address(email))
msg = tostr("Your email address (", email, ") is not a usable account.");
elseif ((result = this:verify_email_address(email)) == E_INVARG)
msg = tostr("Unable to connect to ", this:parse_address(email)[2], ".");
elseif (typeof(result) == STR)
msg = tostr("The site ", (parse = this:parse_address(email))[2], " does not recognize ", parse[1], " as a valid account.");
else
return 0;
endif
if (display)
player:tell(msg);
return 1;
else
return msg;
endif
"Last modified Tue Jun 15 00:19:01 1993 EDT by Ranma (#200).";

read

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #87:wait_for_response line 9: $network:read

Source

"for trusted players, they can read from objects they own or open connections";
if (!this:trust(caller_perms()))
return E_PERM;
elseif (valid(x = args[1]))
if ((x.owner == x) || (x.owner != caller_perms()))
return E_INVARG;
endif
"elseif (!this:is_outgoing_connection(x) return E_PERM";
endif
return `read(@args) ! ANY';

is_open

Spec this none thisFlags rxdOwner #36Definer #72

Referenced by

• #87:close line 9: $network:is_open
• #87:open_data line 6: $network:is_open
• #87:put_data line 7: $network:is_open
• #87:close_data line 5: $network:is_open

Source

":is_open(object)";
"return true if the object is somehow connected, false otherwise.";
return typeof(`idle_seconds(@args) ! ANY') == INT;
"Relies on test in idle_seconds, and the error catching";

incoming_connection

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #0:do_login_command line 5: $network:incoming_connection

Source

"Peer at an incoming connection.  Decide if it should be connected to something, return that object. If it should be ignored (outbound connection), return 1. Called only by #0:do_login_command";
if (caller != #0)
return;
endif
what = args[1];
"this code for unix servers >= 1.7.5 only";
if (index(`connection_name(what) ! ANY => ""', " to "))
"outbound connection";
if (ct = $list_utils:assoc(what, this.connect_connections_to))
this.connect_connections_to = setremove(this.connect_connections_to, ct);
return ct[2];
else
return 1;
endif
else
return 0;
endif

return_address_for

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #72:sendmail line 17: this:return_address_for

Source

":return_address_for(player) => string of 'return address'. Currently inbound mail doesn't work, so this is a bogus address.";
who = args[1];
if (valid(who) && is_player(who))
return tostr(toint(who), "@", this.site, " (", who.name, ")");
else
return tostr($login.registration_address, " (non-player ", who, ")");
endif

server_started

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #0:server_started line 3: $network:server_started

Source

"called when restarting to clean out state.";
if (caller != #0)
return E_PERM;
endif
this.connect_connections_to = {};

is_outgoing_connection

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #72:notify line 6: this:is_outgoing_connection

Source

return index(`connection_name(args[1]) ! ANY => ""', " to ");

notify

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #87:do_command line 5: $network:notify

Source

"for trusted players, they can write to connections";
if (!this:trust(caller_perms()))
return E_PERM;
elseif (valid(x = args[1]))
return E_INVARG;
elseif (!this:is_outgoing_connection(x))
return E_PERM;
endif
return notify(x, args[2]);

suspend_if_needed

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #72:raw_sendmail line 22: this:suspend_if_needed

Source

"$command_utils:suspend_if_needed but chowned to player";
if ($command_utils:running_out_of_time())
set_task_perms(caller_perms().wizard ? player | caller_perms());
return $command_utils:suspend_if_needed(@args);
endif

error

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

none

Source

":error(ERN, host, port) interpret open_network_connection(host, port) error";
{msg, host, port} = args;
if (msg == E_PERM)
return "Networking not enabled in server, or else user doesn't have permission to call o_n_c();";
elseif (msg == E_INVARG)
return tostr("The host/port ", toliteral(host), "/", toliteral(port), " is invalid or is not responding.");
elseif (msg == E_QUOTA)
return tostr("The connection to ", toliteral(host), "/", toliteral(port), " cannot be made at this time.");
else
return tostr("Unusual error: ", toliteral(msg));
endif

help_msg

Spec this none thisFlags rxdOwner #36Definer #72

Referenced by

none

Source

"'cause this doesn't have a $_utils name";
return this:description();

adjust_postmaster_for_password

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #24:do_new_password line 25: $network:adjust_postmaster_for_password
• #24:do_new_password line 31: $network:adjust_postmaster_for_password

Source

"adjust_postmaster_for_password(enter_or_exit): permits the MOO to have two different postmasters for different kinds of bounces.  If entering password (argument \"enter\"), change to $network.password_postmaster, else (argument \"exit\") change to $network.usual_postmaster.";
if (args[1] == "enter")
$network.postmaster = $network.password_postmaster;
$network.errors_to_address = $network.password_postmaster;
$network.envelope_from = $network.password_postmaster;
else
$network.postmaster = $network.usual_postmaster;
$network.errors_to_address = $network.usual_postmaster;
$network.envelope_from = $network.blank_envelope ? "" | $network.usual_postmaster;
endif

add_queued_mail

Spec this none thisFlags rxdOwner #36Definer #72

Referenced by

none

Source

"$network:add_queued_mail( mail message )";
"  -- where `mail message' is in the same format as passed to :raw_sendmail";
if (caller == this)
this.queued_mail = {@this.queued_mail, {time(), args}};
if (!$code_utils:task_valid(this.queued_mail_task))
fork fid (3600)
this:send_queued_mail();
endfork
this.queued_mail_task = fid;
endif
return 1;
else
return E_PERM;
endif

send_queued_mail

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #72:add_queued_mail line 7: this:send_queued_mail

Source

"$network:send_queued_mail()";
"  -- tries to send the mail stored in the .queued_mail property";
while (queued_mail = this.queued_mail)
message = queued_mail[1];
if (!this:raw_sendmail(@message[2]))
this.queued_mail = setremove(this.queued_mail, message);
else
"wait an hour";
suspend(3600);
endif
endwhile

tcp_wait

Spec this none thisFlags rxdOwner #2Definer #72

Referenced by

• #72:raw_sendmail line 43: this:tcp_wait

Source

"Copied from sendmail fix (#88079):tcp_wait by Lineman (#108318) Mon Feb  1 19:28:18 1999 PST";
{conn, ?timeout = 0} = args;
if (!caller_perms().wizard)
return E_PERM;
elseif (timeout)
fork task (timeout)
boot_player(conn);
endfork
endif
while (1)
if (typeof(line = `read(conn) ! ANY') == ERR)
break;
elseif (match(line, "^[0-9][0-9][0-9] "))
timeout && `kill_task(task) ! ANY';
break;
endif
endwhile
return line;