who commands #318

wh*o cwh*o

Spec any any anyFlags rxdOwner #361Definer #318

Referenced by

none

Source

if (index(verb, "cwh"))
if (!args)
if (player.programmer)
player:tell("Use 'pwho' to see just players. To look at a specific corp or corps use 'cwho <corp> [<corp> <corp> ...]");
return;
endif
corp = player.employer;
if (!valid(corp))
player:tell("Have you thought about becoming a corporate whore?");
return;
endif
return this:_who({}, {corp}, 1);
else
corps = $lu:make(length(args), #-1);
for c in (children($biz))
if (idx = c.symbol in args)
corps[idx] = c;
endif
endfor
to_list = {};
crap = {};
for i in [1..length(corps)]
c = corps[i];
if (!valid(c))
crap = {@crap, tostr("\"", args[i], "\"")};
elseif (`c.hide_biz ! ANY')
"nothin";
else
to_list = {@to_list, c};
endif
endfor
if (crap)
many = length(crap) > 1;
player:tell("I don't know what ", $su:english_list(crap, "", "or"), many ? " are." | " is.");
endif
if (!to_list)
player:tell("No corps found to list!");
return;
endif
return this:_who({}, to_list, player.programmer);
endif
else
to_list = {};
if (args)
potentials = $su:match_player(args);
to_list = {};
crap = {};
for i in [1..length(potentials)]
p = potentials[i];
if (!valid(p))
crap = {@crap, tostr("\"", args[i], "\"")};
elseif (p.programmer && (!player.programmer))
"nothin";
else
to_list = {@to_list, p};
endif
endfor
if (crap)
many = length(crap) > 1;
player:tell("I don't know who ", $su:english_list(crap, "", " or "), many ? " are." | " is.");
endif
if (!to_list)
player:tell("No players found to list!");
return;
endif
endif
if ((!to_list) && player:check_pref("minimalwho"))
return this:_who({}, {}, -1);
endif
return this:_who(to_list, {}, player.programmer);
endif

whosymbol

Spec this none thisFlags rxdOwner #361Definer #318

Referenced by

• #318:_who line 53: $whofo:whosymbol

Source

{p, ?show_detail = 0, ?verbose = 0} = args;
"if (show_detail && (!p.programmer))";
"  c = p.employer;";
"  if (!valid(c))";
"    \"nothing\";";
"  elseif (p in c.ranks[\"holders\"])";
"    return verbose ? \"holder\" | \"$\";";
"  elseif (p in c.ranks[\"board\"])";
"    return verbose ? \"board\" | \"%\";";
"  elseif (p in c.ranks[\"managers\"])";
"    return verbose ? \"mgmt\" | \"&\";";
"  endif";
"endif";
if (p in $rpg.bots)
return verbose ? "bot" | "B";
elseif (is_a(p, $wiz))
return verbose ? "wizard" | "!";
elseif (p.programmer)
if (`p.chillmin ! ANY')
return verbose ? "chillmin" | "c";
endif
return verbose ? "admin" | "*";
"elseif (valid(p.employer) && (p in p.employer.ranks[\"holders\"]))";
"  return verbose ? \"holder\" | \"$\";";
"elseif (p.xp_total < $rpg.newbie_xp)";
"  return verbose ? \"newbie\" | \"N\";";
endif
return "";

wholocation

Spec this none thisFlags rxdOwner #361Definer #318

Referenced by

• #318:_who line 76: $whofo:wholocation

Source

{p, ?use_body = 1, ?from_region = #-1} = args;
if (gamevalid(p.body) && use_body)
area = area(p.body);
else
area = area(p);
endif
if (!valid(area))
return "";
endif
region = area:region();
if (valid(from_region) && (region == from_region))
return area:who_name();
elseif (!valid(region))
return "";
elseif (is_a(player, $builder))
return tostr("(", region:abbreviated_name(), ") ", area:who_name());
else
return region:who_name();
endif

_who

Spec this none thisFlags rxdOwner #361Definer #318

Referenced by

• #89:awh*o line 7: $whofo:_who
• #89:pwh*o line 7: $whofo:_who
• #118:command_who line 22: #318:_who
• #318:wh*o line 12: this:_who
• #318:wh*o line 40: this:_who
• #318:wh*o line 68: this:_who
• #318:wh*o line 70: this:_who

Source

"Copied from Frankenthrope (#142):_who Fri Oct 29 16:16:14 2010 CDT";
"Copied from who commands (#217820):_who by Ragabash (#45093) Fri Oct 29 16:03:42 2010 CDT";
{?targets = {}, ?corps = {}, ?show_detail = 0} = args;
do_fullcount = 0;
if (!targets)
do_fullcount = 1;
targets = connected_players();
endif
"collect data";
data = {};
datacolors = {};
verbose_symbols = player:check_pref("verbosewho");
show_admins = player.programmer;
colors = $whofo.colors;
hide_corps = 0;
count = 0;
admincount = 0;
fullcount = 0;
if (show_detail == -1)
hide_corps = 1;
show_detail = player.programmer;
endif
if (show_detail)
widths = verbose_symbols ? $whofo.verbose_widths | $whofo.normal_widths;
headers = $whofo.headers;
cols = 6;
else
widths = verbose_symbols ? $whofo.verbose_widths_no_area | $whofo.normal_widths_no_area;
headers = $whofo.headers_no_area;
cols = 5;
endif
if (show_detail)
player_region = `area(player):region() ! E_INVIND => #-1';
use_body = !player.programmer;
endif
for p in (targets)
if ((!show_admins) && p.programmer)
if (do_fullcount)
admincount = admincount + 1;
endif
continue;
endif
if (do_fullcount)
fullcount = fullcount + 1;
endif
employer = #-1;
"employer = p.programmer ? #-1 | p.employer;";
if (corps)
if (!(employer in corps))
continue;
endif
endif
symb = $whofo:whosymbol(p, show_detail, verbose_symbols);
idle = `idle_seconds(p) ! E_INVARG => -1';
idlecolor = ((idle >= 0) && (idle < 600)) ? colors["active_player"] | colors["idle_player"];
try
doing = $su:escape(p:who_doing_msg());
except e (ANY)
$rpg:report_error(e);
doing = "";
endtry
name = tostr(idlecolor, $su:left(p.name, widths[2] * -1), $ansi.reset);
empl = "";
if (symb == "B")
empl = $ansi.green + "bot";
elseif (p.programmer)
if (`p.chillmin ! ANY')
empl = $ansi.cyan + "chill";
else
empl = $ansi.magenta + "admin";
endif
else
empl = valid(employer) ? employer.symbol | "";
endif
if (show_detail)
loc = $whofo:wholocation(p, use_body, player_region);
data = {@data, {symb, name, empl, idle, loc, doing}};
else
data = {@data, {symb, name, empl, idle, doing}};
endif
count = count + 1;
endfor
"sort here";
data = $lu:sort_alist(data, 4);
if (show_detail && player:check_pref("whosortbyarea"))
data = $lu:sort_alist(data, 5);
elseif (!player:check_pref("whosortbytime"))
data = $lu:sort_alist(data, 3);
endif
"show data!";
suspend(0);
if (!verbose_symbols)
headers[1] = "";
endif
headcol = colors["header"];
line = headcol;
for i in [1..cols]
if (hide_corps && (i == 3))
continue;
endif
line = tostr(line, $ansi.underline_on, $su:left(headers[i], widths[i]), $ansi.reset, (i == cols) ? "" | (headcol + " "));
endfor
notify(player, line);
lastcorp = "";
usealtcolor = 0;
if (show_detail)
colcolors = {colors["symbol"], "", colors["corp1"], "", colors["area"], colors["doing"]};
else
colcolors = {colors["symbol"], "", colors["corp1"], "", colors["doing"]};
endif
for d in (data)
line = "";
if (!hide_corps)
if (d[3] != lastcorp)
usealtcolor = !usealtcolor;
lastcorp = d[3];
colcolors[3] = usealtcolor ? colors["corp2"] | colors["corp1"];
endif
endif
d[4] = (d[4] < 0) ? "off" | $time:short_duration(d[4]);
for i in [1..cols]
if (hide_corps && (i == 3))
continue;
endif
if (i != 2)
line = tostr(line, colcolors[i], $su:left(d[i], -widths[i]), $ansi.reset, (i == cols) ? "" | " ");
else
line = tostr(line, colcolors[i], d[i], $ansi.reset, (i == cols) ? "" | " ");
endif
endfor
notify(player, line);
endfor
if (player:check_pref("wholegend"))
if (show_detail)
leg = tostr($ansi.green, "$ ", $ansi.reset, $ansi.bold_on, "holder. ", $ansi.reset, $ansi.green, " % ", $ansi.reset, $ansi.bold_on, "board member. ", $ansi.reset, $ansi.green, " & ", $ansi.reset, $ansi.bold_on, "manager.", $ansi.reset);
notify(player, leg);
endif
leg = tostr($ansi.green, " N ", $ansi.reset, $ansi.bold_on, "newbie. ", $ansi.reset, $ansi.green, " $ ", $ansi.reset, $ansi.bold_on, "corp holder.", $ansi.reset, $ansi.green, " B ", $ansi.reset, $ansi.bold_on, "bot. ", $ansi.reset);
notify(player, leg);
endif
if (do_fullcount)
if (admincount)
msg = tostr(fullcount, " players and ", admincount, " admins connected (total: ", fullcount + admincount, ".)");
else
msg = tostr(fullcount, " players and admins connected.");
endif
msg = (colors["footer"] + $su:right(msg, -79)) + $ansi.reset;
notify(player, msg);
if ((fullcount + admincount) >= $login.highest_connected_players)
msg = (colors["footer"] + $su:right("A new record!", -79)) + $ansi.reset;
notify(player, msg);
endif
else
msg = tostr(count, " players.");
msg = (colors["footer"] + $su:right(msg, -79)) + $ansi.reset;
notify(player, msg);
endif

testwho testcwho

Spec any any anyFlags rxdOwner #361Definer #318

Referenced by

none

Source

return this:(verb[5..$])(@args);

corpwh*o

Spec any any anyFlags rxdOwner #361Definer #318

Referenced by

none

Source

return this:cwho(@args);