generic monster #107

g*et t*ake

Spec this none noneFlags rxdOwner #36Definer #107

Referenced by

none

Source

if (player != this.owner)
if ((((!this.alert) || (!this.mobile)) && (c = $set_utils:intersection(player:contents(), children($cuffs)))) && (player in c[1].trustees))
c[1]:_cuff(this);
elseif ((this.alert && this.alive) && this.mobile)
player:tell(this:titlec(), " cautiously dodges your advance.");
this.location:announce_all_but({this, player}, tostr(this:titlec(), " cautiously avoids ", player:title(), "."));
else
player:tell("Why not try searching ", this:title(), " instead?");
endif
else
$command_utils:do_huh(verb, args);
endif

capture cuff

Spec this none noneFlags rdOwner #36Definer #107

Referenced by

none

Source

if ((((!this.alert) || (!this.mobile)) && (c = $set_utils:intersection(player:contents(), children($cuffs)))) && c[1]:ok_to_use())
c[1]:_cuff(this);
elseif (((((player.stats_current[2][1] > (this.stats_current[2][1] * 1.2)) || (player.stats_current[2][2] > (this.stats_current[2][2] * 1.2))) || (player.stats_current[2][4] > (this.stats_current[2][4] * 2.0))) && (c = $set_utils:intersection(player:contents(), children($cuffs)))) && (player in c[1].trustees))
c[1]:_cuff(this);
elseif ((this.alert && this.alive) && this.mobile)
player:tell(this:titlec(), " cautiously dodges your advance.");
this.location:announce(this:titlec(), " cautiously avoids ", player:title(), ".");
else
player:tell("Why not try searching ", this:title(), " instead?");
endif

release uncuff lose

Spec this none noneFlags rxdOwner #36Definer #107

Referenced by

none

Source

if (verb == "lose")
if (this == player.followed_by)
$you:say_action("%N %<attempts> to evade all followers.");
return player:dump_followers();
else
return player:tell(this:titlec(), " is only casually following you, if at all.");
endif
endif
"Cuffs";
if ((c = $set_utils:intersection(this:contents(), children($cuffs))) && c[1]:ok_to_use())
return c[1]:_uncuff(this);
elseif (c != {})
return player:tell("Only an authorized person can release ", this.po, ".");
endif
"Mental";
if (this.following == player)
this:_release();
elseif (valid(this.following))
player:tell("Only the person who captured ", this:title(), " can release ", this.po, ".");
else
player:tell(this:titlec(), " is not a prisoner.");
endif

_leash

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

• #107:_leash line 16: this:_leash
• #107:_capture line 8: this:_leash

Source

if ((valid(this.following) && this.following.alert) && this.following.alive)
suspend(1);
if (((valid(this.following) && (this.following.location != this.location)) && $object_utils:isa(this.following.location, $room)) && (!$object_utils:isa(this.following.location, $editor)))
this.location:announce_all_but({this}, this:titlec(), " follows ", this.following:title(), " out.");
this:moveto(this.following.location);
this.location:announce_all_but({this}, this:titlec(), " is being led by ", this.following:title(), ".");
elseif ((valid(this.following) && $object_utils:isa(this.following.location, $terrain)) && (!this.following.location:match_loc(this.following, this)))
this.location:announce_all_but({this, this.following}, this:titlec(), " follows.");
this.x_loc = this.following.x_loc;
this.y_loc = this.following.y_loc;
this:tell("You follow.");
this.following:tell(this:titlec(), " follows.");
this.location:announce_all_but({this, this.following}, this:titlec(), " follows in shackles.");
endif
fork (4)
this:_leash();
endfork
else
this:_release();
endif

@com*bat @str*ength @int*elligence @dex*terity @hea*lth

Spec this is anyFlags rdOwner #36Definer #107

Referenced by

none

Source

if ((player != this.owner) && (!player.programmer))
return player:tell("Permission denied.");
elseif (!(toint(iobjstr) > 0))
try
number = (tofloat(iobjstr) > 0.1) ? 1.0 | E_INVARG;
except v (ANY)
return player:tell("You must use a valid number greater than 0.1");
endtry
endif
number = tofloat(iobjstr);
if (verb in {"@str", "@strength"})
this.stats[2][1] = number;
this.stats_current[2][1] = number;
elseif (verb in {"@int", "@intelligence"})
this.stats[2][3] = number;
this.stats_current[2][3] = number;
elseif (verb in {"@dex", "@dexterity"})
this.stats[2][2] = number;
this.stats_current[2][2] = number;
elseif (verb in {"@hea", "@health"})
this.stats[2][4] = number;
this.stats_current[2][4] = number;
else
this.skills[2][1] = number;
endif
player:tell("Set.");

tell_contents

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

• #107:look_self line 23: this:tell_contents

Source

c = args[1];
if (c)
au = $ansi_utils;
longear = {};
gear = {};
width = player:linelen();
half = width / 2;
player:tell("Carrying:");
for thing in (c)
cx = tostr(" ", thing:title(), " (", thing, ")");
if ($object_utils:has_property(player, "wielded"))
cx = (this.wielded == thing) ? tostr(cx, " (ready)") | cx;
endif
if (valid(au) ? au:length(cx) | (length(cx) > half))
longear = {@longear, cx};
else
gear = {@gear, cx};
endif
endfor
player:tell_lines($string_utils:columnize(gear, 2, width));
player:tell_lines(longear);
endif

eat consume

Spec this none noneFlags rdOwner #36Definer #107

Referenced by

none

Source

if (this.alive)
player:tell($string_utils:pronoun_sub("You'll have to kill %o first.", this));
elseif (!this.edible)
player:tell("You can't eat that!");
else
$you:say_action(tostr("%N %<", verb, "s> some of ", this:title(), "."));
endif

rot_away

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

• #107:die line 25: this:rot_away

Source

"wiz perms";
this.location:announce_all("The corpse of ", this:title(), " dissolves quickly.");
this:dump_goodies(1);
move(this, this.grave);
this.location:announce_all_but({this}, this:titlec(), " has arrived.");
if (this.gestate > 120)
$scheduler:schedule(this.gestate, this, "birth");
else
fork (this.gestate)
this:birth();
endfork
endif

tell

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

• #107:_leash line 11: this:tell

Source

if ((((player in connected_players()) && (player != this.owner)) && (this.hostility > 1)) && (!this.my_tell))
fork (2)
if (((`this.alive ! E_PROPNF => 0' && this.alert) && this.mobile) && (player.location == this.location))
this.enemy = player;
if ((this.stats_current[2][4] > (this.stats[2][4] * 0.1)) && (random(6) < this.hostility))
stun = (this.wielded.can_stun || this.wielded.can_paralyse) ? 1 | 0;
this.my_tell = 1;
this.location:do_attack(tostr(this), tostr(this.enemy), this:damage(), stun);
this.my_tell = 0;
endif
endif
endfork
endif
if ((((player in connected_players()) && this.wander_ok) && (!this.countdown_til_stop)) && (!$scheduler:valid_task(call_function("tonum", this.wander_task))))
this.countdown_til_stop = random(10) + 10;
this:plan_next_move();
endif
pass(@args);

take_health

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

none

Source

"USAGE: beneficiary:take_health(healing points)";
this.stats_current[2][4] = this.stats_current[2][4] + tofloat(args[1]);
this.stats_current[2][4] = (this.stats_current[2][4] > this.stats[2][4]) ? this.stats[2][4] | this.stats_current[2][4];
return this.stats_current[2][4];

armor

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

• #107:take_hit line 18: this:armor

Source

armor = 0.0;
for x in (this:contents())
if ($object_utils:has_property(x, "armor") && x.wornness)
armor = armor + x:shield_rating();
endif
endfor
return armor;

damage

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

• #107:tell line 8: this:damage
• #107:take_hit line 10: this:damage

Source

"USAGE: assailant:damage()";
"Returns wielded weapon damage, modified by strength.";
"If missle weapon is used, returns just weapon damage.";
"Damage will vary up or down from the base by a 25% margin.";
"If there are additional combat skills affecting damage, this is the verb to hack.";
if (this.wielded.shoots)
damage = this.wielded.projectile_dam;
else
damage = this.wielded.damage_base + ((this.stats_current[2][1] - 10.0) / 3.142);
endif
moddam = random(5);
if ((moddam = 1) && (!args))
damage = damage - (damage * 0.25);
elseif ((moddam = 5) && (!args))
damage = damage + (damage * 0.25);
endif
return (damage > 0.0) ? damage | 0.1;

to_hit

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

• #107:roll_against line 13: this:to_hit

Source

"If missle weapon, returns dexterity, modified by basic combat skill";
"If not, returns average strength & dexterity, modified by combat skill";
"If there are additional skills affecting striking accuracy, this is the verb to hack.";
combat = "combat" in this.skills[1];
if (this.wielded.shoots)
attack = this.stats_current[2][2] + sqrt(this.skills[2][combat]);
else
attack = ((this.stats_current[2][2] + this.stats_current[2][1]) / 2.0) + sqrt(this.skills[2][combat]);
endif
return (attack > 0.0) ? attack | 0.1;

to_defend

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

• #107:roll_against line 16: this:to_defend

Source

"Returns dexterity, modified by basic combat skill.";
"Compared to to_hit(), combat skill has only half the effect.";
"If there are additional skills (or armor) affecting defense, this is the verb to hack.";
combat = "combat" in this.skills[1];
dex = (!(this.alert && this.mobile)) ? 0.1 | this.stats_current[2][2];
defense = dex + (sqrt(this.skills[2][combat]) / 2.0);
return (defense > 0.0) ? defense | 0.1;

title

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

• #107:g*et line 8: this:title
• #107:capture line 9: this:title
• #107:release line 19: this:title
• #107:eat line 6: this:title
• #107:rot_away line 2: this:title
• #136:rot_away line 3: this:title

Source

title = this.name;
blurb = "";
if (!this.alive)
blurb = "dead";
elseif (!this.alert)
blurb = "unconscious";
elseif (!this.mobile)
blurb = "immobilized";
elseif ((this.stats_current[2][4] / (this.stats[2][4] + 0.0001)) < 0.75)
blurb = "injured";
endif
title = blurb ? tostr(title, "(", blurb, ")") | title;
return title;

wander

Spec none none noneFlags rxdOwner #36Definer #107

Referenced by

• #107:take_hit line 12: this:wander
• #107:plan_next_move line 4: this:wander

Source

"Finds and takes a random exit. If you want to repeat this act, you need to call the verb from within a timed loop, but 2 seconds is the minimum delay before wandering.";
"If this.terrain_only is true, it will stay in a terrain and never take a real exit.";
"If this.greedy is true, it will look around for something to grab instead. If nothing is found, it will wander.";
suspend(1);
if (`(((!this.alert) || (!this.mobile)) || (!this.alive)) || (!this.wander_ok) ! ANY => "CAUGHT DURING A RECYCLE"')
return;
elseif (this.greedy)
for treasure in (this.location:contents())
if ($thing in $object_utils:ancestors(treasure))
treasure:moveto(this);
if (treasure.location == this)
this.location:announce_all($string_utils:pronoun_sub(tostr(this:titlec(), " %<grabs> ", treasure:title(), "."), this));
return;
endif
endif
endfor
endif
if ($object_utils:isa(this.location, $room) && (!$object_utils:isa(this.location, $terrain)))
real = ((rlen = length(rexits = this.location:obvious_exits())) && (rexit = rexits[random(rlen)]):is_unlocked_for(this)) ? 1 | 0;
if ($object_utils:isa(this.location, $veroom))
virtual = ((vlen = length(vexits = this.location.virtual_exits)) && (vexit = vexits[random(vlen)])) ? 1 | 0;
else
virtual = 0;
endif
if (real && virtual)
if (random(2) == 2)
rexit:move(this);
elseif (this.location:exit_unlocked_for(vexit, this))
this.location:match_exit(vexit[1][1]);
this.location:move(this);
endif
elseif (real)
rexit:move(this);
elseif (virtual)
this.location:match_exit(vexit[1][1]);
this.location:move(this);
else
"No way out. Go home.";
try
this:moveto(this.home);
except v (ANY)
this:moveto($dead_zone);
endtry
endif
elseif ($object_utils:isa(this.location, $terrain))
if (!this.terrain_only)
real = (((rlen = length(rexits = this.location:obvious_exits())) && (rexit = rexits[random(rlen)]):is_unlocked_for(this)) && this.location:match_loc(rexit, this)) ? 1 | 0;
if (real)
return rexit:move(this);
endif
endif
for t in (this.location.compass)
way = this.location.compass[random($)];
target = this.location:loc_way(way, this.x_loc, this.y_loc);
if (target != {0, 0})
if (way == "u")
wayfrom = "below";
elseif (way == "d")
wayfrom = "above";
elseif (w = way in $list_utils:slice(this.location.strip_pairs))
wayfrom = this.location.strip_pairs[w][2];
elseif (w = way in $list_utils:slice(this.location.strip_pairs, 2))
wayfrom = this.location.strip_pairs[w][1];
endif
way = this.location:parse_dir(way, "long");
wayfrom = this.location:parse_dir(wayfrom, "long");
this.location:announce_all($string_utils:pronoun_sub(tostr(this.location.relocate_msg, way, "."), this));
this.location:set_object_loc(this, target[1], target[2]);
return this.location:announce_all($string_utils:pronoun_sub(tostr(this.location.loc_arrive_msg, wayfrom, "."), this));
endif
endfor
endif

look_self

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

none

Source

desc = this:description();
if (desc)
player:tell_lines(desc);
else
player:Tell("You see nothing special.");
endif
health = this.stats_current[2][4] / (this.stats[2][4] + 0.0001);
if (!this.alive)
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} dead.", this));
elseif (!this.alert)
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} unconscious.", this));
elseif (!this.mobile)
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} immobilized.", this));
elseif (health < 0.75)
if (health < 0.25)
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} obviously in very poor health.", this));
else
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} obviously in poor health.", this));
endif
else
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} awake and %{!looks} alert.", this));
endif
this:tell_contents(this.contents);

reached_limit

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

none

Source

return (length(this:contents()) >= toint(1.5 * this.stats_current[2][1])) ? 1 | 0;

_capture

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

none

Source

"WIZ OWNED";
"This is if called by handcuffs or mental control verbs.";
this.following = player;
player.followed_by = this;
if ($scheduler:kill_task(this.wander_task))
this.wander_task = 0;
endif
this:_leash();

_release

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

• #107:release line 17: this:_release
• #107:_leash line 19: this:_release

Source

"WIZ OWNED...to be called from handcuffs or mental control verbs.";
if (valid(this.following))
$you:say_action("%N %<releases> %d.");
this.wander_task = (0 || (!$scheduler:valid_task(call_function("tonum", this.wander_task)))) ? $scheduler:schedule_every(this.wait_seconds, this, "wander") | this.wander_task;
player:dump_followers();
endif

birth

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

• #107:rot_away line 10: this:birth
• #136:rot_away line 12: this:birth

Source

"wiz-owned";
this.alive = 1;
this.alert = 1;
this.mobile = 1;
this.stats_current = this.stats;
paw = this.wielded;
this.wielded = (this.weapon_types != {}) ? this.weapon_types[random($)] | paw;
this.wielded = (this.wielded.f && (!(this.wielded in {$hand, $claw, $teeth}))) ? this.wielded:replicate() | paw;
this.wielded = valid(this.wielded) ? this.wielded | paw;
if (this.wielded != paw)
this.wielded:moveto(this);
endif
try
this:moveto(this.home);
except v (ANY)
this:moveto($dead_zone);
endtry
this.location:announce_all($string_utils:pronoun_sub(this.birth_msg, this));
return;

dump_goodies

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

• #107:rot_away line 3: this:dump_goodies
• #107:_loot line 5: this:dump_goodies
• #136:rot_away line 4: this:dump_goodies

Source

"USAGE: dump_goodies(1 or 0) => moves contents of this to this location.";
"       if 1 is the argument, money is dumped, too";
"wiz-owned";
if (valid(this.location))
if (this.natural_def)
this.wielded = (this.natural_def == 2) ? $hand | $claw;
else
this.wielded = $teeth;
endif
for x in (this.contents)
try
if (($object_utils:has_callable_verb(x, "recycle_at_death") && (!((this.alive && this.alert) && this.mobile))) && x.recycle_at_death)
x:recycle_at_death();
else
x:moveto(this.location);
endif
if ($object_utils:has_property(x, "x_loc"))
x.x_loc = this.x_loc;
x.y_loc = this.y_loc;
endif
except v (ANY)
"it won't move";
endtry
endfor
"Move money to this location";
if ((this.money != {}) && args[1])
money = $recycler:_create($death_purse, $default_holder);
$building_utils:set_names(money, tostr(this.name, "'s cash purse,cash purse,cash,purse,money"));
money.money = this.money;
this.money = {};
money:moveto(this.location);
money.x_loc = this.x_loc;
money.y_loc = this.y_loc;
endif
endif

die

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

• #107:take_hit line 21: this:die

Source

"resets props, moves monster to afterlife.";
"wiz-owned";
who = (length(callers()) < 2) ? player | callers()[2][3];
trustees = {this.owner};
for x in ($object_utils:ancestors(this))
trustees = setadd(trustees, x.owner);
endfor
for x in ($object_utils:ancestors(this.location))
trustees = setadd(trustees, x.owner);
endfor
if ((!(who in trustees)) && (!who.wizard))
"Bogus killer";
return;
elseif ((!this.alive) && this.alert)
"already dead";
return this:pass_out();
endif
this.alert = 0;
this.alive = 0;
this.location:announce_all_but({this}, $string_utils:pronoun_sub(this.death_msg, this));
if (this.rot_time > 120)
$scheduler:schedule(this.rot_time, this, "rot_away");
else
fork (this.rot_time)
this:rot_away();
endfork
endif
this.stats_current = {{"Strength", "Dexterity", "Intelligence", "Health"}, {0.0, 0.0, 0.0, 0.0}};

pass_out

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

• #107:die line 16: this:pass_out

Source

"Bye-bye land for 60 seconds";
if (this.alert)
if ((player.wielded == $hand) || (player:damage(1) < 4.0))
this.location:announce_all_but({this}, $string_utils:pronoun_sub("%N %<becomes> dazed.", this));
timeout = 15;
wakeup = "%N %<regains> focus.";
else
this.location:announce_all_but({this}, $string_utils:pronoun_sub("%N %<falls> unconscious.", this));
timeout = 60;
wakeup = "%N %<awakens> from unconsciousness.";
endif
this.alert = 0;
fork (timeout)
if (this.alive || (this.location == $dead_zone))
this.alert = 1;
this.location:announce_all_but({this}, $string_utils:pronoun_sub(wakeup, this));
endif
endfork
endif

freeze

Spec this none thisFlags rxdOwner #36Definer #107

Referenced by

none

Source

"Paralysis for 60 seconds";
if (this.mobile)
this.location:announce_all_but({this}, $string_utils:pronoun_sub("%N %<becomes> immobilized.", this));
this.mobile = 0;
fork (60)
this.mobile = 1;
if (this:alive())
this.location:announce_all_but({this}, $string_utils:pronoun_sub("%N %<regains> mobility.", this));
endif
endfork
endif

take_hit

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

none

Source

"USAGE: victim:take_hit(damage[, attacker])";
"       wiz-owned to prevent permission problems";
damage = tofloat(args[1]);
this.enemy = ((length(args) > 1) && valid(args[2])) ? args[2] | this.enemy;
fork (1)
this.my_tell = 1;
if ((this.alive && this.alert) && this.mobile)
if (this.hostility && (this.stats_current[2][4] > (this.stats[2][4] * 0.333)))
stun = (this.wielded.can_stun || this.wielded.can_paralyse) ? 1 | 0;
`this.location:do_attack(tostr(this), tostr(this.enemy), this:damage(), stun) ! ANY => "invalid enemy or bad location"';
else
this:wander();
endif
endif
this.my_tell = 0;
endfork
if (((caller == this.location) || (caller == this.owner)) || (caller == this))
damage = ((x = damage - this:armor()) > 0.1) ? x | 0.1;
this.stats_current[2][4] = this.stats_current[2][4] - damage;
if (this.stats_current[2][4] < 0.0)
this:die();
endif
endif
return this.stats_current[2][4];

plan_next_move

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

• #107:tell line 16: this:plan_next_move
• #107:@start line 33: this:plan_next_move

Source

"wiz perms - Chance of monster getting recycled during this verb, so 'try' is used.";
try
if (this.wander_ok && this.countdown_til_stop)
this:wander();
this.wander_task = $scheduler:schedule(this.wait_seconds, this, "plan_next_move");
this.countdown_til_stop = this.countdown_til_stop - 1;
endif
except v (ANY)
return #2:tell(v, " on ", this);
endtry
fork (1)
`this.wander_ok = 0 ! ANY => "must be dead"';
endfork
fork (3)
`this.wander_ok = 1 ! ANY => "must be dead"';
endfork

@start @stop

Spec this none noneFlags rdOwner #2Definer #107

Referenced by

none

Source

"wiz-owned to allow scheduling";
if ((!player.programmer) && (!(player == this.owner)))
return;
endif
if (this.wander_task)
if (verb == "@start")
player:tell(this:titlec(), " is already wandering.");
elseif ($scheduler:valid_task(call_function("tonum", this.wander_task)))
$scheduler:kill_task(this.wander_task);
this.wander_task = 0;
this.wander_ok = 0;
player:tell(this:titlec(), " has stopped wandering.");
fork (3)
"double-check";
this.wander_ok = 0;
endfork
else
player:tell("Invalid wander task. Resetting wander_task to 0. ", this:titlec(), " can resume wandering at any time.");
this.wander_task = 0;
this.wander_ok = 0;
endif
else
if (this.wielded in {$teeth, $claw, $hand, $nothing})
if (this.natural_def)
this.wielded = (this.natural_def == 2) ? $hand | $claw;
else
this.wielded = $teeth;
endif
endif
if (verb == "@start")
this.countdown_til_stop = random(10) + 10;
this.wander_ok = 1;
this:plan_next_move();
player:tell(this:titlec(), " is now wandering every ", this.wait_seconds, " seconds. \"@stop ", this, ", then \"@set ", this, ".wait_seconds to <seconds>\" to change the rate.");
else
player:tell(this:titlec(), " was not wandering.");
endif
endif

init_for_core

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

• #136:init_for_core line 13: pass(

Source

if (caller_perms().wizard)
this.wielded = $claw;
this.home = $player_start;
this.grave = (this == $replicating_monster) ? $breeder | $player_start;
pass(@args);
endif

_loot

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

• #107:loot line 1: this:_loot

Source

"USAGE: loot/rob/pilfer/roll/search/strip <monster> => if monster is knocked out, moves monster.contents to the room.";
"wiz-owned";
if (player.location == this.location)
if ((!this.alert) || (!this.mobile))
this:dump_goodies(1);
$you:say_action("%N %<searches> %d for valuable goods.");
this.location:tell_contents(setremove(this.location:contents(), player), this.location.ctype);
else
player:tell(this:titlec(), " cautiously dodges your advance.");
this.location:announce_all_but({this, player}, tostr(this:titlec(), " cautiously avoids ", player:title(), "."));
endif
else
player:tell("There is no \"", dobjstr, "\" here.");
endif

roll_against

Spec this none thisFlags rxdOwner #2Definer #107

Referenced by

none

Source

"USAGE: roll_against(StatOrSkillName or nothing) => Tests for successful action attempt.";
"       => 0=failure, 1=success, 2=total success";
"supports: strength, dexterity, intelligence, health, attack, defense, combat";
name = `args[1] ! E_RANGE => ""';
if (!name)
level = 10.5;
sk = 0;
elseif (i = name in this.stats[1])
level = this.stats[2][i];
sk = 0;
elseif (name in {"combat", "attack"})
sk = "combat" in this.skills[1];
level = this:to_hit();
elseif (name == "defense")
sk = "combat" in this.skills[1];
level = this:to_defend();
else
level = 10.5;
sk = 0;
endif
roll = tofloat((random(6) + random(6)) + random(6));
if ((roll < 5.0) || (roll < (level - 10.0)))
hit = 2;
elseif ((roll < level) && (roll < 16.0))
hit = 1;
else
hit = 0;
endif
return hit;

loot rob pilfer roll search strip

Spec this none noneFlags rxdOwner #2Definer #107

Referenced by

none

Source

this:_loot();