Conversion Utils #87

dd_to_dms dh_to_hms

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":dd_to_dms(INT|FLOAT <degrees>) => LIST {INT <degrees>, INT <minutes>, FLOAT <seconds>}";
"This verb converts decimal degrees to degrees, minutes, and seconds.";
dd = tofloat(args[1]);
s = (((dd - tofloat(d = toint(dd))) * 60.0) - tofloat(m = toint((dd - tofloat(d)) * 60.0))) * 60.0;
return {d, m, s};

dms_to_dd hms_to_dh

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":dms_to_dd(INT|FLOAT <deg>, INT|FLOAT <min>, INT|FLOAT <sec>) => FLOAT <deg>";
"This verb converts degrees/minutes/seconds to decimal degrees.";
{d, m, s} = args[1..3];
d = tofloat(d);
m = tofloat(m);
s = tofloat(s);
return (d + (m / 60.0)) + (s / 3600.0);

rect_to_polar

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":rect_to_polar(INT|FLOAT <x>, INT|FLOAT <y>) => FLOAT <radius>, FLOAT <angle>.";
"This verb converts from rectangular (x,y) coordinates to polar (r, theta) coordinates.";
{x, y} = args[1..2];
x = tofloat(x);
y = tofloat(y);
return {sqrt((x * x) + (x * x)), `atan(y, x) ! E_INVARG => 0.0'};

polar_to_rect

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":polar_to_rect(INT|FLOAT <radius>, INT|FLOAT <angle>) => FLOAT <x>, FLOAT <y>";
"This verb converts from polar (radius, angle) coordinates to rectangulat (x,y) coordinates.";
{r, a} = args[1..2];
r = tofloat(r);
a = tofloat(a);
return {(r = r / (1.0 + (z2 = (z = tan(a / 2.0)) * z))) * (1.0 - z2), (r * 2.0) * z};

F_to_C degF_to_degC

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":F_to_C(INT|FLOAT <Fahrenheit>) => FLOAT <Celsius>";
"This verb converts Fahrenheit degrees to Celsius degrees.";
return (tofloat(args[1]) - 32.0) / 1.8;

C_to_F degC_to_degF

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":C_to_F(INT|FLOAT <Celsius>) => FLOAT <Fahrenheit>";
"This verb converts Celsius degrees to Fahrenheit degrees.";
return (tofloat(args[1]) * 1.8) + 32.0;

convert

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":convert(STR <units>, STR <units>) => FLOAT conversion factor | LIST errors.";
"This verb attempts to compute the conversion factor between two sets of units. If the two inputs are of the same type (two speeds, two lengths, etc.), the value is returned. If the two inputs are not of the same type, a LIST is returned as follows: {1, {FLOAT <value>, STR <units>}. {FLOAT <value>, STR <units>}}. The 1 indicates that the two inputs were correctly formed. <value> is the conversion factor of the input into the basic <units>. This error output is useful for determining the basic structure and value of an unknown unit of measure. If either of the inputs can not be broken down to known units, a LIST is returned as follows: {0, STR <bad input>}.";
"";
"The format of the input strings is fairly straight forward: any multiplicative combination of units, ending in an optional digit to represent that unit is raised to a power, the whole of which is preceeded by an initial value. Examples: \"100 kg m/sec2\", \"35 joules\", \"2000 furlongs/fortnight\"";
"";
"Some example uses:";
";$convert_utils:convert(\"2000 furlongs/fortnight\", \"mph\")";
"=> 0.744047619047619";
";$convert_utils:convert(\"kilowatt hours\", \"joules\")";
"=> 3600000.0";
"";
";$convert_utils:convert(\"furlongs\", \"mph\")";
"=> {1, {201.168, \"m\"}, {044704, \"m / s\"}}";
"";
";$convert_utils:convert(\"junk\", \"meters\")";
"=> {0, \"junk\"}";
{havestr, wantstr} = args;
have = this:_do_convert(havestr);
want = this:_do_convert(wantstr);
if ((have && want) && (have[2] == want[2]))
return have[1] / want[1];
elseif (have && want)
return {1, {have[1], this:_format_units(@have[2])}, {want[1], this:_format_units(@want[2])}};
else
return {0, have ? wantstr | havestr};
endif

_do_convert

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

• #87:convert line 18: this:_do_convert
• #87:convert line 19: this:_do_convert
• #87:_do_convert line 44: this:_do_convert
• #87:_do_convert line 57: this:_do_convert

Source

"THIS VERB IS NOT INTENDED FOR USER USAGE.";
":_do_convert is the workhorse of $convert_utils:convert and is based loosely upon the 'units' Perl script the ships with BSD Unix.";
"Essentially, it breaks the input up into values and units, attempts to break each unit down into elementary (basic) units, modifies the value as it goes, until it has no more input or can not convert a unit into a basic unit.";
instr = args[1];
units = this.basic_units_template;
value = 1.0;
top = 1;
"Ensure that the division mark is a spearate word.";
instr = $string_utils:substitute(instr, {{"/", " / "}});
while (instr)
"Grab the next word to process";
{first, instr} = $string_utils:first_word(instr);
if (first == "/")
"Now we're working with values under the division mark - units with negative exponents.";
top = 1 - top;
continue;
elseif (match(first, "|"))
"The word was a value expressed as a ratio. Compute the ratio and adjust the value accordingly.";
value = this:_do_value(first, value, top);
continue;
elseif ($string_utils:is_integer(first) || $string_utils:is_float(first))
"The word was a value. Adjust the accumulated value accordingly.";
value = top ? value * tofloat(first) | (value / tofloat(first));
continue;
elseif (match(first, "[0-9]$"))
"The word ends with a digit, but isn't a value. It must be a powered unit. Expand it: cm3 => cm cm cm";
subs = match(first, "%([a-zA-Z]+%)%([0-9]+%)");
first = substitute("%1", subs);
power = toint(substitute("%2", subs));
while (power > 0)
instr = (first + " ") + instr;
power = power - 1;
endwhile
continue;
else
"Check to see if the word starts with one or more metric prefix and attempt to evaluate the prefix.";
{first, value, top} = this:_try_metric_prefix(first, value, top);
"Check to see if we have a basic unit. If so, adjust the apropriate unit count.";
if (index = first in this.basic_units)
units[index][2] = top ? units[index][2] + 1 | (units[index][2] - 1);
continue;
elseif (prop = `this.(first) ! E_PROPNF => 0')
"Check to see if this is a known unit. If so, convert it and adjust the value and units.";
result = this:_do_convert(prop);
value = top ? value * result[1] | (value / result[1]);
for i in [1..length(units)]
units[i][2] = top ? units[i][2] + result[2][i][2] | (units[i][2] - result[2][i][2]);
endfor
continue;
elseif (first[$] == "s")
"Check to see if this is a normal 's'-ending plural, and try to do the above checks again.";
temp = first[1..$ - 1];
if (index = temp in this.basic_units)
units[index][2] = top ? units[index][2] + 1 | (units[index][2] - 1);
continue;
elseif (prop = `this.(temp) ! E_PROPNF => 0')
result = this:_do_convert(prop);
value = top ? value * result[1] | (value / result[1]);
for i in [1..length(units)]
units[i][2] = top ? units[i][2] + result[2][i][2] | (units[i][2] - result[2][i][2]);
endfor
continue;
endif
endif
"We were unable to find any conversion for the current word, so halt all operation and return 0.";
return 0;
endif
endwhile
"We were able to successfully convert each part of the input. Return the equivalent value and units.";
return {value, units};

_try_metric_prefix

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

• #87:_do_convert line 37: this:_try_metric_prefix

Source

"THIS VERB IS NOT INTENDED FOR USER USAGE.";
":_try_metric_prefix runs through the metrix multipliers and tries to match them against the beginning of the input string. If successful, the given value is adjusted appropritately, and the input string is modified. The verb loops until there are no more prefix matches. (Hence, \"kilodecameter\" can be matched with only one verb call.";
"If anyone knows of other possibilities here, please let me know.";
{first, value, top} = args;
while (1)
if (subs = match(first, "^yocto%(.*%)"))
first = substitute("%1", subs);
value = top ? value / 1e+24 | (value * 1e+24);
continue;
endif
if (subs = match(first, "^zepto%(.*%)"))
first = substitute("%1", subs);
value = top ? value / 1e+21 | (value * 1e+21);
continue;
endif
if (subs = match(first, "^atto%(.*%)"))
first = substitute("%1", subs);
value = top ? value / 1e+18 | (value * 1e+18);
continue;
endif
if (subs = match(first, "^femto%(.*%)"))
first = substitute("%1", subs);
value = top ? value / 1e+15 | (value * 1e+15);
continue;
endif
if (subs = match(first, "^pico%(.*%)"))
first = substitute("%1", subs);
value = top ? value / 1000000000000.0 | (value * 1000000000000.0);
continue;
endif
if (subs = match(first, "^nano%(.*%)"))
first = substitute("%1", subs);
value = top ? value / 1000000000.0 | (value * 1000000000.0);
continue;
endif
if (match(first, "^micron"))
break;
endif
if (subs = match(first, "^micro%(.*%)"))
first = substitute("%1", subs);
value = top ? value / 1000000.0 | (value * 1000000.0);
continue;
endif
if (subs = match(first, "^milli%(.*%)"))
first = substitute("%1", subs);
value = top ? value / 1000.0 | (value * 1000.0);
continue;
endif
if (subs = match(first, "^centi%(.*%)"))
first = substitute("%1", subs);
value = top ? value / 100.0 | (value * 100.0);
continue;
endif
if (subs = match(first, "^deci%(.*%)"))
first = substitute("%1", subs);
value = top ? value / 10.0 | (value * 10.0);
continue;
endif
if (subs = match(first, "^%(deca%|deka%)%(.*%)"))
first = substitute("%2", subs);
value = (!top) ? value / 10.0 | (value * 10.0);
continue;
endif
if (subs = match(first, "^hecto%(.*%)"))
first = substitute("%1", subs);
value = (!top) ? value / 100.0 | (value * 100.0);
continue;
endif
if (subs = match(first, "^kilo%(.*%)"))
first = substitute("%1", subs);
value = (!top) ? value / 1000.0 | (value * 1000.0);
continue;
endif
if (subs = match(first, "^mega%(.*%)"))
first = substitute("%1", subs);
value = (!top) ? value / 1000000.0 | (value * 1000000.0);
continue;
endif
if (subs = match(first, "^giga%(.*%)"))
first = substitute("%1", subs);
value = (!top) ? value / 1000000000.0 | (value * 1000000000.0);
continue;
endif
if (subs = match(first, "^tera%(.*%)"))
first = substitute("%1", subs);
value = (!top) ? value / 1000000000000.0 | (value * 1000000000000.0);
continue;
endif
if (subs = match(first, "^peta%(.*%)"))
first = substitute("%1", subs);
value = (!top) ? value / 1e+15 | (value * 1e+15);
continue;
endif
if (subs = match(first, "^exa%(.*%)"))
first = substitute("%1", subs);
value = (!top) ? value / 1e+18 | (value * 1e+18);
continue;
endif
if (subs = match(first, "^zetta%(.*%)"))
first = substitute("%1", subs);
value = (!top) ? value / 1e+21 | (value * 1e+21);
continue;
endif
if (subs = match(first, "^yotta%(.*%)"))
first = substitute("%1", subs);
value = (!top) ? value / 1e+24 | (value * 1e+24);
continue;
endif
break;
endwhile
return {first, value, top};

_format_units

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

• #87:convert line 23: this:_format_units
• #87:convert line 23: this:_format_units

Source

"THIS VERB IS NOT INTENDED FOR USER USAGE.";
":_format_units takes the associative list of units and powers and construct a more user friendly string.";
top = bottom = "";
for pair in (args)
if (pair[2] > 0)
top = tostr(top, " ", pair[1], (pair[2] > 1) ? pair[2] | "");
elseif (pair[2] < 0)
bottom = tostr(bottom, " ", pair[1], (pair[2] < -1) ? -pair[2] | "");
endif
endfor
if (bottom)
return ((top + " /") + bottom)[2..$];
else
return top[2..$];
endif

K_to_C degK_to_degC

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":K_to_C (INT|FLOAT <Kelvin>) => FLOAT <Celcius>";
"This verb converts Kelvin degrees to Celcius degrees.";
return tofloat(args[1]) - 273.0;

C_to_K degC_to_degK

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":C_to_K (INT|FLOAT <Celcius>) => FLOAT <Kelvin>";
"This verb converts Celcius degrees to Kelvin degrees.";
return tofloat(args[1]) + 273.0;

F_to_R degF_to_degR

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":F_to_R (INT|FLOAT <Fahrenheit>) => FLOAT <Rankine>";
"This verb converts Fahrenheit degrees to Rankine degrees.";
return tofloat(args[1]) + 491.4;

R_to_F degR_to_degF

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

none

Source

":R_to_F (INT|FLOAT <Rankine>) => FLOAT <Fahrenheit>";
"This verb converts Rankine degrees to Fahrenheit degrees.";
return tofloat(args[1]) - 491.4;

_do_value

Spec this none thisFlags rxdOwner #29Definer #87

Referenced by

• #87:_do_convert line 19: this:_do_value

Source

"THIS VERB IS NOT INTENDED FOR USER USAGE.";
":_do_value takes a string of the form <number>|<number>, interprets it as a ratio, and applies that ratio to the incoming 'value' accordingly with the 'top' input, and returns it back to the calling verb.";
{first, value, top} = args;
{numer, denom} = $string_utils:explode(first, "|");
return top ? (value * tofloat(numer)) / tofloat(denom) | ((value * tofloat(denom)) / tofloat(numer));