Generic Puppet #7680

com*mand

Spec this to anyFlags rxdOwner #78Definer #7680

Referenced by

none

Source

"command <puppet> to <cmdline>";
"Command the puppet to `do' the given command line, processing it as if it were a command issued by a player.";
"who = (callers() && (caller != this)) ? caller_perms() | player;";
who = callers() ? caller_perms() | player;
set_task_perms(who);
if (this:command_ok(who))
  text = substitute("%1", $sysobj:match(argstr, ("%<" + prepstr) + "%> *%(.+%)$"));
  if (text)
    who:tell("You transmit the command \"", text, "\" to ", this.name, ".");
    this:do(text);
  else
    who:tell("Transmit what to ", this.name, "?");
  endif
else
  who:tell($string_utils:pronoun_sub("%n %<ignores> your command.", this));
  return E_PERM;
endif

mon*itor

Spec this none noneFlags rxdDefiner #7680

Referenced by

none

Source

"mon*itor <puppet>";
"Have everything heard by the puppet relayed back to you.";
who = (callers() && (caller != this)) ? caller_perms() | player;
if (this:monitor_ok(who))
  this:add_monitor(who);
  this:tell(who.name, " starts monitoring.");
else
  who:tell($string_utils:pronoun_sub("%n %<doesn't> want you monitoring %o.", this));
  this:tell($string_utils:nn(who), " is refused permission to monitor.");
  return E_PERM;
endif

ign*ore

Spec this none noneFlags rxdDefiner #7680

Referenced by

none

Source

"ignore <puppet>";
"Stop monitoring the puppet.";
who = (callers() && (caller != this)) ? caller_perms() | player;
if (who in this.tell_forward)
  this:tell(who.name, " stops monitoring.");
  this:remove_monitor(who);
else
  who:tell("You aren't listening to ", this.name, ".");
endif

tell

Spec this none thisDefiner #7680

Referenced by

• #7680:mon*itor line 6: this:tell
• #7680:mon*itor line 9: this:tell
• #7680:ign*ore line 5: this:tell
• #7680:wh*isper line 1: this:tell
• #7680:i line 20: this:tell
• #7680:do line 39: this:tell

Source

pass(@args);
this:tell2(@args);

moveto

Spec this none thisDefiner #7680

Referenced by

• #259:moveto line 7: pass(

Source

"Do a fake :look_self check with the puppet as `player'.";
{dest} = args;
old = this.location;
if ((this == $local.puppet) && ((old == this.home) || (dest != this.home)))
  return E_PERM;
endif
pass(dest);
where = this.location;
if ((this.tell_forward && (where != old)) && valid(where))
  this:call_as_puppet(where, "look_self", {this.brief});
endif
"Quinn 09-DEC-93 0223: Added call_as_puppet line to prevent weird spoofs.";
"THX (#105941) - Thu Dec 14, 2000 - Put in a check for $local.puppet so it doesn't get moved willy-nilly.";

wh*isper

Spec any to thisFlags rxdDefiner #7680

Referenced by

none

Source

this:tell(player.name, " whispers, \"", dobjstr, "\"");
player:tell("You whisper, \"", dobjstr, "\" to ", this.name, ".");

acceptable

Spec this none thisDefiner #7680

Referenced by

none

Source

{what} = args;
return !is_player(what);

look_self

Spec this none thisDefiner #7680

Referenced by

• #259:look_self line 1: pass(

Source

pass(@args);
if (this.simulating)
  if ((time = this:idle_time()) == 999999999)
    player:tell($string_utils:pronoun_sub("%S %<is> sleeping.", this));
  elseif (time < 120)
    player:tell($string_utils:pronoun_sub("%S %<is> awake and %<looks> alert.", this));
  else
    time = $string_utils:from_seconds(time);
    player:tell($string_utils:pronoun_sub(("%S %<is> awake, but %<has> been %<staring off into space> for " + time) + ".", this));
  endif
  if (this.contents)
    player:tell("Carrying:");
    for thing in (this.contents)
      player:tell("  ", thing:title());
    endfor
  endif
endif

sweep_msg

Spec this none thisDefiner #7680

Referenced by

none

Source

if (y = setremove(this.tell_forward, player))
  return "is listening for " + $string_utils:nn_list(y);
endif

monitor_ok command_ok

Spec this none thisDefiner #7680

Referenced by

• #259:hidden_verbs line 16: this:command_ok
• #259:hidden_verbs line 19: this:monitor_ok
• #7680:com*mand line 6: this:command_ok
• #7680:mon*itor line 4: this:monitor_ok
• #7680:do line 1: this:command_ok

Source

{who} = args;
return who in {this.owner, $code_utils:verb_loc().owner, @this.(verb)};

idle_time

Spec this none thisDefiner #7680

Referenced by

• #7680:look_self line 3: this:idle_time

Source

time = 999999999;
for who in (setadd((typeof(y = this.command_ok) == LIST) ? y | {}, this.owner))
  if (((who in connected_players()) && ((who in this.tell_forward) || (who.location == this.location))) && (time > (y = idle_seconds(who))))
    time = y;
  endif
endfor
return time;

seek

Spec any none noneFlags rxdDefiner #7680

Referenced by

none

Source

return this.feature_pc:(verb)(@args);

tell2

Spec this none thisFlags rxOwner #49853Definer #7680

Referenced by

• #7680:tell line 2: this:tell2

Source

if (typeof(set_task_perms(this.owner)) == ERR)
  return E_PERM;
endif
for q in (this.tell_forward)
  q:tell($string_utils:pronoun_sub(this.echo_prefix_msg, this), @args);
endfor
text = tostr(@args);
for q in (this.listen_actions)
  if (y = $string_utils:match_string(text, q[1]))
    fork (0)
      comm = q[2][random(length(q[2]))];
      if (typeof(y) == LIST)
        for w in (y)
          comm = strsub(comm, "%" + tostr(w in y), w);
        endfor
      endif
      this:do(comm, @q[3..length(q)]);
      return;
    endfork
  endif
endfor

is_listening

Spec this none thisFlags rxdOwner #49853Definer #7680

Referenced by

none

Source

for x in (this.tell_forward)
  if (x:is_listening())
    return 1;
  endif
endfor
return 0;

linelen

Spec this none thisDefiner #7680

Referenced by

none

Source

"Copied from generic player (#6):linelen by Hacker (#18105) Fri Oct 30 15:50:47 1992 PST";
return abs(this.linelen);

i inv*entory

Spec none none noneFlags rxdDefiner #7680

Referenced by

none

Source

"originally from $player:inv";
if (this.contents)
  c = this.contents;
  longear = {};
  gear = {};
  width = player:linelen();
  half = width / 2;
  player:tell("Carrying:");
  for thing in (c)
    cx = tostr(" ", thing:title());
    if (length(cx) > half)
      longear = {@longear, cx};
    else
      gear = {@gear, cx};
    endif
  endfor
  this:tell_lines($string_utils:columnize(gear, 2, width));
  this:tell_lines(longear);
else
  this:tell("You are empty-handed.");
endif

parse_command

Spec this none thisDefiner #7680

Referenced by

• #7680:do line 9: this:parse_command

Source

":parse_command(cmdline-string) Pass to $string_utils by default.";
$local.rpg:s_i_n(0);
return $string_utils:parse_command(@args);
"THX (#105941) - Wed Dec 20, 2000 - Stuffed a suspend check in 'ere.";

call_as_puppet

Spec this none thisFlags rxdOwner #2487Definer #7680

Referenced by

• #7680:moveto line 10: this:call_as_puppet
• #7680:do line 19: this:call_as_puppet
• #7680:do line 22: this:call_as_puppet
• #7680:do line 25: this:call_as_puppet
• #7680:do line 28: this:call_as_puppet
• #7680:do line 35: this:call_as_puppet

Source

"-- WIZARDLY --";
":call_as_puppet(object, verbname, args)";
"Calls the given verb, after setting 'player' to this 'puppet'.";
if ((caller == this) || $perm_utils:controls(caller_perms(), this))
  actual = player;
  player = this;
  result = this:call(this, @args);
  player = actual;
  return result;
else
  return E_PERM;
endif

add_monitor

Spec this none thisDefiner #7680

Referenced by

• #7680:mon*itor line 5: this:add_monitor

Source

":add_monitor(who)";
if ((caller == this) || $perm_utils:controls(caller_perms(), this))
  {who} = args;
  if (who != this)
    return this.tell_forward = setadd(this.tell_forward, who);
  endif
else
  return E_PERM;
endif

remove_monitor

Spec this none thisDefiner #7680

Referenced by

• #7680:ign*ore line 6: this:remove_monitor

Source

":remove_monitor(who)";
if ((caller == this) || $perm_utils:controls(caller_perms(), this))
  {who} = args;
  return this.tell_forward = setremove(this.tell_forward, who);
else
  return E_PERM;
endif

my_match_object

Spec this none thisDefiner #7680

Referenced by

none

Source

"Copied from generic player (#6):my_match_object by ur-Rog (#6349) Mon May  5 16:29:14 1997 PDT";
":my_match_object(string [,location])";
return $string_utils:match_object(@{@args, this.location}[1..2], this);

my_match_recipient

Spec this none thisDefiner #7680

Referenced by

none

Source

return $failed_match;

do

Spec this none thisFlags rxdOwner #49853Definer #7680

Referenced by

• #259:do_follow line 5: this:do
• #259:choose_weaponry line 24: this:do
• #259:choose_weaponry line 27: this:do
• #7680:com*mand line 10: this:do
• #7680:tell2 line 17: this:do

Source

if (this:command_ok(cp = caller_perms()) || (caller == this))
  who = cp.wizard ? player | cp;
  {text, @now} = args;
  brev = {"\"", ":", ";", "?"};
  rep = {"say ", "emote ", "eval", "help"};
  if (indx = `text[1] ! E_RANGE => " "' in brev)
    text = rep[indx] + text[2..$];
  endif
  if ((y = this:parse_command(text, this)) && valid(this.location))
    player = this;
    {verb, d, p, i, a, s} = y;
    {dobj, dobjstr} = d;
    {prep, prepstr} = p;
    {iobj, iobjstr} = i;
    {args, argstr} = a;
    verbargs = {s, {dobj, prep, iobj}};
    if (this:find_verb(player, verb, @verbargs))
      "this:call(who, player, verb, args, @now);";
      this:call_as_puppet(player, verb, args, @now);
    elseif (this:find_verb(player.location, verb, @verbargs))
      "this:call(who, player.location, verb, args, @now);";
      this:call_as_puppet(player.location, verb, args, @now);
    elseif (this:find_verb(dobj, verb, @verbargs))
      "this:call(who, dobj, verb, args, @now);";
      this:call_as_puppet(dobj, verb, args, @now);
    elseif (this:find_verb(iobj, verb, @verbargs))
      "this:call(who, iobj, verb, args, @now);";
      this:call_as_puppet(iobj, verb, args, @now);
    else
      "Comment out for now; should replace with correct huh sequence.";
      "this:call_as_puppet(who, player.location, \"huh2\", {verb, args}, @now)";
      "... Rog suggests:";
      "this:call(who, $command_utils, \"do_huh\", {verb, args}, @now);";
      "Recent change as per 6178-6182 on *wiz Ho_Yan 8/23/99. And above lines too.";
      this:call_as_puppet($command_utils, "do_huh", {verb, args}, @now);
    endif
  else
    "1/15/96, Heathcliff";
    this:tell("I don't understand that.");
  endif
else
  return E_PERM;
endif
"Mooshie (#106469) - Sat Dec 27, 1997 - Sped up, 1.8.0 conventions, etc.";

find_verb

Spec this none thisDefiner #7680

Referenced by

• #7680:do line 17: this:find_verb
• #7680:do line 20: this:find_verb
• #7680:do line 23: this:find_verb
• #7680:do line 26: this:find_verb

Source

{where, vrb, match, split, @rest} = args;
if (valid(where) && (def = $object_utils:has_verb(where, vrb)))
  {def} = def;
  if (`{first, second, third} = `verb_args(def, vrb) ! E_PERM' ! E_TYPE' in {{"this", "none", "this"}, E_TYPE})
    return 0;
    "make sure to exclude this none this verbs";
  endif
  {ds, ps, is} = match;
  {do, pn, io} = split;
  {owner, perms, name} = verb_info(def, vrb);
  return index(perms, "x") && (((((first == "this") && (where == do)) || (first in ds)) || (second in ps)) && (((third == "this") && (where == io)) || (third in is)));
endif
return 0;
"Mooshie (#106469) - Wed Jan 21, 1998 - Complete overhaul. That was a bit too much indexing for my liking.";
"Profane (#30788) - Fri Oct 19, 2001 - Trap for !r verbs";

initialize

Spec this none thisFlags rxdOwner #49853Definer #7680

Referenced by

• #259:initialize line 13: pass(

Source

if ((caller == this) || $perm_utils:controls(caller_perms(), this))
  "Grump 6/22/93: took out #24222.puppets initialization -- what was it here for?";
  this.home = this.owner.home;
  this.debug = 0;
  this.command_ok = {};
  this.listen_actions = {};
  this.monitor_ok = {};
  this.tell_forward = {};
  pass(@args);
else
  return E_PERM;
endif
"Mooshie (#106469) - Thu Jan 22, 1998 - Updated the security a bit and moved the pass() call *inside* the security, where we want it.";

call

Spec this none thisFlags rxdOwner #49853Definer #7680

Referenced by

• #7680:call_as_puppet line 7: this:call

Source

if (caller_perms().wizard)
  {who, what, vrb, pass, @rest} = args;
  set_task_perms(who.wizard ? $no_one | who);
  return what:(vrb)(@pass);
else
  return E_PERM;
endif
"Mooshie (#106469) - Thu Jan 22, 1998 - New version.";

is_home

Spec this none thisDefiner #7680

Referenced by

none

Source

":is_home() => 1 or 0";
{home, loc} = {this.home, this.location};
home = (typeof(home) == OBJ) ? home | loc;
if ((loc == home) || (loc == `home.dest ! E_PROPNF, E_INVIND => loc'))
  return 1;
endif
return 0;

enterfunc exitfunc

Spec this none thisDefiner #7680

Referenced by

none

Source

return 1;