Posing Feature #310

pose_ex

Spec this none thisFlags rxdOwner #361Definer #310

Referenced by

• #310:.* line 3: this:pose_ex

Source

"This is actually used as .* or pose.  The above name is coz I frigged it to be callable with strings, and I have added .* and pose to do so.";
"Enter your pose as if you were typing in a first-person voice.";
"-- Pose recognises the following:";
"Names    -- Exact matches on the aliases of gendered objects in the room.";
"Pronouns -- Pronouns will match for the last player mentioned.";
"Addition verbs you wish conjugated to your gender should be prefixed with a colon.";
"-- For example:";
"   .kick chuck, bruising him on his shin as I :laugh madly.";
"You   -> You kick chuck, bruising him on his shin as you laugh madly.";
"Chuck -> Quinn kicks you, bruising you on your shin as he laughs madly.";
"Room  -> Quinn kicks Chuck, bruising him on his shin as he laughs madly.";
"  '.kick chuck, bruising chuck on chuck's shin...' would produce the same, except 'him' would translate to 'chuck', since a literal name was specified.";
"As evident above, antecedent identification is rather simple right now.";
"-- Special subs:";
"/all /everybody /everyone -> A list of every $player in the room.";
"Many thanks to Quinn for the original development of this code.";
"I have made some minor fixes to allow better use by my code on here.";
verb = args[1];
args = listdelete(args, 1);
if (args)
argstr = args[1];
args = $string_utils:words(argstr);
endif
if ((l = length(verb)) < 2)
player:tell("The syntax \"", verb, argstr ? " " + argstr | "", "\" is invalid.");
return;
elseif ((verb == "pose") && args)
verb = "." + args[1];
args = listdelete(args, 1);
else
verb = verb[2..l];
endif
overb = $gender_utils:get_conj("/" + verb, player);
here = player.location;
if (!args)
punk = match(verb, "[a-z0-9]$") ? "." | "";
player:tell("You ", $su:escape(verb + punk));
here:announce(player:name(), " ", $su:escape(overb + punk));
return;
endif
la = length(args);
if (pos = (("/all" in args) || ("/everyone" in args)) || ("/everybody" in args))
contents = setremove(this:class_list(here:contents(), $player), player);
titles = $string_utils:words($string_utils:title_list(contents));
if (pos == 1)
args = (pos == la) ? titles | {@titles, @verb[pos + 1..la]};
elseif (pos == la)
args = {@verb[1..pos - 1], @titles};
else
args = {@verb[1..pos - 1], @titles, @verb[pos + 1..la]};
endif
endif
parsed = this.pose_feature:parse_pose_args(@this:args_with_quotes(args));
"messages = this.pose_feature:build_messages(@parsed);";
"msg = messages[1];";
"omsg = messages[2];";
msg = omsg = "";
for w in (msglist = parsed[2])
if (w == "(ps)")
msg = tostr(msg, "you", " ");
omsg = tostr(omsg, player.ps, " ");
elseif (w == "(pr)")
msg = tostr(msg, "yourself", " ");
omsg = tostr(omsg, player.pr, " ");
elseif (w == "(po)")
msg = tostr(msg, "you", " ");
omsg = tostr(omsg, player.po, " ");
elseif (((lw = length(w)) > 1) && (w[1] == ":"))
aux_verb = w[2..lw];
msg = tostr(msg, aux_verb, " ");
if (aux_verb[lw - 1] == ",")
omsg = tostr(omsg, $gender_utils:get_conj("/" + aux_verb[1..lw - 2], player), ", ");
else
omsg = tostr(omsg, $gender_utils:get_conj("/" + aux_verb, player), " ");
endif
else
msg = tostr(msg, w, " ");
omsg = tostr(omsg, w, " ");
endif
endfor
msg = tostr("You ", verb, " ", $su:escape(msg[1..length(msg) - 1]));
omsg = tostr(player:title(), " ", $su:escape((overb + " ") + omsg[1..length(omsg) - 1]));
msg = tostr(msg, match(msg, "[a-z0-9)]$") ? "." | "");
omsg = tostr(omsg, match(omsg, "[a-z0-9)]$") ? "." | "");
subs = {};
for dp in [1..length(involved = parsed[1])]
dude = involved[dp];
subs = {@subs, {tostr("(", dp, ")"), dude:title()}, {tostr("(", dp, "s)"), dude.ps}, {tostr("(", dp, "p)"), dude.pp}, {tostr("(", dp, "o)"), dude.po}, {tostr("(", dp, "r)"), dude.pr}, {"ands", "and"}};
endfor
already_told_player = 0;
for dp in [1..length(involved)]
dude = involved[dp];
msg_subs = subs;
spa = ((dp - 1) * 5) + 1;
spb = ((dp - 1) * 5) + 5;
msg_subs[spa..spb] = {{tostr("(", dp, ")"), "you"}, {tostr("(", dp, "s)"), "you"}, {tostr("(", dp, "p)"), "your"}, {tostr("(", dp, "o)"), "you"}, {tostr("(", dp, "r)"), "yourself"}};
if (dude == player)
tell = $string_utils:substitute(msg, msg_subs);
already_told_player = 1;
else
tell = $string_utils:substitute(omsg, msg_subs);
endif
"ugly little workaround for possessives without antecedents";
dude:tell(strsub(strsub(tell, "you's", "your"), "you'", "your"));
endfor
if (!already_told_player)
player:tell($string_utils:substitute(msg, subs));
endif
player.location:announce_all_but(setadd(involved, player), $su:substitute(omsg, subs));

.*

Spec any any anyFlags rxdOwner #361Definer #310

Referenced by

none

Source

"This is just a pass-through verb for convenient use.";
"Its usage is documented under pose_ex.";
this:pose_ex(verb, argstr);

parse_pose_args

Spec this none thisFlags rxdOwner #361Definer #310

Referenced by

none

Source

":parse_pose_args(cmd-line-args)";
message = args = args || $string_utils:words(argstr);
vi = player in (involved = {player});
pron_props = {"s", "p", "o", "r"};
last_pronouns = {player.ps, player.pp, player.po, player.pr};
all_preps = $code_utils._all_preps;
for wp in [1..length(args)]
ls = length(string = args[wp]);
match = $string_utils:strip_chars(string, "!.,;:?");
poss = 0;
if (((!string) || (string[1] == ":")) || (string[1] == "."))
"...don't bother...";
elseif (match == "me")
message[wp] = "(po)";
elseif (match == "myself")
message[wp] = "(pr)";
elseif (match == "I")
message[wp] = "(ps)";
elseif (p = match in last_pronouns)
"pronoun referring to a matched character";
message[wp] = tostr("(", tostr(vi), pron_props[p], ")");
elseif ((m = match(match, "%(%w+%)s$")) && (p = substitute("%1", m) in last_pronouns))
"reflexive possessive referring to a matched character";
"ie: \"That's his.\" should parse to \"That's yours.\" for `him'.";
message[wp] = tostr("(", tostr(vi), pron_props[p], ")s");
else
if (poss = string in {"my", "mine"})
victim = player;
elseif (poss = $match_utils:parse_possessive_reference(match))
victim = this:match_object_exactly(poss[1]);
else
victim = this:match_object_exactly(match);
endif
if (this:is_character(victim))
ovi = victim in involved;
vi = victim in (involved = setadd(involved, victim));
if (!poss)
"It isn't possessive.";
word = tostr("(", vi, ")");
elseif (string == "mine")
"mine -> yours, hers, etc";
"grr.. this'll screw up outwardly for pps ending in 's'";
word = tostr("(", vi, "p)", "s" || (match(victim.pp, "s$") ? "" | "s"));
elseif (ovi || (typeof(poss) != LIST))
"The possessive pronoun has a clear antecedent.";
word = tostr("(", vi, "p)");
else
"Antecedent was found by parsing for a possessive.";
"Use the victim's name, suffixed with possessive punctuation.";
word = tostr("(", vi, ")", strsub(match, poss[1], ""));
endif
punctuation = (m = match(string, "%(%W+%)$")) ? substitute("%1", m) | "";
message[wp] = word + punctuation;
last_pronouns = {victim.ps, victim.pp, victim.po, victim.pr};
endif
endif
endfor
return {involved, message};

args_with_quotes

Spec this none thisFlags rxdOwner #361Definer #310

Referenced by

• #310:pose_ex line 53: this:args_with_quotes

Source

":args_with_quotes(cmdline_args)";
"Return the arglist with argstr quotes intact.";
oargstr = argstr;
oargs = nargs = args[1];
while (m = match(oargstr, "\"%([^\"]*%)\""))
if ((i = substitute("%1", m) in oargs) && (!match(oargs[i], "^\".*\"$")))
nargs[i] = tostr("\"", oargs[i], "\"");
endif
oargstr = oargstr[1..m[3][1][1] - 2] + oargstr[m[3][1][2] + 2..length(oargstr)];
endwhile
return nargs;

match_object_exactly

Spec this none thisFlags rxdOwner #361Definer #310

Referenced by

• #310:parse_pose_args line 30: this:match_object_exactly
• #310:parse_pose_args line 32: this:match_object_exactly

Source

":social_match(string)";
"Matches on room's occupants, accepting exact matches on an alias only.";
string = args[1];
where = (length(args) > 1) ? args[2] | player.location;
for dude in (where:contents())
if (string in `dude.aliases ! E_PERM => {}')
return dude;
endif
endfor
return $failed_match;

match_object_exactly

Spec none none noneFlags rxdOwner #361Definer #310

Referenced by

none

Source

No program (verb defined but unprogrammed).

is_char*acter

Spec this none thisFlags rxdOwner #361Definer #310

Referenced by

none

Source

":is_char(OBJ what) => true if we should bother speaking to `what'";
return valid(what = args[1]) && (is_player(what) || $object_utils:isa(what, #7680));