Generic Editor #50

say

Spec any any anyFlags rxdOwner #36Definer #50

Referenced by

none

Source

if ((caller != player) && (caller_perms() != player))
return E_PERM;
endif
if (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
else
this:insert_line(who, argstr);
endif

emote

Spec any any anyFlags rxdOwner #36Definer #50

Referenced by

none

Source

if ((caller != player) && (caller_perms() != player))
return E_PERM;
endif
if (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
else
this:append_line(who, argstr);
endif

enter

Spec any none noneFlags rdOwner #36Definer #50

Referenced by

none

Source

if (!this:loaded(player))
player:tell(this:nothing_loaded_msg());
else
lines = $command_utils:read_lines();
if (typeof(lines) == ERR)
player:notify(tostr(lines));
return;
endif
this:insert_line(this:loaded(player), lines, 0);
endif

lis*t view

Spec any any anyFlags rdOwner #36Definer #50

Referenced by

none

Source

nonum = 0;
if (verb == "view")
if (!args)
l = {};
for i in [1..length(this.active)]
if (this.readable[i])
l = {@l, this.active[i]};
endif
endfor
if (l)
player:tell("Players having readable texts in this editor:  ", $string_utils:names_of(l));
else
player:tell("No one has published anything in this editor.");
endif
return;
elseif ($command_utils:player_match_result(plyr = $string_utils:match_player(args[1]), args[1])[1])
"...no such player";
return;
elseif ((!(who = this:loaded(plyr))) || (!this:readable(who)))
player:tell(plyr.name, "(", plyr, ") has not published anything in this editor.");
return;
endif
args = listdelete(args, 1);
elseif (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
return;
endif
len = length(this.texts[who]);
ins = this.inserting[who];
window = 8;
if (len < (2 * window))
default = {"1-$"};
elseif (ins <= window)
default = {tostr("1-", 2 * window)};
else
default = {tostr(window, "_-", window, "^"), tostr(2 * window, "$-$")};
endif
if (typeof(range = this:parse_range(who, default, @args)) != LIST)
player:tell(tostr(range));
elseif (range[3] && (!(nonum = "nonum" == $string_utils:trim(range[3]))))
player:tell("Don't understand this:  ", range[3]);
elseif (nonum)
player:tell_lines(this.texts[who][range[1]..range[2]]);
else
for line in [range[1]..range[2]]
this:list_line(who, line);
if ($command_utils:running_out_of_time())
suspend(0);
if (!(who = this:loaded(player)))
player:tell("ack!  something bad happened during a suspend...");
return;
endif
endif
endfor
if ((ins > len) && (len == range[2]))
player:tell("^^^^");
endif
endif

ins*ert n*ext p*revious .

Spec any none noneFlags rdOwner #36Definer #50

Referenced by

none

Source

if (i = index(argstr, "\""))
text = argstr[i + 1..$];
argstr = argstr[1..i - 1];
else
text = 0;
endif
spec = $string_utils:trim(argstr);
if (index("next", verb) == 1)
verb = "next";
spec = "+" + (spec || "1");
elseif (index("prev", verb) == 1)
verb = "prev";
spec = "-" + (spec || "1");
else
spec = spec || ".";
endif
if (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
elseif (ERR == typeof(number = this:parse_insert(who, spec)))
if (verb in {"next", "prev"})
player:tell("Argument must be a number.");
else
player:tell("You must specify an integer or `$' for the last line.");
endif
elseif ((number > (max = length(this.texts[who]) + 1)) || (number < 1))
player:tell("That would take you out of range (to line ", number, "?).");
else
this.inserting[who] = number;
if (typeof(text) == STR)
this:insert_line(who, text);
else
if (verb != "next")
(number > 1) ? this:list_line(who, number - 1) | player:tell("____");
endif
if (verb != "prev")
(number < max) ? this:list_line(who, number) | player:tell("^^^^");
endif
endif
endif

del*ete

Spec any any anyFlags rdOwner #36Definer #50

Referenced by

none

Source

if (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
elseif (typeof(range = this:parse_range(who, {"_", "1"}, @args)) != LIST)
player:tell(range);
elseif (range[3])
player:tell("Junk at end of cmd:  ", range[3]);
else
player:tell_lines((text = this.texts[who])[from = range[1]..to = range[2]]);
player:tell("---Line", (to > from) ? "s" | "", " deleted.  Insertion point is before line ", from, ".");
this.texts[who] = {@text[1..from - 1], @text[to + 1..$]};
if (!this.changes[who])
this.changes[who] = 1;
this.times[who] = time();
endif
this.inserting[who] = from;
endif

f*ind

Spec any any anyFlags rxdOwner #36Definer #50

Referenced by

none

Source

if (callers() && (caller != this))
return E_PERM;
endif
if (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
elseif (typeof(subst = this:parse_subst(argstr && (argstr[1] + argstr), "c", "Empty search string?")) != LIST)
player:tell(tostr(subst));
elseif (typeof(start = subst[4] ? this:parse_insert(who, subst[4]) | this.inserting[who]) == ERR)
player:tell("Starting from where?", subst[4] ? ("  (can't parse " + subst[4]) + ")" | "");
else
search = subst[2];
case = !index(subst[3], "c", 1);
text = this.texts[who];
tlen = length(text);
while ((start <= tlen) && (!index(text[start], search, case)))
start = start + 1;
endwhile
if (start > tlen)
player:tell("`", search, "' not found.");
else
this.inserting[who] = start + 1;
this:list_line(who, start);
endif
endif

s*ubst

Spec any any anyFlags rxdOwner #36Definer #50

Referenced by

none

Source

if (callers() && (caller != this))
return E_PERM;
endif
if (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
elseif (typeof(subst = this:parse_subst(argstr)) != LIST)
player:tell(tostr(subst));
elseif (typeof(range = this:parse_range(who, {"_", "1"}, @$string_utils:explode(subst[4]))) != LIST)
player:tell(range);
elseif (range[3])
player:tell("Junk at end of cmd:  ", range[3]);
else
fromstr = subst[1];
tostr = subst[2];
global = index(subst[3], "g", 1);
case = !index(subst[3], "c", 1);
munged = {};
text = this.texts[who];
changed = {};
for line in [from = range[1]..to = range[2]]
t = t0 = text[line];
if (!fromstr)
t = tostr + t;
elseif (global)
t = strsub(t, fromstr, tostr, case);
elseif (i = index(t, fromstr, case))
t = (t[1..i - 1] + tostr) + t[i + length(fromstr)..$];
endif
if (strcmp(t0, t))
changed = {@changed, line};
endif
munged = {@munged, t};
endfor
if (!changed)
player:tell("No changes in line", (from == to) ? tostr(" ", from) | tostr("s ", from, "-", to), ".");
else
this.texts[who] = {@text[1..from - 1], @munged, @text[to + 1..$]};
if (!this.changes[who])
this.changes[who] = 1;
this.times[who] = time();
endif
for line in (changed)
this:list_line(who, line);
endfor
endif
endif

m*ove c*opy

Spec any any anyFlags rdOwner #36Definer #50

Referenced by

none

Source

verb = (is_move = verb[1] == "m") ? "move" | "copy";
if (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
return;
endif
wargs = args;
t = to_pos = 0;
while (t = "to" in (wargs = wargs[t + 1..$]))
to_pos = to_pos + t;
endwhile
range_args = args[1..to_pos - 1];
if ((!to_pos) || (ERR == typeof(dest = this:parse_insert(who, $string_utils:from_list(wargs, " ")))))
player:tell(verb, " to where? ");
elseif ((dest < 1) || (dest > ((last = length(this.texts[who])) + 1)))
player:tell("Destination (", dest, ") out of range.");
elseif (("from" in range_args) || ("to" in range_args))
player:tell("Don't use that kind of range specification with this command.");
elseif (typeof(range = this:parse_range(who, {"_", "^"}, @args[1..to_pos - 1])) != LIST)
player:tell(range);
elseif (range[3])
player:tell("Junk before `to':  ", range[3]);
elseif ((is_move && (dest >= range[1])) && (dest <= (range[2] + 1)))
player:tell("Destination lies inside range of lines to be moved.");
else
from = range[1];
to = range[2];
ins = this.inserting[who];
text = this.texts[who];
if (!is_move)
this.texts[who] = {@text[1..dest - 1], @text[from..to], @text[dest..last]};
if (ins >= dest)
this.inserting[who] = ((ins + to) - from) + 1;
endif
else
"oh shit... it's a move";
if (dest < from)
newtext = {@text[1..dest - 1], @text[from..to], @text[dest..from - 1], @text[to + 1..last]};
if ((ins >= dest) && (ins <= to))
ins = (ins > from) ? (ins - from) + dest | (((ins + to) - from) + 1);
endif
else
newtext = {@text[1..from - 1], @text[to + 1..dest - 1], @text[from..to], @text[dest..last]};
if ((ins > from) && (ins < dest))
ins = (ins <= to) ? ((ins + dest) - to) - 1 | (((ins - to) + from) - 1);
endif
endif
this.texts[who] = newtext;
this.inserting[who] = ins;
endif
if (!this.changes[who])
this.changes[who] = 1;
this.times[who] = time();
endif
player:tell("Lines ", is_move ? "moved." | "copied.");
endif

join*literal

Spec any any anyFlags rdOwner #36Definer #50

Referenced by

none

Source

if (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
elseif (typeof(range = this:parse_range(who, {"_-^", "_", "^"}, @args)) != LIST)
player:tell(range);
elseif (range[3])
player:tell("Junk at end of cmd:  ", range[3]);
elseif (!(result = this:join_lines(who, @range[1..2], length(verb) <= 4)))
player:tell((result == 0) ? "Need at least two lines to join." | result);
else
this:list_line(who, range[1]);
endif

fill

Spec any any anyFlags rdOwner #36Definer #50

Referenced by

none

Source

fill_column = 70;
if (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
elseif (typeof(range = this:parse_range(who, {"_", "1"}, @args)) != LIST)
player:tell(range);
elseif (range[3] && ((range[3][1] != "@") || ((fill_column = toint(range[3][2..$])) < 10)))
player:tell("Usage:  fill [<range>] [@ column]   (where column >= 10).");
else
join = this:join_lines(who, @range[1..2], 1);
newlines = this:fill_string((text = this.texts[who])[from = range[1]], fill_column);
if (fill = ((nlen = length(newlines)) > 1) || (newlines[1] != text[from]))
this.texts[who] = {@text[1..from - 1], @newlines, @text[from + 1..$]};
if (((insert = this.inserting[who]) > from) && (nlen > 1))
this.inserting[who] = (insert + nlen) - 1;
endif
endif
if (fill || join)
for line in [from..(from + nlen) - 1]
this:list_line(who, line);
endfor
else
player:tell("No changes.");
endif
endif

pub*lish perish unpub*lish depub*lish

Spec none none noneFlags rdOwner #36Definer #50

Referenced by

none

Source

if (!(who = this:loaded(player)))
player:tell(this:nothing_loaded_msg());
return;
endif
if (typeof(e = this:set_readable(who, index("publish", verb) == 1)) == ERR)
player:tell(e);
elseif (e)
player:tell("Your text is now globally readable.");
else
player:tell("Your text is read protected.");
endif

w*hat

Spec none none noneFlags rxdOwner #36Definer #50

Referenced by

• #48:w*hat line 1: pass(

Source

if (!(this:ok(who = player in this.active) && (typeof(this.texts[who]) == LIST)))
player:tell(this:nothing_loaded_msg());
else
player:tell("You are editing ", this:working_on(who), ".");
player:tell("Your insertion point is ", (this.inserting[who] > length(this.texts[who])) ? "after the last line: next line will be #" | "before line ", this.inserting[who], ".");
player:tell(this.changes[who] ? this:change_msg() | this:no_change_msg());
if (this.readable[who])
player:tell("Your text is globally readable.");
endif
endif

abort

Spec none none noneFlags rdOwner #36Definer #50

Referenced by

none

Source

if (!this.changes[who = player in this.active])
player:tell("No changes to throw away.  Editor cleared.");
else
player:tell("Throwing away session for ", this:working_on(who), ".");
endif
this:reset_session(who);
if (this.exit_on_abort)
this:done();
endif

done q*uit pause

Spec none none noneFlags rxdOwner #36Definer #50

Referenced by

• #47:send line 41: this:done
• #50:abort line 8: this:done

Source

if (!(caller in {this, player}))
return E_PERM;
elseif (!(who = player in this.active))
player:tell("You are not actually in ", this.name, ".");
return;
elseif (!valid(origin = this.original[who]))
player:tell("I don't know where you came here from.");
else
player:moveto(origin);
if (player.location == this)
player:tell("Hmmm... the place you came from doesn't want you back.");
else
if (msg = this:return_msg())
player.location:announce($string_utils:pronoun_sub(msg));
endif
return;
endif
endif
player:tell("You'll have to use 'home' or a teleporter.");

huh2

Spec this none thisFlags rxdOwner #2Definer #50

Referenced by

none

Source

"This catches subst and find commands that don't fit into the usual model, e.g., s/.../.../ without the space after the s, and find commands without the verb `find'.  Still behaves in annoying ways (e.g., loses if the search string contains multiple whitespace), but better than before.";
set_task_perms(caller_perms());
if ((c = callers()) && ((c[1][1] != this) || (length(c) > 1)))
return pass(@args);
endif
verb = args[1];
v = 1;
vmax = min(length(verb), 5);
while ((v <= vmax) && (verb[v] == "subst"[v]))
v = v + 1;
endwhile
argstr = $code_utils:argstr(verb, args[2]);
if (((v > 1) && (v <= length(verb))) && (((vl = verb[v]) < "A") || (vl > "Z")))
argstr = (verb[v..$] + (argstr && " ")) + argstr;
return this:subst();
elseif ("/" == verb[1])
argstr = (verb + (argstr && " ")) + argstr;
return this:find();
else
pass(@args);
endif

insertion

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

none

Source

return this:ok(who = args[1]) && this.inserting[who];

set_insertion

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

none

Source

return this:ok(who = args[1]) && ((((ins = toint(args[2])) < 1) ? E_INVARG | ((ins <= (max = length(this.texts[who]) + 1)) || (ins = max))) && (this.inserting[who] = ins));

changed retain_session_on_exit

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #47:send line 42: this:changed
• #47:retain_session_on_exit line 1: pass(
• #47:no_littering_msg line 2: this:changed
• #48:e*dit line 1: this:changed
• #50:invoke line 9: this:changed
• #50:exitfunc line 2: this:retain_session_on_exit

Source

return this:ok(who = args[1]) && this.changes[who];

set_changed

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #47:set_subject line 5: this:set_changed
• #47:sending line 7: this:set_changed
• #47:to*: line 7: this:set_changed
• #47:also*-to: line 5: this:set_changed
• #47:not-to*: line 34: this:set_changed
• #47:reply-to*: line 6: this:set_changed
• #47:send line 11: this:set_changed
• #47:send line 29: this:set_changed
• #47:send line 32: this:set_changed
• #48:save line 26: this:set_changed
• #49:com*pile line 77: this:set_changed

Source

return this:ok(who = args[1]) && (((unchanged = !args[2]) || (this.times[who] = time())) && (this.changes[who] = !unchanged));

origin

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

none

Source

return this:ok(who = args[1]) && this.original[who];

set_origin

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

none

Source

return this:ok(who = args[1]) && (((valid(origin = args[2]) && (origin != this)) || ((origin == $nothing) || E_INVARG)) && (this.original[who] = origin));

readable

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #47:pri*nt line 6: this:readable
• #47:message_with_headers line 1: this:readable
• #50:lis*t line 19: this:readable
• #50:text line 2: this:readable

Source

return (((who = args[1]) < 1) || (who > length(this.active))) ? E_RANGE | this.readable[who];

set_readable

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:pub*lish line 5: this:set_readable

Source

return this:ok(who = args[1]) && (this.readable[who] = !(!args[2]));

text

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #47:message_with_headers line 1: this:text
• #48:save line 12: this:text
• #49:com*pile line 55: this:text
• #49:com*pile line 59: this:text
• #50:print line 1: this:text

Source

{?who = player in this.active} = args;
return (this:readable(who) || this:ok(who)) && this.texts[who];

load

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #47:init_session line 7: this:load
• #48:init_session line 3: this:load
• #49:init_session line 3: this:load

Source

texts = args[2];
if (!(fuckup = this:ok(who = args[1])))
return fuckup;
elseif (typeof(texts) == STR)
texts = {texts};
elseif ((typeof(texts) != LIST) || (length(texts) && (typeof(texts[1]) != STR)))
return E_TYPE;
endif
this.texts[who] = texts;
this.inserting[who] = length(texts) + 1;
this.changes[who] = 0;
this.readable[who] = 0;
this.times[who] = time();

working_on

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:w*hat line 4: this:working_on
• #50:abort line 4: this:working_on
• #50:invoke line 12: this:working_on
• #50:invoke line 16: this:working_on
• #50:invoke line 24: this:working_on
• #50:invoke line 27: this:working_on
• #50:enterfunc line 10: this:working_on

Source

"Dummy routine.  The child editor should provide something informative";
return this:ok(who = args[1]) && (("something [in " + this.name) + "]");

ok

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #47:working_on line 1: this:ok
• #47:init_session line 2: this:ok
• #47:message_with_headers line 1: this:ok
• #47:set_subject line 1: this:ok
• #47:sending line 1: this:ok
• #47:recipient_names line 1: this:ok
• #47:retain_session_on_exit line 1: this:ok
• #47:no_littering_msg line 2: this:ok
• #48:init_session line 1: this:ok
• #49:working_on line 1: this:ok
• #49:init_session line 2: this:ok
• #50:w*hat line 1: this:ok
• #50:insertion line 1: this:ok
• #50:set_insertion line 1: this:ok
• #50:changed line 1: this:ok
• #50:set_changed line 1: this:ok
• #50:origin line 1: this:ok
• #50:set_origin line 1: this:ok
• #50:set_readable line 1: this:ok
• #50:text line 2: this:ok
• #50:load line 2: this:ok
• #50:working_on line 2: this:ok
• #50:list_line line 2: this:ok
• #50:insert_line line 8: this:ok
• #50:append_line line 8: this:ok
• #50:join_lines line 2: this:ok
• #50:parse_number line 3: this:ok
• #50:parse_range line 3: this:ok
• #50:parse_insert line 2: this:ok
• #50:kill_session line 2: this:ok
• #50:reset_session line 2: this:ok

Source

who = args[1];
if ((who < 1) || (who > length(this.active)))
return E_RANGE;
elseif ((length(c = callers()) < 2) ? player == this.active[who] | ((c[2][1] == this) || ($perm_utils:controls(c[2][3], this.active[who]) || (c[2][3] == $generic_editor.owner))))
return 1;
else
return E_PERM;
endif

loaded

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #47:subj*ect: line 1: this:loaded
• #47:to*: line 1: this:loaded
• #47:also*-to: line 1: this:loaded
• #47:not-to*: line 1: this:loaded
• #47:reply-to*: line 1: this:loaded
• #47:send line 2: this:loaded
• #47:who line 8: this:loaded
• #48:save line 1: this:loaded
• #48:w*hat line 2: this:loaded
• #48:mode line 2: this:loaded
• #49:com*pile line 2: this:loaded
• #49:comment line 6: this:loaded
• #49:uncomment line 6: this:loaded
• #50:say line 4: this:loaded
• #50:emote line 4: this:loaded
• #50:enter line 1: this:loaded
• #50:enter line 9: this:loaded
• #50:lis*t line 19: this:loaded
• #50:lis*t line 24: this:loaded
• #50:lis*t line 49: this:loaded
• #50:ins*ert line 17: this:loaded
• #50:del*ete line 1: this:loaded
• #50:f*ind line 4: this:loaded
• #50:s*ubst line 4: this:loaded
• #50:m*ove line 2: this:loaded
• #50:join*literal line 1: this:loaded
• #50:fill line 2: this:loaded
• #50:pub*lish line 1: this:loaded
• #50:invoke line 9: this:loaded
• #50:enterfunc line 9: this:loaded
• #50:y*ank line 23: this:loaded
• #50:y*ank line 39: this:loaded
• #50:y*ank line 48: this:loaded
• #50:y*ank line 59: this:loaded
• #50:y*ank line 81: this:loaded

Source

return ((who = args[1] in this.active) && (typeof(this.texts[who]) == LIST)) && who;

list_line

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:lis*t line 46: this:list_line
• #50:ins*ert line 33: this:list_line
• #50:ins*ert line 36: this:list_line
• #50:f*ind line 22: this:list_line
• #50:s*ubst line 43: this:list_line
• #50:join*literal line 10: this:list_line
• #50:fill line 19: this:list_line

Source

$ansi_utils:add_noansi();
if (this:ok(who = args[1]))
f = 1 + ((line = args[2]) in {(ins = this.inserting[who]) - 1, ins});
player:tell($string_utils:right(line, 3, " _^"[f]), ":_^"[f], " ", this.texts[who][line]);
endif
$ansi_utils:remove_noansi();

insert_line

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #47:init_session line 16: this:insert_line
• #50:say line 7: this:insert_line
• #50:enter line 9: this:insert_line
• #50:ins*ert line 30: this:insert_line
• #50:append_line line 11: this:insert_line
• #50:y*ank line 23: this:insert_line
• #50:y*ank line 39: this:insert_line
• #50:y*ank line 48: this:insert_line
• #50:y*ank line 59: this:insert_line
• #50:y*ank line 81: this:insert_line

Source

":insert_line([who,] line or list of lines [,quiet])";
"  inserts the given text at the insertion point.";
"  returns E_NONE if the session has no text loaded yet.";
if (typeof(args[1]) != INT)
args = {player in this.active, @args};
endif
{who, lines, ?quiet = this.active[who]:edit_option("quiet_insert")} = args;
if (!(fuckup = this:ok(who)))
return fuckup;
elseif (typeof(text = this.texts[who]) != LIST)
return E_NONE;
else
if (typeof(lines) != LIST)
lines = {lines};
endif
p = this.active[who];
insert = this.inserting[who];
this.texts[who] = {@text[1..insert - 1], @lines, @text[insert..$]};
this.inserting[who] = insert + length(lines);
if (lines)
if (!this.changes[who])
this.changes[who] = 1;
this.times[who] = time();
endif
if (!quiet)
if (length(lines) != 1)
p:tell("Lines ", insert, "-", (insert + length(lines)) - 1, " added.");
else
p:tell("Line ", insert, " added.");
endif
endif
else
p:tell("No lines added.");
endif
endif

append_line

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:emote line 7: this:append_line

Source

":append_line([who,] string)";
"  appends the given string to the line before the insertion point.";
"  returns E_NONE if the session has no text loaded yet.";
if (typeof(args[1]) != INT)
args = {player in this.active, @args};
endif
{who, string} = args;
if (!(fuckup = this:ok(who)))
return fuckup;
elseif ((append = this.inserting[who] - 1) < 1)
return this:insert_line(who, {string});
elseif (typeof(text = this.texts[who]) != LIST)
return E_NONE;
else
this.texts[who][append] = text[append] + string;
if (!this.changes[who])
this.changes[who] = 1;
this.times[who] = time();
endif
p = this.active[who];
if (!p:edit_option("quiet_insert"))
p:tell("Appended to line ", append, ".");
endif
endif

join_lines

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:join*literal line 7: this:join_lines
• #50:fill line 9: this:join_lines

Source

{who, from, to, english} = args;
if (!(fuckup = this:ok(who)))
return fuckup;
elseif (from >= to)
return 0;
else
nline = "";
for line in ((text = this.texts[who])[from..to])
if (!english)
nline = nline + line;
else
len = length(line) + 1;
while ((len = len - 1) && (line[len] == " "))
endwhile
if (len > 0)
nline = (nline + line) + (index(".:", line[len]) ? "  " | " ");
endif
endif
endfor
this.texts[who] = {@text[1..from - 1], nline, @text[to + 1..$]};
if ((insert = this.inserting[who]) > from)
this.inserting[who] = (insert <= to) ? from + 1 | ((insert - to) + from);
endif
if (!this.changes[who])
this.changes[who] = 1;
this.times[who] = time();
endif
return to - from;
endif

parse_number

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:parse_range line 24: this:parse_number
• #50:parse_range line 29: this:parse_number
• #50:parse_range line 37: this:parse_number
• #50:parse_range line 38: this:parse_number
• #50:parse_range line 40: this:parse_number
• #50:parse_range line 42: this:parse_number

Source

"parse_number(who,string,before)   interprets string as a line number.  In the event that string is `.', `before' tells us which line to use.  Return 0 if string is bogus.";
{who, string, before} = args;
if (!(fuckup = this:ok(who)))
return fuckup;
endif
last = length(this.texts[who]);
ins = this.inserting[who] - 1;
after = !before;
if (!string)
return 0;
elseif ("." == string)
return ins + after;
elseif (!(i = index("_^$", string[slen = length(string)])))
return toint(string);
else
start = {ins + 1, ins, last + 1}[i];
n = 1;
if ((slen > 1) && (!(n = toint(string[1..slen - 1]))))
return 0;
elseif (i % 2)
return start - n;
else
return start + n;
endif
endif

parse_range

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #49:comment line 8: this:parse_range
• #49:uncomment line 8: this:parse_range
• #50:lis*t line 38: this:parse_range
• #50:del*ete line 3: this:parse_range
• #50:s*ubst line 8: this:parse_range
• #50:m*ove line 18: this:parse_range
• #50:join*literal line 3: this:parse_range
• #50:fill line 4: this:parse_range
• #50:parse_range line 10: this:parse_range

Source

"parse_range(who,default,@args) => {from to rest}";
numargs = length(args);
if (!(fuckup = this:ok(who = args[1])))
return fuckup;
elseif (!(last = length(this.texts[who])))
return this:no_text_msg();
endif
default = args[2];
r = 0;
while (default && (LIST != typeof(r = this:parse_range(who, {}, default[1]))))
default = listdelete(default, 1);
endwhile
if (typeof(r) == LIST)
from = r[1];
to = r[2];
else
from = to = 0;
endif
saw_from_to = 0;
not_done = 1;
a = 2;
while (((a = a + 1) <= numargs) && not_done)
if (args[a] == "from")
if ((a == numargs) || (!(from = this:parse_number(who, args[a = a + 1], 0))))
return "from ?";
endif
saw_from_to = 1;
elseif (args[a] == "to")
if ((a == numargs) || (!(to = this:parse_number(who, args[a = a + 1], 1))))
return "to ?";
endif
saw_from_to = 1;
elseif (saw_from_to)
a = a - 1;
not_done = 0;
elseif (i = index(args[a], "-"))
from = this:parse_number(who, args[a][1..i - 1], 0);
to = this:parse_number(who, args[a][i + 1..$], 1);
not_done = 0;
elseif (f = this:parse_number(who, args[a], 0))
from = f;
if ((a == numargs) || (!(to = this:parse_number(who, args[a + 1], 1))))
to = from;
else
a = a + 1;
endif
not_done = 0;
else
a = a - 1;
not_done = 0;
endif
endwhile
if (from < 1)
return tostr("from ", from, "?  (out of range)");
elseif (to > last)
return tostr("to ", to, "?  (out of range)");
elseif (from > to)
return tostr("from ", from, " to ", to, "?  (backwards range)");
else
return {from, to, $string_utils:from_list(args[a..numargs], " ")};
endif

parse_insert

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:ins*ert line 19: this:parse_insert
• #50:f*ind line 8: this:parse_insert
• #50:m*ove line 12: this:parse_insert

Source

"parse_ins(who,string)  interprets string as an insertion point, i.e., a position between lines and returns the number of the following line or 0 if bogus.";
if (!(fuckup = this:ok(who = args[1])))
return fuckup;
endif
{who, string} = args;
last = length(this.texts[who]) + 1;
ins = this.inserting[who];
if (i = index("-+", string[1]))
rest = string[2..$];
return ((n = toint(rest)) || (rest == "0")) ? {ins - n, ins + n}[i] | E_INVARG;
else
if (!(j = index(string, "^") || index(string, "_")))
offset = 0;
else
offset = (j == 1) || toint(string[1..j - 1]);
if (!offset)
return E_INVARG;
elseif (string[j] == "^")
offset = -offset;
endif
endif
rest = string[j + 1..$];
if (i = rest in {".", "$"})
return offset + {ins, last}[i];
elseif (!(n = toint(rest)))
return E_INVARG;
else
return (offset + (j && (string[j] == "^"))) + n;
endif
endif

parse_subst

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:f*ind line 6: this:parse_subst
• #50:s*ubst line 6: this:parse_subst

Source

{cmd, ?recognized_flags = "gc", ?null_subst_msg = "Null substitution?"} = args;
if (!cmd)
return "/xxx/yyy[/[g][c]] [<range>] expected..";
endif
bchar = cmd[1];
cmd = cmd[2..$];
fromstr = cmd[1..(b2 = index(cmd + bchar, bchar, 1)) - 1];
cmd = cmd[b2 + 1..$];
tostr = cmd[1..(b2 = index(cmd + bchar, bchar, 1)) - 1];
cmd = cmd[b2 + 1..$];
cmdlen = length(cmd);
b2 = 0;
while (((b2 = b2 + 1) <= cmdlen) && index(recognized_flags, cmd[b2]))
endwhile
return ((fromstr == "") && (tostr == "")) ? null_subst_msg | {fromstr, tostr, cmd[1..b2 - 1], cmd[b2..$]};

invoke

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #6:@notedit line 1: $note_editor:invoke
• #6:@edit line 6: $verb_editor:invoke
• #6:@edit line 13: $note_editor:invoke
• #40:@send line 12: $mail_editor:invoke
• #40:@answer line 10: $mail_editor:invoke
• #40:@gripe line 1: $mail_editor:invoke
• #40:@typo line 17: $mail_editor:invoke
• #40:@quickr*eply line 29: $mail_editor:invoke
• #40:@quick*send line 46: $mail_editor:invoke
• #49:e*dit line 4: this:invoke
• #104:@edit-d*etail line 8: $note_editor:invoke
• #118:@vdig line 66: $note_editor:invoke

Source

":invoke(...)";
"to find out what arguments this verb expects,";
"see this editor's parse_invoke verb.";
new = args[1];
if ((!(caller in {this, player})) && (!$perm_utils:controls(caller_perms(), player)))
"...non-editor/non-player verb trying to send someone to the editor...";
return E_PERM;
endif
if ((who = this:loaded(player)) && this:changed(who))
if (!new)
if (this:suck_in(player))
player:tell("You are working on ", this:working_on(who));
endif
return;
elseif (player.location == this)
player:tell("You are still working on ", this:working_on(who));
if (msg = this:previous_session_msg())
player:tell(msg);
endif
return;
endif
"... we're not in the editor and we're about to start something new,";
"... but there's still this pending session...";
player:tell("You were working on ", this:working_on(who));
if (!$command_utils:yes_or_no("Do you wish to delete that session?"))
if (this:suck_in(player))
player:tell("Continuing with ", this:working_on(player in this.active));
if (msg = this:previous_session_msg())
player:tell(msg);
endif
endif
return;
endif
"... note session number may have changed => don't trust `who'";
this:kill_session(player in this.active);
endif
spec = this:parse_invoke(@args);
if (typeof(spec) == LIST)
if ((player:edit_option("local") && $object_utils:has_verb(this, "local_editing_info")) && (info = this:local_editing_info(@spec)))
this:invoke_local_editor(@info);
elseif (this:suck_in(player))
this:init_session(player in this.active, @spec);
endif
endif

suck_in

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:invoke line 11: this:suck_in
• #50:invoke line 26: this:suck_in
• #50:invoke line 41: this:suck_in

Source

"The correct way to move someone into the editor.";
if (((loc = (who_obj = args[1]).location) != this) && (caller == this))
this.invoke_task = task_id();
who_obj:moveto(this);
if (who_obj.location == this)
try
"...forked, just in case loc:announce is broken...";
"changed to a try-endtry. Lets reduce tasks..Ho_Yan 12/20/96";
if (valid(loc) && (msg = this:depart_msg()))
loc:announce($string_utils:pronoun_sub(msg));
endif
except (ANY)
"Just drop it and move on";
endtry
else
who_obj:tell("For some reason, I can't move you.   (?)");
this:exitfunc(who_obj);
endif
this.invoke_task = 0;
endif
return who_obj.location == this;

new_session

Spec this none thisFlags rxdOwner #2Definer #50

Referenced by

• #50:accept line 1: this:new_session

Source

"WIZARDLY";
{who_obj, from} = args;
if ($object_utils:isa(from, $generic_editor))
"... never put an editor in .original, ...";
if (w = who_obj in from.active)
from = from.original[w];
else
from = #-1;
endif
endif
if (caller != this)
return E_PERM;
elseif (who = who_obj in this.active)
"... edit in progress here...";
if (valid(from))
this.original[who] = from;
endif
return -1;
else
for p in ({{"active", who_obj}, {"original", valid(from) ? from | $nothing}, {"times", time()}, @this.stateprops})
this.(p[1]) = {@this.(p[1]), p[2]};
endfor
return length(this.active);
endif

kill_session

Spec this none thisFlags rxdOwner #2Definer #50

Referenced by

• #47:send line 44: this:kill_session
• #50:invoke line 35: this:kill_session
• #50:exitfunc line 7: this:kill_session
• #50:do_flush line 11: this:kill_session

Source

"WIZARDLY";
if (!(fuckup = this:ok(who = args[1])))
return fuckup;
else
for p in ({@this.stateprops, {"original"}, {"active"}, {"times"}})
this.(p[1]) = listdelete(this.(p[1]), who);
endfor
return who;
endif

reset_session

Spec this none thisFlags rxdOwner #2Definer #50

Referenced by

• #50:abort line 6: this:reset_session

Source

"WIZARDLY";
if (!(fuckup = this:ok(who = args[1])))
return fuckup;
else
for p in (this.stateprops)
this.(p[1])[who] = p[2];
endfor
this.times[who] = time();
return who;
endif

kill_all_sessions

Spec this none thisFlags rxdOwner #2Definer #50

Referenced by

• #50:@flush line 13: this:kill_all_sessions
• #50:initialize line 3: this:kill_all_sessions
• #50:init_for_core line 3: this:kill_all_sessions

Source

"WIZARDLY";
if ((caller != this) && (!caller_perms().wizard))
return E_PERM;
else
for victim in (this.contents)
victim:tell("Sorry, ", this.name, " is going down.  Your editing session is hosed.");
victim:moveto(((who = victim in this.active) && valid(origin = this.original[who])) ? origin | (valid(victim.home) ? victim.home | $player_start));
endfor
for p in ({@this.stateprops, {"original"}, {"active"}, {"times"}})
this.(p[1]) = {};
endfor
return 1;
endif

acceptable

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:accept line 1: this:acceptable

Source

return is_player(who_obj = args[1]) && (who_obj.wizard || pass(@args));

enterfunc

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

none

Source

who_obj = args[1];
if (who_obj.wizard && (!(who_obj in this.active)))
this:accept(who_obj);
endif
pass(@args);
if (this.invoke_task == task_id())
"Means we're about to load something, so be quiet.";
this.invoke_task = 0;
elseif (who = this:loaded(who_obj))
who_obj:tell("You are working on ", this:working_on(who), ".");
elseif (msg = this:nothing_loaded_msg())
who_obj:tell(msg);
endif

exitfunc

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

• #50:suck_in line 17: this:exitfunc

Source

if (!(who = (who_obj = args[1]) in this.active))
elseif (this:retain_session_on_exit(who))
if (msg = this:no_littering_msg())
who_obj:tell_lines(msg);
endif
else
this:kill_session(who);
endif
pass(@args);

@flush

Spec this any anyFlags rxdOwner #36Definer #50

Referenced by

none

Source

"@flush <editor>";
"@flush <editor> at <month> <day>";
"@flush <editor> at <weekday>";
"The first form removes all sessions from the editor; the other two forms remove everything older than the given date.";
if ((caller_perms() != #-1) && (caller_perms() != player))
raise(E_PERM);
elseif (!$perm_utils:controls(player, this))
player:tell("Only the owner of the editor can do a ", verb, ".");
return;
endif
if (!prepstr)
player:tell("Trashing all sessions.");
this:kill_all_sessions();
elseif (prepstr != "at")
player:tell("Usage:  ", verb, " ", dobjstr, " [at [mon day|weekday]]");
else
p = prepstr in args;
if (t = $time_utils:from_day(iobjstr, -1))
elseif (t = $time_utils:from_month(args[p + 1], -1))
if (length(args) > (p + 1))
if (!(n = toint(args[p + 2])))
player:tell(args[p + 1], " WHAT?");
return;
endif
t = t + ((n - 1) * 86400);
endif
else
player:tell("couldn't parse date");
return;
endif
this:do_flush(t, "noisy");
endif
player:tell("Done.");

@stateprop

Spec any for/about thisFlags rdOwner #36Definer #50

Referenced by

none

Source

if (!$perm_utils:controls(player, this))
player:tell(E_PERM);
return;
endif
if (i = index(dobjstr, "="))
default = dobjstr[i + 1..$];
prop = dobjstr[1..i - 1];
if (argstr[1 + index(argstr, "=")] == "\"")
elseif (default[1] == "#")
default = toobj(default);
elseif (index("0123456789", default[1]))
default = toint(default);
elseif (default == "{}")
default = {};
endif
else
default = 0;
prop = dobjstr;
endif
if (typeof(result = this:set_stateprops(prop, default)) == ERR)
player:tell((result == E_RANGE) ? tostr(".", prop, " needs to hold a list of the same length as .active (", length(this.active), ").") | ((result != E_NACC) ? result | (prop + " is already a property on an ancestral editor.")));
else
player:tell("Property added.");
endif

@rmstateprop

Spec any out of/from inside/from thisFlags rdOwner #36Definer #50

Referenced by

none

Source

if (!$perm_utils:controls(player, this))
player:tell(E_PERM);
elseif (typeof(result = this:set_stateprops(dobjstr)) == ERR)
player:tell((result != E_NACC) ? result | (dobjstr + " is already a property on an ancestral editor."));
else
player:tell("Property removed.");
endif

initialize

Spec this none thisFlags rxdOwner #36Definer #50

Referenced by

none

Source

if ($perm_utils:controls(caller_perms(), this))
pass(@args);
this:kill_all_sessions();
endif

init_for_core

Spec this none thisFlags rxdOwner #2Definer #50

Referenced by

none

Source

if (caller_perms().wizard)
pass();
this:kill_all_sessions();
if (this == $generic_editor)
this.help = $editor_help;
endif
if ($object_utils:defines_verb(this, "is_not_banned"))
delete_verb(this, "is_not_banned");
endif
endif