matching utilities #51

match

Spec this none thisFlags rxdOwner #36Definer #51

Referenced by

• #51:match line 27: this:match
• #51:match line 28: this:match
• #90:whois line 52: $match_utils:match
• #91:follow line 2: $match_utils:match
• #91:g*et line 12: $match_utils:match
• #91:g*et line 17: $match_utils:match
• #91:dr*op line 10: $match_utils:match
• #91:gi*ve line 12: $match_utils:match
• #91:gi*ve line 22: $match_utils:match
• #104:l*ook line 15: $match_utils:match
• #104:l*ook line 38: $match_utils:match
• #104:valid_attack line 4: $match_utils:match
• #104:valid_attack line 5: $match_utils:match
• #104:queue_attack line 4: $match_utils:match
• #104:queue_attack line 5: $match_utils:match
• #104:advance_queue line 6: $match_utils:match
• #104:advance_queue line 7: $match_utils:match
• #104:match line 2: $match_utils:match
• #104:loot line 10: $match_utils:match

Source

":match(string, object-list)";
"Return object in 'object-list' aliased to 'string'.";
"Matches on a wide variety of syntax, including:";
" \"5th axe\" -- The fifth object matching \"axe\" in the object list.";
" \"where's sai\" -- The only object contained in 'where' matching \"sai\" (possible $ambiguous_match).";
" \"where's second staff\" -- The second object contained in 'where' matching \"staff\".";
" \"my third dagger\" -- The third object in your inventory matching \"dagger\".";
"Ordinal matches are determined according to the match's position in 'object-list' or, if a possessive (such as \"where\" above) is given, then the ordinal is the nth match in that object's inventory.";
"In the matching room (#3879@LambdaMOO), the 'object-list' consists of first the player's contents, then the room's, and finally all exits leading from the room.";
{string, olist} = args;
if (!string)
return $nothing;
elseif (string == "me")
return player;
elseif (string == "here")
return player.location;
elseif (valid(object = $string_utils:literal_object(string)))
return object;
elseif (valid(object = $string_utils:match(string, olist, "aliases")))
return object;
elseif (valid(object = $string_utils:match(string, olist, "aliases")) || ((object != $ambiguous_match) && valid(object = this:match_remembered(string, olist))))
return object;
elseif (parsed = this:parse_ordinal_reference(string))
return this:match_nth(parsed[2], olist, parsed[1]);
elseif (parsed = this:parse_possessive_reference(string))
{whostr, objstr} = parsed;
if (valid(whose = this:match(whostr, olist)))
return this:match(objstr, whose.contents);
else
return whose;
endif
else
return object;
endif

match_nth

Spec this none thisFlags rxdOwner #36Definer #51

Referenced by

• #51:match line 24: this:match_nth

Source

":match_nth(string, objlist, n)";
"Find the nth object in 'objlist' that matches 'string'.";
{what, where, n} = args;
for v in (where)
z = 0;
for q in (v.aliases)
z = z || (index(q, what) == 1);
endfor
"begin remember system code";
if (!z)
for q in (`v:short_desc_matches() ! E_VERBNF => {}')
z = z || (index(q, what) == 1);
endfor
if ((!z) && $object_utils:has_property(player, "remembered_names"))
for rmb in (player.remembered_names)
z = z || (index(rmb[2], what) == 1);
endfor
endif
endif
"end remember system code";
if (z && (!(n = n - 1)))
return v;
endif
endfor
return $failed_match;

match_verb

Spec this none thisFlags rxdOwner #2Definer #51

Referenced by

• #90:last_huh line 6: $match_utils:match_verb
• #90:last_huh line 8: $match_utils:match_verb
• #118:here_huh line 9: $match_utils:match_verb
• #118:here_huh line 13: $match_utils:match_verb
• #118:here_huh line 19: $match_utils:match_verb

Source

"$match_utils:match_verb(verbname, object) => Looks for a command-line style verb named <verbname> on <object> with current values of prepstr, dobjstr, dobj, iobjstr, and iobj.  If a match is made, the verb is called with @args[3] as arguments and 1 is returned.  Otherwise, 0 is returned.";
{vrb, what, rest} = args;
if (where = $object_utils:has_verb(what, vrb))
if ((vargs = verb_args(where[1], vrb)) != {"this", "none", "this"})
if (((((((vargs[2] == "any") || ((!prepstr) && (vargs[2] == "none"))) || index(("/" + vargs[2]) + "/", ("/" + prepstr) + "/")) && (((vargs[1] == "any") || ((!dobjstr) && (vargs[1] == "none"))) || ((dobj == what) && (vargs[1] == "this")))) && (((vargs[3] == "any") || ((!iobjstr) && (vargs[3] == "none"))) || ((iobj == what) && (vargs[3] == "this")))) && index(verb_info(where[1], vrb)[2], "x")) && verb_code(where[1], vrb))
set_task_perms(caller_perms());
what:(vrb)(@rest);
return 1;
endif
endif
endif

match_list

Spec this none thisFlags rxdOwner #36Definer #51

Referenced by

• #51:object_match_failed line 21: $match_utils:match_list
• #90:@stats line 6: $match_utils:match_list
• #118:here_huh line 16: $match_utils:match_list

Source

":match_list(string, object_list) -> List of all matches.";
{what, where} = args;
if (!what)
return {};
endif
r = {};
for v in (where)
if (!(v in r))
z = 0;
for q in (v.aliases)
z = z || (q && (index(q, what) == 1));
endfor
if (z)
r = listappend(r, v);
endif
endif
endfor
return r;

parse_ordinal_reference parse_ordref

Spec this none thisFlags rxdOwner #36Definer #51

Referenced by

• #51:match line 23: this:parse_ordinal_reference

Source

":parse_ordref(string)";
"Parses strings referring to an 'nth' object.";
"=> {INT n, STR object} Where 'n' is the number the ordinal represents, and 'object' is the rest of the string.";
"=> 0 If the given string is not an ordinal reference.";
"  Example:";
":parse_ordref(\"second broadsword\") => {2, \"broadsword\"}";
":parse_ordref(\"second\") => 0";
"  Note that there must be more to the string than the ordinal alone.";
if (m = match(args[1], ("^" + this.ordinal_regexp) + " +%([^ ].+%)$"))
o = substitute("%1", m);
n = (o in this.ordn) || (o in this.ordw);
return n && {n, substitute("%2", m)};
else
return 0;
endif

parse_possessive_reference

Spec this none thisFlags rxdOwner #36Definer #51

Referenced by

• #51:match line 25: this:parse_possessive_reference

Source

":parse_possessive_reference(string)";
"Parses strings in a possessive format.";
"=> {STR whose, STR object}  Where 'whose' is the possessor of 'object'.";
"If the string consists only of a possessive string (ie: \"my\", or \"yduJ's\"), then 'object' will be an empty string.";
"=> 0 If the given string is not a possessive reference.";
"  Example:";
":parse_possessive_reference(\"joe's cat\") => {\"joe\", \"cat\"}";
":parse_possessive_reference(\"sis' fish\") => {\"sis\", \"fish\"}";
"  Strings are returned as a value suitable for a :match routine, thus 'my' becoming 'me'.";
":parse_possessive_reference(\"my dog\") => {\"me\", \"dog\"}";
string = args[1];
if (m = match(string, "^my$%|^my +%(.+%)?"))
return {"me", substitute("%1", m)};
elseif (m = match(string, "^%(.+s?%)'s? *%(.+%)?"))
return {substitute("%1", m), substitute("%2", m)};
else
return 0;
endif

object_match_failed

Spec this none thisFlags rxOwner #36Definer #51

Referenced by

none

Source

"Usage: object_match_failed(object, string[, ambigs])";
"Prints a message if string does not match object.  Generally used after object is derived from a :match_object(string).";
"ambigs is an optional list of the objects that were matched upon.  If given, the message printed will list the ambiguous among them as choices.";
{match_result, string, ?ambigs = 0} = args;
tell = (0 && $perm_utils:controls(caller_perms(), player)) ? "notify" | "tell";
if ((index(string, "#") == 1) && ($code_utils:toobj(string) != E_TYPE))
"...avoid the `I don't know which `#-2' you mean' message...";
if (!valid(match_result))
player:(tell)(tostr("There is no \"", string, "\" that you can see."));
endif
return !valid(match_result);
elseif (match_result == $nothing)
player:(tell)("You must give the name of some object.");
elseif (match_result == $failed_match)
player:(tell)(tostr("There is no \"", string, "\" that you can see."));
elseif (match_result == $ambiguous_match)
if (typeof(ambigs) != LIST)
player:(tell)(tostr("I don't know which \"", string, "\" you mean."));
return 1;
endif
ambigs = $match_utils:match_list(string, ambigs);
ambigs = $list_utils:map_property(ambigs, "name");
if ((length($list_utils:remove_duplicates(ambigs)) == 1) && $object_utils:isa(player.location, this.matching_room))
player:(tell)(tostr("I don't know which \"", string, "\" you mean.  Try using \"first ", string, "\", \"second ", string, "\", etc."));
else
player:(tell)(tostr("I don't know which \"", string, "\" you mean: ", $string_utils:english_list(ambigs, "nothing", " or "), "."));
endif
return 1;
elseif (!valid(match_result))
player:(tell)(tostr("The object you specified does not exist.  Seeing ghosts?"));
else
return 0;
endif
return 1;

init_for_core

Spec this none thisFlags rxdOwner #2Definer #51

Referenced by

none

Source

if (caller_perms().wizard)
pass();
this.matching_room = $nothing;
endif

match_remembered

Spec this none thisFlags rxdOwner #36Definer #51

Referenced by

• #51:match line 21: this:match_remembered

Source

":match_remembered(string, object-list)";
"Return object in 'object-list' aliased to 'string'.";
"Matches on player.remembered_names and object.";
"Used by $match_utils:match.";
"Always call $match_utils:match instead of this verb, as it is more thorough.";
string = args[1];
olist = args[2];
if (!string)
return $nothing;
endif
matches = {};
for object in (olist)
if (string in `object:short_desc_matches() ! E_VERBNF => {}')
matches = setadd(matches, object);
endif
endfor
if (length(matches) == 2)
matches = setremove(matches, player);
endif
if (length(matches) > 1)
return $ambiguous_match;
elseif (matches)
return matches[1];
endif
object = $failed_match;
if (`!(!property_info(player, "remembered_names")) ! E_PROPNF => 0')
for rmbrd in (player.remembered_names)
if ((string == rmbrd[2]) && (rmbrd[1] in olist))
matches = {@matches, rmbrd[1]};
endif
endfor
if (length(matches) > 1)
return $ambiguous_match;
elseif (matches)
object = matches[1];
endif
endif
return object;