Everyman #38

eval

Spec this none thisFlags rxdOwner #2Definer #38

Referenced by

• #49:uncomment line 20: $no_one:eval
• #59:verb_documentation line 15: $no_one:eval
• #59:verb_usage line 14: $no_one:eval

Source

"eval(code)";
"Evaluate code with $no_one's permissions (so you won't damage anything).";
"If code does not begin with a semicolon, set this = caller (in the code to be evaluated) and return the value of the first `line' of code.  This means that subsequent lines will not be evaluated at all.";
"If code begins with a semicolon, set this = caller and let the code decide for itself when to return a value.  This is how to do multi-line evals.";
exp = args[1];
if (this:bad_eval(exp))
return E_PERM;
endif
set_task_perms(this);
if (exp[1] != ";")
return eval(tostr("this=", caller, "; return ", exp, ";"));
else
return eval(tostr("this=", caller, ";", exp, ";"));
endif

moveto

Spec this none thisFlags rxdOwner #36Definer #38

Referenced by

none

Source

return 0;

eval_d

Spec this none thisFlags rxdOwner #2Definer #38

Referenced by

• #10:request_character line 23: $no_one:eval_d
• #30:subst line 21: $no_one:eval_d
• #30:subst line 31: $no_one:eval_d
• #58:@gethelp line 12: $no_one:eval_d
• #58:set_eval_env line 5: $no_one:eval_d

Source

":eval_d(code)";
"exactly like :eval except that the d flag is unset";
"Evaluate code with $no_one's permissions (so you won't damage anything).";
"If code does not begin with a semicolon, set this = caller (in the code to be evaluated) and return the value of the first `line' of code.  This means that subsequent lines will not be evaluated at all.";
"If code begins with a semicolon, set this = caller and let the code decide for itself when to return a value.  This is how to do multi-line evals.";
exp = args[1];
if (this:bad_eval(exp))
return E_PERM;
endif
set_task_perms(this);
if (exp[1] != ";")
return $code_utils:eval_d(tostr("this=", caller, "; return ", exp, ";"));
else
return $code_utils:eval_d(tostr("this=", caller, ";", exp, ";"));
endif

call_verb

Spec this none thisFlags rxdOwner #2Definer #38

Referenced by

none

Source

"call_verb(object, verb name, args)";
"Call verb with $no_one's permissions (so you won't damage anything).";
"One could do this with $no_one:eval, but ick.";
set_task_perms(this);
return args[1]:(args[2])(@args[3]);

bad_eval

Spec this none thisFlags rxdOwner #2Definer #38

Referenced by

• #38:eval line 6: this:bad_eval
• #38:eval_d line 7: this:bad_eval
• #59:eval_d line 7: $no_one:bad_eval

Source

"Return 1 if this code will call fork, suspend, or eval.";
"At present it's overzealous---it should check for delimited uses of the above calls, in case someone has a variable called prevalent.";
exp = args[1];
if ((index(exp, "eval") || index(exp, "fork")) || index(exp, "suspend"))
"Well, they had one of the evil words in here.  See if it was in a quoted string or not -- we want to permit player:tell(\"Gentlemen use forks.\")";
for bad in ({"eval", "fork", "suspend"})
l = index(exp, bad);
if (l && (!$code_utils:inside_quotes(exp[1..l])))
return 1;
endif
endfor
endif
return 0;

set_*

Spec this none thisFlags rxdOwner #36Definer #38

Referenced by

none

Source

if (!caller_perms().wizard)
return E_PERM;
else
return pass(@args);
endif