housekeeper #71

look_self

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

none

Source

player:tell_lines(this:description());
player:tell($string_utils:pronoun_sub("%S %<is> moving around from room to room, cleaning up.", this));

cleanup

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

none

Source

"$housekeeper:cleanup([insist]) => clean up player's objects. Argument is 'up' or 'up!' for manually requested cleanups (notify player differently)";
if (caller_perms() != this)
return E_PERM;
endif
for object in (this.clean)
x = object in this.clean;
if (this.requestors[x] == player)
if (result = this:replace(object, @args))
player:tell(result, ".");
endif
endif
(ticks_left() < 3000) && suspend(0);
endfor
player:tell("The housekeeper has finished cleaning up your objects.");

replace

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

• #71:cleanup line 8: this:replace
• #71:scheduled_cleanup line 9: this:replace

Source

"replace the object given to its proper spot (if there is one).";
{object, ?insist = 0} = args;
i = object in this.clean;
if (!i)
return tostr(object, " is not on the ", this.name, "'s cleanup list");
endif
place = this.destination[i];
if (!(($recycler:valid(object) && ($recycler:valid(place) || (place == #-1))) && (!(object.location in this.recycle_bins))))
"object no longer valid (recycled or something), remove it.";
this.clean = listdelete(this.clean, i);
this.requestors = listdelete(this.requestors, i);
this.destination = listdelete(this.destination, i);
return tostr(object) + " is no longer valid, removed from cleaning list";
endif
oldloc = loc = object.location;
if (object.location == place)
"already in its place";
return "";
endif
requestor = this.requestors[i];
if (insist != "up!")
if ($code_utils:verb_or_property(object, "in_use"))
return ("Not returning " + object.name) + " because it claims to be in use";
endif
for thing in (object.contents)
if (thing:is_listening())
return ((("Not returning " + object.name) + " because ") + thing.name) + " is inside";
endif
(ticks_left() < 4000) && suspend(0);
endfor
if (valid(loc) && (loc != $limbo))
if (loc:is_listening())
return ((("Not returning " + object.name) + " because ") + loc.name) + " is holding it";
endif
for y in (loc:contents())
if ((y != object) && y:is_listening())
return (((("Not returning " + object.name) + " because ") + y.name) + " is in ") + loc.name;
endif
(ticks_left() < 4000) && suspend(0);
endfor
endif
endif
if (valid(place) && (!place:acceptable(object)))
return (place.name + " won't accept ") + object.name;
endif
try
requestor:tell("As you requested, the housekeeper tidies ", $string_utils:nn(object), " from ", $string_utils:nn(loc), " to ", $string_utils:nn(place), ".");
if ($object_utils:has_verb(loc, "announce_all_but"))
loc:announce_all_but({requestor, object}, "At ", requestor.name, "'s request, the ", this.name, " sneaks in, picks up ", object.name, " and hurries off to put ", ($object_utils:has_property(object, "po") && (typeof(object.po) == STR)) ? object.po | "it", " away.");
endif
except (ANY)
"Ignore errors";
endtry
this:moveit(object, place, requestor);
if ((loc = object.location) == oldloc)
return (object.name + " wouldn't go; ") + ((!place:acceptable(object)) ? (" perhaps " + $string_utils:nn(place)) + " won't let it in" | ((" perhaps " + $string_utils:nn(loc)) + " won't let go of it"));
endif
try
object:tell("The housekeeper puts you away.");
if ($object_utils:isa(loc, $room))
loc:announce_all_but({object}, "At ", requestor.name, "'s request, the housekeeper sneaks in, deposits ", object:title(), " and leaves.");
else
loc:tell("You notice the housekeeper sneak in, give you ", object:title(), " and leave.");
endif
except (ANY)
"Ignore errors";
endtry
return "";

cleanup_list

Spec any none noneFlags rxdOwner #36Definer #71

Referenced by

none

Source

if (args)
if (!valid(who = args[1]))
return;
endif
player:tell(who.name, "'s personal cleanup list:");
else
who = 0;
player:tell("Housekeeper's complete cleanup list:");
endif
player:tell("------------------------------------------------------------------");
printed_anything = 0;
objs = this.clean;
reqs = this.requestors;
dest = this.destination;
for i in [1..length(objs)]
(ticks_left() < 5000) && suspend(2);
req = reqs[i];
ob = objs[i];
place = dest[i];
if (((who == 0) || (req == who)) || (ob.owner == who))
if (!valid(ob))
player:tell($string_utils:left(tostr(ob), 7), $string_utils:left("** recycled **", 50), "(", req.name, ")");
else
player:tell($string_utils:left(tostr(ob), 7), $string_utils:left(ob.name, 26), "=>", $string_utils:left(tostr(place), 7), place.name || "nowhere", " (", req.name, ")");
endif
printed_anything = 1;
endif
endfor
if (!printed_anything)
player:tell("** The housekeeper has nothing in the cleanup list.");
endif
player:tell("------------------------------------------------------------------");

add_cleanup

Spec any any anyFlags rxdOwner #36Definer #71

Referenced by

none

Source

if (!$perm_utils:controls(caller_perms(), this))
return E_PERM;
endif
{what, ?who = player, ?where = what.location} = args;
if ((what < #1) || (!valid(what)))
return "invalid object";
endif
if ($object_utils:isa(who, $guest))
return tostr("Guests can't use the ", this.name, ".");
endif
if (!is_player(who))
return tostr("Non-players can't use the ", this.name, ".");
endif
if (!valid(where))
return tostr("The ", this.name, "doesn't know how to find ", where, " in order to put away ", what.name, ".");
endif
if (is_player(what))
return ("The " + this.name) + " doesn't do players, except to cart them home when they fall asleep.";
endif
for x in (this.eschews)
if ($object_utils:isa(what, x[1]))
ok = 0;
for y in [3..length(x)]
if ($object_utils:isa(what, x[y]))
ok = 1;
endif
endfor
if (!ok)
return tostr("The ", this.name, " doesn't do ", x[2], "!");
endif
endif
endfor
if ($object_utils:has_callable_verb(where, "litterp") ? where:litterp(what) | ((where in this.public_places) && (!(what in where.residents))))
return tostr("The ", this.name, " won't litter ", where.name, "!");
endif
if (i = what in this.clean)
if ((!this:controls(i, who)) && valid(this.destination[i]))
return tostr(this.requestors[i].name, " already asked that ", what.name, " be kept at ", this.destination[i].name, "!");
endif
this.requestors[i] = who;
this.destination[i] = where;
else
this.clean = {what, @this.clean};
this.requestors = {who, @this.requestors};
this.destination = {where, @this.destination};
endif
return tostr("The ", this.name, " will keep ", what.name, " (", what, ") at ", valid(where) ? ((where.name + " (") + tostr(where)) + ")" | where, ".");

remove_cleanup

Spec any none noneFlags rxdOwner #36Definer #71

Referenced by

none

Source

if (!$perm_utils:controls(caller_perms(), this))
return E_PERM;
endif
{what, ?who = player} = args;
if (i = what in this.clean)
if (!this:controls(i, who))
return tostr("You may remove an object from ", this.name, " list only if you own the object, the place it is kept, or if you placed the original cleaning order.");
endif
this.clean = listdelete(this.clean, i);
this.destination = listdelete(this.destination, i);
this.requestors = listdelete(this.requestors, i);
return tostr(what.name, " (", what, ") removed from cleanup list.");
else
return tostr(what.name, " not in cleanup list.");
endif

controls

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

• #71:add_cleanup line 37: this:controls
• #71:remove_cleanup line 6: this:controls

Source

"does player control entry I?";
{i, who} = args;
if ((who in {this.owner, @this.owners}) || who.wizard)
return "Yessir.";
endif
cleanable = this.clean[i];
if (this.requestors[i] == who)
return "you asked for the previous result, you can change this one.";
elseif (((who == cleanable.owner) || (!valid(dest = this.destination[i]))) || (who == dest.owner))
return "you own the object or the place where it is being cleaned to, or the destination is no longer valid.";
else
return "";
endif

litterbug

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

• #71:scheduled_cleanup line 12: this:litterbug

Source

for room in (this.public_places)
for thingy in (room.contents)
suspend(10);
if (((thingy.location == room) && this:is_litter(thingy)) && (!this:is_watching(thingy, $nothing)))
"if it is litter and no-one is watching";
fork (0)
this:send_home(thingy);
endfork
suspend(0);
endif
endfor
endfor

is_watching

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

• #71:litterbug line 4: this:is_watching

Source

return valid(thing = args[1]) && thing:is_listening();

send_home

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

• #71:litterbug line 7: this:send_home

Source

if (caller != this)
return E_PERM;
endif
litter = args[1];
littering = litter.location;
this:ejectit(litter, littering);
home = litter.location;
if ($object_utils:isa(home, $room))
home:announce_all("The ", this.name, " sneaks in, deposits ", litter:title(), " and leaves.");
else
home:tell("You notice the ", this.name, " sneak in, give you ", litter:title(), " and leave.");
endif
if ($object_utils:has_callable_verb(littering, "announce_all_but"))
littering:announce_all_but({litter}, "The ", this.name, " sneaks in, picks up ", litter:title(), " and rushes off to put it away.");
endif

moveit

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

• #71:replace line 54: this:moveit

Source

"Wizardly verb to move object with requestor's permission";
if (caller != this)
return E_PERM;
else
set_task_perms(player = args[3]);
return args[1]:moveto(args[2]);
endif

ejectit

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

• #71:send_home line 6: this:ejectit

Source

"this:ejectit(object,room): Eject args[1] from args[2].  Callable only by housekeeper's quarters verbs.";
if (caller == this)
args[2]:eject(args[1]);
endif

is_object_cleaned

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

• #71:is_cleaning line 3: this:is_object_cleaned

Source

what = args[1];
if (!(where = what in this.clean))
return 0;
else
return {this.destination[where], this.requestors[where]};
endif

is_litter

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

• #71:litterbug line 4: this:is_litter

Source

thingy = args[1];
for x in (this.litter)
if ($object_utils:isa(thingy, x[1]) && (!$object_utils:isa(thingy, x[2])))
return 1;
endif
endfor
return 0;

init_for_core

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

none

Source

if (caller_perms().wizard)
this.password = "Impossible password to type";
this.last_password_time = 0;
this.litter = {};
this.public_places = {};
this.requestors = {};
this.destination = {};
this.clean = {};
this.eschews = {};
this.recycle_bins = {};
this.cleaning = #-1;
this.task = {0, 0};
this.owners = {#2};
this.mail_forward = {#2};
this.player_queue = {};
this.move_player_task = 0;
this.moveto_task = 0;
pass(@args);
endif

clean_status

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

none

Source

count = 0;
for i in (this.requestors)
if (i == player)
count = count + 1;
endif
(ticks_left() < 5000) && suspend(1);
endfor
player:tell("Number of items in cleanup list: ", tostr(length(this.clean)));
player:tell("Number of items you requested to be tidied: ", tostr(count));
player:tell("Number of requestors: ", tostr(length($list_utils:remove_duplicates(this.requestors))));
player:tell("Time to complete one cleaning circuit: ", $time_utils:english_time(length(this.clean) * this:time()));

is_cleaning

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

none

Source

"return a string status if the hosuekeeper is cleaning this object";
cleanable = args[1];
info = this:is_object_cleaned(cleanable);
if (info == 0)
return tostr(cleanable.name, " is not cleaned by the ", this.name, ".");
else
return tostr(cleanable.name, " is kept tidy at ", info[1].name, " (", info[1], ") at ", info[2].name, "'s request.");
endif

time

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

• #71:clean_status line 11: this:time
• #71:scheduled_cleanup line 5: this:time
• #71:@begin line 8: this:time

Source

"Returns the amount of time to suspend between objects while continuous cleaning.";
"Currently set to try to complete cleaning circuit in one hour, but not exceed one object every 20 seconds.";
return max(20 + $login:current_lag(), length(this.clean) ? 3600 / length(this.clean) | 0);

acceptable

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

none

Source

return caller == this;

move_players_home

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

• #3:disfunc line 6: $housekeeper:move_players_home
• #104:disfunc line 7: $housekeeper:move_players_home

Source

if (!$perm_utils:controls(caller_perms(), this))
"perms don't control the $housekeeper; probably not called by $room:disfunc then. Used to let args[1] call this. No longer.";
return E_PERM;
endif
this.player_queue = {@this.player_queue, {args[1], time() + 300}};
if (!`$scheduler:valid_task(this.task[1]) ! E_PROPNF => 0')
this:do_move_players_home();
endif

move_em

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

• #71:do_move_players_home line 14: this:move_em

Source

if (caller == this)
who = args[1];
set_task_perms(who.owner);
fork (0)
start = who.location;
dest = who.programmer ? who.home | $player_start;
this:set_moveto_task();
who:moveto(dest);
suspend(1);
if (who.location != start)
if ($terrain in $object_utils:ancestors(start))
msg = this:take_away_msg(who);
for x in (start.contents)
if (start:match_loc(who, x))
x:tell(msg);
endif
endfor
else
start:announce(this:take_away_msg(who));
endif
endif
if (who.location == who.home)
who.home:announce(this:drop_off_msg(who));
endif
who.home = who.programmer ? who.home | start;
endfork
else
return E_PERM;
endif

take_away_msg drop_off_msg

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

• #71:move_em line 12: this:take_away_msg
• #71:move_em line 19: this:take_away_msg
• #71:move_em line 23: this:drop_off_msg

Source

return $string_utils:pronoun_sub(this.(verb), args[1], this);

set_moveto_task

Spec this none thisFlags rxdOwner #36Definer #71

Referenced by

• #71:move_em line 7: this:set_moveto_task

Source

"sets $housekeeper.moveto_task to the current task_id() so player:moveto's can check for validity.";
if (caller != this)
return E_PERM;
endif
this.moveto_task = task_id();

scheduled_cleanup

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

none

Source

"needs $scheduler. if an integer arg is passed, sets the wait time to that.";
if (!($perm_utils:controls(caller_perms(), this) && `toint($scheduler) ! E_PROPNF => 0'))
return E_PERM;
endif
wait = args ? args[1] | this:time();
if (this.cleaning_index < length(this.clean))
x = this.clean[this.cleaning_index];
this.cleaning_index = this.cleaning_index + 1;
`this:replace(x) ! ANY => ""';
else
this.cleaning_index = 0;
this:litterbug();
endif
this:do_move_players_home();
this.task[1] = $scheduler:schedule(wait, this, "scheduled_cleanup", {wait});

do_move_players_home

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

• #71:move_players_home line 7: this:do_move_players_home
• #71:scheduled_cleanup line 14: this:do_move_players_home

Source

if (!$perm_utils:controls(caller_perms(), this))
"perms don't control the $housekeeper; probably not called by $room:disfunc then. Used to let args[1] call this. No longer.";
return E_PERM;
endif
if ($code_utils:task_valid(this.move_player_task))
"the move-players-home task is already running";
return;
endif
fork tid (10)
while (this.player_queue)
if ((mtime = this.player_queue[1][2]) < (time() + 200))
if (is_player(who = this.player_queue[1][1]) && (!$object_utils:connected(who)))
if (`$rp_regulator.do_clean_rooms ! E_PROPNF => 0' || (who.location != who.home))
this:move_em(who);
endif
endif
this.player_queue = listdelete(this.player_queue, 1);
endif
(ticks_left() < 5000) && suspend(1);
endwhile
endfork
this.move_player_task = tid;

fix_all_exits

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

• #71:object_scrub line 16: this:fix_all_exits

Source

"USAGE: call from the $scheduler at least weekly.";
if (!caller_perms().wizard)
return E_PERM;
endif
for x in ($object_utils:descendants_suspended($exit))
if ((!x.f) && `parent(x.dest) == $garbage ! ANY => 0')
$recycler:_recycle(x);
elseif (!x.f)
(ticks_left() < 10000) && suspend(1);
alist = $list_utils:remove_duplicates({x.name, @x.aliases});
alist = this:exit_alias_builder(alist);
x.name = alist[1];
x.aliases = alist;
endif
endfor
for r in ($object_utils:descendants_suspended($veroom))
(ticks_left() < 10000) && suspend(1);
if (xl = length(r.virtual_exits))
removals = {};
for x in [1..xl]
if (`parent(r.virtual_exits[x][2]) == $garbage ! ANY => 0')
removals = {@removals, r.virtual_exits[x]};
else
r.virtual_exits[x][1] = this:exit_alias_builder(r.virtual_exits[x][1]);
endif
(ticks_left() < 10000) && suspend(1);
endfor
r.virtual_exits = $set_utils:diff(r.virtual_exits, removals);
endif
endfor

exit_alias_builder

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

• #71:fix_all_exits line 11: this:exit_alias_builder
• #71:fix_all_exits line 24: this:exit_alias_builder

Source

"USAGE: exit_alias_builder(alias list) => new alias list";
aliai = args[1];
name = $string_utils:strip_chars(aliai[1], ")>]");
alist = $string_utils:explode(name, "[");
alist = $string_utils:explode(alist[1], "(");
alist = $string_utils:explode(alist[1], "<");
blist = $string_utils:words($string_utils:subst(alist[1], {{"_", " "}}));
for i in [1..length(blist)]
blist[i] = $string_utils:capitalize(blist[i]);
endfor
name = $string_utils:from_list(blist);
if (name == "North")
aliai = setadd(aliai, "N");
elseif (name == "South")
aliai = setadd(aliai, "S");
elseif (name == "East")
aliai = setadd(aliai, "E");
elseif (name == "West")
aliai = setadd(aliai, "W");
elseif (name == "Northwest")
aliai = setadd(aliai, "NW");
elseif (name == "Northeast")
aliai = setadd(aliai, "NE");
elseif (name == "Southwest")
aliai = setadd(aliai, "SW");
elseif (name == "Southeast")
aliai = setadd(aliai, "SE");
elseif (name == "Up")
aliai = setadd(aliai, "U");
elseif (name == "Down")
aliai = setadd(aliai, "D");
elseif (name == "Exit")
aliai = setadd(aliai, "O");
aliai = setadd(aliai, "Out");
elseif (name == "Out")
aliai = setadd(aliai, "O");
aliai = setadd(aliai, "Exit");
endif
longname = ((name + " [") + $string_utils:lowercase($list_utils:shortest(aliai))) + "]";
suspend(0);
aliai[1] = $string_utils:strip_chars(longname, "_");
aliai = setadd(aliai, name);
needsfix = 0;
if ((la = length(aliai)) > 1)
for i in [2..length(aliai)]
(ticks_left() < 10000) && suspend(0);
aliai[i] = $string_utils:strip_chars(aliai[i], " _[]<>()");
if (length(aliai[i]) < 3)
(ticks_left() < 10000) && suspend(0);
aliai[i] = $string_utils:lowercase(aliai[i]);
if ((aliai[i] in {"i", "t", "g", "l"}) && (length(name) > 1))
aliai[i] = name[1..2];
needsfix = 1;
endif
if ((aliai[i] in {"th", "dr"}) && (length(name) > 2))
aliai[i] = name[1..3];
needsfix = 1;
endif
endif
(ticks_left() < 10000) && suspend(0);
endfor
endif
if (needsfix)
longname = ((name + " [") + $string_utils:lowercase($list_utils:shortest(aliai))) + "]";
aliai[1] = $string_utils:strip_chars(longname, "_");
endif
aliai = $list_utils:remove_duplicates(aliai);
return aliai;

fix_object_aliases

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

• #71:object_scrub line 14: this:fix_object_aliases

Source

"$housekeeper:fix_object_aliases -- makes sure .aliases[1] == .name";
if (!caller_perms().wizard)
return E_PERM;
else
baddies = {};
for x in [2..toint(max_object())]
(ticks_left() < 4000) && suspend(0);
if (((parent(o = toobj(x)) != $garbage) && (o != $garbage)) && `o.name != o.aliases[1] ! E_RANGE => 1')
baddies = {@baddies, tostr($string_utils:nn(o), " owned by ", $string_utils:nn(o.owner))};
o.aliases = setremove(o.aliases, o.name);
o.aliases = {o.name, @o.aliases};
endif
endfor
if (baddies)
$mail_agent:send_message(this, this.owners, "Alias fix report", {"Had a bad \".alias\" property:", @baddies});
endif
endif

object_scrub daily

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

none

Source

"-- called from $housekeeper:continuous(interval)";
"-- will run at an interval 400 x litter cleanup interval";
"-- cleans sloppy object properties around the MOO";
"-- called infrequently because of lag.";
if (!caller_perms().wizard)
return E_PERM;
elseif (!(i = `toint(args[1]) ! ANY => 0'))
return E_INVARG;
endif
this.task[2] = $scheduler:schedule(400 * i, this, "daily", {i});
for p in (connected_players())
p:notify("! -- There may be some heavy lag as the MOO checks every object for bad properties and duplicate verbs.");
endfor
`this:fix_object_aliases() ! ANY => $mail_agent:send_message(this, this.owners, "Cleanup Bug!", {"Halted at $housekeeper:fix_object_aliases()"})';
suspend(15);
`this:fix_all_exits() ! ANY => $mail_agent:send_message(this, this.owners, "Cleanup Bug!", {"Halted at $housekeeper:fix_all_exits()"})';
suspend(15);
`this:knock_em_homers() ! ANY => $mail_agent:send_message(this, this.owners, "Cleanup Bug!", {"Halted at $housekeeper:knock_em_homers()"})';
suspend(15);
`this:find_duplicate_verbs() ! ANY => $mail_agent:send_message(this, this.owners, "Cleanup Bug!", {"Halted at $housekeeper:find_duplicate_verbs()"})';
for p in (connected_players())
p:notify("! -- Cleanup complete.");
endfor

@begin

Spec this at/to anyFlags rdOwner #2Definer #71

Referenced by

none

Source

"@begin <this> at <interval>";
"start the housekeeper cleaning continuously.";
"Kill any previous continuous task. Uses $scheduler";
"and iobjstr if either are available.";
if (!player.wizard)
return E_PERM;
endif
wait = (w = toint(iobjstr)) ? w | this:time();
fork (0)
if (`$scheduler:valid_task(this.task[2]) ! ANY => 0')
taskn = this.task[2];
this.task[2] = 0;
$scheduler:kill_task(taskn);
endif
this.task[2] = $scheduler:schedule(2 * wait, this, "object_scrub", {wait});
endfork
fork (0)
if (`$scheduler:valid_task(this.task[1]) ! ANY => 0')
taskn = this.task[1];
this.task[1] = 0;
$scheduler:kill_task(taskn);
endif
this.cleaning_index = 0;
this.task[1] = $scheduler:schedule(wait, this, "scheduled_cleanup", {wait});
endfork
suspend(1);
player:tell("Location cleaning task = ", this.task[1]);
player:tell("Property cleaning task = ", this.task[2]);

find_duplicate_verbs

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

• #71:object_scrub line 20: this:find_duplicate_verbs

Source

"$housekeeper:find_duplicate_verbs -- looks for 2 verbs of the same name on same object.";
if (!caller_perms().wizard)
return E_PERM;
else
baddies = {};
for x in [0..toint(max_object())]
((ticks_left() < 6000) || (seconds_left() < 3)) && suspend(1);
voibs = verbs(o = toobj(x));
if (voibs != (clean = $list_utils:remove_duplicates(voibs)))
dubvoibs = $set_utils:difference_suspended(voibs, clean);
loc = dubvoibs[1] in voibs;
baddies = {@baddies, tostr($string_utils:nn(o), ":", dubvoibs[1], " (", loc, "),", " owned by ", $string_utils:nn(o.owner), " hint----> verb ", loc + 1, " = ", voibs[loc + 1])};
endif
endfor
if (baddies)
$mail_agent:send_message(this, this.owners, "Duplicate verb report", {"These objects have duplicate verbs:", @baddies});
endif
endif

knock_em_homers

Spec this none thisFlags rxdOwner #2Definer #71

Referenced by

• #71:object_scrub line 18: this:knock_em_homers

Source

"A daily cleanup of $homers that didn't get triggered.";
if (!caller_perms().wizard)
return E_PERM;
endif
homers = $object_utils:descendants_suspended($homer);
for homey in (homers)
if (homey.returning && (homey.location != homey.home))
`$scheduler:schedule(homey.how_long, homey, "go_home") ! ANY => "oh well"';
endif
(ticks_left() < 2000) && suspend(0);
endfor