generic liquid container #338

tell_contents

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

• #338:look_self line 2: this:tell_contents

Source

if (!this.show_contents)
return;
endif
holding = this:occupants($liquid);
if (!holding)
player:tell("It is empty.");
else
pct = this:percent_full();
if (pct > 90)
desc = "It's full of %t.";
elseif (pct > 70)
desc = "It's almost filled with %t.";
elseif (pct > 40)
desc = "It's about half full of %t.";
elseif (pct > 25)
desc = "It's less than half full of %t.";
else
desc = "It has a little %t at the bottom.";
endif
fn = {};
for x in (holding)
if (m = x.look_container_msg)
fn = setadd(fn, m);
endif
endfor
fn = $su:english_list(fn);
player:tell(strsub(desc, "%t", fn));
endif

look_self

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

• #134:look_self line 2: pass(

Source

pass(@args);
this:tell_contents();

acceptable

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

what = args[1];
if (!is_a(what, $liquid))
return 0;
endif
if (this:capacity_left() < what.accumulation)
return 0;
endif
return 1;

capacity_left

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

• #338:acceptable line 5: this:capacity_left
• #338:fill line 14: this:capacity_left
• #338:fill line 30: this:capacity_left
• #338:fill_from line 2: this:capacity_left

Source

cap = this.capacity;
for x in (this:occupants($liquid))
cap = cap - x.accumulation;
endfor
return max(cap, 0);

fill

Spec this out of/from inside/from anyFlags rxdOwner #361Definer #338

Referenced by

none

Source

target = $mu:match(iobjstr, {@player:occupants($thing), @player.location:occupants($thing), @player.location:occupants($exit), player.location});
if (iobjstr == "here")
target = player.location;
endif
if (!valid(target))
player:tell("From a wha?");
return;
elseif (!$api.vessel:is_on(target))
player:tell("You can't fill ", this:iname(), " from ", target:iname(), ".");
return;
elseif (target == this)
player:tell("You can't fill ", this:dname(), " from itself because that's just stupid.");
return;
elseif (!this:capacity_left())
player:tell(this:dnamec(), " is already full.");
return;
elseif (!this.health)
player:tell("It's too broken to hold any liquid.");
return;
elseif (!$recycler:valid(target))
target = $match_utils:match_ambiguous(iobjstr, {@player.contents, @player.location.contents});
if (!$recycler:valid(target))
player:tell("You don't see a '", iobjstr, "' to fill ", this:dname(), " from.");
return;
endif
endif
if (!$ou:has_verb(target, "lose_unit"))
player:tell("You can't fill your ", this.name, " from ", target:iname(), ".");
return;
elseif (!this:capacity_left())
player:tell("Your ", this.name, " is already full.");
return;
elseif (is_a(target, $thing) && (!target:occupants($liquid)))
player:tell(target:dnamec(), " is empty.");
return;
elseif ($ou:has_verb(target, "cant_fill_from") && (m = target:cant_fill_from(player, this)))
player:tell("You can't fill your ", this.name, " from ", target:dname(), ", because ", m, ".");
return;
endif
player:aat($su:ps(target.fill_from_msg, player, this, target));
this:fill_from(target);

fill_from

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

• #338:fill line 41: this:fill_from

Source

source = args[1];
units = (length(args) > 1) ? args[2] | this:capacity_left();
filled = 0;
while (units > 0)
if (valid(liquid = source:lose_unit()))
liquid:add_to(this);
units = units - 1;
filled = filled + 1;
else
if (source.recycle_on_empty)
if (is_a(this.location, $living))
this.location:tell("You toss away the empty ", source.name, ".");
endif
$rpg:junk(source);
else
is_a(loc = this.location, $living) && loc:tell(source:dnamec(), " is now empty.");
endif
return;
endif
$cu:sin();
endwhile
`source:on_fill_from(this, filled) ! E_VERBNF => 0';
if (($rpg:valid(source) && (!source:occupants($liquid))) && `source.recycle_on_empty ! ANY')
if (is_a(this.location, $living))
this.location:tell("You toss away the empty ", source.name, ".");
endif
$rpg:junk(source);
endif
is_a(this.location, $living) && this.location:tell(this:dnamec(), " is now full.");

lose_unit

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

• #338:_start_drink line 17: this:lose_unit

Source

if (liquids = this:occupants($liquid))
liquid = liquids[random(length(liquids))];
type = parent(liquid);
liquid.accumulation = liquid.accumulation - 1;
if (liquid.accumulation < 1)
$rpg:junk(liquid);
endif
return type;
endif
return #-1;

gain_unit

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

type = args[1];
type:add_to(this);

_start

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

action = args[2][1];
return this:("_start_" + action)(@args);

_finish

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

action = args[2][1];
return this:("_finish_" + action)(@args);

drink sip

Spec this none noneFlags rxdOwner #361Definer #338

Referenced by

none

Source

player:queue_action(this, {"drink"}, 0, "drink " + this.name);

_start_drink

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

who = args[1];
doses = (length(args) > 2) ? args[3] | 1;
if (this.hold_to_drink)
if (!who:_wield(this, 0, 1))
player:tell("You'd have to be holding it first.");
return E_NONE;
endif
endif
if (!this:occupants($liquid))
who:tell(this:dnamec(), " is empty.");
return E_NONE;
else
m = this.drink_msg;
if (m)
who:aat($su:ps(m, who, this, this));
endif
liquid = this:lose_unit();
liquid:drink(who, doses);
return {1.0, 0};
endif

_finish_drink

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

who = args[1];
if (!this:occupants($liquid))
who:tell("You drank the last drops from ", this:dname(), ".");
if (this.recycle_on_empty)
$rpg:junk(this);
who.wielding = setremove(who.wielding, this);
endif
endif

dump empty

Spec this none noneFlags rxdOwner #361Definer #338

Referenced by

none

Source

if (!(liquids = this:occupants($liquid)))
player:tell(this:dnamec(), " is already empty.");
elseif (this.location != player)
player:tell("You're not holding ", this:dname(), ".");
else
player:_wield(this, 0, 1);
if (is_a(player.location, #1034))
player:aat($su:ps(("%DN dumps %p %t into the " + player.location.liquid.name) + ".", player, this));
else
player:aat(player:dnamec(), " dumps ", player.pp, " ", this.name, " out on the ", player.location:floor_msg(), ".");
for x in (liquids)
x:moveto(player.location);
endfor
endif
if (this.recycle_on_empty && (!this.f))
$recycler:_recycle(this);
endif
endif

smell

Spec this none noneFlags rxdOwner #361Definer #338

Referenced by

none

Source

smells = {};
player:aat(player:dnamec(), " sniffs at ", (this.location == player) ? player.pp | "the", " ", this.name, ".");
for x in (this:occupants($liquid))
if (s = x.smell_msg)
if (!(x.smell_msg in smells))
smells = {@smells, x.smell_msg};
endif
endif
endfor
if (smells)
player:tell("It smells like ", $su:english_list(smells), ".");
else
player:tell("You don't smell anything.");
endif

weight

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

wt = 0;
if (this.weight != -1)
for x in (this.contents)
w = `x.weight_per_unit ! ANY => 0';
wt = wt + (w * `x.accumulation ! ANY => 0');
endfor
endif
return this.weight + wt;

can_glob

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

if (this.contents)
return 0;
endif
return pass(@args);

value

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

wt = 0;
for x in (this.contents)
w = `x.value_per_unit ! ANY => 0';
wt = wt + (w * x.accumulation);
endfor
return this.value + wt;

_break

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

if (!this.contents)
return pass(@args);
else
if (is_a(this.location, $room))
this.location:announce_all(this:dnamec(), " splits open, spilling liquid across the ", this.location:floor_msg(), ".");
elseif (is_a(who = this.location, $creature))
who:aat(who:dnamec(), "'s ", this.name, " breaks, soaking ", who.po, " with liquid.");
endif
for x in (this.contents)
x:moveto(this.location);
endfor
pass(@args);
endif

on_spawn

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

liquids = (typeof(this.spawn_liquid) == LIST) ? this.spawn_liquid | {this.spawn_liquid};
lc = 1;
for x in [1..this.capacity]
yield;
liquid = liquids[lc];
lc = lc + 1;
if (lc > length(liquids))
lc = 1;
endif
if (valid(liquid))
if ($ou:has_property(liquid, "blood"))
liquid:add_to(this, lc, liquid.blood);
else
liquid:add_to(this, lc);
endif
endif
endfor
return pass(@args);

wash

Spec none with/using thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

if ((!(d = player:occupants($decal))) && (!#43890:doses_for(player)))
player:tell("You don't have any stains to wash off.");
return;
elseif (!(water = this:occupants(#169515)))
player:tell("You can't wash with air. It's empty.");
return;
endif
player:queue_action($actions.verb, {this, "do_wash", {player}, 3.0}, 1, "wash");

percent_full

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

• #338:tell_contents line 8: this:percent_full

Source

hc = 0;
for x in (this.contents)
hc = hc + x.accumulation;
endfor
pct = toint((tofloat(hc) / tofloat(this.capacity)) * 100.0);
return pct;

recycle

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

• #134:recycle line 2: pass(

Source

for x in (this.contents)
$recycler:_recycle(x);
endfor
return pass(@args);

supports_fish

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

if (length(f = this:occupants($liquid)) == 1)
if (is_a(f[1], #169515))
return 1;
endif
endif

cant_fill_from

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

No program (verb defined but unprogrammed).

on_fill_from

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

No program (verb defined but unprogrammed).

toast

Spec any with/using thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

if (!player:_wield(this))
player:tell("You'd have to be holding ", this:dname(), " to make a toast.");
return;
endif
if (!valid(who = $mu:match(dobjstr, player.location:occupants($living))))
player:aat(player:dnamec(), " raises ", player.pp, " ", this.name, (".  \"" + player:text_sub(("To " + dobjstr) + "!")) + "\"");
elseif (!(drinks = who:occupants(#239716, "wielding")))
player:tell(who:dnamec(), " isn't holding a drink.");
elseif (who == player)
player:aat(player:dnamec(), " raises ", player.pp, " ", this.name, ".  \"To ME!\"");
else
player:aat(player:dnamec(), " raises ", player.pp, " ", this.name, ", clinking it against ", who:dname(), "'s ", drinks[1].name, ".");
endif

action_doing_msg

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

action = args[2][1];
if (action == "drink")
return "drinking from " + this:dname();
else
$nets.prognet:announce(#2, (((("unknown liquid (#239716) doing_msg => " + $su:nn(player)) + " used ") + $su:nn(this)) + " args: ") + toliteral(args), 1);
return "";
endif

drink drink2

Spec none out of/from inside/from thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

player:queue_action(this, {"drink"}, 0, "drink " + this.name);

do_wash

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

who = args[1];
if ((!(d = who:occupants($decal))) && (!#43890:doses_for(who)))
who:tell("You don't have any stains to wash off.");
return;
elseif (!(water = this:occupants(#169515)))
who:tell("You can't wash with that.");
return;
endif
water = water[1];
decal = #-1;
if (#43890:doses_for(who))
who:aat(who:dnamec(), " frantically splashes ", water.name, " from ", who.pp, " ", this.name, " on ", who.po, "self.");
#43890:remove_from(who, 1);
(!this.infinite_fluid) && water:reduce_by(2);
return;
endif
(!this.infinite_fluid) && water:reduce_by(5);
for x in (d)
if ((!x.f) && x.wipeable)
decal = x;
break;
endif
endfor
if (!is_a(decal, $decal))
who:tell("That didn't seem to work.");
return;
endif
who:aat($su:ps(this.wash_msg, who, this, who.location, water, decal));
od = parent(decal);
decal:reduce_by(1);
if (decal.location == who)
who:tell("You got some of ", od:dname(), " off.");
else
who:tell("You got the last of ", od:dname(), " off.");
endif

unchuggable

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

{who} = args;
if (!this:occupants($liquid))
return "it's empty";
elseif (this.location != who)
return "you're not holding it";
else
return this.unchuggable;
endif

on_chug

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

{who} = args;
drops = max(1, $skills.endurance:total(player) - 10);
while (drops && `valid(l = this:occupants($liquid)[random($)]) ! E_INVARG => 0')
n = min(drops, l.accumulation);
l:drink(who, n);
l:reduce_by(n);
drops = drops - n;
endwhile
return {0, this:occupants($liquid)};

chug slam shoot pound

Spec this none noneFlags rxdOwner #361Definer #338

Referenced by

none

Source

if (this.location == player)
player:queue_action($actions.chug, {this}, 1, "chug " + this:dname());
else
player:tell("You have to be holding it.");
endif

chug_choke_chance

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

none

Source

return 0;

entomb

Spec this none thisFlags rxdOwner #361Definer #338

Referenced by

• #134:entomb line 3: pass(

Source

"Copied from generic liquid container (#239716):recycle by chill (#241405) Wed Jun  2 21:43:18 2010 CDT";
for x in (this.contents)
$recycler:_recycle(x);
endfor
return pass(@args);