LambdaCore generic container (use $container instead) #8

p*ut in*sert d*rop

Spec any in/inside/into thisFlags rxdOwner #361Definer #8

Referenced by

none

Source

if (!valid(dobj))
dobj = $match_utils:match(dobjstr, {@player.contents, @player.location.contents});
endif
if ((this.location != player) && (this.location != player.location))
player:tell("You can't get at ", this.name, ".");
elseif (dobj == $nothing)
player:tell("What do you want to put ", prepstr, " ", this.name, "?");
elseif ($command_utils:object_match_failed(dobj, dobjstr))
elseif ((dobj.location != player) && (dobj.location != player.location))
player:tell("You don't have ", dobj.name, ".");
elseif (!this.opened)
player:tell(this.name, " is closed.");
else
set_task_perms(callers() ? caller_perms() | player);
dobj:moveto(this);
if (dobj.location == this)
player:tell(this:put_msg());
if (msg = this:oput_msg())
player.location:announce(player.name, " ", msg);
endif
else
player:tell(this:put_fail_msg());
if (msg = this:oput_fail_msg())
player.location:announce(player.name, " ", msg);
endif
endif
endif

re*move ta*ke g*et

Spec any out of/from inside/from thisFlags rxdOwner #361Definer #8

Referenced by

none

Source

if (!(this.location in {player, player.location}))
player:tell("Sorry, you're too far away.");
elseif (!this.opened)
player:tell(this.name, " is not open.");
elseif ((dobj = this:match_object(dobjstr)) == $nothing)
player:tell("What do you want to take from ", this.name, "?");
elseif ($command_utils:object_match_failed(dobj, dobjstr))
elseif (!(dobj in this:contents()))
player:tell(dobj.name, " isn't in ", this.name, ".");
else
set_task_perms(callers() ? caller_perms() | player);
if (ctm = player:cant_take(dobj))
player:aat(player.name, " tries to get ", dobj:iname(), " from ", this:dname(), ", but ", ctm, ".");
return;
endif
dobj:moveto(player);
if (dobj.location == player)
player:tell(this:remove_msg());
if (msg = this:oremove_msg())
player.location:announce(player.name, " ", msg);
endif
else
dobj:moveto(this.location);
if (dobj.location == this.location)
player:tell(this:remove_msg());
if (msg = this:oremove_msg())
player.location:announce(player.name, " ", msg);
endif
player:tell("You can't pick up ", dobj.name, ", so it tumbles onto the floor.");
else
player:tell(this:remove_fail_msg());
if (msg = this:oremove_fail_msg())
player.location:announce(player.name, " ", msg);
endif
endif
endif
endif

look_self

Spec this none thisFlags rxdOwner #361Definer #8

Referenced by

none

Source

pass();
if (!this.dark)
this:tell_contents();
endif

acceptable

Spec this none thisFlags rxdOwner #361Definer #8

Referenced by

none

Source

return !is_player(args[1]);

open

Spec this none noneFlags rxdOwner #361Definer #8

Referenced by

none

Source

perms = (callers() && (caller != this)) ? caller_perms() | player;
if (this.opened)
player:tell("It's already open.");
"elseif (this:is_openable_by(player))";
elseif (this:is_openable_by(perms))
this:set_opened(1);
player:tell(this:open_msg());
if (msg = this:oopen_msg())
player.location:announce(player.name, " ", msg);
endif
else
player:tell(this:open_fail_msg());
if (msg = this:oopen_fail_msg())
player.location:announce(player.name, " ", msg);
endif
endif

is_openable_by

Spec this none thisFlags rxdOwner #361Definer #8

Referenced by

• #8:open line 5: this:is_openable_by

Source

return (this.open_key == 0) || $lock_utils:eval_key(this.open_key, args[1]);

close

Spec this none noneFlags rxdOwner #361Definer #8

Referenced by

none

Source

if (!this.opened)
player:tell("It's already closed.");
else
this:set_opened(0);
player:tell(this:close_msg());
if (msg = this:oclose_msg())
player.location:announce(player.name, " ", msg);
endif
endif

tell_contents

Spec this none thisFlags rxdOwner #361Definer #8

Referenced by

• #8:look_self line 3: this:tell_contents

Source

if (this.contents)
player:tell("Contents:");
for thing in (this:contents())
player:tell("  ", thing:title());
endfor
elseif (msg = this:empty_msg())
player:tell(msg);
endif

set_opened

Spec this none thisFlags rxdOwner #361Definer #8

Referenced by

• #8:open line 6: this:set_opened
• #8:close line 4: this:set_opened

Source

if (!$perm_utils:controls(caller.owner, this))
return E_PERM;
else
this.opened = opened = !(!args[1]);
this.dark = this.opaque > opened;
return opened;
endif

@opacity

Spec this is anyFlags rxdOwner #361Definer #8

Referenced by

none

Source

if (!$perm_utils:controls(player, this))
player:tell("Can't set opacity of something you don't own.");
elseif ((iobjstr != "0") && (!toint(iobjstr)))
player:tell("Opacity must be an integer (0, 1, 2).");
else
player:tell("Opacity changed:  Now " + {"transparent.", "opaque.", "a black hole."}[1 + this:set_opaque(toint(iobjstr))]);
endif

set_opaque

Spec this none thisFlags rxdOwner #361Definer #8

Referenced by

• #8:@opacity line 6: this:set_opaque

Source

if (!$perm_utils:controls(caller.owner, this))
return E_PERM;
elseif (typeof(number = args[1]) != INT)
return E_INVARG;
else
number = (number < 0) ? 0 | ((number > 2) ? 2 | number);
this.dark = number > this.opened;
return this.opaque = number;
endif

oclose_msg close_msg oopen_msg open_msg oput_fail_msg put_fail_msg oremove_fail_msg oremove_msg remove_fail_msg remove_msg oput_msg put_msg oopen_fail_msg open_fail_msg empty_msg

Spec this none thisFlags rxdOwner #29Definer #8

Referenced by

• #8:p*ut line 17: this:put_msg
• #8:p*ut line 18: this:oput_msg
• #8:p*ut line 22: this:put_fail_msg
• #8:p*ut line 23: this:oput_fail_msg
• #8:re*move line 18: this:remove_msg
• #8:re*move line 19: this:oremove_msg
• #8:re*move line 25: this:remove_msg
• #8:re*move line 26: this:oremove_msg
• #8:re*move line 31: this:remove_fail_msg
• #8:re*move line 32: this:oremove_fail_msg
• #8:open line 7: this:open_msg
• #8:open line 8: this:oopen_msg
• #8:open line 12: this:open_fail_msg
• #8:open line 13: this:oopen_fail_msg
• #8:close line 5: this:close_msg
• #8:close line 6: this:oclose_msg
• #8:tell_contents line 6: this:empty_msg

Source

return (msg = `this.(verb) ! ANY') ? $string_utils:pronoun_sub(msg) | "";

dark

Spec this none thisFlags rxdOwner #361Definer #8

Referenced by

none

Source

return this.(verb);

match_object

Spec this none thisFlags rxdOwner #361Definer #8

Referenced by

• #8:re*move line 5: this:match_object

Source

string = args[1];
return $match_utils:match(string, this.contents);