generic body #148

suggest_next_action _wield com*mand _fight _unwield hkick elect_action hear_event default_elect_action dodge_or_parry at*tack kill hear_event_attack hear_event_move start_fighting knockout wake

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

return 0;

setup

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

• #104:setup line 2: pass(

Source

"setup(OBJ who) => Sets up the corpse so it resembles who's properties";
who = args[1];
destination = ((length(args) > 1) && is_a(args[2], $room)) ? args[2] | who.location;
"DO NOT ADD .meats MODIFYING CODE HERE";
this.player = who;
this:set_name(who:name());
this:set_aliases(who.aliases);
this.has_proper_name = who.has_proper_name;
$gender_utils:set(this, who.gender);
for x in ($ou:leaves($skill))
if (x.name in keys(who.skills))
this.skills[x.name] = who.skills[x.name];
endif
endfor
for prop in (this.sync_props)
`this.(prop) = who.(prop) ! ANY => 0';
endfor
this.body_parts = who.body_parts;
for x in (who.contents)
move(x, this);
endfor
this.posture = "passed out";
`this.clothing = who.clothing ! ANY';
move(this, who.location);
"DO NOT ADD .meats MODIFYING CODE HERE";

die

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

• #148:heartbeat line 7: this:die

Source

who = this.player;
this.health = 0;
if (is_a(who, $creature))
who:die(@args);
else
$nets.prognet:announce(this, "I am a fucked up $body.");
endif

breakdown

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

if (valid(who = this.player))
for x in (this.restore_props)
`who.(x) = this.(x) ! ANY => 0';
endfor
else
return 0;
endif
if (this:dead() && is_a(this, $corpse))
who.blood = this.restorable_blood;
endif
return 0;

search

Spec this none noneFlags rxdOwner #361Definer #148

Referenced by

none

Source

"Search the body for possible loot.";
player:aat($su:capitalize(player:dname()), " searches through ", this:dname(), ".");
if (is_a(this.player, $immortal))
player:tell("You don't find anything useful on ", this:dname(), ".");
return;
endif
if (`this.clothing ! ANY')
clothes = $su:english_list($lu:map_verb(this.clothing, "iname"));
player:tell(this:dnamec(), " is wearing ", clothes, ".");
endif
if (stuff = this:occupants($thing))
"  thelist = $su:english_list($lu:map_verb(stuff, \"iname\"));";
thelist = $english_utils:aggregate_names(stuff);
player:tell("On ", this:dname(), " you find ", thelist, ".");
else
player:tell("You don't find anything useful on ", this:dname(), ".");
endif

tell_health

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

if (this:is_dead())
player:tell(this:dnamec(), " seems to be dead.");
return;
endif
pass(@args);
if (valid(this.player))
player:tell(this:dnamec(), " seems to be passed out.");
endif

cant_take

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

return (this.ps + " is ") + (valid(this.player) ? "unconscious" | "dead");

is_dead

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

• #148:tell_health line 1: this:is_dead
• #148:_wake line 1: this:is_dead
• #148:kick line 3: this:is_dead

Source

":is_dead() => 0: unconscious,";
"              1: dead, but revivable from afterlife,";
"              2: dead and he ain't comin' back.";
return 0;

_wake

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

• #148:_eat line 14: this:_wake

Source

if (valid(this.player) && (this:is_dead() < 2))
this.player:_wake();
endif

threat_rating

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

return 0;

recycle

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

if ($ou:isa(this.player, $creature))
if (this.player.body == this)
this.player.body = #-1;
endif
endif
return pass(@args);

_knockout

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

if (valid(this.player) && $ou:isa(this.player, $creature))
this.player:_knockout(@args);
endif

kick

Spec this none noneFlags rxdOwner #361Definer #148

Referenced by

none

Source

player:tell("You give ", this:dname(), " a rough kick.");
player.location:announce(player:name(), " kicks ", this:dname(), ".");
if (this:is_dead())
player:tell(this.psc, "'s dead all right.");
else
player:tell(this.psc, "'s not dead yet.");
endif

_allows

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

return 1;

hear_event_arrive

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

return;
if ((args[3].name == this.name) && (!is_a(args[3], $corpse)))
this.name = "corpse of " + args[3].name;
this.has_proper_name = 0;
this.aliases = setremove(this.aliases, args[3].name);
endif

follow

Spec this none noneFlags rxdOwner #361Definer #148

Referenced by

none

Source

player:tell("Wouldn't it make more sense to follow someone who's alive and walking around?");

max_carry

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

return 100000;

heartbeat

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

pass(@args);
if ($rpg:valid(this) && is_a(this, $body))
if ((!is_a(this.player, $creature)) || ((valid(this.player) && is_a(this.player:area(), $real_area)) && (!(this.player:region() == $dreamworld))))
if (valid(this.player))
$nets.prognet:announce(this, (((("Killed " + $su:nn(this.player)) + " at the behest of this $body:heartbeat, while the body was at ") + $su:nn(this.location)) + " and the critter was at ") + $su:nn(this.player.location));
endif
this:die();
endif
endif

base_dodge

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

return args[1] + 10;

grab lunge hold

Spec this none noneFlags rxdOwner #361Definer #148

Referenced by

none

Source

player:tell("You get the feeling ", this:dname(), " isn't going to fight back.");
return 0;

_eat

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

"Copied from generic corpse (#5378):_eat by Gilmore (#98) Thu Mar 24 12:55:25 2005 PST";
who = args[1];
if ($ou:has_property(who, "feed_msg"))
m = who.feed_msg;
else
m = this.eat_msg;
endif
who:aat($su:ps(m));
for a in (this.blood)
who:ingest(a[1], a[3], 0);
endfor
this:take_damage(#277, 1, $bodypart, who);
if (random(100) < 25)
this:_wake();
endif

get_from

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

"Copied from generic corpse (#5378):get_from by Gilmore (#98) Sun May  1 01:09:55 2005 PDT";
"Copied from generic container (#931):get_from by Gilmore (#98) Mon Apr  4 22:59:27 2005 PDT";
who = args[1];
targets = (typeof(args[2]) == LIST) ? $lu:randomly_permute(args[2]) | {args[2]};
who:queue_action($actions.get, {targets, this, {}}, 1, "get from " + this.name);

cant_get_from

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

getter = args[1];
targets = args[2];
if ((!this.contents) || is_a(this.player, $immortal))
return this:dname() + " doesn't have anything to get";
endif
for x in (targets)
if (!(x in this.contents))
targets = setremove(targets, x);
endif
endfor
if (!targets)
return "it's not on " + this:dname();
endif
return 0;

explode

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

who = this.player;
if (is_a(who, $player))
$quests.giblets:award_to(who);
endif
if (is_a(who, $prog))
return 0;
endif
dtype = (length(args) > 1) ? args[2] | $damage;
if ((is_a(who, $creature) && is_a(this, $body)) && is_a(this.location, $room))
for x in (who.corpse.bodyparts)
if (random(100) <= `x.survive_chance ! E_PROPNF => 40')
thing = $rpg:spawn(x);
`thing:carve_from(this) ! E_VERBNF';
exits = this.location:exits();
if (exits)
exit = exits[random($)];
if ((random(100) < 50) && valid(dest = exit:throws_to(thing, who)))
dest:announce_all($su:ps(exit.otherside.throw_through_msg, who, thing, exit.otherside));
thing:moveto(dest);
else
thing:moveto(this.location);
endif
else
thing:moveto(this.location);
endif
endif
endfor
endif
for x in (this.contents)
this.location:broadcast_event(0, $actions.drop, who, {x, this.location});
x:moveto(this.location);
endfor
move(this, $tomb);

_brainscan

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

if (is_a(p = this.player, $living))
p:_brainscan(@args);
else
this:_whisper(args[1], "Who am I?  Will I ever wake up?");
endif

killed_by

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

if (is_a(this.player, $creature))
return this.player:killed_by(@args);
endif

put_into

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

No program (verb defined but unprogrammed).

cant_put_into

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

return "you just can't";

turn_to_corpse

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

":turn_to_corpse(dtype) => Convert this body into a corpse by changing its parent. Dtype should be the kind of damage that killed the creature.";
who = this.player;
if (is_a(who, $npc))
who.death_time = time();
endif
dtype = (length(args) >= 1) ? args[1] | $damage;
if (is_a(who, $creature))
if (valid(who.corpse))
if (who.corpse == $corpse)
$nets.gamenet:announce(#2, tostr($su:nn(who), " (", $su:nn(parent(who)), ") turned into a $corpse"), 1);
elseif (!is_a(who.corpse, $corpse))
$nets.prognet:announce(#2, tostr($su:nn(who), " (", $su:nn(parent(who)), " turned into a bad corpse: ", $su:nn(who.corpse)), 1);
endif
chparent(this, who.corpse);
this.bodyparts = who.corpse.bodyparts;
else
for x in (this.contents)
x:moveto(this.location);
endfor
move(this, $tomb);
return;
endif
else
chparent(this, $corpse);
endif
this:setup_for(who, dtype);

fighting_target

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

return this.player;

check*pulse

Spec this none noneFlags rxdOwner #29Definer #148

Referenced by

none

Source

player:queue_action(#531330, {this}, 1, "pulse check");

entomb

Spec this none thisFlags rxdOwner #361Definer #148

Referenced by

none

Source

"Copied from generic body (#1031):recycle by Gilmore (#98) Wed Jun  2 21:43:18 2010 CDT";
if ($ou:isa(this.player, $creature))
if (this.player.body == this)
this.player.body = #-1;
endif
endif
return pass(@args);