ANSI Utilities #32

length

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:show_who_listing line 85: this:length
• #32:left line 6: this:length
• #32:right line 6: this:length
• #32:centre line 6: this:length
• #32:columnize line 17: this:length
• #32:space line 3: this:length
• #32:space line 13: this:length
• #32:space line 18: this:length
• #32:fill_string line 14: this:length
• #91:tell_contents line 14: au:length
• #95:at_item line 7: $ansi_utils:length
• #95:at_item line 15: $ansi_utils:length
• #95:at_item line 15: $ansi_utils:length
• #104:look_self line 5: $ansi_utils:length
• #107:tell_contents line 14: au:length

Source

return length(index(a = args[1], "[") ? this:delete(a) | a);

index rindex

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:fill_string line 19: this:rindex
• #32:fill_string line 21: this:index
• #32:fill_string line 40: this:rindex
• #32:fill_string line 42: this:index
• #95:linesplit line 9: au:rindex

Source

":[r]index (STR string, STR character, NUM case_matters)";
"like index() and rindex() but ignores ANSI codes";
return (verb == "index") ? index(this:delete(args[1]), @listdelete(args, 1)) | rindex(this:delete(args[1]), @listdelete(args, 1));

contains_codes

Spec this none thisFlags rxOwner #36Definer #32

Referenced by

• #32:setadd line 6: this:contains_codes
• #32:setremove line 6: this:contains_codes
• #95:@ansi-title line 45: $ansi_utils:contains_codes

Source

":contains_codes(STR string) => True if <string> contains any ANSI codes";
return !(!match(args[1], this.all_regexp));

delete

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #10:notify line 2: $ansi_utils:delete
• #32:length line 1: this:delete
• #32:index line 3: this:delete
• #32:index line 3: this:delete
• #32:setadd line 7: this:delete
• #32:setadd line 9: this:delete
• #32:setremove line 9: this:delete
• #32:setremove line 12: this:delete
• #39:insert line 1: $ansi_utils:delete
• #39:insert line 2: $ansi_utils:delete
• #95:set_name line 7: $ansi_utils:delete
• #95:set_aliases line 9: $ansi_utils:delete
• #95:set_ansi_title line 16: au:delete
• #95:set_ansi_title line 22: au:delete

Source

":delete (STR string) => STR <string> with ANSI codes stripped out";
line = args[1];
if (this.active)
while (index = match(line, this.notify_regexp))
line[index[1]..index[2]] = "";
endwhile
line = strsub(line, "[null]", "");
endif
return line;

update_all

Spec this none thisFlags rxOwner #36Definer #32

Referenced by

• #32:add_code line 28: this:update_all
• #95:@ansi-s*tatus line 82: au:update_all

Source

if (!this:trusts(caller_perms()))
return E_PERM;
endif
codes = this.extra_codes;
"...we really don't need group regexps anymore, but I'm going to keep them around for a while just in case...";
for x in (this.groups)
this.(tostr("group_", x, "_regexp")) = tostr("%[%(", $string_utils:from_list(g = this.("group_" + x), "%|"), "%)%]");
codes = {@codes, @g};
endfor
this.all = codes;
this.all_regexp = tostr("%[%(", $string_utils:from_list(codes, "%|"), "%)%]");
this.terminate_regexp = tostr("%[%(", $string_utils:from_list($set_utils:difference(codes, {@this.default_codes, @this.group_extra}), "%|"), "%)%]");
this.notify_regexp = tostr("%[%(", $string_utils:from_list(setremove(codes, "null"), "%|"), "%)%]");
colors = {};
ccs = {};
for x in (this.group_colors)
if (!((a = this:get_code(x, "ESC")) in ccs))
colors = setadd(colors, x);
ccs = setadd(ccs, a);
endif
endfor
this.random_colors = colors;
this.replace_code_pointers = {};
index = 0;
leaves = $object_utils:leaves_suspended($ansi_pc);
data = {};
ll = length(leaves);
"...this will probably have to suspend on most large MOOs but you'll have to rewrite it so it can..";
while (index <= ll)
index = index + 1;
if (!is_player(leaves[index]))
elseif (typeof(x = this:update_player_codes(leaves[index])) != LIST)
elseif (!(i = $list_utils:iassoc(x, data, 2)))
data = listappend(data, {1, x});
elseif ((((data[i][1] + 1) * length(x)) / ll) >= 6)
"Must be at least 25% of people for 25 element long lists...";
"                 50%               12...";
"                 12%               50... etc";
this.replace_code_pointers = listappend(this.replace_code_pointers, x);
index = 0;
data = {};
else
data[i][1] = data[i][1] + 1;
endif
endwhile

get_code

Spec this none thisFlags rxOwner #36Definer #32

Referenced by

• #32:update_all line 17: this:get_code
• #32:notify line 16: this:get_code

Source

return (caller == this) ? strsub(strsub(this.("code_" + args[1]), "e", args[2] || this.escape, 1), "b", this.beep) | E_PERM;

cutoff*_suspended

Spec this none thisFlags rxOwner #36Definer #32

Referenced by

none

Source

":cutoff[_suspended] (STR string, NUM start, NUM end) => STR";
"Acts like: string[start..end] but ignores ANSI codes.";
args = {@args, 0}[1..4];
if (typeof(info = this:cutoff_locs(@args, verb == "cutoff_suspended")) == LIST)
return args[1][info[1]..info[2]];
else
return info;
endif

add_group

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

":add_group (STR group)";
"Adds <group> to the groups and makes a property for it.";
if (!this:trusts(caller_perms()))
return E_PERM;
elseif (!((args && args[1]) && (typeof(args[1]) == STR)))
return E_INVARG;
elseif (args[1] in this.groups)
return 0;
else
this.groups = setadd(this.groups, args[1]);
arg1 = {this, "group_" + args[1], {}, {$code_utils:verb_perms(), "r"}};
arg2 = {this, tostr("group_", args[1], "_regexp"), "", arg1[4]};
if ($object_utils:has_callable_verb(#0, "add_property"))
$add_property(@arg1);
$add_property(@arg2);
else
add_property(@arg1);
add_property(@arg2);
endif
$ansi_options:add_name(args[1]);
return 1;
endif

add_code

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

":add_code (STR code, NUM/STR sequence, STR group)";
"Adds a new code, <code> and adds it to group <group>.";
"If <sequence> is a string, it is used as the ANSI sequence, otherwise";
"it uses 'e[<sequence>m'.  'e' is replaced with the escape character, and";
"'b' is replaced with the beep character in <sequence>";
if (!this:trusts(caller_perms()))
return E_PERM;
elseif (length(args) < 3)
return E_ARGS;
elseif (!(((args[1] && (typeof(args[1]) == STR)) && (!$object_utils:has_property(this, cn = tostr("code_", args[1])))) && ((group = args[3]) in {@this.groups, E_NONE})))
return E_INVARG;
else
code = args[2];
if (typeof(code) == NUM)
code = tostr("e[", n, "m");
endif
arg = {this, cn, code, {$code_utils:verb_perms(), "r"}};
if ($object_utils:has_verb(#0, "add_property"))
$add_property(@arg);
else
add_property(@arg);
endif
if (args[3] == E_NONE)
this.extra_codes = setadd(this.extra_codes, args[1]);
else
this.("group_" + args[3]) = setadd(this.("group_" + args[3]), args[1]);
endif
this:update_all();
return 1;
endif

show_who_listing

Spec this none thisFlags rxOwner #36Definer #32

Referenced by

• #10:w*ho line 10: $ansi_utils:show_who_listing
• #10:w*ho line 18: $ansi_utils:show_who_listing

Source

":show_who_listing(players[,more_players])";
" prints a listing of the indicated players.";
" For players in the first list, idle/connected times are shown if the player is logged in, otherwise the last_disconnect_time is shown.  For players in the second list, last_disconnect_time is shown, no matter whether the player is logged in.";
idles = itimes = offs = otimes = listing = {};
for p in (args[2])
if (!valid(p))
listing = {@listing, tostr(p, " <invalid>")};
elseif (typeof(t = p.last_disconnect_time) == NUM)
(p in offs) || ((offs = {@offs, p}) && (otimes = {@otimes, {-t, -t, p}}));
elseif (is_player(p))
listing = {@listing, tostr(p.name, " (", p, ") ", (t == E_PROPNF) ? "is not a $player." | "has a garbled .last_disconnect_time.")};
else
listing = {@listing, tostr(p.name, " (", p, ") is not a player.")};
endif
endfor
for p in (args[1])
if (p in offs)
elseif (!valid(p))
listing = {@listing, tostr(p, " <invalid>")};
elseif ((typeof(i = idle_seconds(p)) != ERR) && (p in connected_players()))
(p in idles) || ((idles = {@idles, p}) && (itimes = {@itimes, {i, connected_seconds(p), p}}));
elseif (typeof(t = p.last_disconnect_time) == NUM)
(offs = {@offs, p}) && (otimes = {@otimes, {-t, -t, p}});
elseif (is_player(p))
listing = {@listing, tostr(p.name, " (", p, ") not logged in.", (t == E_PROPNF) ? "  Not a $player." | "  Garbled .last_disconnect_time.")};
else
listing = {@listing, tostr(p.name, " (", p, ") is not a player.")};
endif
endfor
if (!(idles || offs))
return 0;
endif
idles = $list_utils:sort_alist(itimes);
offs = $list_utils:sort_alist(otimes);
headers = {"Player name", @idles ? {"Connected", "Idle time"} | {"Last disconnect time", ""}, "Location"};
total_width = caller:linelen() || 79;
max_name = total_width / 4;
name_width = length(headers[1]);
names = locations = {};
for lst in ({@idles, @offs})
((ticks_left() < 2000) || (seconds_left() < 2)) && suspend(0);
p = lst[3];
"p.name and this:ansi_title(p) should be the same length, saves a call to this:length";
namestr = tostr(this:cutoff(this:ansi_title(p), 1, min(max_name, z = length(p.name)), 1), " (", p, ")");
name_width = max((z + 3) + length(tostr(p)), name_width);
names = {@names, namestr};
(typeof(wlm = p.location:who_location_msg(p)) == STR) || (wlm = valid(p.location) ? p.location.name | tostr("** Nowhere ** (", p.location, ")"));
locations = {@locations, wlm};
endfor
time_width = offs ? 15 | 13;
before = {0, w1 = 3 + name_width, w2 = w1 + time_width, w2 + time_width};
su = $string_utils;
tell1 = headers[1];
tell2 = su:space(tell1, "-");
for j in [2..4]
tell1 = su:left(tell1, before[j]) + headers[j];
tell2 = su:left(tell2, before[j]) + su:space(headers[j], "-");
endfor
listing = {@listing, tell1[1..min(length(tell1), total_width)]};
listing = {@listing, tell2[1..min(length(tell2), total_width)]};
"...";
"...print lines...";
"...";
active = 0;
for i in [1..total = (ilen = length(idles)) + length(offs)]
if (i <= ilen)
lst = idles[i];
if (lst[1] < (5 * 60))
active = active + 1;
endif
l = {names[i], su:from_seconds(lst[2]), su:from_seconds(lst[1]), locations[i]};
else
lct = offs[i - ilen][3].last_connect_time;
ldt = offs[i - ilen][3].last_disconnect_time;
ctime = caller:ctime(ldt) || ctime(ldt);
l = {names[i], (lct <= time()) ? ctime | "Never", "", locations[i]};
if ((i == (ilen + 1)) && idles)
listing = {@listing, su:space(before[2]) + "------- Disconnected -------"};
endif
endif
tell1 = l[1];
for j in [2..4]
tell1 = su:left(tell1, before[j]) + l[j];
endfor
listing = {@listing, this:cutoff(tell1, 1, min(this:length(tell1), total_width))};
if ($command_utils:running_out_of_time())
if ($login:is_lagging())
"Check lag two ways---global lag, but we might still fail due to individual lag of the queue this runs in, so check again later.";
listing = {@listing, tostr("Plus ", total - i, " other players (", total, " total; out of time and lag is high).")};
return;
endif
now = time();
suspend(0);
if ((time() - now) > 10)
listing = {@listing, tostr("Plus ", total - i, " other players (", total, " total; out of time and lag is high).")};
return;
endif
endif
endfor
"...";
"...epilogue...";
listing = {@listing, ""};
if (total == 1)
active_str = ", who has" + ((active == 1) ? "" | " not");
else
if (active == total)
active_str = (active == 2) ? "s, both" | "s, all";
elseif (active == 0)
active_str = "s, none";
else
active_str = tostr("s, ", active);
endif
active_str = tostr(active_str, " of whom ha", (active == 1) ? "s" | "ve");
endif
listing = {@listing, tostr("Total: ", total, " player", active_str, " been active recently.")};
vrb = ((caller == $login) || $perm_utils:controls($code_utils:verb_perms(), caller)) ? "notify" | "tell";
for line in (listing)
caller:(vrb)(line);
((seconds_left() < 2) || (ticks_left() < 4000)) && suspend(0);
endfor
return total;

notify

Spec this none thisFlags rxOwner #2Definer #32

Referenced by

• #32:test_benchmark line 13: $ansi_utils:notify
• #32:test_benchmark line 23: $ansi_utils:notify
• #32:test_benchmark line 26: $ansi_utils:notify
• #32:test_benchmark line 30: $ansi_utils:notify

Source

":notify (OBJ player, STR line[, extra parameters for notify])";
set_task_perms(caller_perms());
plr = args[1];
line = args[2];
"...use property_info() instead of $object_utils:isa to save ticks...";
if (((((index(line, "[") && valid(plr)) && property_info(plr, "ansi_options")) && this.active) && (!(task_id() in this.noansi_queue))) && (!plr:ansi_option("ignore")))
codes = (typeof(z = plr.replace_codes) == NUM) ? this.replace_code_pointers[z] | z;
esc = plr:ansi_option("escape");
while (m = match(line, this.notify_regexp))
z = line[m[1] + 1..m[2] - 1];
(z == "random") && (z = this.random_colors[random(length(this.random_colors))]);
"*****HTML CODE*****";
if (plr:ansi_option("html"))
line[m[1]..m[2]] = (z in codes) ? this:get_html_code(z) | "";
else
line[m[1]..m[2]] = (z in codes) ? this:get_code(z, esc) | "";
endif
"*****END HTML*****";
endwhile
line = strsub(line, "[null]", "");
if (plr:ansi_option("html"))
line = strsub(line, "\"><font", "\"");
endif
endif
if (plr:ansi_option("filter_tags"))
for pair in (this.filter_subs)
line = strsub(line, pair[1], pair[2]);
endfor
endif
return notify(plr, line, @args[3..length(args)]);

add_noansi

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:test_benchmark line 28: this:add_noansi
• #50:list_line line 1: $ansi_utils:add_noansi
• #58:@list*# line 107: $ansi_utils:add_noansi

Source

":add_noansi()";
"Called by tasks to tell players to ignore any ANSI codes from them.";
"Can be undone with a call to :remove_noansi";
if ((length(this.noansi_queue) > 30) && (!$code_utils:task_valid(this.noansi_task)))
fork tid (0)
this:cleanup_noansi();
endfork
this.noansi_task = tid;
endif
this.noansi_queue = setadd(this.noansi_queue, task_id());

remove_noansi

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:test_benchmark line 32: this:remove_noansi
• #50:list_line line 6: $ansi_utils:remove_noansi

Source

":remove_noansi()";
"Start translating the ANSI codes from the current task again";
this.noansi_queue = setremove(this.noansi_queue, task_id());

tell

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

return;

self_diagnostic

Spec this none thisFlags rxOwner #36Definer #32

Referenced by

• #95:@ansi-s*tatus line 78: au:self_diagnostic

Source

":self_diagnostic ([NUM fix[, OBJ plyr]]) => NUM errors fixed";
"Reports all errors found to <plyr> or the current player.";
"Fixes any errors it can if <fix> is specified and true.";
"<errors fixed> is the errors that could have been fixed if <fix> is false.";
if (!this:trusts(caller_perms()))
return E_PERM;
else
count = 0;
for x in (this.diagnostic_tests)
player:tell("Running test \"", x, "\"...");
count = count + (!(!this:("test_" + x)(@args)));
endfor
return count;
endif

trusts

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:update_all line 1: this:trusts
• #32:add_group line 3: this:trusts
• #32:add_code line 6: this:trusts
• #32:self_diagnostic line 5: this:trusts
• #32:update_player_codes line 3: this:trusts
• #95:@ansi-s*tatus line 26: au:trusts

Source

":trusts (OBJ player) => true of <player> is trusted by the ANSI system.";
return (args[1].wizard || (args[1] == this.owner)) || (args[1] in this.trusted);

cutoff_locs

Spec this none thisFlags rxOwner #36Definer #32

Referenced by

• #32:cutoff*_suspended line 4: this:cutoff_locs
• #32:cutoff_assign line 10: this:cutoff_locs
• #95:linesplit line 14: au:cutoff_locs

Source

":cutoff_locs (STR string,NUM start,NUM end[,NUM extra][, NUM suspendok])";
"                                                       => {nstart, nend}";
"Takes <start> and <end>, fixes them to compensate for the ANSI codes, and";
"returns them.  If <extra> is provided and true, <nend> will include the";
"codes after the ending letter.";
start = args[2];
end = args[3];
if (typeof(string = args[1]) != STR)
return E_INVARG;
elseif (!(index(string, "[") && this.active))
return {start, (end == "$") ? length(string) | end};
elseif (start > end)
return args[2..3];
endif
i = begin = 0;
x = 1;
extra = {@args, 0}[4];
reg = this.all_regexp;
l = length(string);
suspendok = {@args, 0}[5];
while (x <= l)
((suspendok && ((ticks_left() < 1000) || (seconds_left() < 2))) && player:tell("suspending...")) && suspend(0);
if (m = match(string, reg))
i = i + (m[1] - 1);
if ((!begin) && ((i + 1) >= start))
begin = (((x + m[1]) - i) + start) - 2;
if (end == "$")
return {begin, l};
endif
endif
if (begin && ((i - extra) >= end))
return {begin, (((x + m[1]) - i) + end) - 2};
endif
x = x + m[2];
string[1..m[2]] = "";
else
return {begin || (((x - i) + start) - 1), (end == "$") ? l | (((x - i) + end) - 1)};
endif
endwhile
return ((end == i) && begin) ? {begin, l} | E_RANGE;

cleanup_noansi

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:add_noansi line 6: this:cleanup_noansi

Source

while (this.noansi_queue && (!$command_utils:running_out_of_time()))
x = this.noansi_queue[1];
if (!$code_utils:task_valid(x))
this.noansi_queue = setremove(this.noansi_queue, x);
endif
endwhile

test_benchmark

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

if (caller != this)
return E_PERM;
else
new = $recycler:_create($ansi_pc);
if (typeof(new) != OBJ)
return player:tell("Unable to create Benchmark test player: ", new);
endif
new:set_name("Benchmark_test_player");
suspend(0);
ticks = ticks_left();
seconds = seconds_left();
for x in [1..3]
$ansi_utils:notify(new, "[blue]B[bold]e[unbold]n[bold]c[unbold]h[bold]m[unbold]a[bold]r[unbold]k [red]T[bold]e[unbold]s[bold]t [random].[random].[random].[random].[random].");
endfor
ticks = ticks - ticks_left();
seconds = seconds - seconds_left();
new:set_ansi_option("colors", 1);
new:set_ansi_option("escape", "~");
new:set_ansi_option("misc", 1);
ticks = ticks + ticks_left();
seconds = seconds + seconds_left();
for x in [1..3]
$ansi_utils:notify(new, "[blue]B[bold]e[unbold]n[bold]c[unbold]h[bold]m[unbold]a[bold]r[unbold]k [red]T[bold]e[unbold]s[bold]t [random].[random].[random].[random].[random].");
endfor
for x in [1..3]
$ansi_utils:notify(new, "Testing...");
endfor
this:add_noansi();
for x in [1..3]
$ansi_utils:notify(new, "[blue]B[bold]e[unbold]n[bold]c[unbold]h[bold]m[unbold]a[bold]r[unbold]k [red]T[bold]e[unbold]s[bold]t [random].[random].[random].[random].[random].");
endfor
this:remove_noansi();
ticks = ticks - ticks_left();
seconds = seconds - seconds_left();
$recycler:_recycle(new);
player:tell("12 notifies: ", ticks, " tick", (ticks == 1) ? "" | "s", ", ", seconds, " second", (seconds == 1) ? "" | "s", ".");
endif

cutoff_assign

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:fill_string line 33: this:cutoff_assign

Source

":cutoff_assign (STR string, NUM start, NUM end, STR replacement[, NUM extra])";
"                                => STR";
"Example:";
"  string[2..3] = \"test\";";
"Is the same as:";
"  string = $ansi_utils:cutoff_assign(string, 2, 3, \"test\");";
"Except that it ignores the ANSI codes in <string> when finding <start> and";
"<end>.  If <extra> is specified and true, any codes after <end> but before";
"the next character will also be overwritten.";
if (typeof(a = this:cutoff_locs(@listdelete(args, 4))) == LIST)
args[1][a[1]..a[2]] = args[4];
return args[1];
else
return a;
endif

setadd

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

":setadd (LIST l, value) => LIST";
"Does the same thing as the built-in setadd(), but if <value> is a string,";
"it won't be added to <l> if <value> with it's ANSI codes stripped out equals";
"any of <l>'s elements with their ANSI codes stripped out.";
l = args[1];
if ((typeof(value = args[2]) == STR) && this:contains_codes(value))
nvalue = this:delete(value);
for x in (l)
if ((typeof(x) == STR) && (this:delete(x) == nvalue))
return l;
endif
endfor
endif
return setadd(l, value);

setremove

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

":setremove (LIST l, value) => LIST";
"Does the same thing as the built-in setremove(), but if <value> is a";
"string, it will remove any string in <l> that, when it's ANSI codes are";
"stripped out, is equal to <value> with it's ANSI codes stripped out.";
l = args[1];
if ((typeof(value = args[2]) != STR) || (!this:contains_codes(value)))
return setremove(l, value);
endif
nvalue = this:delete(value);
for x in [-length(l)..-1]
x = -x;
if ((typeof(l[x]) == STR) && (this:delete(l[x]) == nvalue))
l = listdelete(l, x);
endif
endfor
return l;

ansi_status

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #95:@ansi-s*tatus line 31: $ansi_utils:ansi_status

Source

mess = {};
mess = {@mess, tostr("ANSI Version ", this.version, ":")};
a = 0;
for x in (this.groups)
a = a + length(this.("group_" + x));
endfor
mess = {@mess, tostr("It is ", this.active ? "currently" | "not", " active.  There are ", $string_utils:english_number(a), " codes defined in ", $string_utils:english_number(length(this.groups)), " groups.  There ", (length(this.noansi_queue) == 1) ? "is" | "are", " ", $string_utils:english_number(length(this.noansi_queue)), " tasks in the ignore ANSI task queue, and the cleanup task is ", $code_utils:task_valid(this.noansi_queue) ? "currently" | "not", " running.")};
return mess;

terminate_normal

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:left line 6: this:terminate_normal
• #32:right line 6: this:terminate_normal
• #32:centre line 6: this:terminate_normal
• #32:columnize line 15: this:terminate_normal
• #32:columnize line 17: this:terminate_normal
• #91:say line 4: $ansi_utils:terminate_normal
• #95:say line 8: au:terminate_normal
• #95:@ansi-title line 13: $ansi_utils:terminate_normal
• #95:set_ansi_title line 19: au:terminate_normal
• #95:set_ansi_title line 25: au:terminate_normal
• #116:say line 2: $ansi_utils:terminate_normal

Source

":terminate_normal (STR string) => STR <string> with a [[null]normal] code";
"tacked onto the end if there wasn't one";
if (!index(string = args[1], "["))
return string;
endif
m = rmatch(string, this.terminate_regexp);
while ((string && m) && (m[2] == length(string)))
string = string[1..m[1] - 1];
m = rmatch(string, this.terminate_regexp);
endwhile
return string && (string + ((m && (string[m[1]..m[2]] != "[normal]")) ? "[normal]" | ""));

left

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:columnize line 15: this:left

Source

"$ansi_utils:left(string,width[,filler])";
"";
"Assures that <string> is at least <width> characters wide.  Returns <string> if it is at least that long, or else <string> followed by enough filler to make it that wide. If <width> is negative and the length of <string> is greater than the absolute value of <width>, then the <string> is cut off at <width>.";
"";
"The <filler> is optional and defaults to \" \"; it controls what is used to fill the resulting string when it is too short.  The <filler> is replicated as many times as is necessary to fill the space in question.";
return this:terminate_normal(z = ((l = this:length(out = tostr(args[1]))) < (len = abs(args[2]))) ? out + this:space(l - len, ((length(args) >= 3) && args[3]) || " ") | ((args[2] > 0) ? out | this:cutoff(out, 1, len)));

right

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

"$ansi_utils:right(string,width[,filler])";
"";
"Assures that <string> is at least <width> characters wide.  Returns <string> if it is at least that long, or else <string> preceded by enough filler to make it that wide. If <width> is negative and the length of <string> is greater than the absolute value of <width>, then <string> is cut off at <width>.";
"";
"The <filler> is optional and defaults to \" \"; it controls what is used to fill the resulting string when it is too short.  The <filler> is replicated as many times as is necessary to fill the space in question.";
return this:terminate_normal(((l = this:length(out = tostr(args[1]))) < (len = abs(args[2]))) ? this:space(len - l, ((length(args) >= 3) && args[3]) || " ") + out | ((args[2] > 0) ? out | this:cutoff(out, 1, len)));

centre center

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #104:look_self line 4: $ansi_utils:center

Source

"$ansi_utils:center(string,width[,lfiller[,rfiller]])";
"";
"Assures that <string> is at least <width> characters wide.  Returns <string> if it is at least that long, or else <string> preceded and followed by enough filler to make it that wide.  If <width> is negative and the length of <string> is greater than the absolute value of <width>, then the <string> is cut off at <width>.";
"";
"The <lfiller> is optional and defaults to \" \"; it controls what is used to fill the left part of the resulting string when it is too short.  The <rfiller> is optional and defaults to the value of <lfiller>; it controls what is used to fill the right part of the resulting string when it is too short.  In both cases, the filler is replicated as many times as is necessary to fill the space in question.";
return this:terminate_normal(((l = this:length(out = tostr(args[1]))) < (len = abs(args[2]))) ? tostr(this:space((len - l) / 2, lfill = ((length(args) >= 3) && args[3]) || " "), out, this:space(((len - l) + 1) / -2, (length(args) >= 4) ? args[4] | lfill)) | ((args[2] > 0) ? out | this:cutoff(out, 1, len)));

columnize columnise

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

"columnize (items, n [, width]) - Turn a one-column list of items into an n-column list. 'width' is the last character position that may be occupied; it defaults to a standard screen width. Example: To tell the player a list of numbers in three columns, do 'player:tell_lines ($string_utils:columnize ({1, 2, 3, 4, 5, 6, 7}, 3));'.";
items = args[1];
n = args[2];
width = {@args, 79}[3];
height = ((length(items) + n) - 1) / n;
items = {@items, @$list_utils:make((height * n) - length(items), "")};
colwidths = {};
for col in [1..n - 1]
colwidths = listappend(colwidths, 1 - (((width + 1) * col) / n));
endfor
result = {};
for row in [1..height]
line = tostr(items[row]);
for col in [1..n - 1]
line = tostr(this:terminate_normal(this:left(line, colwidths[col])), " ", items[row + (col * height)]);
endfor
result = listappend(result, this:terminate_normal(this:cutoff(line, 1, min(this:length(line), width))));
endfor
return result;

space

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:left line 6: this:space
• #32:right line 6: this:space
• #32:centre line 6: this:space
• #32:centre line 6: this:space

Source

"space(len,fill) returns a string of length abs(len) consisting of copies of fill.  If len is negative, fill is anchored on the right instead of the left.";
n = args[1];
(typeof(n) == STR) && (n = this:length(n));
if (" " != (fill = {@args, " "}[2]))
fill = fill + fill;
fill = fill + fill;
fill = fill + fill;
elseif ((n = abs(n)) < 70)
return "                                                                      "[1..n];
else
fill = "                                                                      ";
endif
m = (n - 1) / this:length(fill);
while (m)
fill = fill + fill;
m = m / 2;
endwhile
return (n > 0) ? this:cutoff(fill, 1, n) | this:cutoff(fill, ((f = this:length(fill)) + 1) + n, f);

ansi_title

Spec this none thisFlags rxOwner #36Definer #32

Referenced by

• #32:show_who_listing line 44: this:ansi_title
• #95:say line 10: au:ansi_title
• #95:@ansi-title line 35: $ansi_utils:ansi_title
• #95:emote line 10: $ansi_utils:ansi_title

Source

":ansi_title (OBJ player[, STR name]) => STR <player>'s title";
"If <name> is specified, it will be used instead of <player>.name";
name = {@args, args[1].name}[2];
for x in (args[1].ansi_title)
if (typeof(x[2]) == LIST)
nn = x[2][random(length(x[2]))];
else
nn = x[2];
endif
nn && (name = strsub(name, x[1], nn));
endfor
return name;

strip_black

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

gray = 0;
x = 1;
string = args[1];
l = length(string);
while ((x <= l) && (m = match(string[x..l], this.all_regexp)))
code = string[x + m[1]..(x + m[2]) - 2];
if (code in {"gray", "grey"})
gray = 1;
elseif (code in this.group_colors)
gray = 0;
elseif (gray && (code == "unbold"))
string[x + m[2]..(x + m[2]) - 1] = "[white]";
x = x + 7;
endif
x = x + m[2];
endwhile
return string;

quote_ansi

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

":quote_ansi (STR string) => STR new_string";
"Puts a [[null]null] code in the middle of all of the other codes in <string>";
"so they won't be replaced.";
return strsub(args[1], "[", "[[null]");
"...should probably only fix real codes, but this works for now...";

update_player_codes

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

• #32:update_all line 32: this:update_player_codes
• #95:set_ansi_option line 15: $ansi_utils:update_player_codes

Source

":update_player_codes (OBJ player)";
"Updates <player>'s .replace_codes property";
if (!this:trusts(caller_perms()))
return E_PERM;
elseif ($object_utils:isa(plr = args[1], $ansi_pc))
codes = {};
for x in (this.groups)
if (plr:ansi_option(x))
codes = {@codes, @this.("group_" + x)};
(x == "extra") || (codes = setadd(codes, "normal"));
endif
endfor
return plr.replace_codes = (codes in this.replace_code_pointers) || codes;
endif

fill_string

Spec this none thisFlags rxdOwner #36Definer #32

Referenced by

none

Source

"fill(string,width[,prefix])";
"tries to cut <string> into substrings of length < <width> along word boundaries.  Prefix, if supplied, will be prefixed to the 2nd..last substrings.";
if (length(args) < 2)
width = 2 + player:linelen();
prefix = "";
else
width = args[2] + 1;
prefix = {@args, ""}[3];
endif
if (width < (3 + length(prefix)))
return E_INVARG;
endif
string = ("$" + args[1]) + " $";
len = this:length(string);
if (len <= width)
last = len - 1;
next = len;
else
last = this:rindex(this:cutoff(string, 1, width), " ");
if (last < ((width + 1) / 2))
last = width + this:index(this:cutoff(string, width + 1, "$", 1), " ");
endif
next = last;
while (string[next = next + 1] == " ")
endwhile
endif
while (string[last = last - 1] == " ")
endwhile
ret = {this:cutoff(string, 2, last)};
width = width - length(prefix);
minlast = (width + 1) / 2;
while (next < len)
string = this:cutoff_assign(string, 1, next - 1, "$");
"string = \"$\" + string[next..len];";
len = (len - next) + 2;
if (len <= width)
last = len - 1;
next = len;
else
last = this:rindex(this:cutoff(string, 1, width), " ");
if (last < minlast)
last = width + this:index(this:cutoff(string, width + 1, "$", 1), " ");
endif
next = last;
while (string[next = next + 1] == " ")
endwhile
endif
while (string[last = last - 1] == " ")
endwhile
if (last > 1)
ret = {@ret, prefix + this:cutoff(string, 2, last)};
endif
endwhile
return ret;

@ansi-setup

Spec this none noneFlags rxOwner #2Definer #32

Referenced by

none

Source

"Usage:  @ansi-setup <this>";
"Used to fix various core utilities to work with ANSI. This verb can only be used by a wizard, and needs wizperms to run.";
"Ugh, this verb is getting out of control, this stuff should all be moved to diagnostic tests.";
if (!player.wizard)
player:tell("This verb was intended to fix up the rest of a MOO's core so it can function properly with the ANSI PC. If something's wrong, ask a wizard to set this up for you.");
elseif (!$code_utils:verb_perms().wizard)
player:tell("This verb needs to be wizpermed before it can work.");
elseif (!$command_utils:yes_or_no("This will change various verbs in the core so they can be used with the ANSI PC, overwriting the previous verbs. Are you sure you want to do this?"))
player:notify("Well, okay then.");
else
set_task_perms(valid(cp = caller_perms()) ? cp | player);
spiffy = 1;
"----== Corify Objects ==----";
for x in ({"help", "pc", "utils", "options"})
prop = "ansi_" + x;
if (!$object_utils:has_property($sysobj, prop))
add_property($sysobj, prop, #-1, {player, "r"});
player:notify(tostr("Creating a $", prop, " property."));
endif
if (valid($sysobj.(prop)))
elseif (x == "utils")
player:notify(tostr("Setting $", prop, " to ", $string_utils:nn(this), "."));
$sysobj.(prop) = this;
else
objects = {};
for o in ({@player.owned_objects || {}, @player.public_identity.owned_objects || {}, @player.contents || {}, @player.location.contents || {}})
if (index(o.name, "ANSI") && index(o.name, strsub(x, "s", "")))
objects = setadd(objects, o);
endif
endfor
if (!objects)
return player:notify(tostr("Unable to find $", prop, ", please port this object and set #0.", prop, " to it's object number."));
elseif (length(objects) == 1)
player:notify(tostr("Setting $", prop, " to ", $string_utils:nn(objects[1]), "."));
$sysobj.(prop) = objects[1];
else
return player:notify(tostr("Found ", length(objects), " objects that could be $", prop, ", please set #0.", prop, " to the object number of the correct one:  ", $string_utils:nn_list(objects)));
endif
endif
endfor
"----== Wizperm everything that should be ==----";
for x in (this.need_wizperms)
if (!(info = verb_info(y = $sysobj.(x[1]), x[2]))[1].wizard)
player:notify(tostr("Wizperming $", x[1], ":", x[2], "..."));
set_verb_info(y, x[2], listset(info, player, 1));
endif
endfor
if (!($ansi_help in ((typeof(ah = $ansi_pc.help) == LIST) ? ah | {ah})))
player:notify("Setting $ansi_pc.help...");
$ansi_pc.help = $ansi_help;
endif
"----== Various core hacks ==----";
su = $string_utils;
if (!$object_utils:has_callable_verb(su, "redirect_ansi"))
player:notify("Adding $string_utils:redirect_ansi...");
add_verb(su, {$hacker, "rx", "redirect_ansi"}, {"this", "none", "this"});
set_verb_code(su, "redirect_ansi", this.redirect_su_code);
endif
for x in (this.redirect_su_names)
if ((info = verb_info(su, x)) && (!index(info[3], "redirect_ansi")))
nn = "";
for y in ($string_utils:explode(info[3], " "))
nn = tostr(nn, " ", y, "(noansi)");
endfor
set_verb_info(su, x, listset(info, $string_utils:triml(nn), 3));
player:notify(tostr("Renaming $string_utils:\"", info[3], "\" to \"", nn, "\"..."));
endif
endfor
redirect = $string_utils:from_list({"redirect_ansi", @this.redirect_su_names}, " ");
if ((info = verb_info(su, "redirect_ansi"))[3] != redirect)
player:notify(tostr("Renaming $string_utils:redirect_ansi to \"", redirect, "\"."));
set_verb_info(su, "redirect_ansi", listset(info, redirect, 3));
endif
$command_utils:suspend_if_needed(0);
((!((length(vc = verb_code($login, "notify")) == 2) && index(vc[2], "$ansi_utils:delete"))) && $command_utils:yes_or_no("Update $login:notify?")) ? set_verb_code($login, "notify", {"(caller!=$ansi_utils)&&set_task_perms(caller_perms());notify(player,$ansi_utils:delete(args[1]));"}) || $player:notify("$login:notify changed.") | ((spiffy = 0) || player:notify("$login:notify left alone."));
thatline = "line[1..min(width, length(line))]";
newline = "$ansi_utils:cutoff(line,1,min(width,$ansi_utils:length(line)))";
for x in ({"mail_agent", "big_mail_recipient"})
vc = $string_utils:print(verb_code(y = $sysobj.(x), vn = "display_seq_headers"));
player:notify(tostr("$", x, ":", vn, " ", ((index(vc, thatline) && $command_utils:yes_or_no(tostr("Replace \"", thatline, "\" in $", x, ":", vn, " with \"", newline, "\"?"))) && (set_verb_code(y, vn, $string_utils:to_value(strsub(vc, thatline, newline))[2]) == {})) ? "changed." | ((spiffy = 0) || "left alone.")));
endfor
code = {};
for x in (verb_code($login, "@who"))
code = {@code, strsub(x, "$code_utils:show_who_listing", "$ansi_utils:show_who_listing")};
endfor
if (code != verb_code($login, "@who"))
player:notify("Setting $login:@who...");
set_verb_code($login, "@who", code);
endif
$command_utils:suspend_if_needed(0);
code = {};
for x in (verb_code($guest, "do_reset", 0, 0))
if ((m = match(x, "^for x in (%(%{.+%}%))$")) && (info = $string_utils:to_value(substitute("%1", m)))[1])
x = tostr("for x in (", $string_utils:print($set_utils:union(info[2], $ansi_utils.reset_guest_props)), ")");
endif
code = {@code, x};
$command_utils:suspend_if_needed(0);
endfor
if (code != verb_code($guest, "do_reset", 0, 0))
player:notify("Setting $guest:do_reset...");
set_verb_code($guest, "do_reset", code);
endif
code = {};
for x in (verb_code($prog, "@list", 0, 0))
if (code == 0)
elseif (index(x, "$ansi_utils:add_noansi("))
code = 0;
elseif (index(x, "player:notify(tostr(what, \":\", fullname, \"") == 1)
code = {@code, "$ansi_utils:add_noansi();", x};
else
code = {@code, x};
endif
$command_utils:suspend_if_needed(0);
endfor
if (code && (code != verb_code($prog, "@list", 0, 0)))
player:notify("Setting $prog:@list...");
set_verb_code($prog, "@list", code);
endif
code = {};
a = {0, 0};
for x in (verb_code($generic_editor, "list_line"))
a[1] = a[1] || index(x, "$ansi_utils:add_noansi(");
a[2] = a[2] || index(x, "$ansi_utils:remove_noansi(");
code = {@code, x};
$command_utils:suspend_if_needed(0);
endfor
a[1] || (code = {"$ansi_utils:add_noansi();", @code});
a[2] || (code = {@code, "$ansi_utils:remove_noansi();"});
if (code != verb_code($generic_editor, "list_line"))
player:notify("Setting $generic_editor:list_line...");
set_verb_code($generic_editor, "list_line", code);
endif
$command_utils:suspend_if_needed(0);
if (!$object_utils:defines_verb($player_db, "insert"))
player:notify("Adding $player_db:insert...");
add_verb($player_db, {player, "rxd", "insert"}, {"this", "none", "this"});
set_verb_code($player_db, "insert", this.plr_db_insert);
elseif (verb_code($player_db, "insert") != this.plr_db_insert)
player:notify("$player_db:insert already exists, you will have to edit it manually for the ANSI, see $ansi_utils.plr_db_insert for sample code.");
endif
if (verb_code($generic_editor, "fill_string") != this.ge_fill_string)
a = "";
while ($object_utils:has_verb($generic_editor, vname = tostr("fill_string(noansi", a, ")")))
a = call_function("tonum", a) + 1;
endwhile
set_verb_info($generic_editor, "fill_string", listset(verb_info($generic_editor, "fill_string"), vname, 3));
add_verb($generic_editor, {player, "rx", "fill_string"}, {"this", "none", "this"}) || player:notify("Adding new $generic_editor:fill_string...");
set_verb_code($generic_editor, "fill_string", this.ge_fill_string);
endif
"...ugh, I want to put $prog:@dump in here but the one I put on NestMOO is too big to search...";
"----== Set the non-printable characters ==----";
try
$command_utils:suspend_if_needed(0);
for x in ({{"escape", 27, "033"}, {"beep", 7, "007"}})
chr = x[1];
code = x[2];
octal = x[3];
if ((typeof(this.(chr)) != STR) || (length(this.(chr)) != 1))
if (eval(";return chr(64);")[1])
player:notify(tostr("Setting $ansi_utils.", chr, " with chr()..."));
eval(tostr(";$ansi_utils.(\"", chr, "\")=chr(", code, ");"));
elseif ((eval = eval(";return filelist(\"\", \"\");"))[1])
if ((chr + ".chr") in eval[2][1])
player:notify(tostr("Setting $ansi_utils.", chr, " with FUP from file ", chr, ".chr..."));
eval(tostr(";$ansi_utils.(\"", chr, "\")=fileread(\"\", \"", chr, ".chr\")[1];"));
else
player:notify(tostr("FUP detected, please create a file named \"", chr, ".chr\" in the FUP directory and put an ASCII character ", code, " in it.  This can be done on most systems with the command:  echo -e '\\", octal, "' > ", chr, ".chr  from the FUP directory."));
spiffy = 0;
endif
else
z = this.(chr) = tostr("<----- ", $string_utils:uppercase(chr), " ----->");
player:notify(tostr("I can't find any way to set $ansi_utils.", chr, ", please either install the FUP or chr() server patches and rerun this verb, or shut down the MOO, load the DB into an editor, and replace \"", z, "\" with an ASCII character ", code, "."));
spiffy = 0;
endif
endif
endfor
except v (ANY)
player:notify("I could not set 'beep' and 'escape' properties on $ansi_utils. They may already be set to the proper characters.");
if ($command_utils:yes_or_no("I can put <beep> and <esc> where their characters are supposed to be in the database. You can change them with a text editor later. Do you want me to do this?"))
$ansi_utils.escape = "<esc>";
$ansi_utils.beep = "<beep>";
endif
endtry
if (this.active)
player:notify("@ansi-setup finished.");
elseif (!spiffy)
player:notify("@ansi-setup can not verify that everything has been set up correctly, you will probably have to rerun this verb.  If you're sure everything is correct, you can type:  ;;$ansi_utils.active=1;  to activate it.");
elseif ($command_utils:yes_or_no("Everything seems to be set up correctly, activate the ANSI system?"))
this.active = 1;
"...raw notify() the first message in case it breaks, we're wizpermed anyway...";
notify(player, "The ANSI system is now active, it can be deactivated by typing: ;;$ansi_utils.active = 0;");
player:notify(tostr("Welcome to ANSI version ", this.version, "."));
else
player:notify("Not activating the ANSI system, you can do this manually by typing: ;;$ansi_utils.active = 1;  when you're sure everything's set up correctly.");
endif
endif

get_html_code

Spec this none thisFlags rxOwner #36Definer #32

Referenced by

• #32:notify line 14: this:get_html_code

Source

if (args[1] == "normal")
return "</font>";
endif
tags = {@this.group_bold, @this.group_colors};
codes = {"size=\"+1\"", "", "size=\"+1\"", "", "color=\"red\"", "color=\"green\"", "color=\"yellow\"", "color=\"#2222FF\"", "color=\"blue\"", "color=\"#00DDDD\"", "color=\"#666666\"", "color=\"#666666\"", "color=\"#DD00DD\"", "color=\"white\""};
return tostr("<font ", codes[(args[1] in tags) || 2], ">");

player_wrap_off

Spec this none thisFlags rxOwner #2Definer #32

Referenced by

• #95:@ansi-o*ptions line 9: $ansi_utils:player_wrap_off

Source

if (caller == player)
force_input(player, "@wrap off");
endif