Character Generator #141

description

Spec this none thisFlags rxdOwner #36Definer #141

Referenced by

• #141:roll line 6: this:description
• #141:clear line 16: this:description

Source

desc = (typeof(d = pass(@args)) == LIST) ? d | {d};
if (this.type == "random")
bar = $string_utils:space(24, "=");
stats = {};
for line in [1..4]
space = ((st = player.stats[2][line]) < 10.0) ? " " | "";
stat = $string_utils:columnize({tostr("| ", player.stats[1][line]), (space + floatstr(st, 2)) + " |"}, 2, 33)[1];
stats = {@stats, stat + this.instructions_random[line]};
endfor
desc = this.clear_all_skills ? {bar, "WARNING: \"Race\", \"roll\" & \"clear\" will clear all skills.", @desc} | desc;
return {bar, @stats, bar, @desc};
elseif (this.type == "choice")
bar = $string_utils:space(player:linelen() - 13, "_");
st = tostr(floatstr(player.stats_current[2][1], 2), "/", floatstr(player.stats[2][1], 2));
spacer = $string_utils:space((player:linelen() / 2) - (19 + length(st)), " ");
st = tostr("STRENGTH", spacer, st);
DX = tostr(floatstr(player.stats_current[2][2], 2), "/", floatstr(player.stats[2][2], 2));
spacer = $string_utils:space((player:linelen() / 2) - (20 + length(DX)), " ");
DX = tostr("DEXTERITY", spacer, DX);
IQ = tostr(floatstr(player.stats_current[2][3], 2), "/", floatstr(player.stats[2][3], 2));
spacer = $string_utils:space((player:linelen() / 2) - (23 + length(IQ)), " ");
IQ = tostr("INTELLIGENCE", spacer, IQ);
HT = tostr(floatstr(player.stats_current[2][4], 2), "/", floatstr(player.stats[2][4], 2));
spacer = $string_utils:space((player:linelen() / 2) - (17 + length(HT)), " ");
HT = tostr("HEALTH", spacer, HT);
spacer = $string_utils:space((player:linelen() / 2) - 20, ".");
info = tostr(spacer, "CUR/MAX");
header = $string_utils:columnize({info, info}, 2, player:linelen() - 4);
stats = $string_utils:columnize({st, DX, IQ, HT}, 2, player:linelen() - 4);
stathead = tostr("STATISTICS", $string_utils:space(player:linelen() - 23, "_"));
persnl = $string_utils:columnize({player.gender, player.race, player.org, "free: " + floatstr(player.free_points, 2)}, 4, player:linelen() - 6);
desc = this.clear_all_skills ? {bar, "WARNING: \"Race\", \"org\" & \"clear\" will clear all skills.", @desc} | desc;
return {stathead, @header, @stats, bar, @persnl, bar, @this.instructions_choice, @desc};
else
return {"Here.type must be either \"random\" or \"choice\""};
endif

set_stats

Spec this none thisFlags rxdOwner #36Definer #141

Referenced by

• #141:roll line 5: this:set_stats

Source

"for random chargens";
who = args[1];
r = who.race in $list_utils:slice(this.races_random);
boost = (!r) ? {0.0, 0.0, 0.0, 0.0} | this.races_random[r][2];
who.stats[2][1] = $rp_regulator:random_stat(this.stat_keys[1]) + boost[1];
who.stats[2][2] = $rp_regulator:random_stat(this.stat_keys[2]) + boost[2];
who.stats[2][3] = $rp_regulator:random_stat(this.stat_keys[3]) + boost[3];
who.stats[2][4] = $rp_regulator:random_stat(this.stat_keys[4]) + boost[4];
who.stats_current = who.stats;
who.org = this.org;
this.clear_all_skills && clear_property(who, "skills");

facts

Spec none none noneFlags rdOwner #36Definer #141

Referenced by

none

Source

"for random chargens";
"automatically handles race penalties/bonuses report";
if (this.type != "random")
return player:tell_lines(this.instructions_choice);
endif
player:tell_lines(this.org_facts);
for r in (this.races_random)
racestring = ((("  " + $string_utils:capitalize($string_utils:a_or_an(r[1]))) + " ") + r[1]) + " has";
stats = {" to strength,", " to dexterity,", " to intelligence,", " to health,"};
bonustring = "";
for s in [1..4]
if (r[2][s] > 0.0)
bonustring = ((((bonustring + " a +") + floatstr(r[2][s], 2)) + " bonus") + stats[s]) + ",";
elseif (r[2][s] < 0.0)
bonustring = (((bonustring + " a ") + floatstr(r[2][s], 2)) + " penalty") + stats[s];
endif
endfor
bonustring = (!bonustring) ? " no bonuses or penalties." | bonustring[1..$ - 1];
bonustring[$] = ".";
bonustring = ((bonustring + " ") + $string_utils:capitalize(r[1])) + " languages: ";
langs = {};
for l in [1..length(r[3][1])]
langs = (r[3][2][l] >= 2.0) ? {@langs, r[3][1][l].lang_name} | {@langs, "some " + r[3][1][l].lang_name};
endfor
player:tell(((racestring + bonustring) + $string_utils:english_list(langs)) + ".");
endfor

roll

Spec none none noneFlags rdOwner #36Definer #141

Referenced by

none

Source

"for random chargens";
if (this.type != "random")
return player:tell("This is not a random statistics generator.");
endif
this:set_stats(player);
player:tell_lines(this:description());

clear

Spec none none noneFlags rdOwner #36Definer #141

Referenced by

none

Source

clear_property(player, "stats");
clear_property(player, "stats_current");
clear_property(player, "org");
clear_property(player, "race");
clear_property(player, "short_desc_msg");
(this.type == "choice") && (player.free_points = 50.0);
(this.type == "random") && (player.org = this.org);
if (this.clear_all_skills)
clear_property(player, "skills");
clear_property(player, "languages");
clear_property(player, "speaking");
clear_property(player, "remembered_names");
clear_property(player, "short_desc_msg");
clear_property(player, "money");
endif
player:tell_lines(this:description());

race

Spec none none noneFlags rdOwner #36Definer #141

Referenced by

none

Source

this:pick_race(@args);

org

Spec none none noneFlags rdOwner #36Definer #141

Referenced by

none

Source

if (this.type != "random")
this:pick_org(@args);
else
player:tell_lines(this.org_facts);
endif

pick_race

Spec this none thisFlags rxdOwner #36Definer #141

Referenced by

• #141:race line 1: this:pick_race

Source

"USAGE: pick_race()";
"Allows player to choose a race, and adjustments are made to stats.";
if (player.location != this)
return;
endif
racelist = {};
raceprop = "races_" + this.type;
if (length(this.(raceprop)) == 1)
if (this.(raceprop)[1][1] == player.race)
return player:tell("You are already \"", player.race, "\".");
else
player:tell("========================================================");
player:tell("Your current race is \"", player.race, "\". The only race available here is \"", this.(raceprop)[1][1], "\".");
if (!$command_utils:yes_or_no("Do you want to become one now?"))
return player:tell("Your race remains unchanged.");
endif
player.race = this.(raceprop)[1][1];
endif
else
r = 0;
for race in (this.(raceprop))
r = r + 1;
racelist = {@racelist, tostr(r, " - ", race[1])};
endfor
player:tell("========================================================");
player:tell_lines($string_utils:columnize(racelist, 2, 50));
if (!$command_utils:yes_or_no("Do you know enough about these races to make the choice?"))
return player:tell("Type \"? <race name>\" to find out more.");
endif
ok = 0;
while (!ok)
player:tell("Enter the race name or index number.");
newrace = $command_utils:read();
if (((x = toint(newrace)) && (x <= length(this.(raceprop)))) && (x > 0))
player.race = this.(raceprop)[x][1];
ok = 1;
elseif (x = newrace in $list_utils:slice(this.(raceprop)))
player.race = this.(raceprop)[x][1];
ok = 1;
else
player:tell("Invalid race.");
endif
endwhile
endif
x = player.race in $list_utils:slice(this.(raceprop));
if (this.type == "random")
player.stats[2] = {0.0, 0.0, 0.0, 0.0};
player.stats_current = player.stats;
player.languages = this.(raceprop)[x][3];
player:tell("You must 'roll' now.");
elseif (g = player.org in $list_utils:slice(this.orgs))
player.languages = this:merge_lang_lists(this.(raceprop)[x][3], this.orgs[g][4]);
endif
player:tell("Your race is \"", player.race, "\".");
if (this.clear_all_skills)
clear_property(player, "skills");
clear_property(player, "languages");
clear_property(player, "speaking");
clear_property(player, "remembered_names");
clear_property(player, "short_desc_msg");
clear_property(player, "money");
endif
if ((this.type == "choice") && (limit = this:limit_check(player)))
return player:tell_lines(limit);
endif

set

Spec any at/to anyFlags rxdOwner #36Definer #141

Referenced by

none

Source

"for choice chargens";
if (this.type != "choice")
return player:tell("You cannot set your own statistics in this generator. Try \"roll\".");
endif
info = $RP_regulator:parse_stat_level(dobjstr, iobjstr, player);
if (length(info) != 3)
return;
elseif (info[1] == "skill")
return player:tell("Skills must be learned in the game.");
else
index = info[2];
newlevel = info[3];
endif
player.free_points = player.free_points + $RP_regulator:statcost(player.stats[2][index]);
newcost = $RP_regulator:statcost(newlevel);
if (newcost <= player.free_points)
player.free_points = player.free_points - newcost;
player.stats[2][index] = newlevel;
player:tell(player.stats[1][index], " => ", floatstr(newlevel, 2));
player.stats_current = player.stats;
if (limit = this:limit_check(player))
return player:tell_lines(limit);
endif
else
player.free_points = player.free_points - $RP_regulator:statcost(player.stats[2][index]);
player:tell("You don't have enough points for that change.");
player:tell("You may lower another statistic to gain points.");
endif

limit_check

Spec this none thisFlags rxdOwner #36Definer #141

Referenced by

• #141:pick_race line 63: this:limit_check
• #141:set line 21: this:limit_check
• #141:pick_org line 55: this:limit_check
• #141:o*ut line 4: this:limit_check

Source

"for both chargens";
person = args[1];
violations = {};
if (this.type == "choice")
"check for org against race";
if (o = player.org in $list_utils:slice(this.orgs))
if (!(player.race in this.orgs[o][2]))
violations = {@violations, tostr("The ", player.org, " does not allow any ", player.race, ".")};
endif
endif
"check for gender & stats against race";
if (r = player.race in $list_utils:slice(this.races_choice))
"gender from .races_choice[4] => 0=ANY, 1=Male, 2=Female 3=Male/Female";
if ((this.races_choice[r][4] == 1) && (!(player.gender == "male")))
violations = {@violations, tostr("Any \"", player.race, "\" race requires a male gender.")};
elseif ((this.races_choice[r][4] == 2) && (!(player.gender == "female")))
violations = {@violations, tostr("Any \"", player.race, "\" race requires a female gender.")};
elseif ((this.races_choice[r][4] == 3) && (!(player.gender in {"male", "female"})))
violations = {@violations, tostr("The \"", player.race, "\" race requires a male or female gender.")};
endif
for s in [1..4]
if ((player.stats[2][s] < this.races_choice[r][2][s][1]) || (player.stats[2][s] > this.races_choice[r][2][s][2]))
violations = {@violations, tostr(player.stats[1][s], " is outside the limits for ", player.race, ".")};
endif
endfor
endif
"check for gender & stats against org";
if (o = player.org in $list_utils:slice(this.orgs))
if ((this.orgs[o][5] == 1) && (player.gender != "male"))
violations = {@violations, tostr("The ", player.org, " requires a male gender.")};
elseif ((this.orgs[o][5] == 2) && (player.gender != "female"))
violations = {@violations, tostr("The ", player.org, " requires a female gender.")};
endif
for s in [1..4]
if (player.stats[2][s] < this.orgs[o][3][s])
violations = {@violations, tostr(player.stats[1][s], " is under the minimum for the ", player.org, ".")};
endif
endfor
endif
else
if (r = player.race in $list_utils:slice(this.races_random))
"gender from .races_random[4] => 0=ANY, 1=Male, 2=Female 3=Male/Female";
if ((this.races_random[r][4] == 1) && (!(player.gender == "male")))
violations = {@violations, tostr("Any \"", player.race, "\" member of this org must be male.")};
elseif ((this.races_random[r][4] == 2) && (!(player.gender == "female")))
violations = {@violations, tostr("Any \"", player.race, "\" member of this org must be female.")};
elseif ((this.races_random[r][4] == 3) && (!(player.gender in {"male", "female"})))
violations = {@violations, tostr("The \"", player.race, "\" race requires a male or female gender.")};
endif
endif
endif
return violations || 0;

pick_org

Spec this none thisFlags rxdOwner #36Definer #141

Referenced by

• #141:org line 2: this:pick_org

Source

"USAGE: pick_org()";
"For 'choice' chargens.";
"Allows player to choose an organization.";
if (length(this.orgs) == 1)
if (this.orgs[1][1] == player.org)
return player:tell("You are already a member of \"", player.org, "\".");
else
player:tell("========================================================");
player:tell("Your current org is \"", player.org, "\". The only org available here is \"", this.orgs[1][1], "\".");
if (!$command_utils:yes_or_no("Do you want to join now?"))
return player:tell("Your organization remains unchanged.");
endif
player.org = this.orgs[1][1];
endif
else
orglist = {};
o = 0;
for org in (this.orgs)
o = o + 1;
orglist = {@orglist, tostr(o, " - ", org[1])};
endfor
player:tell("========================================================");
player:tell_lines($string_utils:columnize(orglist, 2, 50));
if (!$command_utils:yes_or_no("Do you know enough about these organizations to make the choice?"))
return player:tell("Type \"? <org name>\" to find out more.");
endif
ok = 0;
while (!ok)
player:tell("Enter the organization name or index number.");
neworg = $command_utils:read();
if (((x = toint(neworg)) && (x <= length(this.orgs))) && (x > 0))
player.org = this.orgs[x][1];
ok = 1;
elseif (x = neworg in $list_utils:slice(this.orgs))
player.org = this.orgs[x][1];
ok = 1;
else
player:tell("Invalid organization.");
endif
endwhile
endif
player:tell("Your organization is the \"", player.org, "\".");
if (this.clear_all_skills)
clear_property(player, "skills");
clear_property(player, "languages");
clear_property(player, "speaking");
clear_property(player, "remembered_names");
clear_property(player, "short_desc_msg");
clear_property(player, "money");
endif
x = player.org in $list_utils:slice(this.orgs);
if ((g = player.race in $list_utils:slice(this.races_choice)) && x)
player.languages = this:merge_lang_lists(this.races_choice[g][3], this.orgs[x][4]);
endif
if (limit = this:limit_check(player))
return player:tell_lines(limit);
endif

o*ut exit leave go

Spec any none noneFlags rdOwner #36Definer #141

Referenced by

none

Source

"Checks for proper settings before allowing the player to leave.";
"Calls this:special(), if such a verb exists, to handle any";
"customized touch-ups to character generation.";
if (limit = this:limit_check(player))
player:tell("CHARACTER VIOLATIONS:");
player:tell_lines(limit);
endif
if ((!`player.build_options ! E_PROPNF => 0') && limit)
"a non-builder cannot leave unfixed.";
return player:tell("Fix this problem, and then you can leave.");
elseif (player.location == this)
`this:special() ! E_VERBNF => 0';
this:here_huh(verb, args);
endif

help_msg

Spec this none thisFlags rxdOwner #2Definer #141

Referenced by

none

Source

msg = pass(@args);
if (`this.build_help ! E_PROPNF => 0' && (parent(player) != $rpgamer))
msg = {@msg, "", @this.("build_help_" + this.type)};
endif
return msg;

init_for_core

Spec this none thisFlags rxdOwner #2Definer #141

Referenced by

none

Source

if (caller_perms().wizard)
if (this != $chargen)
for p in (properties($chargen))
if ((!p) in {"build_help", "help_msg"})
clear_property(this, p);
endif
endfor
endif
try
for x in [1..length(this.races_random)]
this.races_random[x][3] = {{$default_lang}, {2.0}};
endfor
except (E_RANGE)
"pass";
endtry
try
for y in [1..length(this.races_choice)]
this.races_choice[y][3] = {{$default_lang}, {2.0}};
endfor
except (E_RANGE)
"pass";
endtry
try
for z in [1..length(this.orgs)]
this.orgs[z][4] = {{$default_lang}, {2.0}};
endfor
except (E_RANGE)
"pass";
endtry
return pass(@args);
endif

merge_lang_lists

Spec this none thisFlags rxdOwner #36Definer #141

Referenced by

• #141:pick_race line 52: this:merge_lang_lists
• #141:pick_org line 53: this:merge_lang_lists

Source

"Takes two versions of the $rpgamer.languages settings and merges the best of both.";
final = alist = args[1];
blist = args[2];
for l in (blist[1])
ib = l in blist[1];
if (ia = l in alist[1])
if (alist[2][ai] < blist[2][bi])
final[2][ai] = blist[2][bi];
endif
else
final[1] = {@final[1], blist[1][ib]};
final[2] = {@final[2], blist[2][ib]};
endif
endfor
return final;