Salesperson #134

take_hit

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

none

Source

"USAGE: victim:take_hit(damage)";
"       Sets off silent alarm in case of attack";
if ((this.location.retail && (!this.location.sanctuary)) && (this.stats_current[2][4] < (this.stats[2][4] * 0.75)))
loc = this.location;
loc.dump_loc = (loc.dump_loc == $rpg_room.dump_loc) ? `loc.virtual_exits[random($)][2] ! ANY => loc.dump_loc' | loc.dump_loc;
fork (6)
loc:announce_all("A loud and shrill alarm begins to ring!");
loc.sanctuary = 1;
endfork
fork (60)
loc.sanctuary = 0;
endfork
endif
pass(@args);
if (random(3) == 1)
this:say(tostr("-", this.enemy, " ", this.outrage_msg));
endif

tell

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

• #134:sell line 2: this:tell
• #134:ask line 6: this:tell
• #134:ask line 8: this:tell
• #134:buy line 2: this:tell

Source

if ((this.location != this.home) && (this in connected_players()))
return pass(@args);
elseif (($string_utils:index_delimited(tostr(@args), "hands you") && (parent(player) == parent(this))) && (!(player in connected_players())))
"This puppet just bought from another puppet.";
return pass(@args);
elseif (`parent(this) == $local.cargo_bot ! ANY => 0')
"has its own tell verb for this stuff";
return pass(@args);
endif
if ($string_utils:index_delimited(tostr(@args), "hands you"))
fork (1)
newstuff = $set_utils:diff(this:contents(), this.oldstuff);
for x in (newstuff)
if ((!$object_utils:has_callable_verb(x, "value")) || $object_utils:has_callable_verb(x, "combine"))
this:say(tostr("-", player, " I can't use this."));
this:_force("give ", x, " to ", player);
else
offer = $money_utils:_from_to("Gold", this.currency, (dobj:value() * tofloat(this.buyback_rate)) / 100.0);
offer = ((money = tofloat(this:_has_amount(this.currency))) < offer) ? money | offer;
this.oldstuff = setadd(this.oldstuff, x);
this:_rem_money(this.currency, offer);
player:_add_money(this.currency, offer);
$you:say_action(tostr("%N %<receives> ", floatstr(offer, 2), " ", this.currency, " from ", this:title(), "."));
this:say(tostr("-", player, " ", this.done_deal_msg));
endif
endfor
endfork
return pass(@args);
endif
if (this.my_tell || ((this.location != this.home) && (this in connected_players())))
return pass(@args);
endif
if ($string_utils:index_delimited(tostr(@args), "asks"))
this:random_free();
if (($string_utils:index_delimited(tostr(@args), "list") || $string_utils:index_delimited(tostr(@args), "prices")) || $string_utils:index_delimited(tostr(@args), this.listname))
this:list();
elseif (($string_utils:index_delimited(tostr(@args), "cash") || $string_utils:index_delimited(tostr(@args), "money")) || $string_utils:index_delimited(tostr(@args), this.currency))
this:collect_cash();
elseif (($string_utils:index_delimited(tostr(@args), "sell") || $string_utils:index_delimited(tostr(@args), "buy")) || $string_utils:index_delimited(tostr(@args), "for sale"))
this:say(tostr("-", player, " ", this.advertise_msg));
endif
endif
pass(@args);

list

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

• #134:tell line 36: this:list
• #134:ask line 17: this:list
• #134:@menu line 2: this:list

Source

this.my_tell = 1;
items = this:items();
length = length(items);
if (!length)
this:say(tostr("-", player, " I don't have any items at the moment, but check back later."));
return this.my_tell = 0;
endif
if (player != this)
this:say(tostr("-", player, " Here is a ", this.listname, " of items for sale."));
endif
this.my_tell = 1;
player:tell("");
fork (3)
this.my_tell = 1;
this.location:announce_all_but({player}, tostr(this:title(), " pulls out a ", this.listname, " and shows it to ", player:title(), "."));
player:tell("--------------------------------------------------");
indices = $string_utils:char_list($string_utils.alphabet)[1..length];
names = {};
prices = {};
for a in [1..length]
names = {@names, tostr(indices[a], " - ", items[a]:title())};
credpr = $object_utils:has_callable_verb(items[a], "combine") ? items[a].value_base | items[a]:value();
prices = {@prices, tostr(floatstr($money_utils:_from_to("Gold", this.currency, credpr), 2), " ", this.currency)};
endfor
player:tell_lines($string_utils:columnize({@names, @prices}, 2, 64));
player:tell("--------------------------------------------------");
if (player != this)
this:say(tostr("-", player, " You can ask me for the product by name or alphabetical index. Items followed by numbers in ( ) can be purchased in bulk."));
fork (3)
player:tell("");
player:tell("(Hints: \"ask ", this:title(), " for <item>\"");
player:tell("        \"buy <item> from ", this:title(), "\"");
player:tell("        \"ask ", this:title(), " for <amount> <bulk item>\")");
endfork
endif
suspend(6);
this.my_tell = 0;
endfork

stock

Spec this with/using anyFlags rdOwner #2Definer #134

Referenced by

none

Source

iobj = valid(iobj) ? iobj | $string_utils:literal_object(iobjstr);
if (((!valid(iobj)) || (!`player.victim_port_msg ! E_PROPNF => 0')) || (!$object_utils:has_callable_verb(iobj, "value")))
return player:tell("The object must be both valid and valuable. You must also be an administrator to perform this out-of-character task.");
endif
if (iobj.f)
this.items = setadd(this.items, iobj);
player:tell("You have added ", iobj:title(), " to ", this:title(), "'s list of goods.");
else
iobj:moveto(this);
this.oldstuff = setadd(this.oldstuff, iobj);
player:tell("You have given ", iobj:title(), " to ", this:title(), ".");
endif

unstock

Spec any out of/from inside/from thisFlags rdOwner #2Definer #134

Referenced by

none

Source

dobj = this:find_product(dobjstr);
if ((!valid(dobj)) || (!`player.victim_port_msg ! E_PROPNF => 0'))
return player:tell("The object must be valid, and you must be an administrator to perform this out-of-character task.");
endif
if (dobj in this:contents())
dobj:moveto(player);
this.oldstuff = setremove(this.oldstuff, dobj);
player:tell("You have taken ", dobj:title(), " from ", this:title(), ".");
else
this.items = setremove(this.items, dobj);
player:tell("You have removed ", dobj:title(), " from ", this:title(), "'s list of goods.");
endif

sell

Spec any at/to thisFlags rdOwner #2Definer #134

Referenced by

none

Source

if (player == this)
return this:tell("Don't be silly.");
endif
this.my_tell = 1;
$you:say_action(tostr("%N %<offers> to sell ", dobjstr, " to ", this:title(), "."));
amountitem = $string_utils:first_word(dobjstr);
amount = toint(amountitem[1]);
itemname = amountitem[2];
if ((valid(dobj) && (dobj in player:contents())) && (!$object_utils:has_callable_verb(dobj, "combine")))
if ($object_utils:has_callable_verb(dobj, "value"))
offer = $money_utils:_from_to("Gold", this.currency, (dobj:value() * tofloat(this.buyback_rate)) / 100.0);
offer = ((money = tofloat(this:_has_amount(this.currency))) < offer) ? money | offer;
this:say(tostr("-", player, " I can offer you no more than ", floatstr(offer, 2), " ", this.currency, " for that."));
this:say(tostr("-", player, " Give it to me if you still want to sell it."));
else
this:say(tostr("-", player, " That has no value to me."));
return this.my_tell = 0;
endif
elseif ($object_utils:has_callable_verb(dobj, "combine") || amount)
if (valid(item = player:match(itemname)))
this:say(tostr("-", player, " I only buy brand new ammunition from authorized dealers."));
return this.my_tell = 0;
else
this:say(tostr("-", player, " I don't buy used ", dobjstr, " in bulk quantities."));
return this.my_tell = 0;
endif
else
player:tell("You don't seem to have any \"", dobjstr, "\" to sell.");
endif

ask

Spec this any anyFlags rxdOwner #2Definer #134

Referenced by

none

Source

if (prepstr == "to")
pass(@args);
elseif (prepstr == "for")
if (player == this)
if (iobjstr in {"list", this.listname, "prices"})
return this:tell("Try \"@menu\".");
endif
return this:tell("Sorry, that's just too convenient to be fair.");
endif
this.my_tell = 1;
$you:say_action(tostr("%N %<asks> ", this:title(), " for ", iobjstr, "."));
this.my_tell = 0;
if (iobjstr in {"stocks", "shelves", "stores", "inventory"})
return this:check_stocks();
endif
if (iobjstr in {"list", this.listname, "prices"})
return this:list();
endif
if (iobjstr in {"money", "cash", this.currency})
return this:collect_cash();
endif
if (iobjstr in {"name", "his name", "her name"})
return this:say(tostr("-", player, " My name is ", this.name, "."));
endif
this:sell_product(iobjstr, player);
else
player:tell("Try: \"ask ", this:title(), " to/for <something>\"");
endif

collect_cash

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

• #134:tell line 38: this:collect_cash
• #134:ask line 20: this:collect_cash

Source

if (player in this.trustees)
this:say(tostr("-", player, " Sure thing, Boss!"));
cash = tofloat(this:_has_amount(this.currency));
this:_rem_money(this.currency, cash);
player:_add_money(this.currency, cash);
this.my_tell = 1;
suspend(2);
$you:say_action(tostr("%N %<receives> ", floatstr(cash, 2), " ", this.currency, " from ", this:title(), "."));
else
this:say(tostr("-", player, " Get away, beggar!"));
endif

sell_product

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

• #134:ask line 25: this:sell_product
• #134:buy line 7: this:sell_product

Source

"usage: sell_product(item name, buyer object)";
"this verb needs to be wiz-owned.";
itemname = args[1];
iobj = args[2];
amountitem = $string_utils:first_word(itemname);
item = (amount = toint(amountitem[1])) ? this:find_product(amountitem[2]) | this:find_product(itemname);
if (item == $failed_match)
return this:say(tostr("-", iobj, " Sorry, I don't have any ", itemname, " today."));
elseif (`player:reached_limit() ! E_VERBNF => "GUEST"')
return this:say(tostr("-", iobj, " You don't look strong enough to carry more!"));
endif
if (amount && (!$object_utils:has_callable_verb(item, "combine")))
return this:say(tostr("-", iobj, " Sorry, I don't sell ", item:title(), " in bulk quantities."));
elseif ((!amount) && $object_utils:has_callable_verb(item, "combine"))
amount = 1;
endif
price = amount ? tofloat(amount) * $money_utils:_from_to("Gold", this.currency, item.value_base) | $money_utils:_from_to("Gold", this.currency, item:value());
if (tofloat(iobj:_has_amount(this.currency)) < price)
this:say(tostr("-", iobj, " ", this.outrage_msg));
return this:say(tostr("-", iobj, " I only deal in ", this.currency, ". Clearly you do not have enough!"));
endif
if (item.f && (item in this.items))
if ($object_utils:has_callable_verb(item, "combine"))
prop = $object_utils:has_property(item, "rounds") ? "rounds" | "units";
if (amount > item.(prop))
return this:say(tostr("-", iobj, " Sorry, I don't have that many."));
elseif (amount == 0)
return this:say(tostr("-", iobj, " Pardon me, I didn't hear how many you wanted."));
endif
this:transfer_ammo(amount, item, iobj);
elseif ($object_utils:has_callable_verb(item, "replicate"))
object = item:replicate();
if (valid(object))
object:moveto(this);
this:_force("give ", object, " to ", iobj);
else
return this:say(tostr("-", iobj, " Ahh, I only have the display model for that, and it's non-functional. :|"));
endif
else
owner = ($set_utils:intersection($object_utils:ancestors(item), {$note, $container}) != {}) ? iobj | $default_holder;
object = $recycler:_create(item, owner);
if (!valid(object))
return player:tell("You have gone over quota. Delete some mail using @rmm.");
endif
object:set_name(item.name);
object.aliases = item.aliases;
object:moveto(this);
this:_force("give ", object, " to ", iobj);
endif
elseif (item in this:contents())
this:_force("give ", item, " to ", iobj);
this.oldstuff = setremove(this.oldstuff, item);
endif
iobj:_rem_money(this.currency, price);
this:_add_money(this.currency, price * 0.35);
this:say(tostr("-", iobj, " ", this.done_deal_msg));

find_product

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

• #134:unstock line 1: this:find_product
• #134:sell_product line 6: this:find_product
• #134:sell_product line 6: this:find_product

Source

"usage: find_product(item name) => object or $failed_match";
"       Returns first item found, never $ambiguous_match, thus";
"       trys to sell inventory before 'ordering' new products";
product = args[1];
if (valid(x = this:index_match(product)))
return x;
endif
if (toobj(product) in this:items())
return toobj(product);
endif
match = $string_utils:match_suspended(product, this:items(), "aliases");
if (match != $ambiguous_match)
return match;
else
"the first exact match will do";
for x in (this:items())
if (product in x.aliases)
return x;
endif
(ticks_left() < 5000) && suspend(0);
endfor
endif

index_match

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

• #134:find_product line 5: this:index_match

Source

items = this:items();
n = length(items);
if (!n)
return $failed_match;
endif
indices = $string_utils:char_list($string_utils.alphabet)[1..n];
if (i = args[1] in indices)
return items[i];
endif
return $failed_match;

items

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

• #134:list line 2: this:items
• #134:find_product line 8: this:items
• #134:find_product line 11: this:items
• #134:find_product line 16: this:items
• #134:index_match line 1: this:items

Source

stuff = this:contents();
for item in (stuff)
if (((item == this.wielded) || $object_utils:has_callable_verb(item, "combine")) || `item.wornness ! E_PROPNF => 0')
stuff = setremove(stuff, item);
endif
endfor
return $list_utils:remove_duplicates({@stuff, @this.items});

_clean_inv

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

none

Source

"Factory buys back used goods from retail outlet";
"Use with the $scheduler";
stuff = this:contents();
for item in (stuff)
if (item.f)
$mail_agent:send_message(this, $default_holder, "Bot Has Generic", {$string_utils:nn(this), $string_utils:nn(item)});
elseif ((((item != this.wielded) && (parent(item) in this.items)) || $object_utils:isa(item, $food1)) || $object_utils:isa(item, $food2))
this:_add_money(this.currency, (item:value() * tofloat(this.buyback_rate)) / 100.0);
$recycler:_recycle(item);
endif
endfor
suspend(0);
this.oldstuff = this:contents();
for item in (this.items)
if (parent(item) == $garbage)
this.items = setremove(this.items, item);
endif
endfor

check_stocks

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

• #134:ask line 14: this:check_stocks

Source

dobj = this;
if ((!(player in this.trustees)) && (!player.wizard))
return player:tell(E_PERM);
endif
objs = {};
for x in (dobj.items)
if ($object_utils:isa(x, $homer))
objs = {@objs, x};
endif
endfor
player:tell($string_utils:left("[white][bold]Name[normal]", 17), $string_utils:left("[yellow][bold]Manufactured[normal]", 18), $string_utils:left("[green][bold]In Stock[normal]", 10));
player:tell("[bold]", $string_utils:space(46, "-"), "[normal]");
for x in (objs)
player:tell($string_utils:left(tostr("[white][bold]", x.name, "[normal]"), 17), $string_utils:right(tostr("[yellow][bold]", x.child_limit, "[normal]"), 6), $string_utils:right(tostr("[green][bold]", x.child_limit - length(children(x)), "[normal]"), 16));
endfor

@menu

Spec none none noneFlags rdOwner #2Definer #134

Referenced by

none

Source

"If the sales bot is a a player, this allows the player to check its own stock.";
this:list();

init_for_core

Spec this none thisFlags rxdOwner #2Definer #134

Referenced by

none

Source

if (caller_perms().wizard)
if (this == $sales_bot)
this.items = {};
this.oldstuff = {};
this.outrage_msg = "This is an outrage!";
this.done_deal_msg = "Wonderful doing business with you!";
this.currency = "Gold";
this.listname = "catalog";
this.buyback_rate = 50;
this.advertise_msg = "Sure, I buy and sell. I can show you a catalog, if you ask for it.";
this.trustees = {#2};
else
for p in (properties($sales_bot))
if ((!p) in {"build_help", "help_msg"})
clear_property(this, p);
endif
endfor
endif
return pass(@args);
endif

buy order

Spec any out of/from inside/from thisFlags rxdOwner #2Definer #134

Referenced by

none

Source

if ((player == this) || (player.location != this.location))
return this:tell("Sorry, that's just too convenient to be fair.");
endif
this.my_tell = 1;
$you:say_action(tostr("%N %<requests> to buy ", dobjstr, " from ", this:title(), "."));
this.my_tell = 0;
this:sell_product(dobjstr, player);