generic workbench #147

do_put

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

none

Source

{who, what} = args;
if (who:cant_take(what))
who:tell($su:ps(this.put_to_failed_msg, who, this, who.location, what, this));
return;
endif
what:moveto(this);
if (what.location == this)
who:tell($su:ps(this.put_to_msg, who, this, who.location, what, this));
who.location:announce_all_but({who}, $su:ps(this.oput_to_msg, who, this, who.location, what, this));
else
who:tell($su:ps(this.put_to_failed_msg, who, this, who.location, what, this));
endif

acceptable

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

none

Source

return 1;

do_get

Spec this none thisFlags rxdOwner #361Definer #147

Referenced by

none

Source

{who, what} = args;
if (who:cant_take(what))
who:tell($su:ps(this.get_from_failed_msg, who, this, who.location, what, this));
return;
endif
what:moveto(who);
if (what.location == who)
who:tell($su:ps(this.get_from_msg, who, this, who.location, what, this));
who.location:announce_all_but({who}, $su:ps(this.oget_from_msg, who, this, who.location, what, this));
else
who:tell($su:ps(this.get_from_failed_msg, who, this, who.location, what, this));
who.location:announce_all_but({who}, $su:ps(this.oget_from_failed_msg, who, this, who.location, what, this));
endif

tell_contents_old

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

none

Source

msg_db = {};
names = {};
if (args)
things = args[1];
else
things = this:contents();
endif
for x in (things)
if (is_a(x, $exit))
things = setremove(things, x);
endif
endfor
if (things)
msg_db = $su:message_db(things, "iname");
for x in (msg_db)
if (length(x[1]) > 1)
name = ($string_utils:aggregate_number(length(x[1])) + " ") + x[1][1]:pname();
else
name = x[2];
endif
names = {@names, name};
endfor
player:tell("You see ", $su:english_list(names), " on ", this:dname(), ".");
endif

look_self

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

none

Source

desc = this:description();
if (desc)
player:tell_lines(desc);
else
player:tell("You see nothing special.");
endif
this:tell_contents();

make_old

Spec any with/using thisFlags rxdOwner #29Definer #147

Referenced by

none

Source

product = this:match_product(dobjstr);
if (length(this.contents) >= this.max_objects)
player:tell(this:dnamec(), " is full, and you don't have room to make anything else on it.");
return;
endif
if (!valid(product))
player:tell($su:ps(this.make_failed_msg, player, this, this.location));
else
player:queue_action($actions.assemble, {this:match_recipe(dobjstr), player, this}, 1, ("assemble" + " ") + product.name);
endif

is_accepted_recipe

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

• #147:is_feasible line 2: this:is_accepted_recipe
• #147:accepted_products line 3: this:is_accepted_recipe
• #147:make line 16: this:is_accepted_recipe
• #147:make line 4: this:is_accepted_recipe
• #147:tell_recipes line 5: this:is_accepted_recipe

Source

{object} = args;
if (is_a(object, $recipe) && is_a(this, object.needs_bench))
return 1;
endif
recipes = this.recipe_type;
if (typeof(recipes) != LIST)
recipes = {recipes};
endif
for x in (recipes)
if (is_a(object, x))
return 1;
endif
endfor
return 0;

feasible_recipes

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

none

Source

recipes = {};
for recipe in (this:accepted_recipes())
if (this:is_feasible(recipe))
recipes = {@recipes, recipe};
endif
endfor
return recipes;

is_feasible

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

• #147:feasible_recipes line 3: this:is_feasible
• #147:do_make line 2: this:is_feasible
• #147:make line 4: this:is_feasible
• #147:tell_recipes line 7: this:is_feasible

Source

{recipe} = args;
if (this:is_accepted_recipe(recipe))
if (ingredients = recipe:find_ingredients(this))
return ingredients;
endif
endif

accepted_products

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

none

Source

items = {};
for item in ({@this:occupants($recipe), @this:occupants(#39999)})
if (this:is_accepted_recipe(item))
items = {@items, item.makes};
endif
if ((this:is_accepted_cookbook_page(item) && (length(item.pages) >= item.current_page)) && (item.current_page > 0))
items = {@items, item.pages[item.current_page].makes};
endif
endfor
return items;

do_make

Spec this none thisFlags rxdOwner #361Definer #147

Referenced by

none

Source

{recipe, who} = args;
if (requires = this:is_feasible(recipe))
check = this:skill_check(who, recipe);
if (check >= 0)
blood = {};
product = recipe.makes;
containers = {};
ingparents = {product};
for x in (recipe.ingredients)
ingparents = {@ingparents, x[1]};
endfor
for each in (requires)
if (is_a(each, $liquid))
liquid_amount = 0;
for xx in (recipe.ingredients)
if (is_a(each, xx[1]))
liquid_amount = xx[2];
endif
endfor
each:reduce_by(liquid_amount);
containers = setadd(containers, each.location);
else
if (is_a(each, $food) && each.blood)
blood = `this:add_blood(blood, each.blood) ! ANY => blood';
endif
each:moveto($tomb);
endif
endfor
diff = -2;
if (this.can_mix_drugs && has_property(product, "blood"))
for x in (this.contents)
if (((!(x in requires)) && (!(x in containers))) && `xb = x:cooked_blood() ! ANY')
is_ing = 0;
for y in (ingparents)
if (is_a(x, y))
is_ing = 1;
endif
endfor
if (!is_ing)
who:aat(who:dnamec(), " mixes ", x:iname(), " into the recipe.");
if ((check = $skills.chemistry:check(who, diff)) > 0)
blood = `this:add_blood(blood, xb) ! ANY => {}';
elseif (check < -3)
who:tell(x:dnamec(), " fizzles, then dissipates through the mixture...ruining it all.");
who:aat(who:dnamec(), " curses loudly.");
x:moveto($tomb);
return E_NONE;
else
who:tell(x:dnamec(), " dissolves uselessly. You fucked it up!  Oh well.");
endif
diff = diff - 3;
x:moveto($tomb);
endif
endif
endfor
endif
models = {};
for i in [1..recipe.makes_count]
model = this:make_product(product, check, who, requires);
`blood = model:blood_adjustment(blood) ! E_VERBNF';
`model.blood = blood ! ANY';
if (recipe.player_owned)
$wiz_utils:set_owner(model, who);
endif
`model = recipe:on_make(who, model, requires) ! E_VERBNF';
models = {@models, model};
endfor
xp = recipe:xp_value(who);
if (xp > 0)
who:award_xp(xp);
endif
m = this.make_msg;
om = this.omake_msg;
m = (recipe.makes_count > 1) ? strsub(m, "%id", tostr(recipe.makes_count, " ", $su:plural(model:name()))) | m;
om = (recipe.makes_count > 1) ? strsub(om, "%id", tostr(recipe.makes_count, " ", $su:plural(model:name()))) | om;
who:tell($su:ps(m, who, this, this.location, model, this));
who.location:announce_all_but({who}, $su:ps(om, who, this, who.location, model, this));
return models;
else
this:skill_check_failed(check, recipe, requires);
who:tell($su:ps(this.make_botched_msg, who, this, this.location, recipe, this));
who.location:announce_all_but({who}, $su:ps(this.omake_botched_msg, who, this, who.location, recipe, this));
return 0;
endif
endif

skill_check

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

• #147:do_make line 3: this:skill_check

Source

{player, recipe} = args;
check = 0;
for skillspec in (recipe.skill_required)
{skill, difficulty} = skillspec;
skill = (typeof(skill) == OBJ) ? skill | $skills.(skill);
check = skill:check(player, difficulty + this.quality);
if (check < 0)
return check;
endif
endfor
return check;

skill_check_failed

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

• #147:do_make line 80: this:skill_check_failed

Source

{score, recipe, requires} = args;
score = abs(score);
if ((score >= 5) && (this.damage_type != #-1))
ouch = (score + this.damage_mod) - 4;
ouch = max(1, ouch);
player:take_damage(this.damage_type, ouch, #3547);
player:tell($su:pronoun_sub(this.make_fuckup_msg));
player.location:announce($su:pronoun_sub(this.omake_fuckup_msg));
endif
score_percentage = (score * 100) / 20;
parts = length(requires);
i = parts / max(100 / max(1, score_percentage), 1);
if (i > 0)
player:tell("You lost ", tostr(i), " of your parts.");
for each in ($lu:randomly_permute(requires)[1..i])
$rpg:junk(each);
player:gain_stress(15);
endfor
endif

match_recipe

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

• #147:make_old line 9: this:match_recipe

Source

{matchstring} = args;
if (!matchstring)
if (length(r = this:accepted_recipes()) == 1)
return r[1];
endif
endif
if (typeof(matchstring) == OBJ)
item = matchstring;
else
item = this:match_product(matchstring);
endif
if (item == #-2)
"ambiguous";
player:tell("You need to be more specific -- I don't know what you mean by '", matchstring, "'. Also make sure you only have one book on your workbench at a time.");
return #-2;
endif
for each in (this:accepted_recipes())
if (each.makes == item)
return each;
endif
endfor
return #-1;

weight

Spec this none thisFlags rxdOwner #361Definer #147

Referenced by

none

Source

if (this.bolted)
return -1;
else
return pass(@args);
endif

is_feasible_old

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

none

Source

"Copied from generic workbench (#5144):is_feasible by Hasu (#4622) Fri Oct  5 02:07:45 2007 CDT";
{recipe} = args;
ingredients = recipe.ingredients;
requires = {};
for item in (this.contents)
for i in [1..length(ingredients)]
{ingredient, quantity} = ingredients[i];
if ($ou:isa(item, ingredient) && (ingredients[i][2] > 0))
ingredients[i] = {ingredient, quantity - 1};
requires = {@requires, item};
break;
endif
endfor
endfor
for each in (ingredients)
{ingredient, quantity} = each;
if (quantity > 0)
return 0;
endif
endfor
return requires;

make_product

Spec this none thisFlags rxdOwner #361Definer #147

Referenced by

• #147:do_make line 59: this:make_product

Source

product = args[1];
check = args[2];
maker = (length(args) > 2) ? args[3] | #-1;
ingredients = (length(args) > 3) ? args[4] | {};
model = $rpg:spawn(product);
`model = model:on_craft(maker, check, ingredients) ! E_VERBNF';
"if (this.craft_announce)";
"  $nets.craftnet:_announce(#-1, ((((maker:dnamec() + \" says, \\\"Made \") + model:iname()) + \" on \") + this:iname()) + \"!\\\"\", 1);";
"endif";
if (((model.weight == -1) || (model.weight > 50000)) && (!is_a(model, #105855)))
model:moveto(this.location);
else
model:moveto(this);
endif
return model;

add_blood

Spec this none thisFlags rxdOwner #29Definer #147

Referenced by

• #147:do_make line 24: this:add_blood
• #147:do_make line 42: this:add_blood

Source

{old, new} = args;
blood = old;
for newdrugspec in (new)
yield;
{newdrug, newtime, newdose} = newdrugspec;
for i in [1..length(blood)]
{drug, time, dose} = blood[i];
if (drug == newdrug)
blood[i][3] = dose + newdose;
continue newdrugspec;
endif
endfor
"must add it";
blood = {@blood, newdrugspec};
endfor
return blood;

list

Spec this none noneFlags rxdOwner #361Definer #147

Referenced by

none

Source

"List all recipes in the workbench, and show whether they can be made.";
this:tell_recipes();

make cook build ass*emble make1

Spec any on top of/on/onto/upon thisFlags rxdOwner #361Definer #147

Referenced by

• #147:make line 5: this:make1

Source

"Assemble a recipe indicated by number.";
r = this:all_recipes();
if (!r)
player:tell("There aren't any recipes in ", this:dname(), ".  You'll have to put one in.");
return;
endif
NUM = tonum(dobjstr);
if (NUM < 1)
player:tell("You need to give a number.  Try 'make 1 on ", this.name, "'.");
return;
elseif (NUM > length(r))
player:tell("There are only ", length(r), " recipes in ", this:dname(), ".");
return;
endif
recipe = r[NUM];
if (!this:is_accepted_recipe(recipe))
player:tell(recipe:dname(), " can't be assembled on ", this:iname(), ".");
return;
endif
if (valid(recipe.needs_bench) && (!is_a(this, recipe.needs_bench)))
player:tell("You realize you can't make ", recipe.makes:iname(), " on ", this:iname(), " -- you'd need ", recipe.needs_bench:iname(), ".");
return;
endif
if (is_a(this, recipe.needs_bench))
"";
else
if (!is_a(recipe, this.recipe_type))
player:tell(recipe:dnamec(), " cannot be used on ", this:dname(), ".");
return;
endif
endif
ing = recipe:find_ingredients(this);
if (typeof(ing) == OBJ)
player:tell("According to ", recipe:dname(), ", you need ", ing:iname(), " -- and you don't have one on ", this:dname(), ".");
return;
endif
player:queue_action($actions.craft, {recipe, player, this}, 1, "assemble");

make make2

Spec any none noneFlags rxdOwner #361Definer #147

Referenced by

none

Source

"Make the first available feasible recipe.";
i = 1;
for x in (this:all_recipes())
if (this:is_accepted_recipe(x) && this:is_feasible(x))
return this:make1(dobjstr = tostr(i));
endif
i = i + 1;
endfor
player:tell("There's no recipe in ", this:dname(), " that can be made with the ingredients inside.");

tell_recipes

Spec this none thisFlags rxdOwner #361Definer #147

Referenced by

• #147:list line 2: this:tell_recipes

Source

i = 1;
player:tell("Available recipes:");
for x in (this:all_recipes())
print = 1;
accepted = this:is_accepted_recipe(x);
if (accepted)
feasible = this:is_feasible(x);
else
feasible = 0;
endif
bold = "";
if (feasible)
check = (($ansi.green + $ansi.bold_on) + "*") + $ansi.reset;
bold = $ansi.bold_on;
elseif (accepted)
check = (($ansi.yellow + $ansi.bold_on) + "x") + $ansi.reset;
else
print = 0;
endif
if (print)
player:tell("  ", $ansi.bold_on, "[", check, $ansi.bold_on, "] ", $ansi.reset, bold, i, ". ", x.name, $ansi.reset);
endif
i = i + 1;
$cu:sin();
endfor
if (i > 1)
player:tell("To assemble a recipe: ", $ansi.bold_on, "make <number> on ", this.name, $ansi.reset, ".");
player:tell("To read a recipe: ", $ansi.bold_on, "read <number> in ", this.name, $ansi.reset, ".");
endif

all_recipes

Spec this none thisFlags rxdOwner #361Definer #147

Referenced by

• #147:make line 2: this:all_recipes
• #147:make line 3: this:all_recipes
• #147:tell_recipes line 3: this:all_recipes
• #147:read line 2: this:all_recipes

Source

r = {};
for x in (this:contents())
if (is_a(x, $recipe))
r = {@r, x};
elseif (is_a(x, $cookbook))
for y in (x.pages)
if (is_a(y, $recipe))
r = {@r, y};
endif
endfor
endif
endfor
return r;

read

Spec any any thisFlags rxdOwner #361Definer #147

Referenced by

none

Source

"Read a recipe in the workbench by number.";
r = this:all_recipes();
if (!r)
player:tell("There aren't any recipes in ", this:dname(), ".  You'll have to put one in.");
return;
endif
n = toint(dobjstr);
if (n < 1)
player:tell("You need to give a number.  Try 'read 1 in ", this.name, "'.");
return;
elseif (n > length(r))
player:tell("There are only ", length(r), " recipes in ", this:dname(), ".");
return;
endif
recipe = r[n];
player:tell("You peer into ", this:dname(), " to read ", recipe:dname(), ".");
suspend(1);
recipe:look_self();

_bolt _unbolt

Spec this none thisFlags rxdOwner #361Definer #147

Referenced by

none

Source

"Automatically generated for the boltable API.";
return $api.boltable.implementation:(verb)(this, @args);