Public Broadcast System #143

init_for_core

Spec this none thisFlags rxdOwner #36Definer #143

Referenced by

none

Source

if (caller_perms().wizard)
for p in (properties(this))
this.(p) = {};
endfor
pass(@args);
endif

cb public pub staff stf help!

Spec any any anyFlags rxdOwner #36Definer #143

Referenced by

none

Source

"* Public channels are HELP! and public/pub/cb";
"* Restricted channels are staff/stf and KMOO";
" -sample commands-";
"cb on                        = Join the channel";
"cb off                       = Leave the channel";
"cb who                       = Who is monitoring the channel";
"cb help                      = displays this help info";
"cb <message>                 = broadcast <message>";
"cb -<player name> <message>  = direct <message> to <player name>";
"cb :<emote phrase>           = like regular emote";
if ((caller != player) && (caller != $guest))
return;
endif
if ((verb in {"staff", "stf"}) && (!$object_utils:isa(player, $frand_class)))
return player:tell("Sorry. The 'staff' channel is not open to you.");
elseif (player in this.banned)
return player:tell("Sorry. You have been temporarily censored.");
endif
argstr = $code_utils:argstr(verb, args, argstr);
if (!argstr)
return this:broadcast(this:get_channel(verb), tostr("(", this:pub_title(player), ")"));
endif
mumbles = this:get_parsed(argstr);
if ((mumbles[1] == "") && (mumbles[3] != ""))
return player:tell(mumbles[3], " is not connected.");
endif
if (mumbles[2] == "")
if (mumbles[1] == "who")
return this:show_who(this:get_channel(verb));
elseif (mumbles[1] == "on")
return this:sign_on(this:get_channel(verb));
elseif (mumbles[1] == "off")
return this:sign_off(this:get_channel(verb));
elseif (mumbles[1] in {"help", "?"})
player:tell_lines({"---", @this.help_msg, "---"});
return;
endif
endif
if (mumbles[3] != "")
if (mumbles[1] == ":")
lead = tostr("[", mumbles[3], "] ", this:pub_title(player), " ");
else
lead = tostr(this:pub_title(player), " ", $gender_utils:get_conj(mumbles[1], player), mumbles[3]);
endif
else
if (mumbles[1] == ":")
lead = tostr(this:pub_title(player), " ");
else
lead = tostr(this:pub_title(player), " ", $gender_utils:get_conj(mumbles[1], player));
endif
endif
if (mumbles[1] == ":")
blabber = tostr(lead, mumbles[2]);
else
blabber = tostr(lead, ", \"", mumbles[2], "\"");
endif
this:broadcast(this:get_channel(verb), blabber);

broadcast

Spec this none thisFlags rxdOwner #36Definer #143

Referenced by

• #143:cb line 21: this:broadcast
• #143:cb line 57: this:broadcast
• #143:sign_on line 6: this:broadcast
• #143:sign_off line 4: this:broadcast

Source

if ((caller == this) || (caller in this.licensed))
group = args[1];
if ((caller == this) && (group == "KMOO"))
return player:tell("That is a commercial broadcast channel.");
endif
for x in (connected_players())
if (x in this.(group))
x:tell("[bold]<", group, ">[unbold] ", args[2]);
endif
endfor
endif

sign_on

Spec this none thisFlags rxdOwner #36Definer #143

Referenced by

• #143:cb line 31: this:sign_on

Source

group = args[1];
if (player in this.(group))
player:tell("You're already monitoring that channel.");
else
this.(group) = setadd(this.(group), player);
this:broadcast(group, tostr(this:pub_title(player), " signs on..."));
endif

sign_off

Spec this none thisFlags rxdOwner #36Definer #143

Referenced by

• #143:cb line 33: this:sign_off

Source

group = args[1];
if (player in this.(group))
this.(group) = setremove(this.(group), player);
this:broadcast(group, tostr(this:pub_title(player), " signs off..."));
player:tell("You are no longer monitoring the \"", group, "\" channel.");
else
player:tell("You were not monitoring the \"", group, "\" channel.");
endif

show_who

Spec this none thisFlags rxdOwner #36Definer #143

Referenced by

• #143:cb line 29: this:show_who

Source

nerds = {};
group = args[1];
for person in (connected_players())
(ticks_left() < 5000) && suspend(0);
if (person in this.(group))
nerds = {@nerds, this:pub_title(person)};
endif
endfor
player:tell("These connected players are listening to the \"", group, "\" channel:");
return player:tell_lines($string_utils:columnize(nerds, 3));

get_parsed

Spec this none thisFlags rxdOwner #36Definer #143

Referenced by

• #143:cb line 23: this:get_parsed

Source

"USAGE: get_parsed(argstr) => {action-STRING,words-STRING,target-STRING}";
if (caller == this)
su = $string_utils;
words = su:trim(args[1]);
action = "";
target = "";
"test for on/off/who";
if (words in {"on", "off", "who", "help", "?"})
return {words, "", ""};
endif
"test for emote";
if (words[1] == ":")
action = ":";
words = words[2..length(words)];
endif
"test for smileys and punctuation, but only if spoken";
if (action != ":")
action = su:get_say_verb(words);
endif
"test for directed speech";
if (words[1] == "-")
{target, words} = su:first_word(words[2..length(words)]);
targobj = su:match_player(target);
if (targobj in {$failed_match, $ambiguous_match, $nothing})
words = tostr("-", target, " ", words);
target = "";
elseif (targobj in connected_players())
target = tostr(su:get_say_verb_prep(action), targobj:title());
else
return {"", "", targobj:title()};
endif
endif
return {action, words, target};
endif
return {"", "", ""};

pub-ban un-pub-ban

Spec any none noneFlags rxdOwner #36Definer #143

Referenced by

none

Source

"WIZ-ONLY! pub-ban <person>";
"          un-pub-ban <person>";
if (caller.wizard || (caller == this.owner))
jerk = $string_utils:match_player(dobjstr);
if (!$rp_regulator:person_match_failed(jerk, dobjstr))
this.public = setremove(this.public, dobj);
this.banned = (verb == "pub-ban") ? setadd(this.banned, dobj) | setremove(this.banned, dobj);
player:notify("Done.");
endif
endif

get_channel

Spec this none thisFlags rxdOwner #36Definer #143

Referenced by

• #143:cb line 21: this:get_channel
• #143:cb line 29: this:get_channel
• #143:cb line 31: this:get_channel
• #143:cb line 33: this:get_channel
• #143:cb line 57: this:get_channel

Source

if (args[1] in {"public", "pub", "cb"})
return "public";
elseif (args[1] in {"staff", "stf"})
return "staff";
elseif (args[1] == "help!")
return "HELP!";
else
return "KMOO";
endif

pub_title

Spec this none thisFlags rxdOwner #36Definer #143

Referenced by

• #143:cb line 21: this:pub_title
• #143:cb line 41: this:pub_title
• #143:cb line 43: this:pub_title
• #143:cb line 47: this:pub_title
• #143:cb line 49: this:pub_title
• #143:sign_on line 6: this:pub_title
• #143:sign_off line 4: this:pub_title
• #143:show_who line 6: this:pub_title

Source

{person, name} = `{args[1], args[1].name} ! ANY => {player, player.name}';
return (x = name in $list_utils:slice(person.ansi_title, 1)) ? person.ansi_title[x][2] | name;