News #53

description

Spec this none thisFlags rxdOwner #29Definer #53

Referenced by

• #53:news_display_seq_full line 4: this:description

Source

raw = ctime(this.last_news_time);
"         111111111122222";
"123456789012345678901234";
"Fri Nov 30 14:31:21 1990";
date = (raw[1..10] + ",") + raw[20..24];
return strsub(this.description, "%d", date);

is_writable_by

Spec this none thisFlags rxdOwner #361Definer #53

Referenced by

• #53:@addnews line 5: this:is_writable_by
• #53:@rmnews line 5: this:is_writable_by
• #53:@setnews line 2: this:is_writable_by
• #53:@clearnews line 2: this:is_writable_by

Source

return pass(@args) || (args[1] in $list_utils:map_prop($object_utils:descendants($wiz), "mail_identity"));

rm_message_seq

Spec this none thisFlags rxdOwner #29Definer #53

Referenced by

• #53:init_for_core line 3: this:rm_message_seq

Source

if (this:ok_write(caller, caller_perms()))
seq = args[1];
this.current_news_going = $seq_utils:intersection(this.current_news, seq);
this.current_news = $seq_utils:contract(this.current_news, seq);
return $mail_agent:(verb)(@args);
else
return E_PERM;
endif

undo_rmm

Spec this none thisFlags rxdOwner #29Definer #53

Referenced by

none

Source

if (!this:ok_write(caller, caller_perms()))
return E_PERM;
endif
seq = $mail_agent:(verb)(@args);
this.current_news = $seq_utils:union(this.current_news_going, $seq_utils:expand(this.current_news, seq));
this.current_news_going = {};
return seq;

expunge_rmm

Spec this none thisFlags rxdOwner #29Definer #53

Referenced by

• #53:init_for_core line 4: this:expunge_rmm

Source

if (!this:ok_write(caller, caller_perms()))
return E_PERM;
endif
this.current_news_going = {};
return $mail_agent:(verb)(@args);

set_current_news

Spec this none thisFlags rxdOwner #29Definer #53

Referenced by

• #53:add_current_news line 4: this:set_current_news
• #53:rm_current_news line 4: this:set_current_news
• #53:@setnews line 11: this:set_current_news
• #53:add_news line 14: this:set_current_news
• #53:rm_news line 14: this:set_current_news
• #53:@clearnews line 3: this:set_current_news

Source

if (!this:ok_write(caller, caller_perms()))
return E_PERM;
else
this.current_news = new = args[1];
if (new)
newlast = $seq_utils:last(new);
newlasttime = this:messages_in_seq(newlast)[2][1];
if (newlasttime > this.last_news_time)
"... only notify people if there exists a genuinely new item...";
this.last_news_time = newlasttime;
this:touch();
endif
else
"...flush everything...";
this.last_news_time = 0;
endif
endif

add_current_news

Spec this none thisFlags rxdOwner #29Definer #53

Referenced by

none

Source

if (!this:ok_write(caller, caller_perms()))
return E_PERM;
else
return this:set_current_news($seq_utils:union(this.current_news, args[1]));
endif

rm_current_news

Spec this none thisFlags rxdOwner #29Definer #53

Referenced by

none

Source

if (!this:ok_write(caller, caller_perms()))
return E_PERM;
else
return this:set_current_news($seq_utils:intersection(this.current_news, $seq_utils:complement(args[1])));
endif

news_display_seq_full

Spec this none thisFlags rxdOwner #361Definer #53

Referenced by

• #6:news line 45: $news:news_display_seq_full

Source

":news_display_seq_full(msg_seq) => {cur, last-read-date}";
"Display the given msg_seq as a collection of news items";
set_task_perms(caller_perms());
desc = this:description();
player:notify((typeof(desc) == LIST) ? desc[1] | desc);
player:notify("");
msgs = $lu:reverse(this:messages_in_seq(args[1]));
for i in [-(n = length(msgs))..-1]
x = msgs[-i];
player:notify_lines(this:to_text(@x[2]));
player:notify("");
$command_utils:suspend_if_needed(0);
endfor
player:notify("(end)");
return {msgs[n][1], msgs[n][2][1]};

to_text

Spec this none thisFlags rxdOwner #29Definer #53

Referenced by

• #53:news_display_seq_full line 10: this:to_text

Source

":to_text(@msg) => message in text form -- formatted like a $news entry circa October, 1993";
date = args[1];
by = args[2];
"by = by[1..index(by, \"(\") - 2]";
subject = (args[4] == " ") ? "-*-NEWS FLASH-*-" | $string_utils:uppercase(args[4]);
text = args[("" in {@args, ""}) + 1..$];
ctime = $time_utils:time_sub("$D, $N $3, $Y", date);
return {ctime, subject, @text};
return {subject, tostr("  by ", by, " on ", ctime), "", @text};

check

Spec this none thisFlags rxdOwner #361Definer #53

Referenced by

• #6:confunc line 15: $news:check

Source

set_task_perms(caller_perms());
if ((player:get_current_message(this) || {0, 0})[2] < this.last_news_time)
if ((n = player:mail_option("news")) in {0, "all"})
player:tell("There is new news.  Type `news' to read all news or `news new' to read just new news.");
elseif (n == "contents")
player:tell("There is new news.  Type `news all' to read all news or `news new' to read just new news.");
elseif (n == "new")
player:tell("There is new news.  Type `news' to read new news, or `news all' to read all news.");
endif
endif

touch

Spec this none noneFlags rxdOwner #361Definer #53

Referenced by

• #53:set_current_news line 11: this:touch

Source

if (!this:ok_write(caller, valid(who = caller_perms()) ? who | player))
player:notify("Permission denied.");
return;
endif
fork (0)
for p in (connected_players())
$command_utils:suspend_if_needed(0);
if ((p:get_current_message(this) || {0, 0})[2] < this.last_news_time)
p:notify("There's a new edition of the newspaper.  Type 'news new' to see the new article(s).");
endif
endfor
endfork

@addnews

Spec any at/to thisFlags rxdOwner #361Definer #53

Referenced by

none

Source

if ((caller_perms() != #-1) && (caller_perms() != player))
raise(E_PERM);
endif
set_task_perms(player);
if (!this:is_writable_by(player))
player:notify("You can't write the news.");
elseif (typeof(result = this:add_news(args[1..(prepstr in args) - 1], player:get_current_message(this) || {0, 0})) == STR)
player:notify(result);
else
new = this.current_news;
if (new)
player:notify("Current newspaper set.");
this:display_seq_headers(new);
else
player:notify("Current newspaper is now empty.");
endif
endif

@rmnews

Spec any out of/from inside/from thisFlags rxdOwner #361Definer #53

Referenced by

none

Source

if ((caller_perms() != #-1) && (caller_perms() != player))
raise(E_PERM);
endif
set_task_perms(player);
if (!this:is_writable_by(player))
player:notify("You can't write the news.");
elseif (typeof(result = this:rm_news(args[1..(prepstr in args) - 1], player:get_current_message(this) || {0, 0})) == STR)
player:notify(result);
else
new = this.current_news;
if (new)
player:notify("Current newspaper set.");
this:display_seq_headers(new);
else
player:notify("Current newspaper is now empty.");
endif
endif

@setnews

Spec this at/to anyFlags rxdOwner #361Definer #53

Referenced by

none

Source

set_task_perms(player);
if (!this:is_writable_by(player))
player:notify("You can't write the news.");
elseif (typeof(seq = this:_parse(strings = args[(prepstr in args) + 1..$], @player:get_current_message(this) || {0, 0})) == STR)
player:notify(seq);
else
old = this.current_news;
if (old == seq)
player:notify("No change.");
else
this:set_current_news(seq);
if (seq)
player:notify("Current newspaper set.");
this:display_seq_headers(seq);
else
player:notify("Current newspaper is now empty.");
endif
endif
endif

_parse

Spec this none thisFlags rxdOwner #29Definer #53

Referenced by

• #6:news line 27: $news:_parse
• #53:@setnews line 4: this:_parse
• #53:add_news line 5: this:_parse
• #53:rm_news line 5: this:_parse

Source

if (!(strings = args[1]))
return "You need to specify a message sequence";
elseif (typeof(pms = this:parse_message_seq(@args)) == STR)
return $string_utils:substitute(pms, {{"%f", "The news"}, {"%<has>", "has"}, {"%%", "%"}});
elseif (typeof(pms) != LIST)
return tostr(pms);
elseif (length(pms) > 1)
return tostr("I don't understand `", pms[2], "'.");
elseif (!(seq = pms[1]))
return tostr("The News (", this, ") has no `", $string_utils:from_list(pms[2][1..used], " "), "' messages.");
else
return seq;
endif

init_for_core

Spec this none thisFlags rxdOwner #361Definer #53

Referenced by

none

Source

if (caller_perms().wizard)
pass();
this:rm_message_seq($seq_utils:range(1, this:length_all_msgs()));
this:expunge_rmm();
this.description = "It's the current issue of the News, dated %d.";
this.mail_forward = {};
for p in ({"moderator_forward", "writers", "last_used_time", "mail_notify"})
this.(p) = $mail_recipient.(p);
endfor
this.moderated = 1;
this.last_news_time = 0;
this.readers = 1;
this.archive_news = {};
$mail_agent:send_message(#2, this, "Welcome to LambdaCore", $wiz_utils.new_core_message);
this:add_news("$");
else
return E_PERM;
endif

add_news

Spec this none thisFlags rxdOwner #361Definer #53

Referenced by

• #53:@addnews line 7: this:add_news
• #53:init_for_core line 15: this:add_news

Source

if (!this:ok_write(caller, caller_perms()))
$error:raise(E_PERM);
endif
{specs, ?cur = {0, 0}} = args;
seq = this:_parse(specs, @cur);
if (typeof(seq) == STR)
return seq;
endif
old = this.current_news;
new = $seq_utils:union(old, seq);
if (old == new)
return "Those messages are already in the news.";
endif
this:set_current_news(new);
return 1;

rm_news

Spec this none thisFlags rxdOwner #361Definer #53

Referenced by

• #53:@rmnews line 7: this:rm_news

Source

if (!this:ok_write(caller, caller_perms()))
raise(E_PERM);
endif
{specs, ?cur = {0, 0}} = args;
seq = this:_parse(specs, @cur);
if (typeof(seq) == STR)
return seq;
endif
old = this.current_news;
new = $seq_utils:intersection(old, $seq_utils:complement(seq));
if (old == new)
return "Those messages were not in the news.";
endif
this:set_current_news(new);
return 1;

@listnews

Spec none on top of/on/onto/upon thisFlags rxdOwner #361Definer #53

Referenced by

none

Source

player:notify("The following articles are currently in the newspaper:");
this:display_seq_headers(this.current_news);

@clearnews

Spec this none noneFlags rxdOwner #29Definer #53

Referenced by

none

Source

set_task_perms(player);
if (this:is_writable_by(player))
this:set_current_news({});
player:notify("Current newspaper is now empty.");
else
player:notify("You can't write the news.");
endif