time utilities #35

day

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #35:time_sub line 55: $time_utils:day

Source

"Given a time() or ctime()-style date, this returns the full name of the day.";
"With no args, uses now.";
if (args)
if (typeof(args[1]) == INT)
time = ctime(args[1]);
elseif (typeof(args[1]) == STR)
time = args[1];
else
return E_TYPE;
endif
else
time = ctime();
endif
dayabbr = $string_utils:explode(time)[1];
return this.days[dayabbr in this.dayabbrs];

month

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #35:time_sub line 59: $time_utils:month

Source

"Given a time() or ctime()-style date, this returns the full name";
"of the month. With no args, uses now.";
if (args)
if (typeof(args[1]) == INT)
time = ctime(args[1]);
elseif (typeof(args[1]) == STR)
time = args[1];
else
return E_TYPE;
endif
else
time = ctime();
endif
monthabbr = $string_utils:explode(time)[2];
return this.months[monthabbr in this.monthabbrs];

ampm

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #130:history line 33: $time_utils:ampm

Source

"Return a time in the form [h]h[:mm[:ss]] {a.m.|p.m.}.  Args are";
"[1]   (optional) either a time() or ctime() style date";
"[2]   (optional) the precision desired--1 for hours, 2 for minutes,";
"        3 for seconds.  If not given, precision defaults to minutes";
{?time = ctime(), ?precision = 2} = args;
if (typeof(time) == INT)
time = ctime(time);
elseif (typeof(time) != STR)
return E_TYPE;
endif
time = $string_utils:explode(time)[4];
hour = toint(time[1..2]);
if (hour == 0)
time = ("12" + time[3..(precision * 3) - 1]) + " a.m.";
elseif (hour == 12)
time = time[1..(precision * 3) - 1] + " p.m.";
elseif (hour > 12)
time = (tostr(hour - 12) + time[3..(precision * 3) - 1]) + " p.m.";
else
time = (tostr(hour) + time[3..(precision * 3) - 1]) + " a.m.";
endif
return time;

to_seconds

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #35:seconds_until_time line 5: $time_utils:to_seconds
• #35:seconds_until_time line 6: $time_utils:to_seconds

Source

"Given string hh:mm:ss ($string_utils:explode(ctime(time))[4]), this returns";
"the number of seconds elapsed since 00:00:00.  I can't remember why I";
"created this verb, but I'm sure it serves some useful purpose.";
return (((60 * 60) * toint(args[1][1..2])) + (60 * toint(args[1][4..5]))) + toint(args[1][7..8]);

sun

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

none

Source

{?time = time()} = args;
r = 10000;
h = (r * r) + (r / 2);
t = ((time + 120) % 86400) / 240;
s = (5 * ((time - 14957676) % 31556952)) / 438291;
phi = (s + t) + this.corr;
cs = $trig_utils:cos(s);
spss = ((($trig_utils:sin(phi) * $trig_utils:sin(s)) + h) / r) - r;
cpcs = ((($trig_utils:cos(phi) * cs) + h) / r) - r;
return (((((this.stsd * cs) - (this.ctcd * cpcs)) - (this.ct * spss)) + h) / r) - r;

from_ctime

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #38:__convert_new line 23: $time_utils:from_ctime

Source

"Given a string such as returned by ctime(), return the corresponding time-in-seconds-since-1970 time returned by time(), or E_DIV if the format is wrong in some essential way.";
words = $string_utils:explode(args[1]);
if (length(words) == 5)
"Arrgh!  the old ctime() didn't return a time zone, yet it arbitrarily decides whether it's standard or daylight savings time.  URK!!!!!";
words = listappend(words, "PST");
endif
if ((((length(words) != 6) || (length(hms = $string_utils:explode(words[4], ":")) != 3)) || (!(month = words[2] in this.monthabbrs))) || (!(zone = $list_utils:assoc(words[6], this.timezones))))
return E_DIV;
endif
year = toint(words[5]);
day = ({-1, 30, 59, 90, 120, 151, 181, 212, 243, 273, 304, 334}[month] + toint(words[3])) + (year * 366);
zone = zone[2];
return (((((((((((((day - ((day + 1038) / 1464)) - ((day + 672) / 1464)) - ((day + 306) / 1464)) - ((day + 109740) / 146400)) - ((day + 73140) / 146400)) - ((day + 36540) / 146400)) - 719528) * 24) + toint(hms[1])) + zone) * 60) + toint(hms[2])) * 60) + toint(hms[3]);

dhms dayshoursminutesseconds

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #4:wel*come line 15: $time_utils:dhms
• #48:tell_eta line 8: $tu:dhms
• #69:display_cache line 10: $time_utils:dhms
• #75:measurement_task line 19: $time_utils:dhms

Source

s = args[1];
if (s < 0)
return "-" + this:(verb)(-s);
endif
m = s / 60;
s = s % 60;
if (m)
ss = tostr((s < 10) ? ":0" | ":", s);
h = m / 60;
m = m % 60;
if (h)
ss = tostr((m < 10) ? ":0" | ":", m, ss);
d = h / 24;
h = h % 24;
return tostr(@d ? {d, (h < 10) ? ":0" | ":"} | {}, h, ss);
else
return tostr(m, ss);
endif
else
return tostr(s);
endif

english_time

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #4:up*time line 4: $time_utils:english_time
• #4:check_for_shutdown line 9: $time_utils:english_time
• #4:temp_newt_registration_string line 1: $time_utils:english_time
• #6:idle line 24: $time_utils:english_time
• #6:@age line 21: $time_utils:english_time
• #6:@age line 32: $time_utils:english_time
• #37:@set_expire line 13: $time_utils:english_time
• #37:@set_expire line 22: $time_utils:english_time
• #37:@register line 18: $time_utils:english_time
• #37:@register line 20: $time_utils:english_time
• #37:@register line 27: $time_utils:english_time
• #37:@validate line 18: $time_utils:english_time
• #49:@blacklist line 28: $time_utils:english_time
• #49:@blacklist line 111: $time_utils:english_time
• #49:@blacklist line 142: $time_utils:english_time
• #49:@deprog*rammer line 29: $time_utils:english_time
• #49:@shutdown line 32: $time_utils:english_time
• #59:show_expire line 5: $time_utils:english_time
• #65:clean_status line 11: $time_utils:english_time
• #103:meat_reaper line 1: $tu:english_time
• #103:meat_reaper line 20: $tu:english_time
• #167:summary line 36: $time_utils:english_time
• #296:_handle_error line 7: $time_utils:english_time
• #296:_do line 11: $time_utils:english_time
• #296:_run line 36: $time_utils:english_time

Source

"english_time(time [,reference time]): returns the time as a string of";
"years, months, days, hours, minutes and seconds using the reference time as";
"the start time and incrementing forwards. it can be given in either ctime()";
"or time() format. if a reference time is not given, it is set to time().";
{_time, ?reftime = time()} = args;
if (_time < 1)
return "0 seconds";
endif
_ctime = (typeof(reftime) == INT) ? ctime(reftime) | reftime;
seclist = {60, 60, 24};
units = {"year", "month", "day", "hour", "minute", "second"};
timelist = {};
for unit in (seclist)
timelist = {_time % unit, @timelist};
_time = _time / unit;
endfor
months = 0;
month = _ctime[5..7] in $time_utils.monthabbrs;
year = toint(_ctime[21..24]);
"attribution: the algorithm used is from the eminently eminent g7.";
while (_time >= (days = this.monthlens[month] + (((month == 2) && ((year % 4) == 0)) && (!((year % 400) in {100, 200, 300})))))
_time = _time - days;
months = months + 1;
if ((month = month + 1) > 12)
year = year + 1;
month = 1;
endif
$command_utils:suspend_if_needed(0);
endwhile
timelist = {months / 12, months % 12, _time, @timelist};
for unit in (units)
i = unit in units;
if (timelist[i] > 0)
units[i] = ((tostr(timelist[i]) + " ") + units[i]) + ((timelist[i] == 1) ? "" | "s");
else
units = listdelete(units, i);
timelist = listdelete(timelist, i);
endif
endfor
return $string_utils:english_list(units);

from_day

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #38:_parse_date line 13: $time_utils:from_day
• #43:@flush line 18: $time_utils:from_day

Source

"from_day(day_of_week,which)";
"numeric time (seconds since 1970) corresponding to midnight (PST) of the given weekday.  Use either the name of the day or a 1..7 number (1==Sunday,...)";
"  which==-1 => use most recent such day.";
"  which==+1 => use first upcoming such day.";
"  which==0  => use closest such day.";
"larger (absolute) values for which specify a certain number of weeks into the future or past.";
{day, ?dir = 0} = args;
if (!(toint(day) || (day = $string_utils:find_prefix(day, this.days))))
return E_DIV;
endif
delta = {288000, 374400, 460800, 547200, 28800, 115200, 201600}[toint(day)];
time = time() - delta;
if (dir)
time = (time / 604800) + ((dir > 0) ? dir | (dir + 1));
else
time = (time + 302400) / 604800;
endif
return (time * 604800) + delta;

from_month

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #35:seconds_until_date line 11: $time_utils:from_month
• #38:_parse_date line 20: $time_utils:from_month
• #38:_parse_date line 26: $time_utils:from_month
• #43:@flush line 19: $time_utils:from_month

Source

"from_month(month,which[,d])";
"numeric time (seconds since 1970) corresponding to midnight (PST) of the dth (first) day of the given month.  Use either the month name or a 1..12 number (1==January,...)";
"  which==-1 => use most recent such month.";
"  which==+1 => use first upcoming such month.";
"  which==0  => use closest such month.";
"larger (absolute) values for which specify a certain number of years into the future or past.";
{month, ?dir = 0, ?dth = 1} = args;
if (!(toint(month) || (month = $string_utils:find_prefix(month, this.months))))
return E_DIV;
endif
delta = ({0, 31, 59, 90, 120, 151, 181, 212, 243, 273, 304, 334}[month] + dth) - 1;
day = (time() - 28800) / 86400;
day = (day - ((day + 672) / 1461)) - delta;
if (dir)
day = ((day / 365) + dir) + (dir <= 0);
else
day = ((2 * day) + 365) / 730;
endif
day = (day * 365) + delta;
day = day + ((day + 671) / 1460);
return (day * 86400) + 28800;

dst_midnight

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #38:_parse_date line 4: $time_utils:dst_midnight
• #38:_parse_date line 6: $time_utils:dst_midnight
• #38:_parse_date line 8: $time_utils:dst_midnight
• #38:_parse_date line 10: $time_utils:dst_midnight
• #38:_parse_date line 12: $time_utils:dst_midnight
• #38:_parse_date line 20: $time_utils:dst_midnight
• #38:_parse_date line 26: $time_utils:dst_midnight

Source

"Takes a time that is midnight PST and converts it to the nearest PDT midnight time if it's during that part of the year where we use PDT.";
time = args[1];
return time - (3600 * (((toint(ctime(time)[12..13]) + 12) % 24) - 12));

time_sub

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #49:@blacklist line 142: $time_utils:time_sub
• #49:display_list line 15: $time_utils:time_sub
• #49:display_list line 22: $time_utils:time_sub
• #53:to_text line 7: $time_utils:time_sub
• #90:timestr line 2: $time_utils:time_sub
• #118:command_history line 23: $time_utils:time_sub
• #118:command_history line 27: $time_utils:time_sub

Source

"Works like pronoun substitution, but substitutes time stuff.";
"Call with time_sub(string, time). returns a string.";
"time is an optional integer in time() format.  If omitted, time() is used.";
"Macros which are unknown are ignored. $Q -> the empty string.";
"Terminal $ are ignored.";
"$H -> hour #. $M -> min #. $S -> second #. 24-hour format, fixed width.";
"$h, $m, $s same x/c have not-fixed format. 00:03:24 vs. 0:3:24";
"$O/$o -> numeric hour in 12-hour format.";
"$D -> long day name. $d -> short day name.";
"$N -> long month name. $n -> short month name.";
"$Y -> long year # (e.g. '1991'). $y -> short year # (e.g. '91')";
"$Z -> the time zone    (added in by r'm later)";
"$P/$p -> AM/PM, or am/pm.";
"$T -> date number. $t -> date number with no extra whitespace etc.";
"$1 -> Month in fixed-width numeric format (01-12)   (added by dpk)";
"$2 -> Month in nonfixed numeric format (1-12)";
"$3 -> Date in fixed-width format, 0-fill";
"$$ -> $.";
"";
"This verb stolen from Ozymandias's #4835:time_subst.";
res = "";
{thestr, ?thetime = time()} = args;
if ((typeof(thestr) != STR) || (typeof(thetime) != INT))
player:tell("Bad arguments to time_subst.");
return;
endif
itslength = length(thestr);
if (!itslength)
return "";
endif
done = 0;
cctime = ctime(thetime);
while (dollar = index(thestr, "$"))
res = res + thestr[1..dollar - 1];
if (dollar == length(thestr))
return res;
endif
thechar = thestr[dollar + 1];
thestr[1..dollar + 1] = "";
if (thechar == "$")
res = res + "$";
elseif (!strcmp(thechar, "h"))
res = res + $string_utils:trim(tostr(toint(cctime[12..13])));
elseif (thechar == "H")
res = res + cctime[12..13];
elseif (!strcmp(thechar, "m"))
res = res + $string_utils:trim(tostr(toint(cctime[15..16])));
elseif (thechar == "M")
res = res + cctime[15..16];
elseif (!strcmp(thechar, "s"))
res = res + $string_utils:trim(tostr(toint(cctime[18..19])));
elseif (thechar == "S")
res = res + cctime[18..19];
elseif (!strcmp(thechar, "D"))
res = res + $time_utils:day(thetime);
elseif (thechar == "d")
res = res + cctime[1..3];
elseif (!strcmp(thechar, "N"))
res = res + $time_utils:month(thetime);
elseif (thechar == "n")
res = res + cctime[5..7];
elseif (!strcmp(thechar, "T"))
res = res + cctime[9..10];
elseif (thechar == "t")
res = res + $string_utils:trim(cctime[9..10]);
elseif (thechar == "O")
res = res + tostr(((toint(cctime[12..13]) + 11) % 12) + 1);
elseif (!strcmp(thechar, "p"))
res = res + ((toint(cctime[12..13]) >= 12) ? "pm" | "am");
elseif (thechar == "P")
res = res + ((toint(cctime[12..13]) >= 12) ? "PM" | "AM");
elseif (!strcmp(thechar, "y"))
res = res + cctime[23..24];
elseif (thechar == "Y")
res = res + cctime[21..24];
elseif (thechar == "Z")
res = res + cctime[26..28];
elseif (thechar == "1")
res = res + $string_utils:right(tostr($string_utils:explode(cctime)[2] in this.monthabbrs), 2, "0");
elseif (thechar == "2")
res = res + tostr($string_utils:explode(cctime)[2] in this.monthabbrs);
elseif (thechar == "3")
res = res + $string_utils:subst(cctime[9..10], {{" ", "0"}});
endif
endwhile
return res + thestr;

mmddyy ddmmyy

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #90:timestr line 2: $time_utils:ddmmyy

Source

"Copied from Archer (#52775):mmddyy Tue Apr  6 17:04:26 1993 PDT";
"Given a time() or ctime()-style date and an optional separator, this returns the MM/DD/YY or DD/MM/YY form of the date (depending on the verb called.)  The default seperator is '/'";
"Uses now, if no args.";
{?time = ctime(), ?divstr = "/"} = args;
if (typeof(time) == INT)
time = ctime(time);
elseif (typeof(time) != STR)
return E_TYPE;
endif
date = $string_utils:explode(time);
day = toint(date[3]);
month = date[2] in $time_utils.monthabbrs;
year = date[5];
daystr = (day < 10) ? "0" + tostr(day) | tostr(day);
monthstr = (month < 10) ? "0" + tostr(month) | tostr(month);
yearstr = tostr(year)[3..4];
if (verb == "mmddyy")
return tostr(monthstr, divstr, daystr, divstr, yearstr);
else
return tostr(daystr, divstr, monthstr, divstr, yearstr);
endif

parse_english_time_interval

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #35:parse_english_time_interval line 12: $time_utils:parse_english_time_interval
• #37:@set_expire line 14: $time_utils:parse_english_time_interval
• #49:@temp-newt line 10: $time_utils:parse_english_time_interval
• #49:parse_templist_duration line 24: $time_utils:parse_english_time_interval
• #59:parse_expire line 12: $time_utils:parse_english_time_interval

Source

"$time_utils:parse_english_time_interval(n1,u1,n2,u2,...)";
"or $time_utils:parse_english_time_interval(\"n1 u1[,] [and] n2[,] u2 [and] ...\")";
"There must be an even number of arguments, all of which must be strings,";
" or there must be just one argument which is the entire string to be parsed.";
"The n's are are numeric strings, and the u's are unit names.";
"The known units are in $time_utils.time_units,";
" which must be kept sorted with bigger times at the head.";
"Returns the time represented by those words.";
"For example,";
" $time_utils:parse_english_time_interval(\"30\",\"secs\",\"2\",\"minutes\",\"31\",\"seconds\") => 181";
if ((length(args) == 1) && index(args[1], " "))
return $time_utils:parse_english_time_interval(@$string_utils:words(args[1]));
endif
a = $list_utils:setremove_all(args, "and");
nargs = length(a);
if (nargs % 2)
return E_ARGS;
endif
nsec = 0;
n = 0;
for i in [1..nargs]
if ((i % 2) == 1)
if ($string_utils:is_numeric(a[i]))
n = toint(a[i]);
elseif (a[i] in {"a", "an"})
n = 1;
elseif (a[i] in {"no"})
n = 0;
else
return E_INVARG;
endif
else
unit = a[i];
if (unit[$] == ",")
unit = unit[1..$ - 1];
endif
ok = 0;
for entry in ($time_utils.time_units)
if ((!ok) && (unit in entry[2..$]))
nsec = nsec + (entry[1] * n);
ok = 1;
endif
endfor
if (!ok)
return E_INVARG;
endif
endif
endfor
return nsec;

seconds_until_date

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

none

Source

"Copied from Ballroom Complex (#29992):from_date by Keelah! (#30246) Tue Jul 13 19:42:32 1993 PDT";
":seconds_until_date(month,day,time,which)";
"month is a string or the numeric representation of the month, day is a number, time is a string in the following format, hh:mm:ss.";
"which==-1 => use most recent such month.";
"which==+1 => use first upcoming such month.";
"which==0 => use closest such month.";
"This will return the number of seconds until the month, day and time given to it.";
"Written by Keelah, on July 5, 1993.";
{month, day, time, which} = args;
converted = 0;
converted = converted + $time_utils:from_month(month, which, day);
current = this:seconds_until_time("12:00:00");
get_seconds = this:seconds_until_time(time);
if (get_seconds < 0)
get_seconds = (get_seconds + 39600) - current;
else
get_seconds = (get_seconds + 39600) - current;
endif
converted = (converted + get_seconds) - time();
return converted;

seconds_until_time

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #35:seconds_until_date line 12: this:seconds_until_time
• #35:seconds_until_date line 13: this:seconds_until_time

Source

"Copied from Ballroom Complex (#29992):seconds_until by Keelah! (#30246) Tue Jul 13 19:42:37 1993 PDT";
":seconds_until_time(hh:mm:ss)";
"Given the string hh:mm:ss, this returns the number of seconds until that hh:mm:ss. If the hh:mm:ss is before the current time(), the number returned is a negative, else the number is a positive.";
"Written by Keelah, on July 4, 1993.";
current = $time_utils:to_seconds(ctime()[12..19]);
time = $time_utils:to_seconds(args[1]);
return toint(time) - toint(current);

daytime_to_str

Spec this none thisFlags rxdOwner #361Definer #35

Referenced by

none

Source

daytime = args[1];
hour = daytime / 3600;
min = (daytime - (hour * 3600)) / 60;
hour = $math_utils:mod(hour, 24);
if (hour > 12)
hour = hour - 12;
ampm = "pm";
elseif (hour == 12)
ampm = "pm";
elseif (hour == 0)
hour = 12;
ampm = "am";
else
ampm = "am";
endif
ctime = (((hour < 10) ? "0" | "") + tostr(hour)) + ":";
ctime = (ctime + (((min < 10) ? "0" | "") + tostr(min))) + ampm;
return ctime;

english_time_rounded

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #49:@prog-check line 43: $time_utils:english_time_rounded
• #49:@prog-check line 52: $time_utils:english_time_rounded

Source

"Copied from time utilities (#43):english_time by Hacker (#36) Thu Sep  6 13:56:13 2007 CDT";
"english_time(time [,reference time]): returns the time as a string of";
"years, months, days, hours, minutes and seconds using the reference time as";
"the start time and incrementing forwards. it can be given in either ctime()";
"or time() format. if a reference time is not given, it is set to time().";
{_time, ?reftime = time()} = args;
if (_time < 1)
return "0 seconds";
endif
_ctime = (typeof(reftime) == INT) ? ctime(reftime) | reftime;
seclist = {60, 60, 24};
units = {"year", "month", "day", "hour", "minute", "second"};
timelist = {};
for unit in (seclist)
timelist = {_time % unit, @timelist};
_time = _time / unit;
endfor
months = 0;
month = _ctime[5..7] in $time_utils.monthabbrs;
year = toint(_ctime[21..24]);
"attribution: the algorithm used is from the eminently eminent g7.";
while (_time >= (days = this.monthlens[month] + (((month == 2) && ((year % 4) == 0)) && (!((year % 400) in {100, 200, 300})))))
_time = _time - days;
months = months + 1;
if ((month = month + 1) > 12)
year = year + 1;
month = 1;
endif
$command_utils:suspend_if_needed(0);
endwhile
timelist = {months / 12, months % 12, _time, @timelist};
for unit in (units)
i = unit in units;
if (timelist[i] > 0)
units[i] = ((tostr(timelist[i]) + " ") + units[i]) + ((timelist[i] == 1) ? "" | "s");
else
units = listdelete(units, i);
timelist = listdelete(timelist, i);
endif
endfor
return units[1];

abbrev_ctime

Spec this none thisFlags rxdOwner #361Definer #35

Referenced by

• #23:display_seq_headers line 15: $time_utils:abbrev_ctime
• #50:seccheck line 56: $time_utils:abbrev_ctime
• #150:service_long_queue line 15: $tu:abbrev_ctime
• #253:format_entry line 6: $time_utils:abbrev_ctime
• #293:txt_log line 16: $time_utils:abbrev_ctime
• #293:txt_log line 28: $time_utils:abbrev_ctime
• #293:txt_log line 37: $time_utils:abbrev_ctime
• #293:msg_summary_line line 9: $time_utils:abbrev_ctime
• #293:extra_text line 37: $time_utils:abbrev_ctime
• #293:msg_summary_line_colored line 11: $time_utils:abbrev_ctime
• #293:old_txt_log line 15: $time_utils:abbrev_ctime
• #293:old_txt_log line 22: $time_utils:abbrev_ctime
• #296:_readlog line 4: $time_utils:abbrev_ctime

Source

":abbrev_time([INT time]) => STR short time depending on how long ago it was.";
"if it wasn't this month, it's mon dy year, otherwise, mon dy time.";
{?time = time()} = args;
{dow, mon, day, tm, yr, tz} = $su:explode(ctime(time));
{nowdow, nowmon, nowday, nowtime, nowyr, nowtz} = $su:explode(ctime());
if ((yr != nowyr) || (mon != nowmon))
return tostr(mon, " ", day, " ", yr);
else
if ((nowday == day) && (nowmon == mon))
return tostr("Today ", tm[1..5]);
endif
return tostr(mon, " ", day, " ", tm[1..5]);
endif

longdate longdate_american

Spec this none thisFlags rxdOwner #361Definer #35

Referenced by

• #130:history line 33: $time_utils:longdate
• #297:report_from_issuelists line 42: $tu:longdate

Source

{?time = ctime()} = args;
if (typeof(time) == INT)
time = ctime(time);
elseif (typeof(time) != STR)
raise(E_TYPE);
endif
{dname, mname, mday, time, year} = $su:explode(time)[1..5];
dname = $tu.days[dname in $tu.dayabbrs];
mname = $tu.months[mname in $tu.monthabbrs];
if (verb == "longdate")
return $su:from_list({dname, mday, mname, year}, " ");
else
m = tostr(mname, " ", mday);
return $su:from_list({dname, m, year}, ", ");
endif

dhms_with_letters

Spec this none thisFlags rxdOwner #29Definer #35

Referenced by

• #50:paramedic line 4: $time_utils:dhms_with_letters

Source

"Copied from time utilities (#43):dhms by Hacker (#36) Fri Apr 30 21:48:30 2010 CDT";
s = args[1];
if (s < 0)
return "-" + this:(verb)(-s);
endif
m = s / 60;
s = s % 60;
if (m)
ss = tostr("m", s, "s");
h = m / 60;
m = m % 60;
if (h)
ss = tostr("h", m, ss);
d = h / 24;
h = h % 24;
return tostr(@d ? {d, "d"} | {}, h, ss);
else
return tostr(m, ss);
endif
else
return tostr(s, "s");
endif

dhms_short

Spec this none thisFlags rxdOwner #361Definer #35

Referenced by

none

Source

{secs} = args;
if (d = secs / 86400)
return tostr(d, "d");
elseif (h = secs / 3600)
return tostr(h, "h");
elseif (m = secs / 60)
return tostr(m, "m");
else
return tostr(secs, "s");
endif

daytime_to_secs

Spec this none thisFlags rxdOwner #361Definer #35

Referenced by

none

Source

":daytime_to_secs(STR) => INT -- converts things like 03:48:39 to a number of seconds since midnight.";
{timestr} = args;
broken = $su:explode(timestr, ":");
if (length(broken) == 3)
{h, m, s} = broken;
return ((tonum(h) * 3600) + (tonum(m) * 60)) + tonum(s);
elseif (length(broken) == 2)
{m, s} = broken;
return (tonum(m) * 60) + tonum(s);
else
raise(E_INVARG);
endif

jdn julian_day_number

Spec this none thisFlags rxdOwner #361Definer #35

Referenced by

• #35:jdn_to_interval line 2: this:julian_day_number
• #293:most_interesting line 3: $tu:julian_day_number

Source

":julian_day_number([INT time]) -> INT days since January 1 4713 BC";
{?when = time()} = args;
when = when - 18000;
return (when / 86400) + 2440587;

jdn_to_interval

Spec this none thisFlags rxdOwner #361Definer #35

Referenced by

• #293:jdn_msg_seq line 2: $tu:jdn_to_interval
• #293:most_interesting line 4: $tu:jdn_to_interval

Source

":jdn_to_interval([INT julian day number]) -> convert the given JDN, or today, into a list of {INT unixtime at 12:00:00 am, INT unixtime at 11:59:59 pm}";
{?jdn = this:julian_day_number()} = args;
jdn = jdn - 2440587;
daystart = (jdn * 86400) - 43200;
"adjust to CDT";
daystart = daystart - 25200;
dayend = daystart + 86399;
return {daystart, dayend};

day_number

Spec none none noneFlags rxdOwner #29Definer #35

Referenced by

none

Source

"Given a time() or ctime()-style date, this returns the number of the day.";
"With no args, uses now.";
if (args)
if (typeof(args[1]) == INT)
time = ctime(args[1]);
elseif (typeof(args[1]) == STR)
time = args[1];
else
return E_TYPE;
endif
else
time = ctime();
endif
dayabbr = $string_utils:explode(time)[1];
return dayabbr in this.dayabbrs;

parts

Spec this none thisFlags rxdOwner #361Definer #35

Referenced by

none

Source

{?time = ctime(), ?include_date = 0} = args;
if (typeof(time) == INT)
time = ctime(time);
elseif (typeof(time) != STR)
raise(E_INVARG);
endif
pieces = $string_utils:explode(time);
hms = {toint(pieces[4][1..2]), toint(pieces[4][4..5]), toint(pieces[4][7..8])};
if (!include_date)
return hms;
endif
return {@hms, pieces[1] in this.dayabbrs, pieces[2] in this.monthabbrs, toint(pieces[3]), toint(pieces[5]), pieces[6]};