Pasting Feature #84

Parent #68Owner #29Flags read, fertileSource hellcore/hellcore.db

Aliases: Pasting Feature

3 verbs · 34 properties · 0 children

Verbs

Properties

Ancestry

• #1 root

  • #5 generic thing

    • #68 Generic Feature Object

      • #84 Pasting Feature

Ancestors (nearest first): #68 Generic Feature Object → #5 generic thing → #1 root

Children: none

Call graph

Source

"Usage: @paste <prefix> <suffix>";
"Announce a series of entered lines to the room the player is in.";
"Before the lines are quoted, player.paste_header is run through";
"$string_utils:pronoun_sub(), and if the result contains the player's";
"name, it is used as a header.  Otherwise player.name centered in a";
"line of dashes is used.";
"A footer comes afterwards, likewise derived from player.paste_footer.";
"<prefix> and <suffix> are placed before and after each line.";
"";
"This verb is, as one might guess, designed for pasting text to MOO using";
"GnuEmacs or a windowing system.  You should remember that after you";
"have pasted the lines in, you must type . on a line by itself, or you'll";
"sit around waiting for $command_utils:read_lines() to finish _forever_.";
{?prefix = "", ?suffix = ""} = args;
lines = $command_utils:read_lines();
namestr = (is_a(player, $immortal) && player.code_name) ? player.code_name | player:real_name();
header = $string_utils:pronoun_sub_secure($code_utils:verb_or_property(player, "paste_header"), "") || $string_utils:center(namestr, 75, "-");
to_tell = {header};
for line in (lines)
to_tell = listappend(to_tell, (prefix + $su:escape(line)) + suffix);
endfor
to_tell = listappend(to_tell, $string_utils:pronoun_sub_secure($code_utils:verb_or_property(player, "paste_footer"), "") || $string_utils:center("finished", 75, "-"));
for thing in (player.location.contents)
$command_utils:suspend_if_needed(0);
thing.listening && thing:tell_lines(to_tell);
endfor
player:tell("Done @pasting.");

"Echo a line prefaced by a vertical bar.";
"Usage:";
"  |message";
"Example:";
"  Hacker wants to echo to the room what he just saw. He enters (either by hand, or with Emacs or a windowing system):";
"      |Haakon has disconnected.";
"  The room sees:";
"      Hacker | Haakon has disconnected.";
if (($skills.brains:total(player) < 6) && (!is_a(player, $immortal)))
m = #130830.emotes;
m = m[random(length(m))];
m = $su:ps(m);
player.location:announce_all(player:dname(), m);
return;
endif
player.location:announce_all((((player:real_name() + " | ") + $su:escape(verb[2..$])) + " ") + $su:escape(argstr));

"Syntax: @paste-to <player>";
"";
"Which will then prompt you for the lines to privately send to <player>. The lines will be surrounded by a default footer and header.";
target = $string_utils:match_player(dobjstr);
if (!valid(target))
player:tell("@paste-to who?");
return;
endif
if ((!player.programmer) && (!target.programmer))
player:tell("Sorry, you cannot @paste-to other players.");
return;
endif
prefix = "";
suffix = "";
lines = $command_utils:read_lines();
to_tell = {$string_utils:center("Private message from " + player:real_name(), 75, "-")};
for line in (lines)
to_tell = listappend(to_tell, (prefix + line) + suffix);
endfor
to_tell = listappend(to_tell, $string_utils:center("end message", 75, "-"));
target:tell_lines(to_tell);
player:tell("Done @pasting.");