JSON Utils #325

parse

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:parse_object line 25: this:parse
• #325:parse_array line 16: this:parse
• #325:read line 2: this:parse

Source

"$json_utils:parse(STR json_text) => returns whatever object type the json_text describes and its length in the JSON text";
if ((length(args) != 1) || typeof(args[1] != STR))
raise(E_INVARG);
endif
json_text = args[1];
cursor = this:count_whitespace(json_text) + 1;
if (json_text[cursor] == "{")
return this:parse_object(json_text);
elseif (json_text[cursor] == "[")
return this:parse_array(json_text);
elseif (json_text[cursor] == "\"")
return this:parse_string(json_text);
elseif (($su:lowercase(json_text[cursor]) == "t") || ($su:lowercase(json_text[cursor]) == "f"))
return this:parse_boolean(json_text);
elseif ($su:lowercase(json_text[cursor]) == "n")
return this:parse_null(json_text);
else
return this:parse_number(json_text);
endif

parse_object

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:parse line 8: this:parse_object

Source

"$ju:parse_object(STR json_text) => creates an object (hash) from the given text";
if ((length(args) != 1) || (typeof(args[1]) != STR))
raise(E_INVARG);
endif
json_text = args[1];
cursor = this:count_whitespace(json_text) + 1;
if (json_text[cursor] != "{")
raise(E_INVARG);
else
cursor = cursor + 1;
endif
object = [];
"JSON Objects look like:";
"  { \"name\" : value , \"name\" : value ... } ";
while (json_text[cursor] != "}")
"Pull out the name";
{name, length} = this:parse_string(json_text[cursor..$]);
cursor = cursor + length;
cursor = cursor + this:count_whitespace(json_text[cursor..$]);
if (json_text[cursor] != ":")
raise(E_INVARG);
else
cursor = cursor + 1;
endif
{value, length} = this:parse(json_text[cursor..$]);
cursor = cursor + length;
cursor = cursor + this:count_whitespace(json_text[cursor..$]);
if (json_text[cursor] == ",")
cursor = cursor + 1;
endif
object[name] = value;
endwhile
return {object, cursor};

parse_array

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:parse line 10: this:parse_array

Source

"$ju:parse_array(STR json_text) => creates an array (list) from the given text";
if ((length(args) != 1) || (typeof(args[1]) != STR))
raise(E_INVARG);
endif
json_text = args[1];
cursor = this:count_whitespace(json_text) + 1;
if (json_text[cursor] != "[")
raise(E_INVARG);
endif
array = {};
cursor = cursor + 1;
"JSON Arrays look like:";
"  [ value, value ... ] ";
while (json_text[cursor] != "]")
yield;
{value, length} = this:parse(json_text[cursor..$]);
cursor = cursor + length;
cursor = cursor + this:count_whitespace(json_text[cursor..$]);
if (json_text[cursor] == ",")
cursor = cursor + 1;
endif
array = listappend(array, value);
endwhile
return {array, cursor};

parse_string

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:parse line 12: this:parse_string
• #325:parse_object line 17: this:parse_string

Source

"$ju:parse_string(STR json_text) => return a string and its length in the JSON text";
if ((length(args) != 1) || (typeof(args[1]) != STR))
raise(E_INVARG);
endif
json_text = args[1];
cursor = this:count_whitespace(json_text) + 1;
if (json_text[cursor] != "\"")
raise(E_INVARG);
else
cursor = cursor + 1;
endif
closing_quote = this:find_closing_quote(json_text[cursor..$]);
string = json_text[cursor..(cursor + closing_quote) - 2];
return {string, (cursor + closing_quote) - 1};

parse_boolean

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:parse line 14: this:parse_boolean

Source

"$ju:parse_boolean(STR json_text) => return a boolean (1 or 0)  and its length in the JSON text";
if ((length(args) != 1) || (typeof(args[1]) != STR))
raise(E_INVARG);
endif
json_text = args[1];
cursor = this:count_whitespace(json_text) + 1;
if ((length(json_text) >= (cursor + 3)) && ($su:lowercase(json_text[cursor..cursor + 3]) == "true"))
return {1, cursor + 3};
elseif ((length(json_text) >= (cursor + 4)) && ($su:lowercase(json_text[cursor..cursor + 4]) == "false"))
return {0, cursor + 4};
else
raise(E_INVARG);
endif

parse_null

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:parse line 16: this:parse_null

Source

"$ju:parse_null(STR json_text) => return a null (empty string, chosen somewhat arbitrarily)  and its length in the JSON text";
if ((length(args) != 1) || (typeof(args[1]) != STR))
raise(E_INVARG);
endif
json_text = args[1];
cursor = this:count_whitespace(json_text) + 1;
if ((length(json_text) >= (cursor + 3)) && ($su:lowercase(json_text[cursor..cursor + 3]) == "null"))
return {"", cursor + 3};
else
raise(E_INVARG);
endif

parse_number

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:parse line 18: this:parse_number

Source

"$ju:parse_number(STR json_text) => return a number and its length in the JSON text";
if ((length(args) != 1) || (typeof(args[1]) != STR))
raise(E_INVARG);
endif
json_text = args[1];
cursor = this:count_whitespace(json_text) + 1;
"Find where this number ends";
next_nonnumber = this:next_non_number_char(json_text[cursor..$]);
if (!next_nonnumber)
next_nonnumber = length(json_text[cursor..$]) + 1;
endif
border = (cursor + next_nonnumber) - 2;
num_str = json_text[cursor..border];
"Check to see what kind of number it is";
if ((index(num_str, "e") || index(num_str, "E")) || index(num_str, "."))
"It's a real number";
return {tofloat(num_str), border};
else
"It's an integer";
return {toint(num_str), border};
endif

count_whitespace

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:parse line 6: this:count_whitespace
• #325:parse_object line 6: this:count_whitespace
• #325:parse_object line 19: this:count_whitespace
• #325:parse_object line 27: this:count_whitespace
• #325:parse_array line 6: this:count_whitespace
• #325:parse_array line 18: this:count_whitespace
• #325:parse_string line 6: this:count_whitespace
• #325:parse_boolean line 6: this:count_whitespace
• #325:parse_null line 6: this:count_whitespace
• #325:parse_number line 6: this:count_whitespace

Source

"$json_utils:count_whitespace(STR json_text) => return the number of whitespaces at the beginning of the string";
if ((length(args) != 1) || (typeof(args[1]) != STR))
raise(E_INVARG);
endif
json_text = args[1];
cursor = 1;
while ((cursor <= length(json_text)) && (json_text[cursor] == " "))
cursor = cursor + 1;
endwhile
return cursor - 1;

next_whitespace

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

none

Source

"$json_utils:next_whitespace(STR json_str) => returns the index of the first whitespace we find";
if ((length(args) != 1) || (typeof(args[1]) != STR))
raise(E_INVARG);
endif
return index(args[1], " ");

find_closing_quote

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:parse_string line 12: this:find_closing_quote

Source

"$json_utils:find_closing_quote(STR json_str) => returns the index of the quote that closes the JSON string, or 0 if it's not found";
if ((length(args) != 1) || (typeof(args[1]) != STR))
raise(E_INVARG);
endif
json_str = args[1];
cursor = 1;
while (cursor <= length(json_str))
quote = index(json_str[cursor..$], "\"");
if (quote)
"See if the quote has a backslash... if it doesn't it's not real";
if ((quote == 1) || (json_str[quote - 1] != "\\"))
return quote;
endif
cursor = cursor + quote;
else
return 0;
endif
endwhile

next_non_number_char

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:parse_number line 8: this:next_non_number_char

Source

"$json_utils:next_whitespace(STR json_str) => returns the index of the first whitespace we find";
if ((length(args) != 1) || (typeof(args[1]) != STR))
raise(E_INVARG);
endif
json_text = args[1];
cursor = 1;
while (cursor <= length(json_text))
if (!this:is_number_char(json_text[cursor]))
return cursor;
endif
cursor = cursor + 1;
endwhile
return 0;

is_number_char

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:next_non_number_char line 8: this:is_number_char

Source

if (((length(args) != 1) || (typeof(args[1]) != STR)) || (length(args[1]) != 1))
raise(E_INVARG);
endif
digit = args[1][1];
if (((((((((((((digit == "0") || (digit == "1")) || (digit == "2")) || (digit == "3")) || (digit == "4")) || (digit == "5")) || (digit == "6")) || (digit == "7")) || (digit == "8")) || (digit == "9")) || (digit == ".")) || (digit == "e")) || (digit == "E"))
return 1;
else
return 0;
endif

write

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:write line 14: this:write
• #325:write line 23: this:write

Source

pip = args[1];
wrote_first_entry = 0;
if (typeof(pip) == STR)
return this:quote(pip);
elseif ((typeof(pip) == INT) || (typeof(pip) == FLOAT))
return tostr(pip);
elseif (typeof(pip) == HASH)
output = "{";
for entry in (pip)
{key, value} = entry;
if (wrote_first_entry)
output = output + ",";
endif
output = ((output + this:quote(key)) + ":") + this:write(value);
endfor
return output + "}";
elseif (typeof(pip) == LIST)
output = "[";
for entry in (pip)
if (wrote_first_entry)
output = output + ",";
endif
output = output + this:write(entry);
wrote_first_entry = 1;
endfor
return output + "]";
elseif (typeof(pip) == OBJ)
"This should probably dump all verbs, flags, and props";
"Right now objects are just converted to strings...";
return this:quote(tostr(pip));
else
raise(E_INVARG);
endif

quote

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #325:write line 4: this:quote
• #325:write line 14: this:quote
• #325:write line 30: this:quote

Source

return ("\"" + $su:substitute(args[1], {{"\"", "\\\""}})) + "\"";

read

Spec this none thisFlags rxdOwner #361Definer #325

Referenced by

• #326:_www_post line 3: $json_utils:read

Source

"$json_utils:read(json_text) => returns a data structure formed from the JSON text";
return this:parse(args[1])[1];