staff #331

heal

Spec this none thisFlags rdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobj, (rpg = $local.rpg).skills.(verb)) && valid(targ = this:check_live_target(player, dobj, rpg.skills.(verb), peaceful = 1)))
  if (targ.inj <= 0)
    player:tell(targ.character.name, " is uninjured.");
  elseif (doll.paralyzed = rpg.magic_db.iceshell_paralyzed_msg)
    player:tell("You'll have to get rid of that shell of ice around ", target.character.name, " first.");
  else
    this:spell(player, targ, rpg.skills.(verb), 0, peaceful);
  endif
endif

storm

Spec this none thisFlags rdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, $local.rpg.skills.(verb)))
  this:spell(player, player.location, $local.rpg.skills.(verb));
endif

unwall

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobj, skill = $local.rpg.skills.forcewall) && valid(targ = this:check_live_target(player, dobjstr, skill)))
  if (!(info = targ:read_misc_note("force_wall")))
    player:tell("There is no wall of force around ", targ.character.po, ".");
  else
    mod = 20;
    if (valid(mage_doll = info[1]) && (parent(mage_doll) == $local.rpg.doll))
      if (mage_doll.character != player)
        player:tell("You didn't cast that wall around ", targ.character.name, ";  this might be a little difficult. . .");
        mod = -info[2];
      endif
    else
      player:tell("The original caster of that wall is no more, allowing you to easily dispel the magick.");
      mod = 200;
    endif
    this:spell(player, targ, "unwall", mod, 0, skill);
  endif
endif

forcewall

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, skill = $local.rpg.skills.(verb)) && valid(targ = this:check_live_target(player, dobjstr, skill, peaceful = 1)))
  this:spell(player, targ, skill, 0, peaceful, skill);
endif

look_self

Spec this none thisDefiner #331

Referenced by

none

Source

pass(@args);
if (valid(this.mounted))
  player:tell("Mounted at the tip of the ", this.name, " is a ", this.mounted.name, ".");
endif

enchant

Spec none with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, skill = $local.rpg.skills.(verb)))
  if (this:enchantment())
    player:tell(this:titlec(), " is already enchanted.");
  else
    this:spell(player, this, skill, 0, 1);
  endif
endif

barkskin

Spec none with thisFlags rxdDefiner #331

Referenced by

none

Source

rpg = $local.rpg;
if (this:check_casting(player, dobjstr, $local.rpg.skills.(verb)))
  "if ($math_utils:sum($list_utils:map_arg($math_utils, \"sum\", $list_utils:map_prop(rpg:get_doll(player).wearing, \"cover\"))))";
  "  player:tell(\"You'll have to remove what you're wearing first.\");";
  "else";
  for item in ($local.rpg:get_doll(player).schedule)
    if (item[2] in {"unslow", "unspeed"})
      player:tell("Your altered metabolism prevents the spell from affecting you.");
      return;
    endif
  endfor
  this:spell(player, player, $local.rpg.skills.(verb), 0, 1);
endif
"endif";
"Hydros (#106189) - Fri May 27, 2005 - Removed the armour check.  This is already done in $local.rpg.magic_db:barkskin.";

biting_cloud

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, $local.rpg.skills.(verb)) && valid(targ = this:check_live_target(player, dobjstr, $local.rpg.skills.(verb))))
  this:spell(player, targ, $local.rpg.skills.(verb));
endif

claim

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, (rpg = $local.rpg).skills.(verb)) && valid(targ = this:check_object_target(player, dobjstr)))
  if (rpg.object_db:is_monster(targ))
    rpg:playertell(player, "Sorry, but the LRPG prohibits slavery.");
  else
    doll = rpg:get_doll(player);
    claimed_by = targ:claimed_by();
    claimed_objs = doll:claimed_objects();
    if (((!valid(claimed_by)) && (length(claimed_objs) < doll.max_claims)) || (targ in claimed_objs))
      rpg:playertell(player, "You don't need a spell to accomplish that.");
    elseif (is_player(targ.location) && (!$object_utils:connected(targ.location)))
      rpg:playertell(player, "Hold your magic! By edict of the great wizard, bystanders must not be molested.");
    else
      this:spell(player, targ, rpg.skills.(verb), 0, 1);
    endif
  endif
endif

unbark

Spec none with thisFlags rxdDefiner #331

Referenced by

none

Source

rpg = $local.rpg;
if (this:check_casting(player, dobjstr, rpg.skills.barkskin))
  doll = rpg:get_doll(player);
  if (!(rpg.magic_db.bs_combat_effect in doll.magic_effects))
    player:tell("While your skin may be tough and gnarly, it is not the result of magick.  Perhaps you should consult a dermatologist.");
  else
    player:tell("You try to cast Girdling the Bark.");
    rpg:say_action(this:casting_msg(player, "unbark", player), player);
    data = doll.schedule[$list_utils:iassoc("unbark", doll.schedule, 2)];
    doll:cancel(data);
    rpg.toady:call_verb(data[1], data[2], {doll, @data[4]});
    doll:check_ins(15);
  endif
endif

title

Spec this none thisDefiner #331

Referenced by

• #331:enchantment line 8: this:title
• #331:enchantment line 10: this:title

Source

name = valid(this.mounted) ? this.mounted.name + "-tipped " | "";
return name + pass(@args);

mount

Spec any on thisFlags rxdDefiner #331

Referenced by

none

Source

rpg = $local.rpg;
if ($command_utils:object_match_failed(what = player:my_match_object(dobjstr), dobjstr))
elseif (what.location != player)
  rpg:playertell(player, "You have to be holding the ", what.name, " in order to mount it into ", this.name, ".");
elseif (this.location != player)
  rpg:playertell(player, "Hard to do that without holding ", this.name, ".");
elseif (!rpg.object_db:is_gem(what))
  rpg:playertell(player, "That doesn't seem to be a likely candidate for mounting.");
elseif (!valid(doll = rpg:get_doll(player)))
  rpg:playertell(player, "You haven't the foggiest notion how to accomplish that. Perhaps you should go play with the cows.");
elseif (doll.paralyzed)
  if (typeof(doll.paralyzed) == STR)
    rpg:playertell(player, doll.paralyzed);
  else
    rpg:playertell(player, "Your'e paralyzed. Knock it off.");
  endif
elseif (is_player(player) && (`idle_seconds(player) ! ANY => 500' > (2 * rpg.idle_threshold)))
  rpg:playertell(player, "You drop your ", what.name, "and lose it.");
  what:moveto(rpg.cemetery);
elseif ($recycler:valid(this.mounted))
  rpg:playertell(player, "You'll have to unmount the ", this.mounted.name, " first.");
elseif (!doll:long_enough())
  rpg:playertell(player, "You're trying to do too many things at once.  Take a deep breath and try again.");
elseif ((try_ = rpg.skills.gadget:resolve(player, 0)) < 1)
  rpg:playertell(player, "You fumble around for a bit, but can't seem to manage to get the ", what.name, " mounted on ", this.name, ".");
else
  rpg:say_action(("%N deftly %<mounts> " + what.name) + " upon the tip of %p %t.", player);
  what:moveto(this);
  this.mounted = what;
  doll.last_attack = time();
endif
"Profane (#30788) - Sun Oct 26 14:11:34 1997 PST - Check for paralysis and idleness";

unmount

Spec any from thisFlags rxdDefiner #331

Referenced by

none

Source

what = this:match(dobjstr);
rpg = $local.rpg;
if (this.location != player)
  rpg:playertell(player, "Hard to do that while you're not holding ", this.name, ".");
elseif ($command_utils:object_match_failed(what, dobjstr))
elseif ((!valid(this.mounted)) || (what != this.mounted))
  rpg:playertell(player, "That does not seem to be mounted in ", this.name, ".");
elseif (!$recycler:valid(doll = rpg:get_doll(player)))
  rpg:playertell(player, "You haven't the slightest idea how to do that. Perhaps you should go play with the cows.");
else
  this.mounted:moveto(player);
  this.mounted = $nothing;
  rpg:say_action("%N deftly %<unmounts> a %t from %p %i.", player, what);
  doll.last_attack = time();
endif
"Irin Sat Oct 12 15:10:35 1996 PDT -- changed to match this.contents, rather than player.contents.";

exitfunc

Spec this none thisDefiner #331

Referenced by

none

Source

{what} = args;
if (!(rpg = $local.rpg):trusted_efunc())
  return E_PERM;
elseif (((!$recycler:valid(this.mounted)) || (this.mounted.location != this)) || (this.mounted == what))
  this.mounted = $nothing;
endif

shatter

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, (rpg = $local.rpg).skills.(verb)) && valid(target = this:check_object_target(player, dobjstr)))
  db = rpg.object_db;
  dude = target.location;
  doll = rpg:get_doll(dude);
  "if (is_player(dude) && (!(((!valid(doll)) || (dude in connected_players())) || ((idle_seconds(dude) > 180) && ((time() - doll.last_attack) > 180)))))";
  if (is_player(dude) && (!valid(this:check_live_target(player, dude, rpg.skills.(verb), 0))))
    return;
  elseif (rpg.magic_db.is_combat_effect in `doll:get_att("freeze_effects") ! E_INVIND => {}')
    player:tell("You'll have to shatter the shell of ice around ", dude.name, " first.");
  elseif (((!db:is_monster(target)) && ((db:is_money(target) || db:is_gem(target)) || db:is_metallic(target))) && (`typeof(target.condition) ! ANY' == NUM))
    this:spell(player, target, rpg.skills.(verb));
  elseif (`target:receive_shatter(target, rpg.skills.(verb)) ! E_VERBNF => 0')
    "... target handled the attack ...";
  else
    player:tell("My God!  ", target:titlec(), " seems to be immune to Terram magic!");
  endif
endif
"Profane 31-MAR-97 1330PST -- no shatter stuff on disconnected players.";
"Hydros (#106189) - Sun Apr 17, 2005 - Added :check_live_target line to handle new PKProtection effect, and because it should probably have this check anyway.";

harden

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, $local.rpg.skills.(verb)) && valid(target = this:check_object_target(player, dobjstr)))
  if ((!`target.condition ! ANY => 0') || `target.wooden ! E_PROPNF, E_PERM => `target.leather ! E_PROPNF, E_PERM => 1'')
    player:tell("My God!  ", target:titlec(), " seems to be immune to Terram magic!");
  elseif (target.location != player)
    player:tell("You must hold ", target:title(), " to affect it.");
  else
    this:spell(player, target, $local.rpg.skills.(verb), 0, 1);
  endif
endif

hail

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, $local.rpg.skills.(verb)) && (targets = this:check_multiple_live_targets(player, dobjstr, $local.rpg.skills.(verb))))
  this:spell(player, targets, $local.rpg.skills.(verb));
endif

iceshell

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, skill = $local.rpg.skills.(verb)) && valid(targ = this:check_live_target(player, dobjstr, skill, peaceful = 0)))
  if ($local.rpg.magic_db.is_combat_effect in targ:get_att("freeze_effects"))
    player:tell(targ.character.name, " is already encased in ice.");
  else
    this:spell(player, targ, verb, 0, peaceful, skill);
  endif
endif

waterwhip

Spec none with thisFlags rxdDefiner #331

Referenced by

none

Source

rpg = $local.rpg;
if (this:check_casting(player, dobjstr, skill = rpg.skills.(verb)))
  doll = rpg:get_doll(player);
  generic = rpg.magic_db.(verb);
  for t in (generic:get_value("dispellers"))
    {who, when} = t;
    if (when < time())
      generic:set_value("dispellers", setremove(generic:get_value("dispellers"), t));
    elseif (who == player)
      return rpg:playertell(player, "You recently dispelled a waterwhip and the dessicating energies still swirl around you.");
    endif
  endfor
  whip = $list_utils:iassoc("unwhip", schedule = doll:get_att("schedule"), 2);
  if (whip && (schedule[whip][4][1].location == player))
    player:tell("You already have one.");
  else
    this:spell(player, generic, verb, 0, 1, skill);
  endif
endif

acceptable

Spec this none thisDefiner #331

Referenced by

none

Source

return $object_utils:isa(thing = args[1], $local.rpg.gem);

conjure

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

magic = (rpg = $local.rpg).magic_db;
spell = rpg.skills.(verb);
if (this:check_casting(player, dobjstr, spell))
  if ("submerged" in player.location:get_room_flags())
    player:tell("You cannot conjure animals underwater!");
  else
    animal = summoned = 0;
    for type in (magic.summonable_animals)
      if (animal)
      elseif ($sysobj:match(dobjstr, type))
        animal = type in magic.summonable_animals;
      endif
    endfor
    for critter in (children(magic.summonable_animal))
      if (critter:master() == player)
        summoned = summoned + 1;
      endif
    endfor
    if ((!animal) && dobjstr)
      player:tell("I don't think you can conjure a \"", dobjstr, "\".");
    else
      this:spell(player, player.location, spell, -55 * summoned, 1, spell, animal);
    endif
  endif
endif
"Irin Fri Oct 18 16:41:25 1996 PDT -- One animal per person, _please_.";
"Profane 2-SEP-97 1706PDT -- no conjure underwater.";

summon

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

"Copied from thin wand (#65144):summon by Griffen (#93228) Sat Sep  7 13:46:25 1996 PDT";
"...usage: summon <truename> with <foci>...";
spell = $local.rpg.skills.(verb);
if (this:check_casting(player, dobjstr, spell))
  this:spell(player, player.location, spell, 0, 1, spell, dobjstr);
endif
"...Griffen (#93228), 6-11-96.  Added...";

may_cast

Spec this none thisDefiner #331

Referenced by

none

Source

"may_cast(doll, spell) => can we cast the spell?";
{doll, spell} = args;
who = doll.character;
if (is_player(who) && `$perm_utils:caller()[1]:gem_needed(doll, spell) ! ANY => 1')
  if (spell in this.gem_spells)
    if (valid(this.mounted) && (!index(this.mounted.name, "pearl")))
      return 1;
    else
      who:tell(("You'll have to mount a gem on your " + this.name) + " to cast that spell.");
      return 0;
    endif
  elseif (spell in this.pearl_spells)
    if (valid(this.mounted) && index(this.mounted.name, "pearl"))
      return 1;
    else
      who:tell(("You'll have to mount a pearl on your " + this.name) + " to cast that spell.");
      return 0;
    endif
  endif
endif
return 1;

pay_cost

Spec this none thisDefiner #331

Referenced by

none

Source

":pay_cost(doll, spell, skill, div) => pay the cost of the casting.";
rpg = $local.rpg;
if ((caller == this) || (caller.owner in rpg.gms))
  {doll, spell, skillobj, costdiv} = args;
  if (is_player(doll.character) && ((spell in this.gem_spells) || (spell in this.pearl_spells)))
    if (!$recycler:valid(mounted = this.mounted))
      "Hmm, how'd they manage to cast the spell then? Oh well, we'll just skip the gem bit.";
      return pass(doll, spell, skillobj, costdiv);
    endif
    price = (skillobj.diff / (costdiv * 4)) + (length(children(parent(mounted))) / 375);
    tvalue = mounted:get_true_value();
    tvalue = (typeof(tvalue) == NUM) ? tvalue | 0;
    mounted:set_true_value(tvalue - price);
    avalue = mounted:get_appraised_value();
    if (avalue)
      mounted:set_appraised_value(max(((avalue - price) + random(20)) - random(20), 1));
    endif
    if (this.mounted:get_true_value() < 1)
      rpg:say_action(("The " + this.mounted.name) + " mounted on %n's %t shatters into a thousand slivers!", this.location, this);
      this.mounted = $nothing;
      fork (rpg.gm_lag)
        if ($recycler:valid(mounted))
          mounted:moveto(rpg.gem_dispenser);
        endif
      endfork
    endif
  endif
  pass(doll, spell, skillobj, costdiv);
endif
"Profane 30-NOV-96 1309PST - move this.mounted=$nothing outside of fork.";
"Irin Sun Dec  1 18:45:19 1996 PST -- Changed this.mounted to mounted, inside the fork, so that gems _will_ shatter.";
"Profane 7-DEC-96 1234PST -- removed obsolete reference to gem_focus_dispenser";

do_enchant

Spec this none thisDefiner #331

Referenced by

none

Source

":do_enchant(power, end time) => Enchant the item.";
if ($local.rpg:trusted(caller_perms()))
  {power, dur} = args;
  if (this.enchantment)
    this.enchantment[1] = max(power, this.enchantment[1]);
    this.enchantment[2] = max(this.enchantment[2] + (dur / 2), time() + dur);
  else
    this.enchantment = {power, time() + dur};
  endif
endif

dam

Spec this none thisDefiner #331

Referenced by

none

Source

return pass(@args) + (this:enchantment() / 10);

con

Spec this none thisDefiner #331

Referenced by

none

Source

return max(1, pass(@args) - (this:enchantment() / 50));
"THX (#105941) - Tue Jan  9, 2001 - Made enchantment subtractive.  It might actually help now.";

enchantment

Spec this none thisDefiner #331

Referenced by

• #331:enchant line 2: this:enchantment
• #331:dam line 1: this:enchantment
• #331:con line 1: this:enchantment
• #331:attack line 1: this:enchantment
• #331:hidden_verbs line 21: this:enchantment
• #331:magicfist line 1: this:enchantment
• #331:firebolt line 1: this:enchantment
• #331:fortify line 1: this:enchantment

Source

if (enc = this.enchantment)
  (rpg = $local.rpg):secure();
  if (enc[2] < time())
    if (valid(x = rpg:get_doll(this.location)))
      if ((x.body_areas == rpg.magic_db.barkskin_body_areas) && (this in x.wielding))
        return enc[1];
      endif
      name = (this.location.name + "'s ") + this:title();
    else
      name = this:title();
    endif
    rpg:say_action(name + " seems to flicker briefly.", this.location, this, this.location.location);
    this.enchantment = 0;
    return 0;
  else
    return enc[1];
  endif
endif
return 0;
"THX (#105941) - Wed Jul 12, 2000 - If the caster is barkskinned, let's let the enchantment stay!";

attack parry

Spec this none thisDefiner #331

Referenced by

none

Source

return pass(@args) + (this:enchantment() / 15);

set_mounted

Spec this none thisDefiner #331

Referenced by

none

Source

":set_mounted(OBJ gem) => Sets the .mounted value, allowing non G_M code to change this on G_M owned objects.  It is the coding GM's responsibility to make sure any already mounted gems are removed, and any unmounted gems are moved to the staff.";
if ($local.rpg:trusted(caller_perms()))
  this.mounted = args[1];
endif

acidrain

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, skill = $local.rpg.skills.(verb)) && valid(targ = this:check_live_target(player, dobjstr, skill)))
  storms = $local.rpg.magic_db:storms_active_in(player.location);
  if (!(targ.character in $list_utils:slice(storms, 2)))
    player:tell("There's no storm above ", targ.character.name, " to turn into acid.");
  elseif (targ.character == player)
    player:tell("Melting yourself with acid is not very comfortable. I don't advise it.");
  else
    this:spell(player, targ, skill, 0);
  endif
endif

appraise

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

skill = $local.rpg.skills.(verb);
if (this:check_casting(player, dobjstr, skill) && valid(target = this:check_object_target(player, dobjstr)))
  if (target.location != player)
    player:tell("You have to hold something to use this spell on it.");
  elseif ($local.rpg.object_db:is_money(target))
    player:tell("Um, just count it. You don't need a spell.");
  elseif (parent(target) != $local.rpg.gem)
    player:tell("The spell only works on gems, pal.");
  elseif (target:get_appraised_value())
    player:tell("The ", target.name, " has already been appraised.");
  else
    this:spell(player, target, skill, 0, 1);
  endif
endif

hidden_verbs

Spec this none thisDefiner #331

Referenced by

none

Source

"Swiped from Staff:hidden_verbs by Dagard (#49807) Mon Dec  1 12:00:42 1997 PST";
{who} = args;
prev = pass(who);
staff = (rpg = $local.rpg).staff;
if (valid(this.mounted))
  prev = {@prev, {staff, "mount", {"any", "on top of/on/onto/upon", "this"}}};
  pearl = index(this.mounted.name, "pearl");
  gem = !pearl;
else
  prev = {@prev, {staff, "unmount", {"any", "out of/from inside/from", "this"}}};
  pearl = gem = 0;
endif
pearl || (prev = {@prev, {staff, "iceshell", {"any", "with/using", "this"}}});
pearl || (prev = {@prev, {staff, "waterwhip", {"none", "with/using", "this"}}});
pearl || (prev = {@prev, {staff, "acidrain", {"any", "with/using", "this"}}});
gem || (prev = {@prev, {staff, "shatter", {"any", "with/using", "this"}}});
gem || (prev = {@prev, {staff, "hail", {"any", "with/using", "this"}}});
gem || (prev = {@prev, {staff, "harden", {"any", "with/using", "this"}}});
gem || (prev = {@prev, {staff, "summon", {"any", "with/using", "this"}}});
gem || (prev = {@prev, {staff, "appraise", {"any", "with/using", "this"}}});
if (!this:enchantment())
  prev = {@prev, {staff, "magicfist magic*_fist punch", {"any", "with/using", "this"}}};
  prev = {@prev, {staff, "firebolt heat", {"any", "with/using", "this"}}};
endif
return prev;
"THX (#105941) - Wed Feb 16, 2000 - Added removal of pearl-or-gem requiring verbs if not mounted and added removal of verbs that require enchantment if no enchantment is present.";

break

Spec this none thisDefiner #331

Referenced by

none

Source

(rpg = $local.rpg):secure();
mounted = this.mounted;
loc = this.location;
if (valid(mounted))
  mounted:moveto(rpg.cemetery.turf[1]);
endif
"Moving to nothing is necessary 'cause otherwise it gets offed when the staff itself gets offed.";
if ((typeof(pass(@args)) != ERR) && valid(mounted))
  if (valid(rpg:get_doll(loc)))
    mounted:moveto(loc.location);
    rpg:say_action(("The " + mounted.name) + " from %n's %t tumbles to the ground.", loc);
  else
    mounted:moveto(loc);
  endif
else
  "Ooops, error. move the gem back!";
  `mounted:moveto(this) ! E_INVIND';
endif

magicfist magic*_fist punch

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:enchantment())
  if (this:check_casting(player, dobjstr, (rpg = $local.rpg).skills.magic_fist) && valid(target = this:check_live_target(player, dobjstr, rpg.skills.magic_fist)))
    this:spell(player, target, rpg.skills.magic_fist);
  endif
else
  player:tell((random(3) == 1) ? ("The " + this.name) + " that you are holding might be a focus for that spell if you enchanted it first ..." | "You need to be wielding the proper focus.");
endif

firebolt heat

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:enchantment() < 99)
  player:tell("You try to cast the ", verb, " spell, but realize you lack the proper focus.");
elseif (this:check_casting(player, dobjstr, skill = $local.rpg.skills.(verb)) && valid(targ = this:check_live_target(player, dobjstr, skill, peaceful = 0)))
  this:spell(player, targ, skill, 0);
endif

viper_bite

Spec none with thisFlags rxdDefiner #331

Referenced by

none

Source

rpg = $local.rpg;
if (this:check_casting(player, dobjstr, skill = rpg.skills.(verb)))
  "if (rpg:get_doll(player).natural_weapons != rpg.doll.natural_weapons)";
  "  player:tell(\"Hmm, you can't get the spell to work.\");";
  "else";
  this:spell(player, player, skill);
  "endif";
endif

unviper

Spec none with thisFlags rxdDefiner #331

Referenced by

none

Source

rpg = $local.rpg;
if (this:check_casting(player, dobj, rpg.skills.viper_bite))
  "if (!(rpg.magic_db.viper_bite in (doll = rpg:get_doll(player)).natural_weapons))";
  if (!(rpg.magic_db.viper_bite in rpg.object_db.natweap_db:get_all_natweaps(doll = rpg:get_doll(player))))
    player:tell("You don't have any dental problems that can be fixed by magick.");
  else
    this:spell(player, doll, "unviper", 0, 0, rpg.skills.viper_bite);
  endif
endif

nickname

Spec this none thisDefiner #331

Referenced by

none

Source

{nickname} = args;
if (children(this) || this.unique)
elseif ((this.owner == $local.rpg.owner) && ($code_utils:verb_loc() == parent(this)))
  $local.rpg:secure();
  this.name = nickname;
  this.aliases = setadd(this.aliases, nickname);
endif

stoneflesh

Spec none with thisFlags rxdDefiner #331

Referenced by

none

Source

rpg = $local.rpg;
if (this:check_casting(player, dobjstr, skill = rpg.skills.harden))
  this:spell(player, player, verb, 0, 1, skill);
endif

parch

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, dobjstr, skill = $local.rpg.skills.(verb)) && valid(targ = this:check_live_target(player, dobjstr, skill, peaceful = 0)))
  this:spell(player, targ, verb, 0, peaceful, skill);
endif

unstone

Spec none with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:check_casting(player, player.location, $local.rpg.skills.harden))
  this:spell(player, $local.rpg:get_doll(player), "unstone", 0, 1, $local.rpg.skills.harden);
endif

fortify

Spec any with thisFlags rxdDefiner #331

Referenced by

none

Source

if (this:enchantment() < 111)
  player:tell("You try to cast the ", verb, " spell, but realize you lack the proper focus.  Your ", this.name, " may not be magickal enough.");
elseif (this:check_casting(player, dobjstr, $local.rpg.skills.harden) && valid(target = this:check_object_target(player, dobjstr)))
  if ((!`target.condition ! ANY => 0') || `!target.wooden ! E_PROPNF, E_PERM => `!target.leather ! E_PROPNF, E_PERM => 1'')
    player:tell("My God!  ", target:titlec(), " seems to be immune to Herbam magic!");
  elseif (target.location != player)
    player:tell("You must hold ", target:title(), " to affect it.");
  elseif ((doll = (rpg = $local.rpg):get_doll(player)):read_misc_note("Knows_Fortify") == E_PROPNF)
    player:tell("You lack the knowledge of how to cast this spell.");
  else
    this:spell(player, target, verb, doll.herbam, 1, rpg.skills.herbam);
  endif
endif
"dalton (#116601) - Wed Jul  9, 2003 - Copied from Hydros' (#106189) prototype ";