generic dispenser #1387

Parent #517Owner —Flags Source rpg_march_2006/Misc/dispenser.txt

Aliases: dispenser, generic dispenser, generic

4 verbs · 12 properties · 0 children

Verbs

Properties

Ancestry

• #517 Generic LRPG Thing

  • #1387 generic dispenser

Ancestors (nearest first): #517 Generic LRPG Thing

Children: none

Call graph

Source

if (player.location != this.location)
  return player:tell("I don't understand that");
endif
rpg = $local.rpg;
what = $string_utils:match(dobjstr, this.dispenses, "aliases", this.dispenses, "name");
if (what == $failed_match)
  player:tell("There are no ", dobjstr, "s in the ", this.name, ".");
  return;
elseif (what == $ambiguous_match)
  player:tell("I don't know which one you mean.");
elseif ((length($list_utils:remove_duplicates(this.takers)) == 1) && (player == this.takers[1]))
  player:tell("Greedy, aren't we? I think you've had enough for now.");
elseif (valid(this.location))
  new = rpg.recycler:_create(what);
  if (typeof(new) == ERR)
    player:tell(this.name, " is unable to produce ", $string_utils:a_or_an(what.name), " ", what.name, ".  A GM should be advised.");
    this.location:announce(player.name, " scrabbles around ", this.name, " but comes away empty-handed.");
    return;
  endif
  new.name = what.name;
  new.aliases = what.aliases;
  player:tell("You take a ", new.name, " from the ", this.name, ".");
  new:moveto(player);
  this.location:announce(player.name, " takes a ", new.name, " from the ", this.name, ".");
  this.takers = {player, this.takers[1]};
endif
"DR 25-AUG-94 -- Added short-circuit if recycler messes up.";
"StarDancer Nov-19-95 -- Added location checks, at Bradley's suggestion";
"Profane 14-DEC-96 1725PST -- added 5 item limit type thing";

what = dobj;
if ((what == $failed_match) || (what == $nothing))
  player:tell("Put what in the ", this.name, "?");
  return;
elseif (what == $ambiguous_match)
  what = $string_utils:match(dobjstr, player.contents, "name", player.contents, "aliases");
  if (what <= $sysobj)
    player:tell("Sorry, I don't know which ", dobjstr, " you mean.");
    return;
  endif
endif
if (what.location != player)
  player:tell("You don't have the ", what.name, ".");
elseif ((player.location != this.location) && (!(player in $local.rpg.gms)))
  player:tell("My, what long arms you have.");
elseif (parent(what) in this.dispenses)
  player:tell("You put the ", what.name, " in the ", this.name, ".");
  if (player.location == this.location)
    this.location:announce(player.name, " puts a ", what.name, " in the ", this.name, ".");
  endif
  what:moveto($local.rpg.cemetery);
else
  player:tell("That doesn't fit.");
endif

pass(@args);
names = {};
for thing in (this.dispenses)
  names = listappend(names, thing.name);
endfor
player:tell("The ", this.name, " contains ", $string_utils:english_list(names), ".");

player:tell("Contact Grand_Master about adopting your generic gear.");
return E_PERM;