generic voodoo doll #74

get

Spec this none noneFlags rxdDefiner #74

Referenced by

none

Source

player:tell("As you approach the voodoo doll, a little hooded man shouts at you to leave it alone and starts beating you with a cane stick until you do.");

attack

Spec this none thisDefiner #74

Referenced by

• #74:attack line 84: this:attack
• #74:hit_aggressor line 38: this:attack
• #74:attack(old) line 95: this:attack

Source

":attack(OBJ target, LIST weapons[, NUM modifier, OBJ area, NUM no_invite])";
{target, weapons, ?bmods = 0, ?barea = 0, ?no_invite = 0} = args;
(rpg = $local.rpg):secure();
location = (by = this.character).location;
doll = rpg:get_doll(target);
if (!this:legal_target(target, doll, caller))
  return;
elseif (typeof(weapons) == LIST)
  weapon = weapons[1];
else
  weapon = weapons;
  weapons = {weapons};
endif
barea = (typeof(barea) == OBJ) ? barea | doll:random_hit_location();
if (typeof(effect = this:combat_effects(target, weapon)) != NUM)
  return effect;
endif
bmods = (bmods + effect) - this:encumbrance();
try
  if ((!valid(weapon)) || (typeof(use = weapon:used(by, target)) != NUM))
    "If :used returns a non-numeric value, the weapon is unusable.";
    return;
  elseif (weapon.owner in rpg.gms)
  elseif (weapon.owner in rpg.ex_gms)
    "Give a break until we can get it @disowned.";
  elseif (`verb_info(weapon, "0") ! E_VERBNF')
    "OK, only penalize them if it has verbs defined..";
    rpg:playertell(by, "You feel foolish!");
    this.int = max(this.int - 1, 1);
    this.pot = 0;
    return;
  endif
except (E_TYPE)
  raise(E_TYPE, ((("Error: " + by.name) + " is passing invalid weapons list (") + $string_utils:from_list(weapons, ", ")) + ")");
except (E_VERBNF)
  raise(E_VERBNF, ("Error:  \"Weapon\" " + tostr(weapon)) + " does not define a :used verb.");
endtry
this:do_attack_notification(target, weapon);
is_player(target) || target:set_last_attacker(by);
weapon:announce_swing(by, target);
weapon:track_usage(1);
weap_dam = weapon:dam(by, target);
attack_bonus = weapon:attack(by, target);
mods = (bmods + use) - (length(weapons) * 10);
str_bonus = (weapon:max_str_bonus(by, target) * this.str) / 25;
squeeze = `max(0, weapon:length(by, target) - location.space) ! ANY => 0';
mods = mods - (3 * squeeze);
damage = ((2 * weap_dam) + str_bonus) - squeeze;
if (((squeeze > 3) && is_player(by)) && (random(25) == 1))
  rpg:playertell(by, "The room is a little small to ", weapon.swing, " your ", weapon.name, " properly.");
endif
"Damage will never be greater than 3 * base.";
"damage = min(damage, 3 * weap_dam)";
"'y' is encumbrance penalty of the weapon.  Wielding a heavy weapon with more than one hand reduces the total penalty.";
"A weak person wielding a heavy weapon will be greatly penalized.";
y = str_bonus - ((3 * (weap_enc = weapon:attack_encumbrance(this))) / (1 + weapon:hands(by, target)));
"y = str_bonus - 3 * (weap_enc = weapon:encumbrance(this)) / 5 / (1 + weapon:hands(by, target));";
if (y < 0)
  mods = mods + (5 * y);
  damage = damage + (y / 2);
endif
foes = 0;
for foe in (this.aggressor)
  if (foe.location == location)
    foes = foes + 1;
  endif
endfor
mods = mods - (max(0, foes - 1) * 15);
connects = ((qual = weapon:skill(by, target):resolve(by, mods)) + attack_bonus) > -25;
if (connects)
  doll:respond(by, qual, damage, weapon, barea);
  this.connect_effects && this:connect_effects(by, target, barea, weapon, qual, 0, 99, 0);
elseif (!weapon:critical_miss(by, target, qual))
  "No critical miss.";
  weapon:announce_miss(by, target, qual);
endif
this:check_fatigue(weap_enc);
weapons = listdelete(weapons, 1);
"If we attack and die for some reason during the attack, no invitation will take place.  Everybody stands around shocked.  If the target dies, everything is fine.";
if ((by in rpg.pcs) && (is_player(by) || by.alive))
  this.aggressor = setadd(this.aggressor, target);
  if (weapons)
    this.act = this.act - max(1, weapon:slowness(by, target));
    this:attack(target, weapons, bmods - 10, barea, 1);
  endif
  if (valid(doll) && (parent(doll) != $garbage))
    doll.aggressor = setadd(doll.aggressor, by);
  endif
  no_invite || this:invite(this.slowness, {1, by, target, weapon});
endif
"Quinn 05-JAN-93: Use verbs for referencing weapon properties.";
"Quinn 28-FEB-93: Won't fork notification if a fork is already pending.";
"Quinn 11-AUG-93: Big re-write.  Created :legal_target and :do_attack_notifica ion to do the mundane chore of checking and notifying targets; cut down the unwieldly verb size; added some minor comments.";
"Quinn 11-AUG-93: Send weapon to :respond.";
"Quinn 22-OCT-93: Added combat_effect.";
"Quinn 19-NOV-93: Added body area support, :critical_miss.  New args to :Respond.";
"Ogwul 01-JAN-94: Allowed :attack to be called without adding the target to the aggressor list and without :invite via the no_invite parameter.";
"Profane 29-DEC-95 1451EST -- Added windwall check thing.";
"Irin Sun Nov  3 10:49:52 1996 PST -- Bwahaha, attack penalty if fighting more than one foe.";
"Irin Thursday, January 30 -- Rewrite of the :invite section to correspond to changes.  Don't use rpg:trusted.";
"Profane 31-MAR-97 1341PST -- s/valid/$recycler:valid/85";
"Profane 15-APR-97 1518PST -- TRY statement for weapon:used";
"THX 18-May-1997  -- Fixed so that foe.location checks against by.location rather than this.location (one's doll is never in the same place as one's attackers).  Added a weeny fatigue check after the (connects) conditional.";
"Profane 3-OCT-97 -- added check for non-gm owned weapons.";
"THX (#105941) - Wed Apr  8, 1998 - Removed this.paralyzed and entangled checks.  this:legal_target now does the checks via this:cannot_move().  subst this.character -> by from line 4 onwards and changed the \"I'm still alive.\" check before the invite call since critters always return a valid doll.";
"Profane (#30788) - Sun May  2, 1999 - add inelegant backfire check circa 90-92";
"Profane (#30788) - Sun May 23, 1999 - windwall moved off into armour_effect";
"THX (#105941) - Mon Feb  5, 2001 - Added a usage tracker call (argument == 1) for swings/attacks.";
"Hydros (#106189) - Sat Jul 23, 2005 - Removed the `2 *' from line 48. Did you know that damage is (was) doubled THREE TIMES in combat code?";
"Hydros (#106189) - Fri Jul 29, 2005 - Change of plans.  The system is built around this equation, so we're changing armour to be more effective instead.";
"dalton (#116601) - Fri Oct  7, 2005 - Modified lines 44 & 69 to reduce effect of weapon's attack stat.";

invite

Spec this none thisDefiner #74

Referenced by

• #74:attack line 89: this:invite
• #74:attack(old) line 101: this:invite

Source

":invite(NUM slowness[LIST {NUM respond, OBJ attacker, OBJ target, OBJ weapon} which hasn't been used in a long time.]) => All dolls in this doll's character's location, + the target of the attack (wherever they are) get a chance to act.";
{slow, @extra} = args;
(rpg = $local.rpg):secure();
if (!valid(where = (by = this.character).location))
  return this.act = 0;
endif
"If invite has already been called, we just decrement .act and return.  The first call to invite will take it from there.  This saves repeating many tasks for each separate invite.";
{rpgdoll, idle_threshold} = {rpg.doll, rpg.idle_threshold};
for c in (callers())
  {thing, verbname, progger, verbloc, typist} = c;
  if ((verbname == "invite") && (verbloc == rpgdoll))
    this.act = this.act - slow;
    return;
  endif
endfor
"Hey, we're actually going to try to use those extra args";
{?respond = 1, ?attacker = this, ?target = $nothing, ?weapon = $nothing} = `extra[1] ! E_RANGE => extra';
dolls = rpg:find_chars(where)[2];
"In case target is in a different room from the attacker.  This could conceivably allow the target free attacks if they're involved in melee, but hopefully getting shot at will negate the advantage here.";
if (valid(target) && valid(d = rpg:get_doll(target)))
  dolls = setadd(dolls, d);
endif
"Check schedules, and increment .act.  Dolls that had left over act will get a bit of a bonus, dolls that were in the negative will lose some of that.";
for doll in (dolls)
  try
    if ((is_player(char = doll.character) && (`idle_seconds(char) ! ANY => 181' > idle_threshold)) || `char.location.peaceful ! ANY => 0')
      doll.aggressor = {};
      dolls = setremove(dolls, doll);
    else
      doll.act = ((doll.act / 2) + 60) - ((char == attacker) ? doll.slowness | 0);
      (random(9) < 9) && doll:check_schedule();
    endif
  except (E_PROPNF, E_INVIND)
    dolls = setremove(dolls, doll);
  endtry
endfor
this.act = this.act - slow;
if ((!respond) || (length(dolls) <= 1))
  return;
endif
acts = short_of_time = 0;
"Find the doll with the highest .act.  Decrement the .act.  call eir :act verb.  Repeat until we run out of time, or all have acts of less than 0.  If we run out of time, before at least 3 have acted, suspend, instead of quitting.";
loops = 1;
while (dolls && ((!short_of_time) || (acts < 3)))
  max = -1;
  fast_dolls = {};
  for doll in (dolls)
    if (`doll.aggressor ! ANY => {}')
      "Took out the 2 * doll.slowness for testing purposes ... put the 2 * back in if you like. - THX";
      doll_act = doll.act = doll.act - (loops * doll.slowness);
      if (doll_act >= 0)
        if (doll_act > max)
          fast_dolls = {doll};
          max = doll_act;
        elseif (doll_act == max)
          fast_dolls = setadd(fast_dolls, doll);
        endif
      else
        dolls = setremove(dolls, doll);
      endif
    else
      dolls = setremove(dolls, doll);
    endif
  endfor
  for doll in (fast_dolls)
    if (`doll.character ! ANY' == 0)
      return 0;
    elseif (`doll.character.location.peaceful ! ANY => 0')
    else
      try
        doll.act = doll.act - (loops * doll.slowness);
        doll:act();
        acts = acts + 1;
      except e (ANY)
        return 0;
      endtry
    endif
  endfor
  if ((short_of_time = (ticks_left() < 8000) || (seconds_left() < 2)) && (acts < 3))
    rpg:s_i_n();
  endif
  "loops = loops + 0.1;";
endwhile
return 0;
"Irin Thursday, Jan 30, 1997 -- complete rewrite and redesign.  I think this is vaguely what it was supposed to do, before it got broken.";
"Probably not the same implementation though.  Now, the acting doll calls it's :invite(), rather than inviting the target.";
"Profane 2-MAY-97 1539PDT -- $recycler:valid check  line 54";
"Profane 7-MAY-97 1714PDT -- removed valid check, fixed scattering of extra, s/target/d/21";
"THX - 7-May-1997 -- De-ticked.  Gave :invite() a way out if there is only one doll going into the while loop.  Set idle check to idle_threshold.  Stopped doing doll:schedule calls on idle/disconnected players.  Removed dolls with no aggressors from the big while-loop ... it's up to hit aggressor to tell the damn doll that it's under attack.  Made the first for-loop in the while-loop a little smarter thus reducing the number of iterations of the second for-loop.   Seems to be working fine now.";
"Profane 10-JUN-97 1855PDT -- Try statement in schedule checking loop, line 24-34";
"THX 17-Jul-1997  -- Put error-catching in doll.aggressor to catch recycled dolls without TBing.  Not that it would happen alot, but it'll save G_M from having to look for an error (only happens with gursts).";
"THX (#105941) - Wed Nov  8, 2000 - Check for char.location.peaceful right in the loop that accumulates the dolls that matter _and_ just before the doll:act() is called in case the beggar has moved.";
"Hannibal (#104762) - Tue July 31, 2001 - Make sure doll is valid before setting act, summonables hit this.";
"Profane (#30788) - Wed Aug  1, 2001 - Refactor act reduction within one round. Now more loops reduce act more. effect: tone down haste.";

hit_aggressor

Spec this none thisDefiner #74

Referenced by

• #74:act line 8: this:hit_aggressor
• #74:act line 11: this:hit_aggressor
• #74:act(old) line 8: this:hit_aggressor
• #74:act(old) line 11: this:hit_aggressor

Source

rpg = $local.rpg;
if (rpg.rpg_options:get(this.rpg_options, "defend"))
  this.act = this.act - 1;
elseif (this.aggressor = setremove(this.aggressor, me = this.character))
  rpg:secure();
  here = me.location;
  if (0)
    this:arm();
    return $failed_match;
  else
    try
      weapon = (random(2) == 1) ? this:wielding()[1] | $list_utils:random_element(this:wielding());
    except (E_RANGE)
      this:arm();
      return $failed_match;
    endtry
    if ((weapon.contents && rpg.object_db:is_missile_weapon(weapon)) && (random(100) <= weapon:speed()))
      weapon = weapon.contents[1];
    endif
  endif
  if ((missile = rpg.object_db:is_missile_ammo(weapon)) && rpg:trusted_verb(here, "Missile_dests"))
    locs = here:missile_dests(me);
  else
    locs = {here};
  endif
  while (this.aggressor)
    targ = (is_player(me) || (!$recycler:valid(me))) ? $nothing | me:pick_aggressor();
    if (!valid(targ))
      targ = this.aggressor[random($)];
    endif
    "if (`targ.location.peaceful ! ANY => 0')";
    "  this.aggressor = setremove(this.aggressor, targ);";
    if ((targ.location in locs) && ((`idle_seconds(targ) ! ANY => 181' < rpg.idle_threshold) || ((!is_player(targ)) && targ.alive)))
      "if ((targ.location in locs) && (((!is_player(targ)) && targ.alive) || ((targ in connected_players()) && (`idle_seconds(targ) ! ANY => 181' < rpg.idle_threshold))))";
      if (missile)
        weapon:deliver_payload(this, targ, weapon, 0, 0, 1);
      elseif (weapon.owner in rpg.gms)
        this:attack(targ, weapon);
      else
        this.wielding = setremove(this.wielding, weapon);
      endif
      return targ;
    else
      this.aggressor = setremove(this.aggressor, targ);
    endif
  endwhile
endif
return $nothing;
"THX (#105941) - Thu Jul 29, 1999 - Changed missiles to call :deliver_payload() instead of this:attack() directly.";
"THX (#105941) - Fri Feb 16, 2001 - Stuffed in an explicit .peaceful check and streamlined the valid target check.";
"THX (#105941) - Wed Mar 21, 2001 - Decrement doll.act for those who are +defend.   Otherwise they grab the invite loop and hold it all to themselves.";
"Mooshie (#106469) - Sun Mar  3, 2002 - Commented out the explicit .peaceful check. The room's :combat_effect should handle this (to deliver messages, if needed, for example). A peaceful room-flag will be forthcoming to make this more generic.";

respond

Spec this none thisDefiner #74

Referenced by

none

Source

":respond(attacker, quality, damage, weapon, loc)";
"attacker -> character initiating the attack";
"quality  -> quality of the attack (final hit roll)";
"damage   -> damage to be applied";
"weapon   -> weapon used to attack";
"loc      -> body area object of hit location";
{by, qual, dam, weapon, loc} = args;
(rpg = $local.rpg):secure();
if (typeof(weapon) != OBJ)
  return this:respond_passed_numbers(by, qual, dam, weapon, loc);
endif
if (!this.armour_effects)
elseif (typeof(effect = this:armour_effects(by, qual, dam, weapon, loc)) == NUM)
  qual = qual - effect;
else
  return effect;
endif
me = this.character;
if (this:cannot_defend())
  return this:receive_damage(dam * (1 + random(3)), max(1, weapon:pen(by, me)), qual, loc, by, weapon);
endif
locstr = loc:title(me);
penalty = -((max(0, length(this.aggressor) - 1) * 20) + this:encumbrance());
parryable = weapon:parryable(by, me) + loc:parry_mod(me, by, weapon);
space = `by.location.space ! ANY';
gms = rpg.gms;
for thing in (this:wielding())
  try
    if (valid(thing))
      if (thing.owner in gms)
        if ((typeof(u = thing:used(me, by)) == NUM) && (this.act > -11))
          mods = ((thing:parry(by, me, weapon) - qual) + parryable) + penalty;
          length = thing:length(me, by);
          mods = mods - `max(3 * space, 0) ! ANY => 0';
          mods = mods + 10;
          if ((best = thing:skill(me, by):resolve(me, mods + u)) > 0)
            this.act = this.act - max(1, (length + thing:slowness(me, by)) / 12);
            thing:announce_parry(by, me, locstr, weapon, qual, best);
            this:check_fatigue(thing:encumbrance());
            weapon:notify_parry(by, me, locstr, thing, qual, best);
            weapon:track_usage(2);
            this.connect_effects && this:connect_effects(by, me, loc, weapon, qual, 0, 99, 1);
            (bydoll = rpg:get_doll(by)).connect_effects && bydoll:connect_effects(me, by, loc, thing, best, 0, 99, 1);
            return;
          endif
        endif
      elseif (thing.owner in rpg.ex_gms)
      else
        rpg:playertell(me, "You feel strangely weaker!");
        this.end = max(this.end - 1, 1);
        this.pot = 0;
        return;
      endif
    else
      this.wielding = setremove(this.wielding, thing);
      return;
    endif
  except (E_VERBNF)
    "It's some non-weapon that's gotten in there somehow.";
    this.wielding = setremove(this.wielding, thing);
  endtry
endfor
dodgable = weapon:dodgable(by, me);
mods = ((((this:hands_free() ? 25 | 0) + dodgable) + penalty) - qual) - `max(0, 50 - space) ! ANY => 0';
mods = mods + 10;
if (rpg.skills.dodge:resolve(me, mods) > 0)
  weapon:track_usage(3);
  this.act = this.act - 1;
  return weapon:announce_dodge(by, me, locstr);
endif
this:receive_damage(dam * (1 + random(3)), max(1, weapon:pen(by, me)), qual, loc, by, weapon);
"Quinn 17-FEB-93: hacked to send attacker to :receive_damage.";
"Quinn 11-AUG-93: Receive weapon (if any) from caller and send to :Receive_damage.";
"Quinn 22-OCT-93: Receive and send hit location.  Removed some literal dodge resolve.";
"Quinn 19-NOV-93: Major re-write.  Cut a lot of kruft.  Redirect old-style calls to :respond_passed_numbers.";
"Profane 9-FEB-95 23:06EST: Added 'qual' and 'try' to :announce_parry call in preparation for weapon degrading.";
"Profane 2-13-95 20:47EST: Added call to weapon:notify_parry for weapon damage hook.";
"Profane 2-9-96 1637EST- Added paralyzation check.";
"Irin Sun Nov  3 10:56:34 1996 PST -- Added evil check for fighting lotsa people penalty thingie.";
"THX 12-MAR-1997 -- Killed off a list indexing, reversed the order of the announce_parry and the notify_parry, and cleaned a wee bit.";
"Profane 18-MAY-97 1541PDT -- added fatigue check to complement one in :attack";
"Profane 12-JUL-97 2147PDT -- TRY statement in the parry bit.";
"Profane 3-OCT-97 -- added check for non-gm owned weapons.";
"THX (#105941) - Mon Apr  6, 1998 - Sped things up by rearranging the conditional.  Remember, set up your conditional path for the _most common_ route the code takes!  Changed this.paralyzed check to this:cannot_move().";
"Irin Thu Jun 11 19:03:52 1998 PDT -- changed :cannot_move to :cannot_defend.";
"Profane (#30788) - Sun May  2, 1999 - insert inelegant backfire checks circa line 38-42";
"THX (#105941) - Mon Nov  1, 1999 - Changed backfire effect to use connect_effects instead.";
"THX (#105941) - Thu Feb  1, 2001 - Decrement this.act by parrying_weapon:slowness() if parry successful.";

set_att

Spec this none thisDefiner #74

Referenced by

• #74:mod_att line 16: this:set_att
• #74:setadd_att line 17: this:set_att

Source

":set_att(att, amt)";
"Sets the doll's `att' property to `amt'.";
{att, amt} = args;
(rpg = $local.rpg):secure();
if (this == rpg.doll)
  "Grand_Master can set $local.rpg.doll stats manually.";
  return E_NACC;
elseif (caller == this)
  "THX (#105941) - Sun Mar  7, 1999 - Dolls check rpg:approve_att_change() before calling this, so don't do it twice.";
elseif (rpg:approve_att_change(player, {this, att, amt}, callers()) == E_PERM)
  return E_PERM;
endif
if (att == "inj")
  if (link = this.lifelinked)
    return rpg.magic_db.ll_death_effect:do_lifelink(amt, link);
  elseif (this.deathless && (amt < this.inj))
    return;
  endif
elseif (att == "slowness")
  this.slowness_mod = rpg.slowness_mods[max(min(amt, 10), 1)];
elseif (att in {"ins", "fat"})
  this:track_callers(att, caller == this, callers = callers(1));
  (i = $list_utils:iassoc(#7970, callers, 4)) && ((callers[i + 1][3] in rpg.gms) || rpg:log_error((((("Possible hack: " + toliteral(callers)) + " ... Player: ") + #20:nn(player)) + " ... Victim: ") + #20:nn(this)));
endif
if (`parent(this).(att) ! ANY => E_RECMOVE' == amt)
  clear_property(this, att);
else
  return `this.(att) = amt ! ANY';
endif
return `this.(att) ! ANY';

die

Spec this any noneFlags rxdDefiner #74

Referenced by

• #74:receive_damage line 78: this:die
• #74:receive_damage_passed_messages line 78: this:die
• #74:hit_result line 59: this:die
• #74:receive_damage(old) line 76: this:die

Source

":die(whoby OBJ [, weapon OBJ])";
{whoby, ?weapon = $nothing} = args;
(rpg = $local.rpg):secure();
victim = this.character;
if (is_player(victim) && (typeof(`idle_seconds(victim) ! ANY') == ERR))
  return E_INVIND;
  "elseif (this:incorporeal(weapon))";
  "  return 0;";
elseif (typeof(effect = this:death_effects(whoby)) != NUM)
  "If a :death_effect does not return a number, then abort the death.";
  return effect;
endif
cp = caller_perms();
where = victim.location;
contents = where:contents();
fork (rpg.gm_lag)
  rpg:check_notification(contents, "notify_death", {victim, whoby});
  `this:murder_anima(whoby) ! E_VERBNF => 0';
endfork
if (is_player(victim))
  (victim == victim.owner) && rpg.death_db:record_death(cp = valid(cp) ? cp | caller, whoby);
  if (((!$object_utils:isa(victim, $guest)) && (this != rpg.object_db.suit_doll)) && (!(rpg.death_db.pkp_effect in this.view_effects)))
    rpg:respawn_non_pkp_pc(this);
  else
    rpg:die(this);
  endif
else
  victim.alive = 0;
  victim:die(whoby);
  `this.aggressor = {} ! ANY';
endif
"Irin Tue Apr 22 11:21:43 1997 PDT -- Disconnected players don't die.";
"THX - 23-Apr-1997 --  Set monster.alive to 0 before passing to monster:die() since they take so long sometimes.";
"THX (#105941) - Wed Oct 13, 1999 - Commented out the explicit lifelink, poison, holdfoe, and iceshell checks and changed them all to use death_effect.";
"Hydros (#106189) - Sun Oct 10, 2004 - Added a call to :murder_anima.  Applies to killed (N)PCs.";
"Hydros (#106189) - Sun Oct 16, 2005 - Added a hook to rpg:respawn_non_pkp_pc(), for folks that have volunteered into the playerkiller realm.";

receive_damage

Spec this none thisDefiner #74

Referenced by

• #74:respond line 20: this:receive_damage
• #74:respond line 71: this:receive_damage
• #74:respond(old) line 20: this:receive_damage
• #74:respond(old) line 67: this:receive_damage

Source

":receive_damage(dam, pen, qual, hitloc, attacker, weapon)";
"dam      -> damage to be applied";
"pen      -> penetration of the weapon";
"qual     -> quality of the attack (final hit roll)";
"hitloc   -> body area object of hit location";
"attacker -> character initiating the attack";
"weapon   -> weapon used to attack";
(rpg = $local.rpg):secure();
try
  {dam, pen, qual, loc, whoby, weapon} = args;
except (E_ARGS)
  return this:receive_damage_passed_messages(@args);
endtry
"if (this:incorporeal(weapon))";
"  return 0;";
"endif";
me = this.character;
effect = 0;
if (this.connect_effects && (effect = this:connect_effects(whoby, me, loc, weapon, qual, dam, pen, 1)))
  if (typeof(effect) == NUM)
    dam = dam - effect;
  else
    return effect;
  endif
endif
if (rpg.object_db:is_critical_hit(weapon) && weapon:critical_hit(whoby, me, qual, loc, dam))
  "weapon handled a critical hit";
  return;
endif
locstr = loc:title(me);
protection = this:armour(pen, loc, whoby, weapon, dam, qual);
size = this.size;
if (((dam - protection) / size) <= 0)
  armour = this.current_armours[2];
  absorbed = `max(armour:absorption(whoby, me, weapon, loc, dam), 1) ! ANY => 1';
  absorbed = absorbed * weapon:con(whoby, me);
  if (rpg:trusted_property(me, "nat_prot"))
    absorbed = absorbed * ((n = me.nat_prot) ? max(1, 2 + (n / 10)) | 1);
  endif
  if ((dam / max(1, size * absorbed)) > 0)
    dam = dam / (size * absorbed);
    sev = ((5 * dam) + (this.inj / 3)) / max(this.end, 5);
    bad = {"slightly bruised", "slightly bruised", "bruised", "bruised", "bruised", "badly bruised"}[min(sev + 1, 6)];
  else
    if (valid(armour = this.current_armours[1]))
      armour:announce_clang(whoby, me, locstr, weapon, qual);
    else
      rpg:rpg_announce_all(me.location, me.name, " is unharmed by the blow.");
    endif
    weapon:notify_clang(whoby, me, loc, armour, qual);
    return -1;
  endif
else
  dam = (((dam - protection) / size) + weapon:special_damage(me, dam, pen, qual, loc, whoby)) || 0;
  sev = ((2 * dam) + (this.inj / 3)) / max(this.end, 5);
  bad = {"scratched", "slightly wounded", "hit", "hit", "hit", "severely wounded"}[min(sev + 1, 6)];
endif
inj = this.inj;
this:mod_att("inj", dam);
shockmod = loc:shock_mod(me, whoby, weapon);
stunmod = loc:stun_resistance(me, whoby, weapon);
try_ = rpg:resolve(me, "shock", shockmod);
if (try_ > (-2 * this.end))
  rpg:check_notification(me, "notify_hit", {whoby, me, weapon, locstr, bad, dam});
  weapon:announce_hit(whoby, me, locstr, bad, 0);
  weapon:hit_special_effect(whoby, me, qual, dam, loc);
  return -2;
elseif ((!inj) || (try_ > ((-2 * (this.end + (is_player(me) ? 20 | 10))) - stunmod)))
  rpg:check_notification(me, "notify_hit", {whoby, me, weapon, locstr, bad, dam});
  weapon:announce_hit(whoby, me, locstr, bad, 1);
  weapon:track_usage(4);
  this.act = max(this.act - 20, -20);
  weapon:hit_special_effect(whoby, me, qual, dam, loc);
  return -3;
elseif (rpg:is_alive(this))
  weapon:announce_kill(whoby, me, locstr);
  weapon:track_usage(5);
  this:die(whoby, weapon);
  weapon:hit_special_effect(whoby, me, qual, dam, loc);
  return -9;
endif
"THX (#105941) - Mon Jul 20, 1998 - Made it programmatically impossible to die unless already injured.";
"THX (#105941) - Wed Jan  6, 1999 - Re-added stunmod modifier and fixed the logic in line 64.";
"THX (#105941) - Sun Jan 10, 1999 - Removed the ugly tangle receive_damage check/call and moved it to the tangle:armour_effect.";
"Profane (#30788) - Sun May  2, 1999 - insert inelegant checks for backfire circa lines 46-48, 64-66, 73-75";
"Profane (#30788) - Sun May 23, 1999 - Moved iceshell off into an armour_effect";
"THX (#105941) - Mon Nov  1, 1999 - Moved the explicit backfire calls to :connect_effects.";
"THX (#105941) - Mon May 29, 2000 - Added a rpg.object_db:is_critical_hit(weapon) check to allow Grand_Master to exclude poorly constructed critical_hit verbs.";
"THX (#105941) - Thu May 17, 2001 - Put in an rpg:is_alive(this) check in before calling this:die() ... maybe we'll have fewer double corpses.";

act

Spec this none thisDefiner #74

Referenced by

none

Source

(rpg = $local.rpg):secure();
if (this:cannot_cast())
  "Assume that the monster would hit somebody if they can't cast.";
  "This could be wrong, but monsters don't yet check if they can cast?  Maybe after talking with various monster owners?  Things that block casting, but not attacking seem rare at the moment...";
  if (this:cannot_attack())
    return;
  endif
  return this:hit_aggressor();
endif
if (is_player(who = this.character))
  this:hit_aggressor();
else
  rpg:s_i_n(1);
  "Assume that their act verb is trusted, if they're not a player and have a doll.";
  who:act();
endif

protection

Spec this none thisDefiner #74

Referenced by

• #74:armour line 7: this:protection
• #74:armour(old) line 46: this:protection

Source

":protection(penetration, hit-location, attacker, weapon-used, dam, [qual])";
rpg = $local.rpg;
{pen, loc, attacker, ?weapon = rpg.weapon, ?dam = 0, ?qual = 0} = args;
me = this.character;
pierce = `weapon:pierce(attacker, me, qual) ! ANY => 0';
r = `random(100) + pierce ! E_TYPE => random(100)';
max = 0;
amax = 1;
best_prot = best_abs = $nothing;
for armour in (this:wearing())
  if (armour:cover(loc) > r)
    protection = armour:protection(attacker, me, weapon, loc, pen, dam);
    absorb = armour:absorption(attacker, me, weapon, loc, dam);
    if (max < protection)
      max = protection;
      best_prot = armour;
    endif
    if (amax < absorb)
      amax = absorb;
      best_abs = armour;
    endif
  endif
endfor
this.current_armours = {best_prot, best_abs};
max = max + ((typeof(loc) == NUM) ? this.body_areas[loc]:nat_prot(me, attacker, weapon) | loc:nat_prot(me, attacker, weapon));
object_db = rpg.object_db;
if (((loc == 4) && (max < 10)) && (r < 75))
  for q in (this.wielding)
    if (object_db:is_shield(q))
      max = 10;
    endif
  endfor
endif
return max(pen * max, 0);
"Quinn 11-AUG-93 1010: Re-written to send attacker and weapon (if given) to the new armour:protection() verb; changed literal shield reference to rpg.shield";
"Quinn 16-OCT-93 0115: Use armour:cover verb instead of propref.";
"Profane 20-JAN-96 0939EST: Added nat_prot modifer for body areas.";
"Irin Wed Sep  4 22:50:51 1996 PDT: Added piercing.";
"Irin Mon Sep 16 18:58:46 1996 PDT -- Added check for absorption, added passing of armour used through .current_armours property.  Nasty hack, but can't otherwise alter the return value.";
"Irin Sun Sep 22 13:15:28 1996 PDT--added optional 'qual' argument, to pass through to :pierce.";
"Irin Mon Sep 23 20:02:36 1996 PDT -- Changed to use call to new object_db for faster execution.";
"THX1138 - 26-Apr-1997 -- Used a scatter assignment and reduced the number of assignments to reduce tickage.";

encumbrance

Spec this none thisDefiner #74

Referenced by

• #74:attack line 18: this:encumbrance
• #74:respond line 23: this:encumbrance
• #74:respond_passed_numbers line 36: this:encumbrance
• #74:respond(old) line 23: this:encumbrance
• #74:attack(old) line 18: this:encumbrance

Source

":encumbrance() -> Total encumbrance of this character.  Usually [0..10].";
if (is_player(char = this.character))
elseif (load = `char:encumbrance() ! E_VERBNF, E_PERM')
  return load;
endif
if (strength = this.str)
  if (typeof(this.weight) == NUM)
    return this.weight;
  else
    weight = this.weight = $local.rpg:weight(char, this) / max(1, strength + (this.size - 10));
    "((weight > 12) && is_player(char)) && $local.rpg.object_db.ol_effect:add(this);";
    return weight;
  endif
else
  return 0;
endif
"Quinn 21-AUG-93 0706: Hacked to return character:encumbrance if exists and is owned by a GM.";
"Profane 2/5/95 13:48EST - fixed use of `STR' as a variable name.";
"StarDancer Oct 21 06:39 1995 PDT - took out call to $object_utils:has_callable_verb, made verb !d";
"Hydros (#106189) - Tue Jan 17, 2006 - I prefer penalizing stat resolves on a sliding scale than just paralyzing them for overload, so I removed it.";

get_att

Spec this none thisDefiner #74

Referenced by

none

Source

"{att} = args; ... documentation only";
if (caller_perms() in $local.rpg.gms)
  return `this.(args[1]) ! ANY';
  "THX (#105941) - Sun Mar 29, 1998 - The following is a nasty hack we used against loser hackers.  Removed for speed.";
  "programmers = $list_utils:slice(callers(), 3);";
  "for loser in ({@rpg.fishy, @rpg.macro_users})";
  "  if (loser in programmers)";
  "    raise(E_PERM);";
  "  endif";
  "endfor";
else
  return E_PERM;
endif

schedule

Spec this none thisDefiner #74

Referenced by

none

Source

":schedule(OBJ object, STR verb, NUM time, LIST args)";
"Schedule this doll to call object:(verb)(doll, @args) at time.";
"The time is approximate, since the schedule is checked only when :invite is called.";
$local.rpg:secure();
this.schedule = listappend(this.schedule, args);

cancel

Spec this none thisDefiner #74

Referenced by

• #74:armour(old) line 17: this:cancel

Source

":cancel(LIST schedule element)";
if ($local.rpg:trusted(caller_perms()))
  this.schedule = setremove(this.schedule, @args);
endif

get_schedule

Spec this none thisDefiner #74

Referenced by

none

Source

{?item = 0} = args;
$local.rpg:secure();
if (item)
  r = {};
  for w in (this.schedule)
    if (w[1] == item)
      r = listappend(r, w);
    endif
  endfor
  return r;
endif
return this.schedule;
"THX (#105941) - Mon Jan 31, 2000 - Updated verb and added security.";