generic puppet #116

take_hit

Spec this none thisFlags rxdOwner #2Definer #116

Referenced by

• #134:take_hit line 14: pass(

Source

"USAGE: victim:take_hit(damage)";
"       wiz-owned to prevent permission problems";
damage = tofloat(args[1]);
fork (2)
if ((this.alive && this.alert) && this.mobile)
if ((this in connected_players()) || (this.enemy == this))
"Make your own descisions";
elseif (this.hostility)
`this.location:do_attack(tostr(this), tostr(this.enemy), this:damage(), 1) ! ANY => "invalid enemy or bad location"';
else
suspend(1);
this:_force("wander");
endif
endif
endfork
if ((((caller == this.location) || (caller == this.owner)) || `caller.hostility ! E_PROPNF => 0') || `caller.weapon ! E_PROPNF => 0')
damage = ((x = damage - this:armor()) > 0.1) ? x | 0.1;
this.stats_current[2][4] = this.stats_current[2][4] - damage;
if (this.stats_current[2][4] < 0.0)
this:die();
endif
endif
return this.stats_current[2][4];

die

Spec this none thisFlags rxdOwner #2Definer #116

Referenced by

• #116:take_hit line 20: this:die

Source

"resets stats & skills, moves puppet to afterlife.";
"wiz-owned";
who = (length(callers()) < 2) ? player | callers()[2][3];
trustees = {this.owner};
for x in ($object_utils:ancestors(this))
trustees = setadd(trustees, x.owner);
endfor
for x in ($object_utils:ancestors(this.location))
trustees = setadd(trustees, x.owner);
endfor
if ((!(who in trustees)) && (!who.wizard))
"Bogus killer";
return;
elseif (!this.alive)
"already dead";
return this:pass_out();
endif
this.alive = 0;
if (valid(this.followed_by))
this.followed_by.following = $nothing;
endif
if (valid(this.following))
this.following.followed_by = $nothing;
endif
this.followed_by = $nothing;
this.following = $nothing;
this.location:announce_all_but({this}, $string_utils:pronoun_sub(this.death_msg, this));
this:tell("The world around you fades to black, and you feel light as a feather.");
this.alert = 0;
this.location:announce_all_but({this}, $string_utils:pronoun_sub(this.death_msg, this));
deathscene = this.location;
fork (7)
deathscene:announce_all("The corpse of ", this:title(), " dissolves quickly.");
this:dump_goodies(1);
move(this, $dead_zone);
this.location:announce_all_but({this}, this:titlec(), "(yes, quite dead) has arrived.");
fork (this.gestate)
this:birth();
endfork
endfork
this.free_points = 0.0;
this.stats_current = {{"Strength", "Dexterity", "Intelligence", "Health"}, {0.0, 0.0, 0.0, 0.0}};

birth

Spec this none thisFlags rxdOwner #2Definer #116

Referenced by

• #116:die line 38: this:birth

Source

"wiz-owned";
this.alive = 1;
this.alert = 1;
this.stats_current = this.stats;
try
this:moveto(this.home);
except v (ANY)
this:moveto($dead_zone);
endtry
this.location:announce_all($string_utils:pronoun_sub(this.birth_msg, this));
return;

_force

Spec this none thisFlags rxdOwner #2Definer #116

Referenced by

• #116:take_hit line 12: this:_force
• #116:go line 6: this:_force
• #116:wander line 40: this:_force
• #116:ask line 5: this:_force
• #116:ask line 19: this:_force
• #116:ask line 33: this:_force
• #116:ask line 64: this:_force
• #116:ask line 67: this:_force
• #116:ask line 80: this:_force
• #134:tell line 16: this:_force
• #134:sell_product line 35: this:_force
• #134:sell_product line 48: this:_force
• #134:sell_product line 51: this:_force

Source

"Wizowned to accomodate force_input";
{action, dpi} = $string_utils:first_word(tostr(@args));
player = this;
if (action[1] == ":")
dpi = tostr(action[2..$], " ", dpi);
action = "emote";
elseif (action[1] in {"-", "`"})
dpi = tostr(@args);
action = "say";
endif
if (action == "say")
return this:say(dpi);
endif
if (action in {"look", "l"})
return this:l(dpi);
endif
if (action == "go")
fork (1)
this:l();
endfork
endif
force_input(this, tostr(action, " ", dpi));

@start @stop

Spec this none noneFlags rdOwner #2Definer #116

Referenced by

none

Source

"wiz-owned to allow scheduling";
if (!$object_utils:isa(player, $frand_class))
return;
endif
if (this.wander_task)
if (verb == "@start")
player:tell(this:titlec(), " is already wandering.");
elseif ($scheduler:valid_task(tonum(this.wander_task)))
$scheduler:kill_task(this.wander_task);
this.wander_task = 0;
player:tell(this:titlec(), " has stopped wandering.");
else
player:tell("Invalid wander task. Resetting wander_task to 0. ", this:titlec(), " can resume wandering at any time.");
this.wander_task = 0;
endif
else
if (verb == "@start")
this.wander_task = $scheduler:schedule_every(this.wait_seconds, this, "wander");
player:tell(this:titlec(), " is now wandering every ", this.wait_seconds, " seconds. \"@set ", this, ".wait_seconds to <seconds>\" to change the rate.");
else
player:tell(this:titlec(), " was not wandering.");
endif
endif

random_free

Spec this none thisFlags rxdOwner #2Definer #116

Referenced by

• #116:look_self line 26: this:random_free
• #134:tell line 34: this:random_free

Source

"WIZ PERMS";
if (`player.free_points ! E_PROPNF => 0')
player.free_points = player.free_points + 0.005;
endif

to_defend

Spec this none thisFlags rxdOwner #36Definer #116

Referenced by

none

Source

"Returns dexterity, modified by basic combat skill.";
"Unlike the $rpgamer verb, does not check for connection.";
combat = "combat" in this.skills[1];
dex = ((!this.alert) || (!this.mobile)) ? 0.1 | this.stats_current[2][2];
defense = (dex + (sqrt(this.skills[2][combat]) / 2.0)) + (this:armor() / 2.0);
return (defense > 0.0) ? defense | 0.1;

tell

Spec this none thisFlags rxdOwner #36Definer #116

Referenced by

• #116:die line 28: this:tell
• #116:direct_say line 12: this:tell
• #116:direct_say line 16: this:tell
• #116:direct_say line 19: this:tell
• #116:l*ook line 8: this:tell
• #116:l*ook line 17: this:tell
• #116:l*ook line 30: this:tell
• #116:l*ook line 32: this:tell
• #116:l*ook line 35: this:tell
• #116:l*ook line 39: this:tell
• #116:l*ook line 41: this:tell
• #116:go line 12: this:tell
• #116:_loot line 13: this:tell
• #134:tell line 2: pass(
• #134:tell line 5: pass(
• #134:tell line 8: pass(
• #134:tell line 28: pass(
• #134:tell line 31: pass(
• #134:tell line 43: pass(

Source

if ((!this.my_tell) || (this in connected_players()))
pass(@args);
if ($string_utils:index_delimited(tostr(@args), "asks you,") && $string_utils:index_delimited(tostr(@args), "name"))
this:say(tostr("-", player, " My name is ", this.name, "."));
endif
endif
for x in (this.watchers)
x:tell("from ", this, ": ", @args);
endfor

watch ignore

Spec this none noneFlags rxdOwner #36Definer #116

Referenced by

none

Source

if (!$object_utils:isa(player, $frand_class))
return player:tell("You're not allowed to watch ", $string_utils:nn(this), ".");
endif
if (player in this.watchers)
if (verb == "watch")
player:tell("You're already watching ", $string_utils:nn(this), ".");
else
this.watchers = setremove(this.watchers, player);
player:tell("You're no longer watching ", $string_utils:nn(this), ".");
endif
else
if (verb == "watch")
this.watchers = setadd(this.watchers, player);
player:tell("You're watching ", $string_utils:nn(this), ".");
else
player:tell("You weren't watching ", $string_utils:nn(this), ".");
endif
endif

say

Spec this none thisFlags rxdOwner #36Definer #116

Referenced by

• #116:_force line 12: this:say
• #116:tell line 4: this:say
• #116:ask line 30: this:say
• #116:ask line 39: this:say
• #116:ask line 47: this:say
• #116:ask line 70: this:say
• #116:ask line 75: this:say
• #116:ask line 78: this:say
• #134:take_hit line 16: this:say
• #134:tell line 15: this:say
• #134:tell line 24: this:say
• #134:tell line 40: this:say
• #134:list line 5: this:say
• #134:list line 9: this:say
• #134:sell line 13: this:say
• #134:sell line 14: this:say
• #134:sell line 16: this:say
• #134:sell line 21: this:say
• #134:sell line 24: this:say
• #134:ask line 23: this:say
• #134:collect_cash line 2: this:say
• #134:collect_cash line 10: this:say
• #134:sell_product line 8: this:say
• #134:sell_product line 10: this:say
• #134:sell_product line 13: this:say
• #134:sell_product line 19: this:say
• #134:sell_product line 20: this:say
• #134:sell_product line 26: this:say
• #134:sell_product line 28: this:say
• #134:sell_product line 37: this:say
• #134:sell_product line 56: this:say

Source

this.my_tell = 1;
argstr = $ansi_utils:terminate_normal(args[1]);
if (!this.alert)
this.my_tell = 0;
return player:tell(this:title(), " is sleeping.");
elseif (argstr[1] in {"-", "`"})
this.my_tell = 0;
return this:direct_say($string_utils:first_word(argstr));
endif
fork (2)
"for realism, delayed response.";
this.my_tell = 1;
sayverb = $string_utils:get_say_verb(argstr);
for ear in (this.location:contents())
ear:tell(this:titlec(), " ", $gender_utils:get_conj(sayverb, this), ", \"", argstr, "\"");
endfor
this.my_tell = 0;
endfork

direct_say

Spec this none thisFlags rxdOwner #36Definer #116

Referenced by

• #116:say line 8: this:direct_say

Source

"USAGE: direct_say(name,words)";
this.my_tell = 1;
name = args[1][1][2..$];
words = args[1][2];
who = this.location:match_object(name);
sayverb = $string_utils:get_say_verb(words);
preppy = $string_utils:get_say_verb_prep(sayverb);
fork (2)
"for realism, delayed response.";
this.my_tell = 1;
if (!valid(who))
this:tell("You ", $you:verb_sub(sayverb), preppy, name, ", \"", words, "\"");
this.location:announce(tostr(this:titlec(), " ", $gender_utils:get_conj(sayverb, this), preppy, name, ", \"", words, "\""));
else
if (who == this)
this:tell("You ", $you:verb_sub(sayverb), preppy, "yourself, \"", words, "\"");
this.location:announce(tostr(this:titlec(), " ", $gender_utils:get_conj(sayverb, this), preppy, $gender_utils:get_pronoun("r", this), ", \"", words, "\""));
else
this:tell("You ", $you:verb_sub(sayverb), preppy, who:title(), ", \"", words, "\"");
who:tell(tostr(this:titlec(), " ", $gender_utils:get_conj(sayverb, this), preppy, "you, \"", words, "\""));
this.location:announce_all_but({this, who}, tostr(this:titlec(), " ", $gender_utils:get_conj(sayverb, this), preppy, who:title(), ", \"", words, "\""));
endif
endif
this.my_tell = 0;
endfork

l*ook

Spec this none thisFlags rxdOwner #36Definer #116

Referenced by

none

Source

argstr = args ? tostr(args[1]) | "";
if (!argstr)
if (!valid(this.location))
player:tell(this, " is nowhere!");
elseif (!($room in $object_utils:ancestors(this.location)))
this.location:look_self(@args);
elseif ($terrain in $object_utils:ancestors(this.location))
this:tell(this.location:title(), " => {", this.x_loc, ",", this.y_loc, "}");
stuff = {};
exitset = {};
wayset = {};
for OBJ in (this.location.contents)
if ({OBJ.x_loc, OBJ.y_loc} == {this.x_loc, this.y_loc})
stuff = {@stuff, OBJ:title()};
endif
endfor
this:tell("Area contents: ", $string_utils:english_list(stuff));
for ex in (this.location.exits)
if (this.location:match_loc(this, ex))
exitset = setadd(exitset, ex);
endif
endfor
for w in (this.location.compass)
if (this.location:loc_way(w, this.x_loc, this.y_loc) != {0, 0})
wayset = setadd(wayset, this.location:parse_dir(w, "long"));
endif
endfor
allways = $set_utils:diff(this.location.long_ways, {"up", "down"});
if ($set_utils:equal(wayset, allways))
this:tell("Exits: You can move horizontally in any direction.");
elseif (wayset != {})
this:tell("Exits: You can move ", $string_utils:english_list(wayset), ".");
endif
if (exitset != {})
this:tell($string_utils:pronoun_sub(tostr(this.location.real_exit_msg, $string_utils:title_list(exitset), "."), this.location));
endif
return;
else
this:tell(".......................");
this.location:look_self(@args);
return this:tell(".......................");
endif
elseif (valid(thing = this.location:match(argstr)))
return thing:look_self();
elseif (thing == $ambiguous_match)
player:tell("Which one?");
elseif (!$command_utils:object_match_failed(this.location:match_exit(argstr), argstr))
return player:tell(this:titlec(), " can't see past the exit.");
endif
return player:tell("(", this:titlec(), " is confused.)");

go

Spec any any anyFlags rxdOwner #36Definer #116

Referenced by

none

Source

place = this.location;
if ($terrain in $object_utils:ancestors(place))
way = dobjstr;
target = place:loc_way(way, this.x_loc, this.y_loc);
if (target != {0, 0})
return this:_force(way);
endif
if (valid(x = place:match_exit(dobjstr)))
if (place:match_loc(x, this))
return place:(verb)(@args);
else
return this:tell("You can't go that way.");
endif
endif
endif
place:(verb)(@args);

wander

Spec none none noneFlags rxdOwner #36Definer #116

Referenced by

none

Source

"Finds and takes a random exit. If you want to repeat this act, you need to call the verb from within a timed loop.";
"If his.terrain_only is true, it will stay in a terrain and never take a real exit.";
if (!((this.alive && this.alert) && this.mobile))
return "Can't move.";
endif
if ($object_utils:isa(this.location, $room) && (!$object_utils:isa(this.location, $terrain)))
real = ((rlen = length(rexits = this.location:obvious_exits())) && (rexit = rexits[random(rlen)]):is_unlocked_for(this)) ? 1 | 0;
if ($object_utils:has_property(this.location, "virtual_exits"))
virtual = ((vlen = length(vexits = this.location.virtual_exits)) && (vexit = vexits[random(vlen)])) ? 1 | 0;
else
virtual = 0;
endif
if (real && virtual)
if (random(2) == 2)
rexit:move(this);
elseif (this.location:exit_unlocked_for(vexit, this))
this.location:match_exit(vexit[1][1]);
this.location:move(this);
endif
elseif (real)
rexit:move(this);
elseif (virtual)
this.location:match_exit(vexit[1][1]);
this.location:move(this);
else
"No way out. Go home.";
this:moveto(this.home);
endif
elseif ($object_utils:isa(this.location, $terrain))
if (!this.terrain_only)
real = (((rlen = length(rexits = this.location:obvious_exits())) && (rexit = rexits[random(rlen)]):is_unlocked_for(this)) && this.location:match_loc(rexit, this)) ? 1 | 0;
if (real)
return rexit:move(this);
endif
endif
for t in (this.location.compass)
way = this.location.compass[random($)];
target = this.location:loc_way(way, this.x_loc, this.y_loc);
if (target != {0, 0})
return this:_force(way);
endif
endfor
endif

look_self

Spec this none thisFlags rxdOwner #36Definer #116

Referenced by

none

Source

player:tell("You look at ", this.name, ".");
desc = this:description();
if (desc)
player:tell_lines(desc);
else
player:Tell("You see nothing special.");
endif
health = this.stats_current[2][4] / (this.stats[2][4] + 0.0001);
if (!this.alert)
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} unconscious.", this));
elseif (!this.alive)
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} ethereal, as if dead.", this));
elseif (health < 0.75)
if (health < 0.25)
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} obviously in very poor health.", this));
else
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} obviously in poor health.", this));
endif
else
player:tell($gender_utils:pronoun_sub("%{:He} %{!is} awake and %{!looks} alert.", this));
endif
if (stuff = this:contents())
player:Tell("");
this:tell_contents(stuff);
endif
this:random_free();

pass_out

Spec this none thisFlags rxdOwner #2Definer #116

Referenced by

• #116:die line 16: this:pass_out

Source

"wiz-owned";
if (this.alert)
if (((player.wielded == $hand) || (player:damage(1) < 4.0)) || (this.enemy != player))
this.location:announce_all_but({this}, $string_utils:pronoun_sub("%N %<becomes> dazed.", this));
timeout = 20;
wakeup = "%N %<regains> focus.";
else
this.location:announce_all_but({this}, $string_utils:pronoun_sub("%N %<falls> unconscious.", this));
timeout = 40;
wakeup = "%N %<awakens> from unconsciousness.";
endif
this.alert = 0;
fork (timeout)
this.alert = 1;
if (this.alive)
this.location:announce_all_but({this}, $string_utils:pronoun_sub(wakeup, this));
endif
endfork
endif

init_for_core

Spec this none thisFlags rxdOwner #2Definer #116

Referenced by

• #134:init_for_core line 19: pass(

Source

if (caller_perms().wizard)
if (this == $puppet)
this.watchers = {};
this.wielded = $hand;
this.free_points = 0.0;
this.stats = {{"Strength", "Dexterity", "Intelligence", "Health"}, {10.0, 10.0, 10.5, 10.0}};
this.stats_current = this.stats;
else
for p in (properties($puppet))
if ((!p) in {"build_help", "help_msg"})
clear_property(this, p);
endif
endfor
endif
return pass(@args);
endif

_loot

Spec this none thisFlags rxdOwner #2Definer #116

Referenced by

none

Source

"USAGE: loot/rob/pilfer/roll/search/strip <person> => if person is knocked out, moves person.contents to the room.";
if (!`player.free_points ! E_PROPNF => 0')
return player:tell("Both parties must be roleplaying to do that.");
endif
"NEEDS WIZ PERMS";
if (player.location == this.location)
if ((this in connected_players()) || (!is_player(this)))
if ((!this.alert) || (!this.mobile))
this:dump_goodies(1);
$you:say_action("%N %<searches> %d for valuable goods.");
this.location:tell_contents(setremove(this.location:contents(), player), this.location.ctype);
else
this:tell("You cautiously dodge ", player:title(), ", who is trying to steal from you.");
player:tell(this:titlec(), " cautiously dodges your advance.");
this.location:announce_all_but({this, player}, tostr(this:titlec(), " cautiously avoids ", player:title(), "."));
endif
else
$you:say_action("%N %<attempts> to search %d for valuable goods, but %<is/are> deflected by a stasis field.");
endif
else
player:tell("There is no \"", dobjstr, "\" here.");
endif

@addlang*uage @add-lang*uage

Spec any at/to thisFlags rdOwner #36Definer #116

Referenced by

none

Source

if ((!player.wizard) && (player != this.owner))
return player:tell(E_PERM);
endif
lang = $string_utils:match(dobjstr, $object_utils:descendants($lang), "lang_name");
if (!valid(lang))
return player:tell("That is an unknown language.");
elseif (!(lang in this.languages[1]))
this.languages = {{@this.languages[1], lang}, {@this.languages[2], 2.0}};
player:tell(lang.lang_name, " added to languages known by ", this:title(), ".");
else
player:tell(this:titlec(), " already knows ", lang.lang_name, ".");
endif

@rmlang*uage @rm-lang*uage

Spec any out of/from inside/from thisFlags rdOwner #36Definer #116

Referenced by

none

Source

if ((!player.wizard) && (player != this.owner))
return player:tell(E_PERM);
endif
lang = $string_utils:match(dobjstr, $object_utils:descendants($lang), "lang_name");
if (!valid(lang))
return player:tell("That is an unknown language.");
elseif (!(lin = lang in this.languages[1]))
player:tell(this:titlec(), " doesn't know ", lang.lang_name, ".");
else
this.languages[1] = listdelete(this.languages[1], lin);
this.languages[2] = listdelete(this.languages[2], lin);
player:tell(lang.lang_name, " removed from languages known by ", this:title(), ".");
endif

ask

Spec this any anyFlags rxdOwner #2Definer #116

Referenced by

• #134:ask line 2: pass(

Source

if ((!player.wizard) && (!(player.location == this.location)))
return player:tell(this:titlec(), " is not here.");
endif
if (((((iobjstr[1] in {"-", ":"}) && this.alive) && this.alert) && this.mobile) && (player.wizard || (player == this.owner)))
return this:_force(iobjstr);
else
this.my_tell = 1;
if (iobjstr && ($string_utils:words(iobjstr)[$] == "me"))
iobjstr = $string_utils:subst(iobjstr, {{" me", tostr(" ", player)}});
endif
niobjstr = $string_utils:substitute(iobjstr, {{tostr(player), "%o"}});
$you:say_action(tostr("%N %<asks> ", this:title(), " ", prepstr, " ", iobjstr, "."));
this.my_tell = 0;
if (!((this.alive && this.alert) && this.mobile))
return player:tell(this:titlec(), " is in no condition to respond.");
elseif (prepstr == "to")
if (iobjstr in {"shut up", "be quiet", "hush"})
this.my_tell = 1;
this:_force(":nods sullenly.");
this.my_tell = 0;
return;
endif
cmdtarg = $string_utils:first_word(iobjstr);
cmd = cmdtarg[1];
targ = cmdtarg[2];
this.my_tell = 1;
if (player in this.bosses)
if (cmd in {"attack", "hit", "fight", "kill", "destroy", "punch", "kick", "stun", "disable", "shoot", "stab"})
if (!targ)
this:say(tostr("-", player, " ", $string_utils:capitalize(cmd), " who?"));
elseif (valid(target = this.location:match(targ)))
this.enemy = target;
this:_force(iobjstr);
this.hostility = 2;
fork (24)
this.hostility = 1;
endfork
elseif (target == $ambiguous_match)
this:say(tostr("-", player, " Which ", targ, "?"));
elseif (this.location:match_fake(targ))
this.location:announce_all(tostr(this:titlec(), " half-heartedly ", cmd, "s ", targ, "."));
else
this.location:announce_all(tostr(this:titlec(), " looks confused."));
endif
elseif (cmd in {"stop", "quit"})
this.hostility = 0;
this:say(tostr("-", player, " Yessir. :("));
fork (2)
this:_release();
if ($scheduler:valid_task(tonum(this.wander_task)))
$scheduler:kill_task(this.wander_task);
this.wander_task = 0;
player:tell(this:titlec(), " has stopped wandering.");
endif
endfork
fork (12)
this.hostility = 1;
endfork
elseif ((cmd in {"hand", "give"}) && ($string_utils:words(targ)[$] == tostr(player)))
theitem = $string_utils:from_list($string_utils:words(targ)[1..$ - 2], " ");
player:tell(theitem);
this:give_item(theitem, player);
elseif (cmd == "follow")
this:_force(tostr("follow ", player));
this:_leash();
else
this:_force(tostr(cmd, " ", targ));
endif
else
this:say(tostr("-", player, " Sorry... I have other priorities."));
endif
this.my_tell = 0;
elseif (prepstr == "for")
if ((!player.wizard) && (player != this.owner))
return this:say(tostr("-", player, " I don't believe so."));
endif
if (iobjstr in {"boss", "commander", "owner"})
this:say(tostr("-", player, " I follow orders from ", $string_utils:nn(this.owner), "."));
elseif ($string_utils:words(iobjstr)[$] in $list_utils:slice($money_utils.currencies))
this:_force(tostr("give ", iobjstr, " to ", player.name));
else
this:give_item(iobjstr, player);
endif
else
player:tell("Try: \"ask ", this:title(), " to/for <something>\"");
endif
endif

infobar

Spec this none thisFlags rxdOwner #2Definer #116

Referenced by

none

Source

No program (verb defined but unprogrammed).