generic genius #155

clear_queue

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

none

Source

":clear_queue()";
"Kill all queued actions.";
for x in ({@this.queue, this.executing})
if (length(x) > 5)
if (task_valid(x[6]))
kill_task(x[6]);
endif
endif
endfor
this.queue = {};
if (task_valid(this.process_queue) && (task_id() != this.process_queue))
kill_task(this.process_queue);
endif
if (this.executing)
this.executing = {};
endif

cancel_current_action

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

none

Source

":cancel_current_action([INT dontabort])";
"If we're currently executing an action, abort it and immediately start our next action.";
if (this.executing)
if (length(this.executing) > 5)
"...Some AI thread was waiting for this action to finish.  KILL IT.";
kill_task(this.executing[6]);
endif
if ((!args) || (!args[1]))
this.executing[1]:_abort(this, @this.executing[2..$]);
endif
this.executing = {};
if (task_valid(this.process_queue))
old_pq = this.process_queue;
this:fork_process_queue();
kill_task(old_pq);
endif
endif

process_queue

Spec this none thisFlags rxOwner #361Definer #155

Referenced by

none

Source

"Copied from Gilmore (#98):process_queue by Satan (#2) Mon Jun  7 20:36:31 2004 PDT";
"Copied from generic actor (#716):process_queue by Satan (#2) Mon Jun  7 15:47:39 2004 PDT";
":process_queue()";
"Keep running actions until we don't have any to run.";
player = this;
next_action_delay = 0;
if ((!this.queue) && (this.health > 0))
if (action = this:suggest_next_action())
this.queue = {action[1]};
next_action_delay = action[2];
endif
endif
while (this.queue)
this.preemptible = 0;
if (this.location == #742)
this.queue = {};
endif
if (this.queue)
action = this.queue[1];
this.preemptible = action[1].preemptible;
this.queue = listdelete(this.queue, 1);
this.last_action = action;
debugtext = $su:print(action[2..$]);
"...sanity check...";
if (((!action[2]) || (typeof(action[2][1]) != OBJ)) || (!is_a(action[2][1], $garbage)))
if (!this.location:check_forbid_action(this, @action))
"...nobody in here cancelled us...";
this.executing = {@action, @{$action, {}, 1, "", 0}[length(action) + 1..$]};
this:debug_tell("action", "start  | ", $su:nn(action[1]), " ", debugtext);
"...start the action...";
if (result = action[1]:_start(this, action[2]))
duration = result[1];
pass_to_finish = result[2];
else
duration = 0.0;
pass_to_finish = 0;
endif
durint = $math_utils:gil_float_to_int(duration);
suspend(durint);
"...finish the action...";
this:debug_tell("action", "finish | ", $su:nn(action[1]), " ", debugtext);
action[1]:_finish(this, action[2], pass_to_finish);
this.executing = {};
if (length(action) > 4)
"...wake up the waiting AI thread...";
resume(action[6], 1);
endif
else
this:debug_tell("action", "forbid | ", $su:nn(action[1]), " ", debugtext);
action[1]:_forbidden(this, @action[2..$]);
if (length(action) > 4)
resume(action[6], 0);
endif
endif
endif
endif
this.preemptible = next_action_delay > 0;
suspend(next_action_delay);
this.preemptible = 0;
if (!this.queue)
"...no more queued actions, do we have an auto-action?...";
if (result = this:suggest_next_action())
action = result[1];
if (((action[1] in $rpg.repeatable_actions) || is_player(this)) || (action != this.last_action))
next_action_delay = result[2];
"...add our auto-action to the queue...";
this.queue = {action};
endif
endif
else
next_action_delay = 0;
endif
endwhile
"...the queue's empty! go away now...";
this.process_queue = 0;

plan_action

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

• #155:p_walkto line 45: this:plan_action
• #155:p_resthome line 2: this:plan_action

Source

if (this.plan_action || ((this.executing && (length(this.executing) > 5)) && task_valid(this.executing[6])))
this:btell("PLAN BURP");
kill_task(task_id());
else
this.plan_action = {@args, @{$action, {}, 1, "", 0}[length(args) + 1..$], task_id()};
this:jumpstart();
return suspend($maxint);
endif

_do_plan

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

• #155:suggest_next_action line 3: this:_do_plan

Source

if (this.plan_action)
r = this.plan_action;
this.plan_action = {};
return r;
endif

suggest_next_action

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

• #155:process_queue line 8: this:suggest_next_action
• #155:process_queue line 62: this:suggest_next_action

Source

if (r = this:_fight())
return {r, 0};
elseif (r = this:_do_plan())
this.pwait = 1;
return {r, 0};
elseif (this.pwait)
return;
else
if (r = this:_wander())
return {r, this.wander_speed};
endif
endif

heartbeat

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

none

Source

pass(@args);
if (!task_valid(this.plan_task))
if (this.pwait)
this:btell("hmm, that's STRANGE.  i thought i had something important to do, but it seems to have vanished.");
this.pwait = 0;
endif
this.plan = "";
this.plan_task = 0;
if (p = this:next_plan())
this:change_plan(@p);
endif
elseif ((!this.executing) && (!this.queue))
pt = this.plan_task;
this.plan_task = 0;
resume(pt);
endif

plan_loop

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

none

Source

this.plan_msg = "thinking";

die

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

none

Source

if (task_valid(this.plan_task))
kill_task(this.plan_task);
endif
return pass(@args);

p_walkto

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

• #155:p_defend line 5: this:p_walkto
• #155:p_resthome line 1: this:p_walkto

Source

":p_walkto(OBJ dest, INT step delay[, STR reasoN, INT hurry])";
"Walk to the destination.  If 'hurry', don't stop to chat.";
{dest, delay, reason, ?hurry = 0} = args;
this.pwait = 1;
this.plan_msg = (("walking to " + dest.name) + " ") + reason;
abort = 0;
lastrooms = {};
if (is_a(dest, $room))
destwho = #-1;
else
destwho = dest;
dest = destwho.location;
endif
while ((!abort) && (this.location != dest))
if (valid(destwho) && (destwho.location == this.location))
this:btell("oh, i ran into ", destwho.name, " on my way to ", dest.name, "!");
return 1;
endif
if (hurry && ((time() - this.last_converse_time) < 5))
this:say(("Sorry, I have to get going " + reason) + ".");
this:btell("stupid talkers, wasting our precious time!");
suspend(1);
else
wait_on_converse = 0;
while ((time() - this.last_converse_time) < 30)
wait_on_converse = 1;
this.plan_msg = ("walking to " + dest.name) + ", but I stopped to chat.";
this:btell("waiting to finish talking");
suspend(5);
endwhile
if (wait_on_converse)
this:say("Alright, I gotta get moving.");
this.plan_msg = "walking to " + dest.name;
endif
endif
if (this.location in lastrooms)
this:btell("damn, i'm lost.");
this:say("Damn.  I'm lost.");
suspend(5);
abort = 1;
elseif (valid(hop = this.location:next_hop_to(dest)))
lastrooms = setadd(lastrooms, this.location);
oldloc = this.location;
this:btell("heading ", hop.name, " to get to ", dest.name, " (", reason, ")");
this:plan_action($actions.move, {hop}, 1, "");
suspend(delay);
while (this.executing || this.queue)
suspend(delay);
endwhile
if (this.location == oldloc)
this:say("Damn!  I'm stuck.");
this:btell("i couldn't go ", hop.name, ", apparently.");
abort = 1;
endif
else
this:btell("damn.  i don't know how to get to ", dest.name, " from ", this.location.name, ".");
return 0;
endif
endwhile
if (!abort)
this:btell("hey, i made it to ", this.location.name, "!");
endif
this.plan_msg = "";
this.pwait = 0;
return this.location == dest;

hear_say_to

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

none

Source

this.last_converse_time = time();
pass(@args);

tell_plan

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

none

Source

who = args[1];
this:say(("I'm " + this.plan_msg) + ".", who);

change_plan

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

• #155:heartbeat line 10: this:change_plan

Source

if (task_valid(this.plan_task))
this:btell(("I'm giving up my " + this.plan_msg) + " plan.");
kill_task(this.plan_task);
this.plan_task = 0;
endif
if (newplan = args[1])
this:btell(((("New plan - " + newplan) + " (") + $su:from_value(args[2..$], 1, 5)) + ")");
fork task_id (0)
try
this:(newplan)(@args[2..$]);
this.plan_task = 0;
this.plan = "";
except e (ANY)
$rpg:report_error(e);
endtry
endfork
this.plan_task = task_id;
this.plan = newplan;
endif

btell

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

• #155:plan_action line 2: this:btell
• #155:heartbeat line 4: this:btell
• #155:p_walkto line 16: this:btell
• #155:p_walkto line 21: this:btell
• #155:p_walkto line 28: this:btell
• #155:p_walkto line 37: this:btell
• #155:p_walkto line 44: this:btell
• #155:p_walkto line 52: this:btell
• #155:p_walkto line 56: this:btell
• #155:p_walkto line 61: this:btell
• #155:change_plan line 2: this:btell
• #155:change_plan line 7: this:btell
• #155:_wander line 2: this:btell
• #155:p_defend line 2: this:btell
• #155:p_defend line 6: this:btell
• #155:p_defend line 12: this:btell
• #155:p_defend line 22: this:btell
• #155:p_defend line 29: this:btell
• #155:p_defend line 33: this:btell

Source

for x in (this.brainlisteners)
x:tell($ansi.cyan, $ansi.bold_on, $su:nn(this), ": ", @args, $ansi.reset);
endfor

_wander

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

• #155:suggest_next_action line 9: this:_wander

Source

if (r = pass(@args))
this:btell("hmm, i think i'll wander ", r[4]);
endif
return r;

p_defend

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

none

Source

who = args[1];
this:btell("I've got to defend ", who.name, "!");
this.pwait = 1;
if (who.location != this.location)
if (!this:p_walkto(who, 1, "to defend " + who.name, 1))
this:btell("So much for defending ", who.name, ".");
return this.pwait = 0;
endif
endif
while ((foes = who.fighting) && (who.location == this.location))
foe = foes[1];
this:btell(foe.name, " is fighting ", who.name, ", and must therefore DIE.");
this:start_fighting(foe);
suspend(1);
while ((foe.location == this.location) && (foe in who.fighting))
if (!(foe in this.fighting))
this:start_fighting(foe);
endif
suspend(5);
endwhile
if (who.location != this.location)
this:btell("damn, ", who.name, " is gone!");
this.pwait = 0;
return 0;
endif
endwhile
this.pwait = 0;
if (who:is_in_afterlife())
this:btell("shit! ", who.name, " died and we couldn't save ", who.po, ".");
this:say("Why, God?  WHY?");
return 0;
else
this:btell("we saved ", who.name, "!");
this:say("You okay?", who);
this.last_converse_time = 0;
this.pwait = 0;
return 1;
endif

next_plan

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

• #155:heartbeat line 9: this:next_plan

Source

"Return the next plan to be executed on a heartbeat, if we don't already have one.";
return 0;

page_send

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

none

Source

who = args[1];
msg = args[2];
fork (1)
who:_receive(this, msg);
endfork

p_resthome

Spec this none thisFlags rxdOwner #361Definer #155

Referenced by

none

Source

if (this:p_walkto(this.home, 3, "to rest", 0))
this:plan_action($actions.recline, {this.location}, 1, "");
endif