generic openable/closable RPG container #43001

close_msg oclose_msg oopen_msg open_msg oopen_fail_msg open_fail_msg empty_msg

Spec this none thisFlags rxDefiner #43001

Referenced by

• #43001:open line 6: this:open_msg
• #43001:open line 7: this:oopen_msg
• #43001:open line 11: this:open_fail_msg
• #43001:open line 12: this:oopen_fail_msg
• #43001:close line 6: this:close_msg
• #43001:close line 7: this:oclose_msg
• #43001:tell_contents line 7: this:empty_msg

Source

return (msg = this.(verb)) ? $string_utils:pronoun_sub(msg, @args) | "";

open

Spec this none noneFlags rxdDefiner #43001

Referenced by

none

Source

"Copied from generic container (#8):open by Nosredna (#2487) Mon Oct  4 00:16:25 1993 PDT";
if (this:opened())
  player:tell("It's already open.");
elseif (this:is_openable_by(callers() ? caller_perms() | player))
  this:set_opened(1);
  player:tell(this:open_msg());
  if (msg = this:oopen_msg(player, this))
    player.location:announce(msg);
  endif
else
  player:tell(this:open_fail_msg());
  if (msg = this:oopen_fail_msg(player, this))
    player.location:announce(msg);
  endif
endif

close

Spec this none noneFlags rxdDefiner #43001

Referenced by

none

Source

"Copied from generic container (#8):close by Nosredna (#2487) Mon Oct  4 00:17:11 1993 PDT";
if (!this:opened())
  player:tell("It's already closed.");
else
  this:set_opened(0);
  player:tell(this:close_msg());
  if (msg = this:oclose_msg())
    player.location:announce(msg);
  endif
endif

is_openable_by

Spec this none thisDefiner #43001

Referenced by

• #43001:open line 4: this:is_openable_by
• #43001:exitfunc line 4: this:is_openable_by

Source

"Copied from generic container (#8):is_openable_by by Nosredna (#2487) Sat Oct  9 19:20:53 1993 PDT";
return (this.open_key == 0) || $lock_utils:eval_key(this.open_key, args[1]);

look_self

Spec this none thisDefiner #43001

Referenced by

none

Source

player:tell_lines((desc = this:description()) ? desc | "You see nothing special.");
if (this.opened)
  this:tell_contents();
endif

tell_contents

Spec this none thisDefiner #43001

Referenced by

• #43001:look_self line 3: this:tell_contents

Source

"Copied from generic container (#8):tell_contents by Nosredna (#2487) Mon Oct  4 00:32:17 1993 PDT";
if (this.contents)
  player:tell("Contents:");
  for thing in (this.contents)
    player:tell("  ", thing:title());
  endfor
elseif (msg = this:empty_msg())
  player:tell(msg);
endif

description

Spec this none thisFlags rxDefiner #43001

Referenced by

• #43001:look_self line 1: this:description

Source

"Need to know if it is opened or closed.";
if (msg = this.description)
  open_msg = this.opened ? "" | " It is closed.";
  return (typeof(msg) == LIST) ? {@msg, open_msg} | (msg + open_msg);
endif

pu*t ins*ert st*ore ca*che

Spec any in thisFlags rxDefiner #43001

Referenced by

• #59000:pu*t line 6: pass(

Source

"Prevent transfer if container is not opened";
if (!this:opened())
  player:tell(this.name, " is closed.");
  return 0;
endif
pass(@args);

re*move ex*tract rec*over ge*t ta*ke

Spec any from thisFlags rxDefiner #43001

Referenced by

• #59000:re*move line 6: pass(

Source

"Prevent transfer if container is not opened";
if (!this:opened())
  player:tell(this.name, " is closed.");
  return 0;
endif
pass(@args);

acceptable

Spec this none thisDefiner #43001

Referenced by

• #59000:acceptable line 2: pass(

Source

"Allow $local.rpg.equipment only if the container is open.";
return pass(@args) && this:opened();

@lock_for_open

Spec this with anyDefiner #43001

Referenced by

none

Source

"Copied from generic container (#8):@lock_for_open by Nosredna (#2487) Sun Oct 17 18:32:59 1993 PDT";
if (caller != this.owner)
  player:tell(E_PERM);
  return;
endif
key = $lock_utils:parse_keyexp(iobjstr, player);
if (typeof(key) == STR)
  player:tell("That key expression is malformed:");
  player:tell("  ", key);
else
  res = this.open_key = key;
  if (typeof(res) == ERR)
    player:tell(res, ".");
  else
    player:tell("Locked opening of ", this.name, " with this key:");
    player:tell("  ", $lock_utils:unparse_key(key));
  endif
endif

set_opened

Spec this none thisDefiner #43001

Referenced by

• #43001:open line 5: this:set_opened
• #43001:close line 5: this:set_opened
• #59000:pick_lock line 21: this:set_opened
• #59000:lock line 21: this:set_opened
• #59000:reset_lock line 9: this:set_opened

Source

if (!$perm_utils:controls(caller.owner, this))
  return E_PERM;
endif
this.opened = opened = !(!args[1]);
return opened;

opened

Spec this none thisDefiner #43001

Referenced by

• #43001:open line 2: this:opened
• #43001:close line 2: this:opened
• #43001:pu*t line 2: this:opened
• #43001:re*move line 2: this:opened
• #43001:acceptable line 2: this:opened

Source

return this.(verb);

exitfunc

Spec this none thisDefiner #43001

Referenced by

none

Source

{thing} = args;
if (!(rpg = $local.rpg):trusted_efunc())
  return E_PERM;
elseif (this:is_openable_by(caller_perms()) || (thing.owner == caller_perms()))
  return pass(thing);
elseif ($recycler:valid(thing))
  "thanks to Dred for a patch on some invalid obj problems";
  su = $string_utils;
  rpg:log_error((((((((((((((("Object moved by container: " + su:nn(thing)) + " moved by ") + su:nn(this)) + " Container Location: ") + su:nn(this.location)) + " from: ") + su:nn(thing.location)) + " Player: ") + su:nn(player)) + " Locale: ") + su:nn(player.location)) + " Callers: ") + toliteral(callers(1))) + " ") + ctime());
  thing:moveto(this);
endif
return 0;